New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
bdytides.F90 in NEMO/branches/2019/dev_r10742_ENHANCE-12_SimonM-Tides/src/OCE/BDY – NEMO

source: NEMO/branches/2019/dev_r10742_ENHANCE-12_SimonM-Tides/src/OCE/BDY/bdytides.F90 @ 12059

Last change on this file since 12059 was 12059, checked in by smueller, 4 years ago

Reversal of changeset [10865] to avoid a conflict in the upcoming sync merge with the trunk; a new version of the modification implemented by changeset [10865] will be applied following the upcoming sync merge with the trunk (ticket #2194)
  • Property svn:keywords set to Id
File size: 27.1 KB
Line 
1MODULE bdytides
2   !!======================================================================
3   !!                       ***  MODULE  bdytides  ***
4   !! Ocean dynamics:   Tidal forcing at open boundaries
5   !!======================================================================
6   !! History :  2.0  !  2007-01  (D.Storkey)  Original code
7   !!            2.3  !  2008-01  (J.Holt)  Add date correction. Origins POLCOMS v6.3 2007
8   !!            3.0  !  2008-04  (NEMO team)  add in the reference version
9   !!            3.3  !  2010-09  (D.Storkey and E.O'Dea)  bug fixes
10   !!            3.4  !  2012-09  (G. Reffray and J. Chanut) New inputs + mods
11   !!            3.5  !  2013-07  (J. Chanut) Compliant with time splitting changes
12   !!----------------------------------------------------------------------
13   !!   bdytide_init  : read of namelist and initialisation of tidal harmonics data
14   !!   tide_update   : calculation of tidal forcing at each timestep
15   !!----------------------------------------------------------------------
16   USE oce            ! ocean dynamics and tracers
17   USE dom_oce        ! ocean space and time domain
18   USE phycst         ! physical constants
19   USE bdy_oce        ! ocean open boundary conditions
20   USE tide_mod       !
21   USE daymod         ! calendar
22   !
23   USE in_out_manager ! I/O units
24   USE iom            ! xIO server
25   USE fldread        !
26   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   bdytide_init     ! routine called in bdy_init
32   PUBLIC   bdytide_update   ! routine called in bdy_dta
33   PUBLIC   bdy_dta_tides    ! routine called in dyn_spg_ts
34
35   TYPE, PUBLIC ::   TIDES_DATA     !: Storage for external tidal harmonics data
36      REAL(wp), POINTER, DIMENSION(:,:,:)    ::   ssh0     !: Tidal constituents : SSH0   (read in file)
37      REAL(wp), POINTER, DIMENSION(:,:,:)    ::   u0, v0   !: Tidal constituents : U0, V0 (read in file)
38      REAL(wp), POINTER, DIMENSION(:,:,:)    ::   ssh      !: Tidal constituents : SSH    (after nodal cor.)
39      REAL(wp), POINTER, DIMENSION(:,:,:)    ::   u , v    !: Tidal constituents : U , V  (after nodal cor.)
40   END TYPE TIDES_DATA
41
42!$AGRIF_DO_NOT_TREAT
43   TYPE(TIDES_DATA), PUBLIC, DIMENSION(jp_bdy), TARGET :: tides  !: External tidal harmonics data
44!$AGRIF_END_DO_NOT_TREAT
45   TYPE(OBC_DATA)  , PUBLIC, DIMENSION(jp_bdy) :: dta_bdy_s  !: bdy external data (slow component)
46
47   INTEGER ::   kt_tide
48
49   !!----------------------------------------------------------------------
50   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
51   !! $Id$
52   !! Software governed by the CeCILL license (see ./LICENSE)
53   !!----------------------------------------------------------------------
54CONTAINS
55
56   SUBROUTINE bdytide_init
57      !!----------------------------------------------------------------------
58      !!                    ***  SUBROUTINE bdytide_init  ***
59      !!                     
60      !! ** Purpose : - Read in namelist for tides and initialise external
61      !!                tidal harmonics data
62      !!
63      !!----------------------------------------------------------------------
64      !! namelist variables
65      !!-------------------
66      CHARACTER(len=80)                         ::   filtide             !: Filename root for tidal input files
67      LOGICAL                                   ::   ln_bdytide_2ddta    !: If true, read 2d harmonic data
68      !!
69      INTEGER                                   ::   ib_bdy, itide, ib   !: dummy loop indices
70      INTEGER                                   ::   ii, ij              !: dummy loop indices
71      INTEGER                                   ::   inum, igrd
72      INTEGER, DIMENSION(3)                     ::   ilen0       !: length of boundary data (from OBC arrays)
73      INTEGER, POINTER, DIMENSION(:)            ::   nblen, nblenrim     ! short cuts
74      INTEGER                                   ::   ios                 ! Local integer output status for namelist read
75      CHARACTER(len=80)                         ::   clfile              !: full file name for tidal input file
76      REAL(wp),ALLOCATABLE, DIMENSION(:,:,:)    ::   dta_read            !: work space to read in tidal harmonics data
77      REAL(wp),ALLOCATABLE, DIMENSION(:,:)      ::   ztr, zti            !:  "     "    "   "   "   "        "      "
78      !!
79      TYPE(TIDES_DATA),  POINTER                ::   td                  !: local short cut   
80      TYPE(MAP_POINTER), DIMENSION(jpbgrd)      ::   ibmap_ptr           !: array of pointers to nbmap
81      !!
82      NAMELIST/nambdy_tide/filtide, ln_bdytide_2ddta
83      !!----------------------------------------------------------------------
84      !
85      IF (nb_bdy>0) THEN
86         IF(lwp) WRITE(numout,*)
87         IF(lwp) WRITE(numout,*) 'bdytide_init : initialization of tidal harmonic forcing at open boundaries'
88         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~'
89      ENDIF
90
91      REWIND(numnam_cfg)
92
93      DO ib_bdy = 1, nb_bdy
94         IF( nn_dyn2d_dta(ib_bdy) >= 2 ) THEN
95            !
96            td => tides(ib_bdy)
97            nblen => idx_bdy(ib_bdy)%nblen
98            nblenrim => idx_bdy(ib_bdy)%nblenrim
99
100            ! Namelist nambdy_tide : tidal harmonic forcing at open boundaries
101            filtide(:) = ''
102
103            ! Don't REWIND here - may need to read more than one of these namelists.
104            READ  ( numnam_ref, nambdy_tide, IOSTAT = ios, ERR = 901)
105901         IF( ios /= 0 )   CALL ctl_nam ( ios , 'nambdy_tide in reference namelist', lwp )
106            READ  ( numnam_cfg, nambdy_tide, IOSTAT = ios, ERR = 902 )
107902         IF( ios >  0 )   CALL ctl_nam ( ios , 'nambdy_tide in configuration namelist', lwp )
108            IF(lwm) WRITE ( numond, nambdy_tide )
109            !                                               ! Parameter control and print
110            IF(lwp) WRITE(numout,*) '  '
111            IF(lwp) WRITE(numout,*) '          Namelist nambdy_tide : tidal harmonic forcing at open boundaries'
112            IF(lwp) WRITE(numout,*) '             read tidal data in 2d files: ', ln_bdytide_2ddta
113            IF(lwp) WRITE(numout,*) '             Number of tidal components to read: ', nb_harmo
114            IF(lwp) THEN
115                    WRITE(numout,*) '             Tidal components: ' 
116               DO itide = 1, nb_harmo
117                  WRITE(numout,*)  '                 ', tide_harmonics(itide)%cname_tide 
118               END DO
119            ENDIF
120            IF(lwp) WRITE(numout,*) ' '
121
122            ! Allocate space for tidal harmonics data - get size from OBC data arrays
123            ! -----------------------------------------------------------------------
124
125            ! JC: If FRS scheme is used, we assume that tidal is needed over the whole
126            ! relaxation area     
127            IF( cn_dyn2d(ib_bdy) == 'frs' ) THEN   ;   ilen0(:) = nblen   (:)
128            ELSE                                   ;   ilen0(:) = nblenrim(:)
129            ENDIF
130
131            ALLOCATE( td%ssh0( ilen0(1), nb_harmo, 2 ) )
132            ALLOCATE( td%ssh ( ilen0(1), nb_harmo, 2 ) )
133
134            ALLOCATE( td%u0( ilen0(2), nb_harmo, 2 ) )
135            ALLOCATE( td%u ( ilen0(2), nb_harmo, 2 ) )
136
137            ALLOCATE( td%v0( ilen0(3), nb_harmo, 2 ) )
138            ALLOCATE( td%v ( ilen0(3), nb_harmo, 2 ) )
139
140            td%ssh0(:,:,:) = 0._wp
141            td%ssh (:,:,:) = 0._wp
142            td%u0  (:,:,:) = 0._wp
143            td%u   (:,:,:) = 0._wp
144            td%v0  (:,:,:) = 0._wp
145            td%v   (:,:,:) = 0._wp
146
147            IF( ln_bdytide_2ddta ) THEN
148               ! It is assumed that each data file contains all complex harmonic amplitudes
149               ! given on the global domain (ie global, jpiglo x jpjglo)
150               !
151               ALLOCATE( zti(jpi,jpj), ztr(jpi,jpj) )
152               !
153               ! SSH fields
154               clfile = TRIM(filtide)//'_grid_T.nc'
155               CALL iom_open( clfile , inum ) 
156               igrd = 1                       ! Everything is at T-points here
157               DO itide = 1, nb_harmo
158                  CALL iom_get( inum, jpdom_autoglo, TRIM(tide_harmonics(itide)%cname_tide)//'_z1', ztr(:,:) )
159                  CALL iom_get( inum, jpdom_autoglo, TRIM(tide_harmonics(itide)%cname_tide)//'_z2', zti(:,:) ) 
160                  DO ib = 1, ilen0(igrd)
161                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
162                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
163                     td%ssh0(ib,itide,1) = ztr(ii,ij)
164                     td%ssh0(ib,itide,2) = zti(ii,ij)
165                  END DO
166               END DO
167               CALL iom_close( inum )
168               !
169               ! U fields
170               clfile = TRIM(filtide)//'_grid_U.nc'
171               CALL iom_open( clfile , inum ) 
172               igrd = 2                       ! Everything is at U-points here
173               DO itide = 1, nb_harmo
174                  CALL iom_get  ( inum, jpdom_autoglo, TRIM(tide_harmonics(itide)%cname_tide)//'_u1', ztr(:,:) )
175                  CALL iom_get  ( inum, jpdom_autoglo, TRIM(tide_harmonics(itide)%cname_tide)//'_u2', zti(:,:) )
176                  DO ib = 1, ilen0(igrd)
177                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
178                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
179                     td%u0(ib,itide,1) = ztr(ii,ij)
180                     td%u0(ib,itide,2) = zti(ii,ij)
181                  END DO
182               END DO
183               CALL iom_close( inum )
184               !
185               ! V fields
186               clfile = TRIM(filtide)//'_grid_V.nc'
187               CALL iom_open( clfile , inum ) 
188               igrd = 3                       ! Everything is at V-points here
189               DO itide = 1, nb_harmo
190                  CALL iom_get  ( inum, jpdom_autoglo, TRIM(tide_harmonics(itide)%cname_tide)//'_v1', ztr(:,:) )
191                  CALL iom_get  ( inum, jpdom_autoglo, TRIM(tide_harmonics(itide)%cname_tide)//'_v2', zti(:,:) )
192                  DO ib = 1, ilen0(igrd)
193                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
194                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
195                     td%v0(ib,itide,1) = ztr(ii,ij)
196                     td%v0(ib,itide,2) = zti(ii,ij)
197                  END DO
198               END DO 
199               CALL iom_close( inum )
200               !
201               DEALLOCATE( ztr, zti ) 
202               !
203            ELSE           
204               !
205               ! Read tidal data only on bdy segments
206               !
207               ALLOCATE( dta_read( MAXVAL(ilen0(1:3)), 1, 1 ) )
208               !
209               ! Set map structure
210               ibmap_ptr(1)%ptr => idx_bdy(ib_bdy)%nbmap(:,1)   ;   ibmap_ptr(1)%ll_unstruc = ln_coords_file(ib_bdy)
211               ibmap_ptr(2)%ptr => idx_bdy(ib_bdy)%nbmap(:,2)   ;   ibmap_ptr(2)%ll_unstruc = ln_coords_file(ib_bdy)
212               ibmap_ptr(3)%ptr => idx_bdy(ib_bdy)%nbmap(:,3)   ;   ibmap_ptr(3)%ll_unstruc = ln_coords_file(ib_bdy)
213
214               ! Open files and read in tidal forcing data
215               ! -----------------------------------------
216
217               DO itide = 1, nb_harmo
218                  !                                                              ! SSH fields
219                  clfile = TRIM(filtide)//TRIM(tide_harmonics(itide)%cname_tide)//'_grid_T.nc'
220                  CALL iom_open( clfile, inum )
221                  CALL fld_map( inum, 'z1' , dta_read(1:ilen0(1),1:1,1:1) , 1,  ibmap_ptr(1) )
222                  td%ssh0(:,itide,1) = dta_read(1:ilen0(1),1,1)
223                  CALL fld_map( inum, 'z2' , dta_read(1:ilen0(1),1:1,1:1) , 1,  ibmap_ptr(1) )
224                  td%ssh0(:,itide,2) = dta_read(1:ilen0(1),1,1)
225                  CALL iom_close( inum )
226                  !                                                              ! U fields
227                  clfile = TRIM(filtide)//TRIM(tide_harmonics(itide)%cname_tide)//'_grid_U.nc'
228                  CALL iom_open( clfile, inum )
229                  CALL fld_map( inum, 'u1' , dta_read(1:ilen0(2),1:1,1:1) , 1, ibmap_ptr(2) )
230                  td%u0(:,itide,1) = dta_read(1:ilen0(2),1,1)
231                  CALL fld_map( inum, 'u2' , dta_read(1:ilen0(2),1:1,1:1) , 1, ibmap_ptr(2) )
232                  td%u0(:,itide,2) = dta_read(1:ilen0(2),1,1)
233                  CALL iom_close( inum )
234                  !                                                              ! V fields
235                  clfile = TRIM(filtide)//TRIM(tide_harmonics(itide)%cname_tide)//'_grid_V.nc'
236                  CALL iom_open( clfile, inum )
237                  CALL fld_map( inum, 'v1' , dta_read(1:ilen0(3),1:1,1:1) , 1, ibmap_ptr(3) )
238                  td%v0(:,itide,1) = dta_read(1:ilen0(3),1,1)
239                  CALL fld_map( inum, 'v2' , dta_read(1:ilen0(3),1:1,1:1) , 1, ibmap_ptr(3) )
240                  td%v0(:,itide,2) = dta_read(1:ilen0(3),1,1)
241                  CALL iom_close( inum )
242                  !
243               END DO ! end loop on tidal components
244               !
245               DEALLOCATE( dta_read )
246               !
247            ENDIF ! ln_bdytide_2ddta=.true.
248            !
249            ! Allocate slow varying data in the case of time splitting:
250            ! Do it anyway because at this stage knowledge of free surface scheme is unknown
251            ALLOCATE( dta_bdy_s(ib_bdy)%ssh ( ilen0(1) ) )
252            ALLOCATE( dta_bdy_s(ib_bdy)%u2d ( ilen0(2) ) )
253            ALLOCATE( dta_bdy_s(ib_bdy)%v2d ( ilen0(3) ) )
254            dta_bdy_s(ib_bdy)%ssh(:) = 0._wp
255            dta_bdy_s(ib_bdy)%u2d(:) = 0._wp
256            dta_bdy_s(ib_bdy)%v2d(:) = 0._wp
257            !
258         ENDIF ! nn_dyn2d_dta(ib_bdy) >= 2
259         !
260      END DO ! loop on ib_bdy
261      !
262   END SUBROUTINE bdytide_init
263
264
265   SUBROUTINE bdytide_update( kt, idx, dta, td, jit, time_offset )
266      !!----------------------------------------------------------------------
267      !!                 ***  SUBROUTINE bdytide_update  ***
268      !!               
269      !! ** Purpose : - Add tidal forcing to ssh, u2d and v2d OBC data arrays.
270      !!               
271      !!----------------------------------------------------------------------
272      INTEGER          , INTENT(in   ) ::   kt          ! Main timestep counter
273      TYPE(OBC_INDEX)  , INTENT(in   ) ::   idx         ! OBC indices
274      TYPE(OBC_DATA)   , INTENT(inout) ::   dta         ! OBC external data
275      TYPE(TIDES_DATA) , INTENT(inout) ::   td          ! tidal harmonics data
276      INTEGER, OPTIONAL, INTENT(in   ) ::   jit         ! Barotropic timestep counter (for timesplitting option)
277      INTEGER, OPTIONAL, INTENT(in   ) ::   time_offset ! time offset in units of timesteps. NB. if jit
278      !                                                 ! is present then units = subcycle timesteps.
279      !                                                 ! time_offset = 0  => get data at "now"    time level
280      !                                                 ! time_offset = -1 => get data at "before" time level
281      !                                                 ! time_offset = +1 => get data at "after"  time level
282      !                                                 ! etc.
283      !
284      INTEGER  ::   itide, igrd, ib       ! dummy loop indices
285      INTEGER  ::   time_add              ! time offset in units of timesteps
286      INTEGER, DIMENSION(3) ::   ilen0    ! length of boundary data (from OBC arrays)
287      REAL(wp) ::   z_arg, z_sarg, zflag, zramp   ! local scalars   
288      REAL(wp), DIMENSION(jpmax_harmo) :: z_sist, z_cost
289      !!----------------------------------------------------------------------
290      !
291      ilen0(1) =  SIZE(td%ssh(:,1,1))
292      ilen0(2) =  SIZE(td%u(:,1,1))
293      ilen0(3) =  SIZE(td%v(:,1,1))
294
295      zflag=1
296      IF ( PRESENT(jit) ) THEN
297        IF ( jit /= 1 ) zflag=0
298      ENDIF
299
300      IF ( (nsec_day == NINT(0.5_wp * rdt) .OR. kt==nit000) .AND. zflag==1 ) THEN
301        !
302        kt_tide = kt - (nsec_day - 0.5_wp * rdt)/rdt
303        !
304        IF(lwp) THEN
305           WRITE(numout,*)
306           WRITE(numout,*) 'bdytide_update : (re)Initialization of the tidal bdy forcing at kt=',kt
307           WRITE(numout,*) '~~~~~~~~~~~~~~ '
308        ENDIF
309        !
310        CALL tide_init_elevation ( idx, td )
311        CALL tide_init_velocities( idx, td )
312        !
313      ENDIF
314
315      time_add = 0
316      IF( PRESENT(time_offset) ) THEN
317         time_add = time_offset
318      ENDIF
319         
320      IF( PRESENT(jit) ) THEN 
321         z_arg = ((kt-kt_tide) * rdt + (jit+0.5_wp*(time_add-1)) * rdt / REAL(nn_baro,wp) )
322      ELSE                             
323         z_arg = ((kt-kt_tide)+time_add) * rdt
324      ENDIF
325
326      ! Linear ramp on tidal component at open boundaries
327      zramp = 1._wp
328      IF (ln_tide_ramp) zramp = MIN(MAX( (z_arg + (kt_tide-nit000)*rdt)/(rn_tide_ramp_dt*rday),0._wp),1._wp)
329
330      DO itide = 1, nb_harmo
331         z_sarg = z_arg * tide_harmonics(itide)%omega
332         z_cost(itide) = COS( z_sarg )
333         z_sist(itide) = SIN( z_sarg )
334      END DO
335
336      DO itide = 1, nb_harmo
337         igrd=1                              ! SSH on tracer grid
338         DO ib = 1, ilen0(igrd)
339            dta%ssh(ib) = dta%ssh(ib) + zramp*(td%ssh(ib,itide,1)*z_cost(itide) + td%ssh(ib,itide,2)*z_sist(itide))
340         END DO
341         igrd=2                              ! U grid
342         DO ib = 1, ilen0(igrd)
343            dta%u2d(ib) = dta%u2d(ib) + zramp*(td%u  (ib,itide,1)*z_cost(itide) + td%u  (ib,itide,2)*z_sist(itide))
344         END DO
345         igrd=3                              ! V grid
346         DO ib = 1, ilen0(igrd) 
347            dta%v2d(ib) = dta%v2d(ib) + zramp*(td%v  (ib,itide,1)*z_cost(itide) + td%v  (ib,itide,2)*z_sist(itide))
348         END DO
349      END DO
350      !
351   END SUBROUTINE bdytide_update
352
353
354   SUBROUTINE bdy_dta_tides( kt, kit, time_offset )
355      !!----------------------------------------------------------------------
356      !!                 ***  SUBROUTINE bdy_dta_tides  ***
357      !!               
358      !! ** Purpose : - Add tidal forcing to ssh, u2d and v2d OBC data arrays.
359      !!               
360      !!----------------------------------------------------------------------
361      INTEGER,           INTENT(in) ::   kt          ! Main timestep counter
362      INTEGER, OPTIONAL, INTENT(in) ::   kit         ! Barotropic timestep counter (for timesplitting option)
363      INTEGER, OPTIONAL, INTENT(in) ::   time_offset ! time offset in units of timesteps. NB. if kit
364      !                                              ! is present then units = subcycle timesteps.
365      !                                              ! time_offset = 0  => get data at "now"    time level
366      !                                              ! time_offset = -1 => get data at "before" time level
367      !                                              ! time_offset = +1 => get data at "after"  time level
368      !                                              ! etc.
369      !
370      LOGICAL  ::   lk_first_btstp            ! =.TRUE. if time splitting and first barotropic step
371      INTEGER  ::   itide, ib_bdy, ib, igrd   ! loop indices
372      INTEGER  ::   time_add                  ! time offset in units of timesteps
373      INTEGER, DIMENSION(jpbgrd)   ::   ilen0 
374      INTEGER, DIMENSION(1:jpbgrd) ::   nblen, nblenrim  ! short cuts
375      REAL(wp) ::   z_arg, z_sarg, zramp, zoff, z_cost, z_sist     
376      !!----------------------------------------------------------------------
377      !
378      lk_first_btstp=.TRUE.
379      IF ( PRESENT(kit).AND.( kit /= 1 ) ) THEN ; lk_first_btstp=.FALSE. ; ENDIF
380
381      time_add = 0
382      IF( PRESENT(time_offset) ) THEN
383         time_add = time_offset
384      ENDIF
385     
386      ! Absolute time from model initialization:   
387      IF( PRESENT(kit) ) THEN 
388         z_arg = ( kt + (kit+time_add-1) / REAL(nn_baro,wp) ) * rdt
389      ELSE                             
390         z_arg = ( kt + time_add ) * rdt
391      ENDIF
392
393      ! Linear ramp on tidal component at open boundaries
394      zramp = 1.
395      IF (ln_tide_ramp) zramp = MIN(MAX( (z_arg - nit000*rdt)/(rn_tide_ramp_dt*rday),0.),1.)
396
397      DO ib_bdy = 1,nb_bdy
398         !
399         IF( nn_dyn2d_dta(ib_bdy) >= 2 ) THEN
400            !
401            nblen(1:jpbgrd) = idx_bdy(ib_bdy)%nblen(1:jpbgrd)
402            nblenrim(1:jpbgrd) = idx_bdy(ib_bdy)%nblenrim(1:jpbgrd)
403            !
404            IF( cn_dyn2d(ib_bdy) == 'frs' ) THEN   ;   ilen0(:) = nblen   (:)
405            ELSE                                   ;   ilen0(:) = nblenrim(:)
406            ENDIF     
407            !
408            ! We refresh nodal factors every day below
409            ! This should be done somewhere else
410            IF ( ( nsec_day == NINT(0.5_wp * rdt) .OR. kt==nit000 ) .AND. lk_first_btstp ) THEN
411               !
412               kt_tide = kt - (nsec_day - 0.5_wp * rdt)/rdt
413               !
414               IF(lwp) THEN
415               WRITE(numout,*)
416               WRITE(numout,*) 'bdy_tide_dta : Refresh nodal factors for tidal open bdy data at kt=',kt
417               WRITE(numout,*) '~~~~~~~~~~~~~~ '
418               ENDIF
419               !
420               CALL tide_init_elevation ( idx=idx_bdy(ib_bdy), td=tides(ib_bdy) )
421               CALL tide_init_velocities( idx=idx_bdy(ib_bdy), td=tides(ib_bdy) )
422               !
423            ENDIF
424            zoff = -kt_tide * rdt ! time offset relative to nodal factor computation time
425            !
426            ! If time splitting, initialize arrays from slow varying open boundary data:
427            IF ( PRESENT(kit) ) THEN           
428               IF ( dta_bdy(ib_bdy)%ll_ssh ) dta_bdy(ib_bdy)%ssh(1:ilen0(1)) = dta_bdy_s(ib_bdy)%ssh(1:ilen0(1))
429               IF ( dta_bdy(ib_bdy)%ll_u2d ) dta_bdy(ib_bdy)%u2d(1:ilen0(2)) = dta_bdy_s(ib_bdy)%u2d(1:ilen0(2))
430               IF ( dta_bdy(ib_bdy)%ll_v2d ) dta_bdy(ib_bdy)%v2d(1:ilen0(3)) = dta_bdy_s(ib_bdy)%v2d(1:ilen0(3))
431            ENDIF
432            !
433            ! Update open boundary data arrays:
434            DO itide = 1, nb_harmo
435               !
436               z_sarg = (z_arg + zoff) * tide_harmonics(itide)%omega
437               z_cost = zramp * COS( z_sarg )
438               z_sist = zramp * SIN( z_sarg )
439               !
440               IF ( dta_bdy(ib_bdy)%ll_ssh ) THEN
441                  igrd=1                              ! SSH on tracer grid
442                  DO ib = 1, ilen0(igrd)
443                     dta_bdy(ib_bdy)%ssh(ib) = dta_bdy(ib_bdy)%ssh(ib) + &
444                        &                      ( tides(ib_bdy)%ssh(ib,itide,1)*z_cost + &
445                        &                        tides(ib_bdy)%ssh(ib,itide,2)*z_sist )
446                  END DO
447               ENDIF
448               !
449               IF ( dta_bdy(ib_bdy)%ll_u2d ) THEN
450                  igrd=2                              ! U grid
451                  DO ib = 1, ilen0(igrd)
452                     dta_bdy(ib_bdy)%u2d(ib) = dta_bdy(ib_bdy)%u2d(ib) + &
453                        &                      ( tides(ib_bdy)%u(ib,itide,1)*z_cost + &
454                        &                        tides(ib_bdy)%u(ib,itide,2)*z_sist )
455                  END DO
456               ENDIF
457               !
458               IF ( dta_bdy(ib_bdy)%ll_v2d ) THEN
459                  igrd=3                              ! V grid
460                  DO ib = 1, ilen0(igrd) 
461                     dta_bdy(ib_bdy)%v2d(ib) = dta_bdy(ib_bdy)%v2d(ib) + &
462                        &                      ( tides(ib_bdy)%v(ib,itide,1)*z_cost + &
463                        &                        tides(ib_bdy)%v(ib,itide,2)*z_sist )
464                  END DO
465               ENDIF
466            END DO             
467         END IF
468      END DO
469      !
470   END SUBROUTINE bdy_dta_tides
471
472
473   SUBROUTINE tide_init_elevation( idx, td )
474      !!----------------------------------------------------------------------
475      !!                 ***  ROUTINE tide_init_elevation  ***
476      !!----------------------------------------------------------------------
477      TYPE(OBC_INDEX) , INTENT(in   ) ::   idx   ! OBC indices
478      TYPE(TIDES_DATA), INTENT(inout) ::   td    ! tidal harmonics data
479      !
480      INTEGER ::   itide, igrd, ib       ! dummy loop indices
481      INTEGER, DIMENSION(1) ::   ilen0   ! length of boundary data (from OBC arrays)
482      REAL(wp),ALLOCATABLE, DIMENSION(:) ::   mod_tide, phi_tide
483      !!----------------------------------------------------------------------
484      !
485      igrd=1   
486                              ! SSH on tracer grid.
487      ilen0(1) =  SIZE(td%ssh0(:,1,1))
488      !
489      ALLOCATE( mod_tide(ilen0(igrd)), phi_tide(ilen0(igrd)) )
490      !
491      DO itide = 1, nb_harmo
492         DO ib = 1, ilen0(igrd)
493            mod_tide(ib)=SQRT(td%ssh0(ib,itide,1)**2.+td%ssh0(ib,itide,2)**2.)
494            phi_tide(ib)=ATAN2(-td%ssh0(ib,itide,2),td%ssh0(ib,itide,1))
495         END DO
496         DO ib = 1 , ilen0(igrd)
497            mod_tide(ib)=mod_tide(ib)*tide_harmonics(itide)%f
498            phi_tide(ib)=phi_tide(ib)+tide_harmonics(itide)%v0+tide_harmonics(itide)%u
499         ENDDO
500         DO ib = 1 , ilen0(igrd)
501            td%ssh(ib,itide,1)= mod_tide(ib)*COS(phi_tide(ib))
502            td%ssh(ib,itide,2)=-mod_tide(ib)*SIN(phi_tide(ib))
503         ENDDO
504      END DO
505      !
506      DEALLOCATE( mod_tide, phi_tide )
507      !
508   END SUBROUTINE tide_init_elevation
509
510
511   SUBROUTINE tide_init_velocities( idx, td )
512      !!----------------------------------------------------------------------
513      !!                 ***  ROUTINE tide_init_elevation  ***
514      !!----------------------------------------------------------------------
515      TYPE(OBC_INDEX) , INTENT(in   ) ::   idx   ! OBC indices
516      TYPE(TIDES_DATA), INTENT(inout) ::   td    ! tidal harmonics data
517      !
518      INTEGER ::   itide, igrd, ib       ! dummy loop indices
519      INTEGER, DIMENSION(3) ::   ilen0   ! length of boundary data (from OBC arrays)
520      REAL(wp),ALLOCATABLE, DIMENSION(:) ::   mod_tide, phi_tide
521      !!----------------------------------------------------------------------
522      !
523      ilen0(2) =  SIZE(td%u0(:,1,1))
524      ilen0(3) =  SIZE(td%v0(:,1,1))
525      !
526      igrd=2                                 ! U grid.
527      !
528      ALLOCATE( mod_tide(ilen0(igrd)) , phi_tide(ilen0(igrd)) )
529      !
530      DO itide = 1, nb_harmo
531         DO ib = 1, ilen0(igrd)
532            mod_tide(ib)=SQRT(td%u0(ib,itide,1)**2.+td%u0(ib,itide,2)**2.)
533            phi_tide(ib)=ATAN2(-td%u0(ib,itide,2),td%u0(ib,itide,1))
534         END DO
535         DO ib = 1, ilen0(igrd)
536            mod_tide(ib)=mod_tide(ib)*tide_harmonics(itide)%f
537            phi_tide(ib)=phi_tide(ib)+tide_harmonics(itide)%v0 + tide_harmonics(itide)%u
538         ENDDO
539         DO ib = 1, ilen0(igrd)
540            td%u(ib,itide,1)= mod_tide(ib)*COS(phi_tide(ib))
541            td%u(ib,itide,2)=-mod_tide(ib)*SIN(phi_tide(ib))
542         ENDDO
543      END DO
544      !
545      DEALLOCATE( mod_tide , phi_tide )
546      !
547      igrd=3                                 ! V grid.
548      !
549      ALLOCATE( mod_tide(ilen0(igrd)) , phi_tide(ilen0(igrd)) )
550
551      DO itide = 1, nb_harmo
552         DO ib = 1, ilen0(igrd)
553            mod_tide(ib)=SQRT(td%v0(ib,itide,1)**2.+td%v0(ib,itide,2)**2.)
554            phi_tide(ib)=ATAN2(-td%v0(ib,itide,2),td%v0(ib,itide,1))
555         END DO
556         DO ib = 1, ilen0(igrd)
557            mod_tide(ib)=mod_tide(ib)*tide_harmonics(itide)%f
558            phi_tide(ib)=phi_tide(ib)+tide_harmonics(itide)%v0 + tide_harmonics(itide)%u
559         ENDDO
560         DO ib = 1, ilen0(igrd)
561            td%v(ib,itide,1)= mod_tide(ib)*COS(phi_tide(ib))
562            td%v(ib,itide,2)=-mod_tide(ib)*SIN(phi_tide(ib))
563         ENDDO
564      END DO
565      !
566      DEALLOCATE( mod_tide, phi_tide )
567      !
568  END SUBROUTINE tide_init_velocities
569
570   !!======================================================================
571END MODULE bdytides
572
Note: See TracBrowser for help on using the repository browser.