source: NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps_rewrite_time_filterswap/src/TOP/TRP/trcsbc.F90 @ 11099

Last change on this file since 11099 was 11099, checked in by davestorkey, 18 months ago

dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps_rewrite_time_filterswap : Updates and bug fixes. This version still doesn't pass all SETTE tests.

  • Property svn:keywords set to Id
File size: 10.0 KB
Line 
1MODULE trcsbc
2   !!==============================================================================
3   !!                       ***  MODULE  trcsbc  ***
4   !! Ocean passive tracers:  surface boundary condition
5   !!======================================================================
6   !! History :  8.2  !  1998-10  (G. Madec, G. Roullet, M. Imbard)  Original code
7   !!            8.2  !  2001-02  (D. Ludicone)  sea ice and free surface
8   !!            8.5  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            9.0  !  2004-03  (C. Ethe)  adapted for passive tracers
10   !!                 !  2006-08  (C. Deltel) Diagnose ML trends for passive tracers
11   !!==============================================================================
12#if defined key_top
13   !!----------------------------------------------------------------------
14   !!   'key_top'                                                TOP models
15   !!----------------------------------------------------------------------
16   !!   trc_sbc      : update the tracer trend at ocean surface
17   !!----------------------------------------------------------------------
18   USE oce_trc         ! ocean dynamics and active tracers variables
19   USE trc             ! ocean  passive tracers variables
20   USE prtctl_trc      ! Print control for debbuging
21   USE iom
22   USE trd_oce
23   USE trdtra
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   trc_sbc   ! routine called by step.F90
29
30   !! * Substitutions
31#  include "vectopt_loop_substitute.h90"
32   !!----------------------------------------------------------------------
33   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
34   !! $Id$
35   !! Software governed by the CeCILL license (see ./LICENSE)
36   !!----------------------------------------------------------------------
37CONTAINS
38
39   SUBROUTINE trc_sbc ( kt, Kmm, ptr, Krhs )
40      !!----------------------------------------------------------------------
41      !!                  ***  ROUTINE trc_sbc  ***
42      !!                   
43      !! ** Purpose :   Compute the tracer surface boundary condition trend of
44      !!      (concentration/dilution effect) and add it to the general
45      !!       trend of tracer equations.
46      !!
47      !! ** Method :
48      !!      * concentration/dilution effect:
49      !!            The surface freshwater flux modify the ocean volume
50      !!         and thus the concentration of a tracer as :
51      !!            tr(Krhs) = tr(Krhs) + emp * tr(Kmm) / e3t   for k=1
52      !!         where emp, the surface freshwater budget (evaporation minus
53      !!         precipitation ) given in kg/m2/s is divided
54      !!         by 1035 kg/m3 (density of ocean water) to obtain m/s.
55      !!
56      !! ** Action  : - Update the 1st level of tr(:,:,:,:,Krhs) with the trend associated
57      !!                with the tracer surface boundary condition
58      !!
59      !!----------------------------------------------------------------------
60      INTEGER,                                    INTENT(in   ) :: kt        ! ocean time-step index
61      INTEGER,                                    INTENT(in   ) :: Kmm, Krhs ! time level indices
62      REAL(wp), DIMENSION(jpi,jpj,jpk,jptra,jpt), INTENT(inout) :: ptr       ! passive tracers and RHS of tracer equation
63      !
64      INTEGER  ::   ji, jj, jn                      ! dummy loop indices
65      REAL(wp) ::   zse3t, zrtrn, zratio, zfact     ! local scalars
66      REAL(wp) ::   zftra, zcd, zdtra, ztfx, ztra   !   -      -
67      CHARACTER (len=22) :: charout
68      REAL(wp), DIMENSION(jpi,jpj)   ::   zsfx
69      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   ztrtrd
70      !!---------------------------------------------------------------------
71      !
72      IF( ln_timing )   CALL timing_start('trc_sbc')
73      !
74      ! Allocate temporary workspace
75      IF( l_trdtrc )  ALLOCATE( ztrtrd(jpi,jpj,jpk) )
76      !
77      zrtrn = 1.e-15_wp
78
79      IF( kt == nittrc000 ) THEN
80         IF(lwp) WRITE(numout,*)
81         IF(lwp) WRITE(numout,*) 'trc_sbc : Passive tracers surface boundary condition'
82         IF(lwp) WRITE(numout,*) '~~~~~~~ '
83         !
84         IF( ln_rsttr .AND. .NOT.ln_top_euler .AND.   &                     ! Restart: read in restart  file
85            iom_varid( numrtr, 'sbc_'//TRIM(ctrcnm(1))//'_b', ldstop = .FALSE. ) > 0 ) THEN
86            IF(lwp) WRITE(numout,*) '          nittrc000-nn_dttrc surface tracer content forcing fields red in the restart file'
87            zfact = 0.5_wp
88            DO jn = 1, jptra
89               CALL iom_get( numrtr, jpdom_autoglo, 'sbc_'//TRIM(ctrcnm(jn))//'_b', sbc_trc_b(:,:,jn) )   ! before tracer content sbc
90            END DO
91         ELSE                                         ! No restart or restart not found: Euler forward time stepping
92           zfact = 1._wp
93           sbc_trc_b(:,:,:) = 0._wp
94         ENDIF
95      ELSE                                         ! Swap of forcing fields
96         IF( ln_top_euler ) THEN
97            zfact = 1._wp
98            sbc_trc_b(:,:,:) = 0._wp
99         ELSE
100            zfact = 0.5_wp
101            sbc_trc_b(:,:,:) = sbc_trc(:,:,:)
102         ENDIF
103         !
104      ENDIF
105
106      ! Coupling online : river runoff is added to the horizontal divergence (hdiv) in the subroutine sbc_rnf_div
107      ! one only consider the concentration/dilution effect due to evaporation minus precipitation + freezing/melting of sea-ice
108      ! Coupling offline : runoff are in emp which contains E-P-R
109      !
110      IF( .NOT.ln_linssh ) THEN  ! online coupling with vvl
111         zsfx(:,:) = 0._wp
112      ELSE                                      ! online coupling free surface or offline with free surface
113         zsfx(:,:) = emp(:,:)
114      ENDIF
115
116      ! 0. initialization
117      IF( nn_ice_tr == -1 ) THEN    ! No tracers in sea ice (null concentration in sea ice)
118         !
119         DO jn = 1, jptra
120            DO jj = 2, jpj
121               DO ji = fs_2, fs_jpim1   ! vector opt.
122                  sbc_trc(ji,jj,jn) = zsfx(ji,jj) * r1_rau0 * ptr(ji,jj,1,jn,Kmm)
123               END DO
124            END DO
125         END DO
126         !
127       ELSE
128         !
129         DO jn = 1, jptra
130            DO jj = 2, jpj
131               DO ji = fs_2, fs_jpim1   ! vector opt.
132                  zse3t = 1. / e3t(ji,jj,1,Kmm)
133                  ! tracer flux at the ice/ocean interface (tracer/m2/s)
134                  zftra = - trc_i(ji,jj,jn) * fmmflx(ji,jj) ! uptake of tracer in the sea ice
135                  zcd   =   trc_o(ji,jj,jn) * fmmflx(ji,jj) ! concentration dilution due to freezing-melting,
136                  !                                         ! only used in the levitating sea ice case
137                  ! tracer flux only       : add concentration dilution term in net tracer flux, no F-M in volume flux
138                  ! tracer and mass fluxes : no concentration dilution term in net tracer flux, F-M term in volume flux
139                  ztfx  = zftra                             ! net tracer flux
140                  !
141                  zdtra = r1_rau0 * ( ztfx + zsfx(ji,jj) * ptr(ji,jj,1,jn,Kmm) ) 
142                  IF ( zdtra < 0. ) THEN
143                     zratio = -zdtra * zse3t * r2dttrc / ( ptr(ji,jj,1,jn,Kmm) + zrtrn )
144                     zdtra = MIN(1.0, zratio) * zdtra ! avoid negative concentrations to arise
145                  ENDIF
146                  sbc_trc(ji,jj,jn) =  zdtra 
147               END DO
148            END DO
149         END DO
150      ENDIF
151      !
152      CALL lbc_lnk( 'trcsbc', sbc_trc(:,:,:), 'T', 1. )
153      !                                       Concentration dilution effect on tracers due to evaporation & precipitation
154      DO jn = 1, jptra
155         !
156         IF( l_trdtrc )   ztrtrd(:,:,:) = ptr(:,:,:,jn,Krhs)  ! save trends
157         !
158         DO jj = 2, jpj
159            DO ji = fs_2, fs_jpim1   ! vector opt.
160               zse3t = zfact / e3t(ji,jj,1,Kmm)
161               ptr(ji,jj,1,jn,Krhs) = ptr(ji,jj,1,jn,Krhs) + ( sbc_trc_b(ji,jj,jn) + sbc_trc(ji,jj,jn) ) * zse3t
162            END DO
163         END DO
164         !
165         IF( l_trdtrc ) THEN
166            ztrtrd(:,:,:) = ptr(:,:,:,jn,Krhs) - ztrtrd(:,:,:)
167            CALL trd_tra( kt, Kmm, Krhs, 'TRC', jn, jptra_nsr, ztrtrd )
168         END IF
169         !                                                       ! ===========
170      END DO                                                     ! tracer loop
171      !                                                          ! ===========
172      !
173      !                                           Write in the tracer restar  file
174      !                                          *******************************
175      IF( lrst_trc .AND. .NOT.ln_top_euler ) THEN
176         IF(lwp) WRITE(numout,*)
177         IF(lwp) WRITE(numout,*) 'sbc : ocean surface tracer content forcing fields written in tracer restart file ',   &
178            &                    'at it= ', kt,' date= ', ndastp
179         IF(lwp) WRITE(numout,*) '~~~~'
180         DO jn = 1, jptra
181            CALL iom_rstput( kt, nitrst, numrtw, 'sbc_'//TRIM(ctrcnm(jn))//'_b', sbc_trc(:,:,jn) )
182         END DO
183      ENDIF
184      !
185      IF( ln_ctl )   THEN
186         WRITE(charout, FMT="('sbc ')") ;  CALL prt_ctl_trc_info(charout)
187                                           CALL prt_ctl_trc( tab4d=ptr(:,:,:,:,Krhs), mask=tmask, clinfo=ctrcnm, clinfo2='trd' )
188      ENDIF
189      IF( l_trdtrc )  DEALLOCATE( ztrtrd )
190      !
191      IF( ln_timing )   CALL timing_stop('trc_sbc')
192      !
193   END SUBROUTINE trc_sbc
194
195#else
196   !!----------------------------------------------------------------------
197   !!   Dummy module :                      NO passive tracer
198   !!----------------------------------------------------------------------
199   USE par_oce
200   USE par_trc
201CONTAINS
202   SUBROUTINE trc_sbc ( kt, Kmm, ptr, Krhs )      ! Empty routine
203      INTEGER,                                    INTENT(in   ) :: kt        ! ocean time-step index
204      INTEGER,                                    INTENT(in   ) :: Kmm, Krhs ! time level indices
205      REAL(wp), DIMENSION(jpi,jpj,jpk,jptra,jpt), INTENT(inout) :: ptr       ! passive tracers and RHS of tracer equation
206      WRITE(*,*) 'trc_sbc: You should not have seen this print! error?', kt
207   END SUBROUTINE trc_sbc
208#endif
209   
210   !!======================================================================
211END MODULE trcsbc
Note: See TracBrowser for help on using the repository browser.