source: NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/TOP/trcini.F90 @ 10963

Last change on this file since 10963 was 10963, checked in by acc, 19 months ago

2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps : Convert TOP routines in top-level TOP directory and all knock on effects of these conversions. SETTE tested.

  • Property svn:keywords set to Id
File size: 13.9 KB
Line 
1MODULE trcini
2   !!======================================================================
3   !!                         ***  MODULE trcini  ***
4   !! TOP :   Manage the passive tracer initialization
5   !!======================================================================
6   !! History :   -   ! 1991-03 (O. Marti)  original code
7   !!            1.0  ! 2005-03 (O. Aumont, A. El Moussaoui) F90
8   !!            2.0  ! 2005-10 (C. Ethe, G. Madec) revised architecture
9   !!            4.0  ! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
10   !!----------------------------------------------------------------------
11#if defined key_top
12   !!----------------------------------------------------------------------
13   !!   'key_top'                                                TOP models
14   !!----------------------------------------------------------------------
15   !!   trc_init  :   Initialization for passive tracer
16   !!   top_alloc :   allocate the TOP arrays
17   !!----------------------------------------------------------------------
18   USE oce_trc         ! shared variables between ocean and passive tracers
19   USE trc             ! passive tracers common variables
20   USE trcnam          ! Namelist read
21   USE daymod          ! calendar manager
22   USE prtctl_trc      ! Print control passive tracers (prt_ctl_trc_init routine)
23   USE trcsub          ! variables to substep passive tracers
24   USE trcrst
25   USE lib_mpp         ! distribued memory computing library
26   USE trcice          ! tracers in sea ice
27   USE trcbc,   only : trc_bc_ini ! generalized Boundary Conditions
28   USE trcstp          ! for time level indices (to be initialised)
29 
30   IMPLICIT NONE
31   PRIVATE
32   
33   PUBLIC   trc_init   ! called by opa
34
35   !!----------------------------------------------------------------------
36   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
37   !! $Id$
38   !! Software governed by the CeCILL license (see ./LICENSE)
39   !!----------------------------------------------------------------------
40CONTAINS
41   
42   SUBROUTINE trc_init( Kbb, Kmm, Kaa )
43      !!---------------------------------------------------------------------
44      !!                     ***  ROUTINE trc_init  ***
45      !!
46      !! ** Purpose :   Initialization of the passive tracer fields
47      !!
48      !! ** Method  : - read namelist
49      !!              - control the consistancy
50      !!              - compute specific initialisations
51      !!              - set initial tracer fields (either read restart
52      !!                or read data or analytical formulation
53      !!---------------------------------------------------------------------
54      !! Time level indices only required for call to update_pointers_trc
55      !! To be removed after IMMERSE development finished.
56      INTEGER, INTENT( in ) :: Kbb, Kmm, Kaa ! time level indices
57      !
58      IF( ln_timing )   CALL timing_start('trc_init')
59      !
60      IF(lwp) WRITE(numout,*)
61      IF(lwp) WRITE(numout,*) 'trc_init : initial set up of the passive tracers'
62      IF(lwp) WRITE(numout,*) '~~~~~~~~'
63      !
64      CALL trc_ini_ctl   ! control
65      CALL trc_nam       ! read passive tracers namelists
66      CALL top_alloc()   ! allocate TOP arrays
67
68      ! Initialisation of temporary pointers (to be deleted after development finished)
69      CALL update_pointers_trc( Kbb, Kmm, Kaa )
70      !
71      IF(.NOT.ln_trcdta )   ln_trc_ini(:) = .FALSE.
72      !
73      IF(lwp) WRITE(numout,*)
74      IF( ln_rsttr .AND. .NOT. l_offline ) CALL trc_rst_cal( nit000, 'READ' )   ! calendar
75      IF(lwp) WRITE(numout,*)
76      !
77      CALL trc_ini_sms   ! SMS
78      CALL trc_ini_trp   ! passive tracers transport
79      CALL trc_ice_ini   ! Tracers in sea ice
80      !
81      IF( lwm .AND. sn_cfctl%l_trcstat ) THEN
82         CALL ctl_opn( numstr, 'tracer.stat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp , narea )
83      ENDIF
84      !
85      CALL trc_ini_state( Kbb, Kmm, Kaa )  !  passive tracers initialisation : from a restart or from clim
86      IF( nn_dttrc /= 1 ) &
87      CALL trc_sub_ini( Kmm )    ! Initialize variables for substepping passive tracers
88      !
89      CALL trc_ini_inv( Kmm )    ! Inventories
90      !
91      IF( ln_timing )   CALL timing_stop('trc_init')
92      !
93   END SUBROUTINE trc_init
94
95
96   SUBROUTINE trc_ini_ctl
97      !!----------------------------------------------------------------------
98      !!                     ***  ROUTINE trc_ini_ctl  ***
99      !! ** Purpose :        Control  + ocean volume
100      !!----------------------------------------------------------------------
101      INTEGER ::   jk    ! dummy loop indices
102      !
103      ! Define logical parameter ton control dirunal cycle in TOP
104      l_trcdm2dc = ln_dm2dc .OR. ( ln_cpl .AND. ncpl_qsr_freq /= 1 )
105      l_trcdm2dc = l_trcdm2dc  .AND. .NOT. l_offline
106      IF( l_trcdm2dc .AND. lwp )   CALL ctl_warn( 'Coupling with passive tracers and used of diurnal cycle.',   &
107         &                           'Computation of a daily mean shortwave for some biogeochemical models ' )
108      !
109   END SUBROUTINE trc_ini_ctl
110
111
112   SUBROUTINE trc_ini_inv( Kmm )
113      !!----------------------------------------------------------------------
114      !!                     ***  ROUTINE trc_ini_stat  ***
115      !! ** Purpose :      passive tracers inventories at initialsation phase
116      !!----------------------------------------------------------------------
117      INTEGER, INTENT(in) ::   Kmm    ! time level index
118      INTEGER             ::  jk, jn  ! dummy loop indices
119      CHARACTER (len=25) :: charout
120      !!----------------------------------------------------------------------
121      !
122      IF(lwp) WRITE(numout,*)
123      IF(lwp) WRITE(numout,*) 'trc_ini_inv : initial passive tracers inventories'
124      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
125      !
126      !                          ! masked grid volume
127      DO jk = 1, jpk
128         cvol(:,:,jk) = e1e2t(:,:) * e3t(:,:,jk,Kmm) * tmask(:,:,jk)
129      END DO
130      !                          ! total volume of the ocean
131      areatot = glob_sum( 'trcini', cvol(:,:,:) )
132      !
133      trai(:) = 0._wp            ! initial content of all tracers
134      DO jn = 1, jptra
135         trai(jn) = trai(jn) + glob_sum( 'trcini', tr(:,:,:,jn,Kmm) * cvol(:,:,:)   )
136      END DO
137
138      IF(lwp) THEN               ! control print
139         WRITE(numout,*)
140         WRITE(numout,*) '   ==>>>   Total number of passive tracer jptra = ', jptra
141         WRITE(numout,*) '           Total volume of ocean                = ', areatot
142         WRITE(numout,*) '           Total inital content of all tracers '
143         WRITE(numout,*)
144         DO jn = 1, jptra
145            WRITE(numout,9000) jn, TRIM( ctrcnm(jn) ), trai(jn)
146         ENDDO
147         WRITE(numout,*)
148      ENDIF
149      IF(lwp) WRITE(numout,*)
150      IF(ln_ctl) THEN            ! print mean trends (used for debugging)
151         CALL prt_ctl_trc_init
152         WRITE(charout, FMT="('ini ')")
153         CALL prt_ctl_trc_info( charout )
154         CALL prt_ctl_trc( tab4d=tr(:,:,:,:,Kmm), mask=tmask, clinfo=ctrcnm )
155      ENDIF
1569000  FORMAT('      tracer nb : ',i2,'      name :',a10,'      initial content :',e18.10)
157      !
158   END SUBROUTINE trc_ini_inv
159
160
161   SUBROUTINE trc_ini_sms
162      !!----------------------------------------------------------------------
163      !!                     ***  ROUTINE trc_ini_sms  ***
164      !! ** Purpose :   SMS initialisation
165      !!----------------------------------------------------------------------
166      USE trcini_pisces  ! PISCES   initialisation
167      USE trcini_cfc     ! CFC      initialisation
168      USE trcini_c14     ! C14  initialisation
169      USE trcini_age     ! age initialisation
170      USE trcini_my_trc  ! MY_TRC   initialisation
171      !
172      INTEGER :: jn
173      !!----------------------------------------------------------------------
174      !
175      ! Pass sn_tracer fields to specialized arrays
176      DO jn = 1, jp_bgc
177         ctrcnm    (jn) = TRIM( sn_tracer(jn)%clsname )
178         ctrcln    (jn) = TRIM( sn_tracer(jn)%cllname )
179         ctrcun    (jn) = TRIM( sn_tracer(jn)%clunit  )
180         ln_trc_ini(jn) =       sn_tracer(jn)%llinit
181         ln_trc_sbc(jn) =       sn_tracer(jn)%llsbc
182         ln_trc_cbc(jn) =       sn_tracer(jn)%llcbc
183         ln_trc_obc(jn) =       sn_tracer(jn)%llobc
184      END DO
185      !   
186      IF( ln_pisces      )   CALL trc_ini_pisces     !  PISCES model
187      IF( ln_my_trc      )   CALL trc_ini_my_trc     !  MY_TRC model
188      IF( ll_cfc         )   CALL trc_ini_cfc        !  CFC's
189      IF( ln_c14         )   CALL trc_ini_c14        !  C14 model
190      IF( ln_age         )   CALL trc_ini_age        !  AGE
191      IF( .NOT.ln_pisces ) ALLOCATE( profsed(2) )
192      !
193      IF(lwp) THEN                   ! control print
194         WRITE(numout,*)
195         WRITE(numout,*) 'trc_init_sms : Summary for selected passive tracers'
196         WRITE(numout,*) '~~~~~~~~~~~~'
197         WRITE(numout,*) '    ID     NAME     INI  SBC  CBC  OBC'
198         DO jn = 1, jptra
199            WRITE(numout,9001) jn, TRIM(ctrcnm(jn)), ln_trc_ini(jn), ln_trc_sbc(jn),ln_trc_cbc(jn),ln_trc_obc(jn)
200         END DO
201      ENDIF
2029001  FORMAT(3x,i3,1x,a10,3x,l2,3x,l2,3x,l2,3x,l2)
203      !
204   END SUBROUTINE trc_ini_sms
205
206
207   SUBROUTINE trc_ini_trp
208      !!----------------------------------------------------------------------
209      !!                     ***  ROUTINE trc_ini_trp  ***
210      !!
211      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
212      !!----------------------------------------------------------------------
213      USE trcdmp , ONLY:  trc_dmp_ini
214      USE trcadv , ONLY:  trc_adv_ini
215      USE trcldf , ONLY:  trc_ldf_ini
216      USE trcrad , ONLY:  trc_rad_ini
217      USE trcsink, ONLY:  trc_sink_ini
218      !
219      INTEGER :: ierr
220      !!----------------------------------------------------------------------
221      !
222      IF( ln_trcdmp )  CALL  trc_dmp_ini          ! damping
223                       CALL  trc_adv_ini          ! advection
224                       CALL  trc_ldf_ini          ! lateral diffusion
225                       !                          ! vertical diffusion: always implicit time stepping scheme
226                       CALL  trc_rad_ini          ! positivity of passive tracers
227                       CALL  trc_sink_ini         ! Vertical sedimentation of particles
228      !
229   END SUBROUTINE trc_ini_trp
230
231
232   SUBROUTINE trc_ini_state( Kbb, Kmm, Kaa )
233      !!----------------------------------------------------------------------
234      !!                     ***  ROUTINE trc_ini_state ***
235      !! ** Purpose :          Initialisation of passive tracer concentration
236      !!----------------------------------------------------------------------
237      USE zpshde          ! partial step: hor. derivative   (zps_hde routine)
238      USE trcrst          ! passive tracers restart
239      USE trcdta          ! initialisation from files
240      !
241      INTEGER, INTENT(in) :: Kbb, Kmm, Kaa   ! time level index
242      INTEGER             :: jn, jl          ! dummy loop indices
243      !!----------------------------------------------------------------------
244      !
245      IF( ln_trcdta )   CALL trc_dta_ini( jptra )           ! set initial tracers values
246      !
247      IF( ln_my_trc )   CALL trc_bc_ini ( jptra, Kmm )      ! set tracers Boundary Conditions
248      !
249      !
250      IF( ln_rsttr ) THEN              ! restart from a file
251        !
252        CALL trc_rst_read( Kbb, Kmm )
253        !
254      ELSE                             ! Initialisation of tracer from a file that may also be used for damping
255!!gm BUG ?   if damping and restart, what's happening ?
256        IF( ln_trcdta .AND. nb_trcdta > 0 ) THEN
257            ! update passive tracers arrays with input data read from file
258            DO jn = 1, jptra
259               IF( ln_trc_ini(jn) ) THEN
260                  jl = n_trc_index(jn) 
261                  CALL trc_dta( nit000, Kmm, sf_trcdta(jl), rf_trfac(jl), tr(:,:,:,jn,Kmm) )
262                  !
263                  ! deallocate data structure if data are not used for damping
264                  IF( .NOT.ln_trcdmp .AND. .NOT.ln_trcdmp_clo ) THEN
265                     IF(lwp) WRITE(numout,*) 'trc_ini_state: deallocate data arrays as they are only used to initialize the run'
266                                                  DEALLOCATE( sf_trcdta(jl)%fnow )
267                     IF( sf_trcdta(jl)%ln_tint )  DEALLOCATE( sf_trcdta(jl)%fdta )
268                     !
269                  ENDIF
270               ENDIF
271            END DO
272            !
273        ENDIF
274        !
275        tr(:,:,:,:,Kbb) = tr(:,:,:,:,Kmm)
276        !
277      ENDIF
278      !
279      tr(:,:,:,:,Kaa) = 0._wp
280      !                                                         ! Partial top/bottom cell: GRADh(tr(Kmm))
281   END SUBROUTINE trc_ini_state
282
283
284   SUBROUTINE top_alloc
285      !!----------------------------------------------------------------------
286      !!                     ***  ROUTINE top_alloc  ***
287      !!
288      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
289      !!----------------------------------------------------------------------
290      USE trc           , ONLY:   trc_alloc
291      USE trdtrc_oce    , ONLY:   trd_trc_oce_alloc
292#if defined key_trdmxl_trc 
293      USE trdmxl_trc    , ONLY:   trd_mxl_trc_alloc
294#endif
295      !
296      INTEGER ::   ierr   ! local integer
297      !!----------------------------------------------------------------------
298      !
299      ierr =        trc_alloc()
300      ierr = ierr + trd_trc_oce_alloc()
301#if defined key_trdmxl_trc 
302      ierr = ierr + trd_mxl_trc_alloc()
303#endif
304      !
305      CALL mpp_sum( 'trcini', ierr )
306      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'top_alloc : unable to allocate standard ocean arrays' )
307      !
308   END SUBROUTINE top_alloc
309
310#else
311   !!----------------------------------------------------------------------
312   !!  Empty module :                                     No passive tracer
313   !!----------------------------------------------------------------------
314CONTAINS
315   SUBROUTINE trc_init                      ! Dummy routine   
316   END SUBROUTINE trc_init
317#endif
318
319   !!======================================================================
320END MODULE trcini
Note: See TracBrowser for help on using the repository browser.