New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcssm.F90 in NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps_rewrite_time_filterswap/src/OCE/SBC – NEMO

source: NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps_rewrite_time_filterswap/src/OCE/SBC/sbcssm.F90 @ 11053

Last change on this file since 11053 was 11053, checked in by davestorkey, 5 years ago

2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps_rewrite_time_filterswap : Merge in latest changes from main branch and finish conversion of "h" variables. NB. This version still doesn't work!
  • Property svn:keywords set to Id
File size: 14.4 KB
Line 
1MODULE sbcssm
2   !!======================================================================
3   !!                       ***  MODULE  sbcssm  ***
4   !! Surface module :  provide time-mean ocean surface variables
5   !!======================================================================
6   !! History :  9.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.3  ! 2010-10  (C. Bricaud, G. Madec)  add the Patm forcing for sea-ice
8   !!            3.7  ! 2015-11  (G. Madec)  non linear free surface by default: e3t_m always computed
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   sbc_ssm       : calculate sea surface mean currents, temperature, 
13   !!                   and salinity over nn_fsbc time-step
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and tracers
16   USE dom_oce        ! ocean space and time domain
17   USE sbc_oce        ! surface boundary condition: ocean fields
18   USE sbcapr         ! surface boundary condition: atmospheric pressure
19   USE eosbn2         ! equation of state and related derivatives
20   USE traqsr, ONLY: ln_traqsr
21   !
22   USE in_out_manager ! I/O manager
23   USE prtctl         ! Print control
24   USE iom            ! IOM library
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   sbc_ssm        ! routine called by step.F90
30   PUBLIC   sbc_ssm_init   ! routine called by sbcmod.F90
31
32   LOGICAL, SAVE ::   l_ssm_mean = .FALSE.   ! keep track of whether means have been read from restart file
33   
34   !!----------------------------------------------------------------------
35   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
36   !! $Id$
37   !! Software governed by the CeCILL license (see ./LICENSE)
38   !!----------------------------------------------------------------------
39CONTAINS
40
41   SUBROUTINE sbc_ssm( kt, Kbb, Kmm )
42      !!---------------------------------------------------------------------
43      !!                     ***  ROUTINE sbc_oce  ***
44      !!                     
45      !! ** Purpose :   provide ocean surface variable to sea-surface boundary
46      !!                condition computation
47      !!               
48      !! ** Method  :   compute mean surface velocity (2 components at U and
49      !!      V-points) [m/s], temperature [Celsius] and salinity [psu] over
50      !!      the periode (kt - nn_fsbc) to kt
51      !!         Note that the inverse barometer ssh (i.e. ssh associated with Patm)
52      !!      is add to ssh_m when ln_apr_dyn = T. Required for sea-ice dynamics.
53      !!---------------------------------------------------------------------
54      INTEGER, INTENT(in) ::   kt   ! ocean time step
55      INTEGER, INTENT(in) ::   Kbb, Kmm   ! ocean time level indices
56      !
57      INTEGER  ::   ji, jj               ! loop index
58      REAL(wp) ::   zcoef, zf_sbc       ! local scalar
59      REAL(wp), DIMENSION(jpi,jpj,jpts) :: zts
60      !!---------------------------------------------------------------------
61      !
62      !                                        !* surface T-, U-, V- ocean level variables (T, S, depth, velocity)
63      DO jj = 1, jpj
64         DO ji = 1, jpi
65            zts(ji,jj,jp_tem) = ts(ji,jj,mikt(ji,jj),jp_tem,Kmm)
66            zts(ji,jj,jp_sal) = ts(ji,jj,mikt(ji,jj),jp_sal,Kmm)
67         END DO
68      END DO
69      !
70      IF( nn_fsbc == 1 ) THEN                             !   Instantaneous surface fields        !
71         !                                                ! ---------------------------------------- !
72         ssu_m(:,:) = uu(:,:,1,Kbb)
73         ssv_m(:,:) = vv(:,:,1,Kbb)
74         IF( l_useCT )  THEN    ;   sst_m(:,:) = eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
75         ELSE                    ;   sst_m(:,:) = zts(:,:,jp_tem)
76         ENDIF
77         sss_m(:,:) = zts(:,:,jp_sal)
78         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
79         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = ssh(:,:,Kmm) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
80         ELSE                    ;   ssh_m(:,:) = ssh(:,:,Kmm)
81         ENDIF
82         !
83         e3t_m(:,:) = e3t(:,:,1,Kmm)
84         !
85         frq_m(:,:) = fraqsr_1lev(:,:)
86         !
87      ELSE
88         !                                                ! ----------------------------------------------- !
89         IF( kt == nit000 .AND. .NOT. l_ssm_mean ) THEN   !   Initialisation: 1st time-step, no input means !
90            !                                             ! ----------------------------------------------- !
91            IF(lwp) WRITE(numout,*)
92            IF(lwp) WRITE(numout,*) 'sbc_ssm : mean fields initialised to instantaneous values'
93            IF(lwp) WRITE(numout,*) '~~~~~~~   '
94            zcoef = REAL( nn_fsbc - 1, wp )
95            ssu_m(:,:) = zcoef * uu(:,:,1,Kbb)
96            ssv_m(:,:) = zcoef * vv(:,:,1,Kbb)
97            IF( l_useCT )  THEN    ;   sst_m(:,:) = zcoef * eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
98            ELSE                    ;   sst_m(:,:) = zcoef * zts(:,:,jp_tem)
99            ENDIF
100            sss_m(:,:) = zcoef * zts(:,:,jp_sal)
101            !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
102            IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = zcoef * ( ssh(:,:,Kmm) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) ) )
103            ELSE                    ;   ssh_m(:,:) = zcoef *   ssh(:,:,Kmm)
104            ENDIF
105            !
106            e3t_m(:,:) = zcoef * e3t(:,:,1,Kmm)
107            !
108            frq_m(:,:) = zcoef * fraqsr_1lev(:,:)
109            !                                             ! ---------------------------------------- !
110         ELSEIF( MOD( kt - 2 , nn_fsbc ) == 0 ) THEN      !   Initialisation: New mean computation   !
111            !                                             ! ---------------------------------------- !
112            ssu_m(:,:) = 0._wp     ! reset to zero ocean mean sbc fields
113            ssv_m(:,:) = 0._wp
114            sst_m(:,:) = 0._wp
115            sss_m(:,:) = 0._wp
116            ssh_m(:,:) = 0._wp
117            e3t_m(:,:) = 0._wp
118            frq_m(:,:) = 0._wp
119         ENDIF
120         !                                                ! ---------------------------------------- !
121         !                                                !        Cumulate at each time step        !
122         !                                                ! ---------------------------------------- !
123         ssu_m(:,:) = ssu_m(:,:) + uu(:,:,1,Kbb)
124         ssv_m(:,:) = ssv_m(:,:) + vv(:,:,1,Kbb)
125         IF( l_useCT )  THEN     ;   sst_m(:,:) = sst_m(:,:) + eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
126         ELSE                    ;   sst_m(:,:) = sst_m(:,:) + zts(:,:,jp_tem)
127         ENDIF
128         sss_m(:,:) = sss_m(:,:) + zts(:,:,jp_sal)
129         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
130         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = ssh_m(:,:) + ssh(:,:,Kmm) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
131         ELSE                    ;   ssh_m(:,:) = ssh_m(:,:) + ssh(:,:,Kmm)
132         ENDIF
133         !
134         e3t_m(:,:) = e3t_m(:,:) + e3t(:,:,1,Kmm)
135         !
136         frq_m(:,:) = frq_m(:,:) + fraqsr_1lev(:,:)
137
138         !                                                ! ---------------------------------------- !
139         IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
140            !                                             ! ---------------------------------------- !
141            zcoef = 1. / REAL( nn_fsbc, wp )
142            sst_m(:,:) = sst_m(:,:) * zcoef     ! mean SST             [Celsius]
143            sss_m(:,:) = sss_m(:,:) * zcoef     ! mean SSS             [psu]
144            ssu_m(:,:) = ssu_m(:,:) * zcoef     ! mean suface current  [m/s]
145            ssv_m(:,:) = ssv_m(:,:) * zcoef     !
146            ssh_m(:,:) = ssh_m(:,:) * zcoef     ! mean SSH             [m]
147            e3t_m(:,:) = e3t_m(:,:) * zcoef     ! mean vertical scale factor [m]
148            frq_m(:,:) = frq_m(:,:) * zcoef     ! mean fraction of solar net radiation absorbed in the 1st T level [-]
149            !
150         ENDIF
151         !                                                ! ---------------------------------------- !
152         IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
153            !                                             ! ---------------------------------------- !
154            IF(lwp) WRITE(numout,*)
155            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields written in ocean restart file ',   &
156               &                    'at it= ', kt,' date= ', ndastp
157            IF(lwp) WRITE(numout,*) '~~~~~~~'
158            zf_sbc = REAL( nn_fsbc, wp )
159            IF( lwxios ) CALL iom_swap(      cwxios_context          )
160            CALL iom_rstput( kt, nitrst, numrow, 'nn_fsbc', zf_sbc, ldxios = lwxios )    ! sbc frequency
161            CALL iom_rstput( kt, nitrst, numrow, 'ssu_m'  , ssu_m, ldxios = lwxios  )    ! sea surface mean fields
162            CALL iom_rstput( kt, nitrst, numrow, 'ssv_m'  , ssv_m, ldxios = lwxios  )
163            CALL iom_rstput( kt, nitrst, numrow, 'sst_m'  , sst_m, ldxios = lwxios  )
164            CALL iom_rstput( kt, nitrst, numrow, 'sss_m'  , sss_m, ldxios = lwxios  )
165            CALL iom_rstput( kt, nitrst, numrow, 'ssh_m'  , ssh_m, ldxios = lwxios  )
166            CALL iom_rstput( kt, nitrst, numrow, 'e3t_m'  , e3t_m, ldxios = lwxios  )
167            CALL iom_rstput( kt, nitrst, numrow, 'frq_m'  , frq_m, ldxios = lwxios  )
168            !
169            IF( lwxios ) CALL iom_swap(      cxios_context          )
170         ENDIF
171         !
172      ENDIF
173      !
174      IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
175         CALL iom_put( 'ssu_m', ssu_m )
176         CALL iom_put( 'ssv_m', ssv_m )
177         CALL iom_put( 'sst_m', sst_m )
178         CALL iom_put( 'sss_m', sss_m )
179         CALL iom_put( 'ssh_m', ssh_m )
180         CALL iom_put( 'e3t_m', e3t_m )
181         CALL iom_put( 'frq_m', frq_m )
182      ENDIF
183      !
184   END SUBROUTINE sbc_ssm
185
186
187   SUBROUTINE sbc_ssm_init( Kbb, Kmm )
188      !!----------------------------------------------------------------------
189      !!                  ***  ROUTINE sbc_ssm_init  ***
190      !!
191      !! ** Purpose :   Initialisation of the sbc data
192      !!
193      !! ** Action  : - read parameters
194      !!----------------------------------------------------------------------
195      INTEGER, INTENT(in) ::   Kbb, Kmm   ! ocean time level indices
196      REAL(wp) ::   zcoef, zf_sbc   ! local scalar
197      !!----------------------------------------------------------------------
198      !
199      IF( nn_fsbc == 1 ) THEN
200         !
201         IF(lwp) WRITE(numout,*)
202         IF(lwp) WRITE(numout,*) 'sbc_ssm_init : sea surface mean fields, nn_fsbc=1 : instantaneous values'
203         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ '
204         !
205      ELSE
206         !               
207         IF(lwp) WRITE(numout,*)
208         IF(lwp) WRITE(numout,*) 'sbc_ssm_init : sea surface mean fields'
209         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~ '
210         !
211         IF( ln_rstart .AND. iom_varid( numror, 'nn_fsbc', ldstop = .FALSE. ) > 0 ) THEN
212            l_ssm_mean = .TRUE.
213            CALL iom_get( numror               , 'nn_fsbc', zf_sbc, ldxios = lrxios )    ! sbc frequency of previous run
214            CALL iom_get( numror, jpdom_autoglo, 'ssu_m'  , ssu_m, ldxios = lrxios  )    ! sea surface mean velocity    (U-point)
215            CALL iom_get( numror, jpdom_autoglo, 'ssv_m'  , ssv_m, ldxios = lrxios  )    !   "         "    velocity    (V-point)
216            CALL iom_get( numror, jpdom_autoglo, 'sst_m'  , sst_m, ldxios = lrxios  )    !   "         "    temperature (T-point)
217            CALL iom_get( numror, jpdom_autoglo, 'sss_m'  , sss_m, ldxios = lrxios  )    !   "         "    salinity    (T-point)
218            CALL iom_get( numror, jpdom_autoglo, 'ssh_m'  , ssh_m, ldxios = lrxios  )    !   "         "    height      (T-point)
219            CALL iom_get( numror, jpdom_autoglo, 'e3t_m'  , e3t_m, ldxios = lrxios  )    ! 1st level thickness          (T-point)
220            ! fraction of solar net radiation absorbed in 1st T level
221            IF( iom_varid( numror, 'frq_m', ldstop = .FALSE. ) > 0 ) THEN
222               CALL iom_get( numror, jpdom_autoglo, 'frq_m'  , frq_m, ldxios = lrxios  )
223            ELSE
224               frq_m(:,:) = 1._wp   ! default definition
225            ENDIF
226            !
227            IF( zf_sbc /= REAL( nn_fsbc, wp ) ) THEN      ! nn_fsbc has changed between 2 runs
228               IF(lwp) WRITE(numout,*) '   restart with a change in the frequency of mean from ', zf_sbc, ' to ', nn_fsbc 
229               zcoef = REAL( nn_fsbc - 1, wp ) / zf_sbc 
230               ssu_m(:,:) = zcoef * ssu_m(:,:) 
231               ssv_m(:,:) = zcoef * ssv_m(:,:)
232               sst_m(:,:) = zcoef * sst_m(:,:)
233               sss_m(:,:) = zcoef * sss_m(:,:)
234               ssh_m(:,:) = zcoef * ssh_m(:,:)
235               e3t_m(:,:) = zcoef * e3t_m(:,:)
236               frq_m(:,:) = zcoef * frq_m(:,:)
237            ELSE
238               IF(lwp) WRITE(numout,*) '   mean fields read in the ocean restart file'
239            ENDIF
240         ENDIF
241      ENDIF
242      !
243      IF( .NOT.l_ssm_mean ) THEN   ! default initialisation. needed by iceistate
244         !
245         IF(lwp) WRITE(numout,*) '   default initialisation of ss._m arrays'
246         ssu_m(:,:) = uu(:,:,1,Kbb)
247         ssv_m(:,:) = vv(:,:,1,Kbb)
248         IF( l_useCT )  THEN    ;   sst_m(:,:) = eos_pt_from_ct( ts(:,:,1,jp_tem,Kmm), ts(:,:,1,jp_sal,Kmm) )
249         ELSE                   ;   sst_m(:,:) = ts(:,:,1,jp_tem,Kmm)
250         ENDIF
251         sss_m(:,:) = ts  (:,:,1,jp_sal,Kmm)
252         ssh_m(:,:) = ssh(:,:,Kmm)
253         e3t_m(:,:) = e3t (:,:,1,Kmm)
254         frq_m(:,:) = 1._wp
255         !
256      ENDIF
257      !
258      IF( .NOT. ln_traqsr )   fraqsr_1lev(:,:) = 1._wp   ! default definition: qsr 100% in the fisrt level
259      !
260      IF( lwxios.AND.nn_fsbc > 1 ) THEN
261         CALL iom_set_rstw_var_active('nn_fsbc')
262         CALL iom_set_rstw_var_active('ssu_m')
263         CALL iom_set_rstw_var_active('ssv_m')
264         CALL iom_set_rstw_var_active('sst_m')
265         CALL iom_set_rstw_var_active('sss_m')
266         CALL iom_set_rstw_var_active('ssh_m')
267         CALL iom_set_rstw_var_active('e3t_m')
268         CALL iom_set_rstw_var_active('frq_m')
269      ENDIF
270
271   END SUBROUTINE sbc_ssm_init
272
273   !!======================================================================
274END MODULE sbcssm
Note: See TracBrowser for help on using the repository browser.