source: NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/TOP/trcini.F90 @ 11527

Last change on this file since 11527 was 11527, checked in by acc, 18 months ago

Branch 2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps. Removal of TOP-specific time indices (Nnn_trc etc.). This completes the removal of the trc sub-timestepping option and dynamics, active tracers and passive tracers must now have common time-steps. Note time-filtering for passive tracers is done in trc_trp (trc_atf) but the (now shared) time indices are not swapped until after calls to tra_atf, dyn_atf and ssh_atf in step. Calls to trc routines after trc_atf have had their time-index arguments adjusted accordingly. These changes have been fully SETTE-tested.

  • Property svn:keywords set to Id
File size: 13.5 KB
Line 
1MODULE trcini
2   !!======================================================================
3   !!                         ***  MODULE trcini  ***
4   !! TOP :   Manage the passive tracer initialization
5   !!======================================================================
6   !! History :   -   ! 1991-03 (O. Marti)  original code
7   !!            1.0  ! 2005-03 (O. Aumont, A. El Moussaoui) F90
8   !!            2.0  ! 2005-10 (C. Ethe, G. Madec) revised architecture
9   !!            4.0  ! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
10   !!----------------------------------------------------------------------
11#if defined key_top
12   !!----------------------------------------------------------------------
13   !!   'key_top'                                                TOP models
14   !!----------------------------------------------------------------------
15   !!   trc_init  :   Initialization for passive tracer
16   !!   top_alloc :   allocate the TOP arrays
17   !!----------------------------------------------------------------------
18   USE oce_trc         ! shared variables between ocean and passive tracers
19   USE trc             ! passive tracers common variables
20   USE trcnam          ! Namelist read
21   USE daymod          ! calendar manager
22   USE prtctl_trc      ! Print control passive tracers (prt_ctl_trc_init routine)
23   USE trcrst
24   USE lib_mpp         ! distribued memory computing library
25   USE trcice          ! tracers in sea ice
26   USE trcbc,   only : trc_bc_ini ! generalized Boundary Conditions
27   USE trcstp          ! for time level indices (to be initialised)
28 
29   IMPLICIT NONE
30   PRIVATE
31   
32   PUBLIC   trc_init   ! called by opa
33
34   !!----------------------------------------------------------------------
35   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
36   !! $Id$
37   !! Software governed by the CeCILL license (see ./LICENSE)
38   !!----------------------------------------------------------------------
39CONTAINS
40   
41   SUBROUTINE trc_init
42      !!---------------------------------------------------------------------
43      !!                     ***  ROUTINE trc_init  ***
44      !!
45      !! ** Purpose :   Initialization of the passive tracer fields
46      !!
47      !! ** Method  : - read namelist
48      !!              - control the consistancy
49      !!              - compute specific initialisations
50      !!              - set initial tracer fields (either read restart
51      !!                or read data or analytical formulation
52      !!---------------------------------------------------------------------
53      !
54      IF( ln_timing )   CALL timing_start('trc_init')
55      !
56      IF(lwp) WRITE(numout,*)
57      IF(lwp) WRITE(numout,*) 'trc_init : initial set up of the passive tracers'
58      IF(lwp) WRITE(numout,*) '~~~~~~~~'
59      !
60      CALL trc_ini_ctl   ! control
61      CALL trc_nam       ! read passive tracers namelists
62      CALL top_alloc()   ! allocate TOP arrays
63
64      !
65      IF(.NOT.ln_trcdta )   ln_trc_ini(:) = .FALSE.
66      !
67      IF(lwp) WRITE(numout,*)
68      IF( ln_rsttr .AND. .NOT. l_offline ) CALL trc_rst_cal( nit000, 'READ' )   ! calendar
69      IF(lwp) WRITE(numout,*)
70      !
71      CALL trc_ini_sms( Nnn )   ! SMS
72      CALL trc_ini_trp          ! passive tracers transport
73      CALL trc_ice_ini          ! Tracers in sea ice
74      !
75      IF( lwm .AND. sn_cfctl%l_trcstat ) THEN
76         CALL ctl_opn( numstr, 'tracer.stat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp , narea )
77      ENDIF
78      !
79      CALL trc_ini_state( Nbb, Nnn, Naa )  !  passive tracers initialisation : from a restart or from clim
80      !
81      CALL trc_ini_inv( Nnn )              ! Inventories
82      !
83      IF( ln_timing )   CALL timing_stop('trc_init')
84      !
85   END SUBROUTINE trc_init
86
87
88   SUBROUTINE trc_ini_ctl
89      !!----------------------------------------------------------------------
90      !!                     ***  ROUTINE trc_ini_ctl  ***
91      !! ** Purpose :        Control  + ocean volume
92      !!----------------------------------------------------------------------
93      INTEGER ::   jk    ! dummy loop indices
94      !
95      ! Define logical parameter ton control dirunal cycle in TOP
96      l_trcdm2dc = ln_dm2dc .OR. ( ln_cpl .AND. ncpl_qsr_freq /= 1 )
97      l_trcdm2dc = l_trcdm2dc  .AND. .NOT. l_offline
98      IF( l_trcdm2dc .AND. lwp )   CALL ctl_warn( 'Coupling with passive tracers and used of diurnal cycle.',   &
99         &                           'Computation of a daily mean shortwave for some biogeochemical models ' )
100      !
101   END SUBROUTINE trc_ini_ctl
102
103
104   SUBROUTINE trc_ini_inv( Kmm )
105      !!----------------------------------------------------------------------
106      !!                     ***  ROUTINE trc_ini_stat  ***
107      !! ** Purpose :      passive tracers inventories at initialsation phase
108      !!----------------------------------------------------------------------
109      INTEGER, INTENT(in) ::   Kmm    ! time level index
110      INTEGER             ::  jk, jn  ! dummy loop indices
111      CHARACTER (len=25) :: charout
112      !!----------------------------------------------------------------------
113      !
114      IF(lwp) WRITE(numout,*)
115      IF(lwp) WRITE(numout,*) 'trc_ini_inv : initial passive tracers inventories'
116      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
117      !
118      !                          ! masked grid volume
119      DO jk = 1, jpk
120         cvol(:,:,jk) = e1e2t(:,:) * e3t(:,:,jk,Kmm) * tmask(:,:,jk)
121      END DO
122      !                          ! total volume of the ocean
123      areatot = glob_sum( 'trcini', cvol(:,:,:) )
124      !
125      trai(:) = 0._wp            ! initial content of all tracers
126      DO jn = 1, jptra
127         trai(jn) = trai(jn) + glob_sum( 'trcini', tr(:,:,:,jn,Kmm) * cvol(:,:,:)   )
128      END DO
129
130      IF(lwp) THEN               ! control print
131         WRITE(numout,*)
132         WRITE(numout,*) '   ==>>>   Total number of passive tracer jptra = ', jptra
133         WRITE(numout,*) '           Total volume of ocean                = ', areatot
134         WRITE(numout,*) '           Total inital content of all tracers '
135         WRITE(numout,*)
136         DO jn = 1, jptra
137            WRITE(numout,9000) jn, TRIM( ctrcnm(jn) ), trai(jn)
138         ENDDO
139         WRITE(numout,*)
140      ENDIF
141      IF(lwp) WRITE(numout,*)
142      IF(ln_ctl) THEN            ! print mean trends (used for debugging)
143         CALL prt_ctl_trc_init
144         WRITE(charout, FMT="('ini ')")
145         CALL prt_ctl_trc_info( charout )
146         CALL prt_ctl_trc( tab4d=tr(:,:,:,:,Kmm), mask=tmask, clinfo=ctrcnm )
147      ENDIF
1489000  FORMAT('      tracer nb : ',i2,'      name :',a10,'      initial content :',e18.10)
149      !
150   END SUBROUTINE trc_ini_inv
151
152
153   SUBROUTINE trc_ini_sms( Kmm )
154      !!----------------------------------------------------------------------
155      !!                     ***  ROUTINE trc_ini_sms  ***
156      !! ** Purpose :   SMS initialisation
157      !!----------------------------------------------------------------------
158      USE trcini_pisces  ! PISCES   initialisation
159      USE trcini_cfc     ! CFC      initialisation
160      USE trcini_c14     ! C14  initialisation
161      USE trcini_age     ! age initialisation
162      USE trcini_my_trc  ! MY_TRC   initialisation
163      !
164      INTEGER, INTENT(in) ::   Kmm ! time level indices
165      INTEGER :: jn
166      !!----------------------------------------------------------------------
167      !
168      ! Pass sn_tracer fields to specialized arrays
169      DO jn = 1, jp_bgc
170         ctrcnm    (jn) = TRIM( sn_tracer(jn)%clsname )
171         ctrcln    (jn) = TRIM( sn_tracer(jn)%cllname )
172         ctrcun    (jn) = TRIM( sn_tracer(jn)%clunit  )
173         ln_trc_ini(jn) =       sn_tracer(jn)%llinit
174         ln_trc_sbc(jn) =       sn_tracer(jn)%llsbc
175         ln_trc_cbc(jn) =       sn_tracer(jn)%llcbc
176         ln_trc_obc(jn) =       sn_tracer(jn)%llobc
177      END DO
178      !   
179      IF( ln_pisces      )   CALL trc_ini_pisces( Kmm )     !  PISCES model
180      IF( ln_my_trc      )   CALL trc_ini_my_trc( Kmm )     !  MY_TRC model
181      IF( ll_cfc         )   CALL trc_ini_cfc   ( Kmm )     !  CFC's
182      IF( ln_c14         )   CALL trc_ini_c14   ( Kmm )     !  C14 model
183      IF( ln_age         )   CALL trc_ini_age   ( Kmm )     !  AGE
184      IF( .NOT.ln_pisces ) ALLOCATE( profsed(2) )
185      !
186      IF(lwp) THEN                   ! control print
187         WRITE(numout,*)
188         WRITE(numout,*) 'trc_init_sms : Summary for selected passive tracers'
189         WRITE(numout,*) '~~~~~~~~~~~~'
190         WRITE(numout,*) '    ID     NAME     INI  SBC  CBC  OBC'
191         DO jn = 1, jptra
192            WRITE(numout,9001) jn, TRIM(ctrcnm(jn)), ln_trc_ini(jn), ln_trc_sbc(jn),ln_trc_cbc(jn),ln_trc_obc(jn)
193         END DO
194      ENDIF
1959001  FORMAT(3x,i3,1x,a10,3x,l2,3x,l2,3x,l2,3x,l2)
196      !
197   END SUBROUTINE trc_ini_sms
198
199
200   SUBROUTINE trc_ini_trp
201      !!----------------------------------------------------------------------
202      !!                     ***  ROUTINE trc_ini_trp  ***
203      !!
204      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
205      !!----------------------------------------------------------------------
206      USE trcdmp , ONLY:  trc_dmp_ini
207      USE trcadv , ONLY:  trc_adv_ini
208      USE trcldf , ONLY:  trc_ldf_ini
209      USE trcrad , ONLY:  trc_rad_ini
210      USE trcsink, ONLY:  trc_sink_ini
211      !
212      INTEGER :: ierr
213      !!----------------------------------------------------------------------
214      !
215      IF( ln_trcdmp )  CALL  trc_dmp_ini          ! damping
216                       CALL  trc_adv_ini          ! advection
217                       CALL  trc_ldf_ini          ! lateral diffusion
218                       !                          ! vertical diffusion: always implicit time stepping scheme
219                       CALL  trc_rad_ini          ! positivity of passive tracers
220                       CALL  trc_sink_ini         ! Vertical sedimentation of particles
221      !
222   END SUBROUTINE trc_ini_trp
223
224
225   SUBROUTINE trc_ini_state( Kbb, Kmm, Kaa )
226      !!----------------------------------------------------------------------
227      !!                     ***  ROUTINE trc_ini_state ***
228      !! ** Purpose :          Initialisation of passive tracer concentration
229      !!----------------------------------------------------------------------
230      USE zpshde          ! partial step: hor. derivative   (zps_hde routine)
231      USE trcrst          ! passive tracers restart
232      USE trcdta          ! initialisation from files
233      !
234      INTEGER, INTENT(in) :: Kbb, Kmm, Kaa   ! time level index
235      INTEGER             :: jn, jl          ! dummy loop indices
236      !!----------------------------------------------------------------------
237      !
238      IF( ln_trcdta )   CALL trc_dta_ini( jptra )           ! set initial tracers values
239      !
240      IF( ln_my_trc )   CALL trc_bc_ini ( jptra, Kmm )      ! set tracers Boundary Conditions
241      !
242      !
243      IF( ln_rsttr ) THEN              ! restart from a file
244        !
245        CALL trc_rst_read( Kbb, Kmm )
246        !
247      ELSE                             ! Initialisation of tracer from a file that may also be used for damping
248!!gm BUG ?   if damping and restart, what's happening ?
249        IF( ln_trcdta .AND. nb_trcdta > 0 ) THEN
250            ! update passive tracers arrays with input data read from file
251            DO jn = 1, jptra
252               IF( ln_trc_ini(jn) ) THEN
253                  jl = n_trc_index(jn) 
254                  CALL trc_dta( nit000, Kmm, sf_trcdta(jl), rf_trfac(jl), tr(:,:,:,jn,Kmm) )
255                  !
256                  ! deallocate data structure if data are not used for damping
257                  IF( .NOT.ln_trcdmp .AND. .NOT.ln_trcdmp_clo ) THEN
258                     IF(lwp) WRITE(numout,*) 'trc_ini_state: deallocate data arrays as they are only used to initialize the run'
259                                                  DEALLOCATE( sf_trcdta(jl)%fnow )
260                     IF( sf_trcdta(jl)%ln_tint )  DEALLOCATE( sf_trcdta(jl)%fdta )
261                     !
262                  ENDIF
263               ENDIF
264            END DO
265            !
266        ENDIF
267        !
268        tr(:,:,:,:,Kbb) = tr(:,:,:,:,Kmm)
269        !
270      ENDIF
271      !
272      tr(:,:,:,:,Kaa) = 0._wp
273      !                                                         ! Partial top/bottom cell: GRADh(tr(Kmm))
274   END SUBROUTINE trc_ini_state
275
276
277   SUBROUTINE top_alloc
278      !!----------------------------------------------------------------------
279      !!                     ***  ROUTINE top_alloc  ***
280      !!
281      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
282      !!----------------------------------------------------------------------
283      USE trc           , ONLY:   trc_alloc
284      USE trdtrc_oce    , ONLY:   trd_trc_oce_alloc
285#if defined key_trdmxl_trc 
286      USE trdmxl_trc    , ONLY:   trd_mxl_trc_alloc
287#endif
288      !
289      INTEGER ::   ierr   ! local integer
290      !!----------------------------------------------------------------------
291      !
292      ierr =        trc_alloc()
293      ierr = ierr + trd_trc_oce_alloc()
294#if defined key_trdmxl_trc 
295      ierr = ierr + trd_mxl_trc_alloc()
296#endif
297      !
298      CALL mpp_sum( 'trcini', ierr )
299      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'top_alloc : unable to allocate standard ocean arrays' )
300      !
301   END SUBROUTINE top_alloc
302
303#else
304   !!----------------------------------------------------------------------
305   !!  Empty module :                                     No passive tracer
306   !!----------------------------------------------------------------------
307CONTAINS
308   SUBROUTINE trc_init                      ! Dummy routine   
309   END SUBROUTINE trc_init
310#endif
311
312   !!======================================================================
313END MODULE trcini
Note: See TracBrowser for help on using the repository browser.