source: NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps_rewrite_time_filterswap/src/TOP/TRP/trcatf.F90 @ 11057

Last change on this file since 11057 was 11057, checked in by davestorkey, 19 months ago

2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps_rewrite_time_filterswap : Rewrite time filtering of tracers and SSH. This version now bit compares with the base code for ORCA1 starting from a restart.
To do:

  1. Check that it bit compares with an Euler timestep.
  2. Full SETTE tests.
  3. Check that it compiles with C1D.
  4. Check that TOP works (see 1).
  • Property svn:keywords set to Id
File size: 12.7 KB
Line 
1MODULE trcatf
2   !!======================================================================
3   !!                       ***  MODULE  trcatf  ***
4   !! Ocean passive tracers:  time stepping on passives tracers
5   !!======================================================================
6   !! History :  7.0  !  1991-11  (G. Madec)  Original code
7   !!                 !  1993-03  (M. Guyon)  symetrical conditions
8   !!                 !  1995-02  (M. Levy)   passive tracers
9   !!                 !  1996-02  (G. Madec & M. Imbard)  opa release 8.0
10   !!            8.0  !  1996-04  (A. Weaver)  Euler forward step
11   !!            8.2  !  1999-02  (G. Madec, N. Grima)  semi-implicit pressure grad.
12   !!  NEMO      1.0  !  2002-08  (G. Madec)  F90: Free form and module
13   !!                 !  2002-08  (G. Madec)  F90: Free form and module
14   !!                 !  2002-11  (C. Talandier, A-M Treguier) Open boundaries
15   !!                 !  2004-03  (C. Ethe) passive tracers
16   !!                 !  2007-02  (C. Deltel) Diagnose ML trends for passive tracers
17   !!            2.0  !  2006-02  (L. Debreu, C. Mazauric) Agrif implementation
18   !!            3.0  !  2008-06  (G. Madec)  time stepping always done in trazdf
19   !!            3.1  !  2009-02  (G. Madec, R. Benshila)  re-introduce the vvl option
20   !!            3.3  !  2010-06  (C. Ethe, G. Madec) Merge TRA-TRC
21   !!----------------------------------------------------------------------
22#if defined key_top
23   !!----------------------------------------------------------------------
24   !!   'key_top'                                                TOP models
25   !!----------------------------------------------------------------------
26   !!   trc_atf     : time stepping on passive tracers
27   !!----------------------------------------------------------------------
28   USE oce_trc         ! ocean dynamics and tracers variables
29   USE trc             ! ocean passive tracers variables
30   USE trd_oce
31   USE trdtra
32   USE tranxt
33   USE bdy_oce   , ONLY: ln_bdy
34   USE trcbdy          ! BDY open boundaries
35# if defined key_agrif
36   USE agrif_top_interp
37# endif
38   !
39   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
40   USE prtctl_trc      ! Print control for debbuging
41
42   IMPLICIT NONE
43   PRIVATE
44
45   PUBLIC   trc_atf   ! routine called by step.F90
46
47   REAL(wp) ::   rfact1, rfact2
48
49   !!----------------------------------------------------------------------
50   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
51   !! $Id$
52   !! Software governed by the CeCILL license (see ./LICENSE)
53   !!----------------------------------------------------------------------
54CONTAINS
55
56   SUBROUTINE trc_atf( kt, Kbb, Kmm, Kaa, ptr )
57      !!----------------------------------------------------------------------
58      !!                   ***  ROUTINE trcatf  ***
59      !!
60      !!        !!!!!!!!!!!!!!!! REWRITE HEADER COMMENTS !!!!!!!!!!!!!!
61      !!
62      !! ** Purpose :   Compute the passive tracers fields at the
63      !!      next time-step from their temporal trends and swap the fields.
64      !!
65      !! ** Method  :   Apply lateral boundary conditions on (uu(Kaa),vv(Kaa)) through
66      !!      call to lbc_lnk routine
67      !!   default:
68      !!      arrays swap
69      !!         (tr(Kmm)) = (tr(Kaa)) ; (tr(Kaa)) = (0,0)
70      !!         (tr(Kbb)) = (tr(Kmm))
71      !!
72      !!   For Arakawa or TVD Scheme :
73      !!      A Asselin time filter applied on now tracers (tr(:,:,:,:,Kmm)) to avoid
74      !!      the divergence of two consecutive time-steps and tr arrays
75      !!      to prepare the next time_step:
76      !!         (tr(Kbb)) = (tr(Kmm)) + atfp [ (tr(Kbb)) + (tr(Kaa)) - 2 (tr(Kmm)) ]
77      !!         (tr(Kmm)) = (tr(Kaa)) ; (tr(Kaa)) = (0,0)
78      !!
79      !!
80      !! ** Action  : - update tr(Kbb), tr(Kmm)
81      !!----------------------------------------------------------------------
82      INTEGER                                   , INTENT( in )  :: kt             ! ocean time-step index
83      INTEGER                                   , INTENT( in )  :: Kbb, Kmm, Kaa ! time level indices
84      REAL(wp), DIMENSION(jpi,jpj,jpk,jptra,jpt), INTENT(inout) :: ptr            ! passive tracers
85      !
86      INTEGER  ::   jk, jn   ! dummy loop indices
87      REAL(wp) ::   zfact            ! temporary scalar
88      CHARACTER (len=22) :: charout
89      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:) ::   ztrdt    ! 4D workspace
90      !!----------------------------------------------------------------------
91      !
92      IF( ln_timing )   CALL timing_start('trc_atf')
93      !
94      IF( kt == nittrc000 .AND. lwp ) THEN
95         WRITE(numout,*)
96         WRITE(numout,*) 'trc_atf : Asselin time filtering on passive tracers'
97      ENDIF
98      !
99#if defined key_agrif
100      CALL Agrif_trc                   ! AGRIF zoom boundaries
101#endif
102      ! Update after tracer on domain lateral boundaries
103      CALL lbc_lnk( 'trcatf', ptr(:,:,:,:,Kaa), 'T', 1. )   
104
105      IF( ln_bdy )  CALL trc_bdy( kt, Kbb, Kmm, Kaa )
106
107      IF( l_trdtrc )  THEN             ! trends: store now fields before the Asselin filter application
108         ALLOCATE( ztrdt(jpi,jpj,jpk,jptra) )
109         ztrdt(:,:,:,:)  = 0._wp
110         IF( ln_traldf_iso ) THEN                       ! diagnose the "pure" Kz diffusive trend
111            DO jn = 1, jptra
112               CALL trd_tra( kt, Kmm, Kaa, 'TRC', jn, jptra_zdfp, ztrdt(:,:,:,jn) )
113            ENDDO
114         ENDIF
115
116         ! total trend for the non-time-filtered variables.
117         zfact = 1.0 / rdttrc
118         ! G Nurser 23 Mar 2017. Recalculate trend as Delta(e3t*T)/e3tn; e3tn cancel from ts(Kmm) terms
119         IF( ln_linssh ) THEN       ! linear sea surface height only
120            DO jn = 1, jptra
121               DO jk = 1, jpkm1
122                  ztrdt(:,:,jk,jn) = ( ptr(:,:,jk,jn,Kaa)*e3t(:,:,jk,Kaa) / e3t(:,:,jk,Kmm) - ptr(:,:,jk,jn,Kmm)) * zfact
123               END DO
124            END DO
125         ELSE
126            DO jn = 1, jptra
127               DO jk = 1, jpkm1
128                  ztrdt(:,:,jk,jn) = ( ptr(:,:,jk,jn,Kaa) - ptr(:,:,jk,jn,Kmm) ) * zfact
129               END DO
130            END DO
131         ENDIF
132         !
133         DO jn = 1, jptra
134            CALL trd_tra( kt, Kmm, Kaa, 'TRC', jn, jptra_tot, ztrdt(:,:,:,jn) )
135         ENDDO
136         !
137         IF( ln_linssh ) THEN       ! linear sea surface height only
138            ! Store now fields before applying the Asselin filter
139            ! in order to calculate Asselin filter trend later.
140            ztrdt(:,:,:,:) = ptr(:,:,:,:,Kmm) 
141         ENDIF
142
143      ENDIF
144      !                                ! Leap-Frog + Asselin filter time stepping
145      IF( .NOT.( (neuler == 0 .AND. kt == nittrc000) .OR. ln_top_euler ) ) THEN    ! Only time filter if not an Euler timestep
146         IF( .NOT. l_offline ) THEN ! Leap-Frog + Asselin filter time stepping
147            IF( ln_linssh ) THEN   ;   CALL tra_nxt_fix( kt, Kbb, Kmm, Kaa, nittrc000,         'TRC', ptr, jptra )                     !     linear ssh
148            ELSE                   ;   CALL tra_nxt_vvl( kt, Kbb, Kmm, Kaa, nittrc000, rdttrc, 'TRC', ptr, sbc_trc, sbc_trc_b, jptra ) ! non-linear ssh
149            ENDIF
150         ELSE
151                                       CALL trc_atf_off( kt, Kbb, Kmm, Kaa )       ! offline
152         ENDIF
153         !
154         CALL lbc_lnk_multi( 'trcatf', ptr(:,:,:,:,Kbb), 'T', 1._wp, ptr(:,:,:,:,Kmm), 'T', 1._wp, ptr(:,:,:,:,Kaa), 'T', 1._wp )
155      ENDIF
156      !
157      IF( l_trdtrc .AND. ln_linssh ) THEN      ! trend of the Asselin filter (tb filtered - tb)/dt )
158         DO jn = 1, jptra
159            DO jk = 1, jpkm1
160               zfact = 1._wp / r2dttrc 
161               ztrdt(:,:,jk,jn) = ( ptr(:,:,jk,jn,Kbb) - ztrdt(:,:,jk,jn) ) * zfact 
162            END DO
163            CALL trd_tra( kt, Kmm, Kaa, 'TRC', jn, jptra_atf, ztrdt(:,:,:,jn) )
164         END DO
165      END IF
166      IF( l_trdtrc ) DEALLOCATE( ztrdt ) 
167      !
168      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
169         WRITE(charout, FMT="('nxt')")
170         CALL prt_ctl_trc_info(charout)
171         CALL prt_ctl_trc(tab4d=ptr(:,:,:,:,Kmm), mask=tmask, clinfo=ctrcnm)
172      ENDIF
173      !
174      IF( ln_timing )   CALL timing_stop('trc_atf')
175      !
176   END SUBROUTINE trc_atf
177
178
179   SUBROUTINE trc_atf_off( kt, Kbb, Kmm, Kaa, ptr )
180      !!----------------------------------------------------------------------
181      !!                   ***  ROUTINE tra_atf_off  ***
182      !!
183      !!          !!!!!!!!!!!!!!!!! REWRITE HEADER COMMENTS !!!!!!!!!!!!!!
184      !!
185      !! ** Purpose :   Time varying volume: apply the Asselin time filter 
186      !!
187      !! ** Method  : - Apply a thickness weighted Asselin time filter on now fields.
188      !!              - save in (ta,sa) a thickness weighted average over the three
189      !!             time levels which will be used to compute rdn and thus the semi-
190      !!             implicit hydrostatic pressure gradient (ln_dynhpg_imp = T)
191      !!              - swap tracer fields to prepare the next time_step.
192      !!                This can be summurized for tempearture as:
193      !!             ztm = ( e3t_n*tn + rbcp*[ e3t_b*tb - 2 e3t_n*tn + e3t_a*ta ] )   ln_dynhpg_imp = T
194      !!                  /( e3t(:,:,:,Kmm)    + rbcp*[ e3t(:,:,:,Kbb)    - 2 e3t(:,:,:,Kmm)    + e3t(:,:,:,Kaa)    ] )   
195      !!             ztm = 0                                                       otherwise
196      !!             tb  = ( e3t_n*tn + atfp*[ e3t_b*tb - 2 e3t_n*tn + e3t_a*ta ] )
197      !!                  /( e3t(:,:,:,Kmm)    + atfp*[ e3t(:,:,:,Kbb)    - 2 e3t(:,:,:,Kmm)    + e3t(:,:,:,Kaa)    ] )
198      !!             tn  = ta
199      !!             ta  = zt        (NB: reset to 0 after eos_bn2 call)
200      !!
201      !! ** Action  : - (tb,sb) and (tn,sn) ready for the next time step
202      !!              - (ta,sa) time averaged (t,s)   (ln_dynhpg_imp = T)
203      !!----------------------------------------------------------------------
204      INTEGER                                   , INTENT(in   ) ::  kt            ! ocean time-step index
205      INTEGER                                   , INTENT(in   ) ::  Kbb, Kmm, Kaa ! time level indices
206      REAL(wp), DIMENSION(jpi,jpj,jpk,jptra,jpt), INTENT(inout) ::  ptr           ! passive tracers
207      !!     
208      INTEGER  ::   ji, jj, jk, jn              ! dummy loop indices
209      REAL(wp) ::   ztc_a , ztc_n , ztc_b , ztc_f , ztc_d    ! local scalar
210      REAL(wp) ::   ze3t_b, ze3t_n, ze3t_a, ze3t_f, ze3t_d   !   -      -
211      !!----------------------------------------------------------------------
212      !
213      IF( kt == nittrc000 )  THEN
214         IF(lwp) WRITE(numout,*)
215         IF(lwp) WRITE(numout,*) 'trc_atf_off : Asselin time filtering'
216         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
217         IF( .NOT. ln_linssh ) THEN
218            rfact1 = atfp * rdttrc
219            rfact2 = rfact1 / rau0
220         ENDIF
221       
222      ENDIF
223      !
224      DO jn = 1, jptra     
225         DO jk = 1, jpkm1
226            DO jj = 1, jpj
227               DO ji = 1, jpi
228                  ze3t_b = e3t(ji,jj,jk,Kbb)
229                  ze3t_n = e3t(ji,jj,jk,Kmm)
230                  ze3t_a = e3t(ji,jj,jk,Kaa)
231                  !                                         ! tracer content at Before, now and after
232                  ztc_b  = ptr(ji,jj,jk,jn,Kbb)  * ze3t_b
233                  ztc_n  = ptr(ji,jj,jk,jn,Kmm)  * ze3t_n
234                  ztc_a  = ptr(ji,jj,jk,jn,Kaa) * ze3t_a
235                  !
236                  ze3t_d = ze3t_a - 2. * ze3t_n + ze3t_b
237                  ztc_d  = ztc_a  - 2. * ztc_n  + ztc_b
238                  !
239                  ze3t_f = ze3t_n + atfp * ze3t_d
240                  ztc_f  = ztc_n  + atfp * ztc_d
241                  !
242                  IF( .NOT. ln_linssh .AND. jk == mikt(ji,jj) ) THEN           ! first level
243                     ze3t_f = ze3t_f - rfact2 * ( emp_b(ji,jj)      - emp(ji,jj)   ) 
244                     ztc_f  = ztc_f  - rfact1 * ( sbc_trc(ji,jj,jn) - sbc_trc_b(ji,jj,jn) )
245                  ENDIF
246
247                  ze3t_f = 1.e0 / ze3t_f
248                  ptr(ji,jj,jk,jn,Kmm) = ztc_f * ze3t_f     ! time filtered "now" field
249                  !
250               END DO
251            END DO
252         END DO
253         !
254      END DO
255      !
256   END SUBROUTINE trc_atf_off
257
258#else
259   !!----------------------------------------------------------------------
260   !!   Default option                                         Empty module
261   !!----------------------------------------------------------------------
262CONTAINS
263   SUBROUTINE trc_atf( kt, Kbb, Kmm, Kaa, ptr ) 
264      INTEGER                                   , INTENT(in) :: kt
265      INTEGER                                   , INTENT(in) :: Kbb, Kmm, Kaa  ! time level indices
266      REAL(wp), DIMENSION(jpi,jpj,jpk,jptra,jpt), INTENT(inout) :: ptr            ! passive tracers
267      WRITE(*,*) 'trc_atf: You should not have seen this print! error?', kt
268   END SUBROUTINE trc_atf
269#endif
270   !!======================================================================
271END MODULE trcatf
Note: See TracBrowser for help on using the repository browser.