New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
bdytides.F90 in NEMO/branches/2019/dev_r10742_ENHANCE-12_SimonM-Tides/src/OCE/BDY – NEMO

source: NEMO/branches/2019/dev_r10742_ENHANCE-12_SimonM-Tides/src/OCE/BDY/bdytides.F90 @ 12065

Last change on this file since 12065 was 12065, checked in by smueller, 4 years ago

Synchronizing with /NEMO/trunk@12055 (ticket #2194)
  • Property svn:keywords set to Id
File size: 26.7 KB
Line 
1MODULE bdytides
2   !!======================================================================
3   !!                       ***  MODULE  bdytides  ***
4   !! Ocean dynamics:   Tidal forcing at open boundaries
5   !!======================================================================
6   !! History :  2.0  !  2007-01  (D.Storkey)  Original code
7   !!            2.3  !  2008-01  (J.Holt)  Add date correction. Origins POLCOMS v6.3 2007
8   !!            3.0  !  2008-04  (NEMO team)  add in the reference version
9   !!            3.3  !  2010-09  (D.Storkey and E.O'Dea)  bug fixes
10   !!            3.4  !  2012-09  (G. Reffray and J. Chanut) New inputs + mods
11   !!            3.5  !  2013-07  (J. Chanut) Compliant with time splitting changes
12   !!----------------------------------------------------------------------
13   !!   bdytide_init  : read of namelist and initialisation of tidal harmonics data
14   !!   tide_update   : calculation of tidal forcing at each timestep
15   !!----------------------------------------------------------------------
16   USE oce            ! ocean dynamics and tracers
17   USE dom_oce        ! ocean space and time domain
18   USE phycst         ! physical constants
19   USE bdy_oce        ! ocean open boundary conditions
20   USE tide_mod       !
21   USE daymod         ! calendar
22   !
23   USE in_out_manager ! I/O units
24   USE iom            ! xIO server
25   USE fldread        !
26   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   bdytide_init     ! routine called in bdy_init
32   PUBLIC   bdytide_update   ! routine called in bdy_dta
33   PUBLIC   bdy_dta_tides    ! routine called in dyn_spg_ts
34
35   TYPE, PUBLIC ::   TIDES_DATA     !: Storage for external tidal harmonics data
36      REAL(wp), POINTER, DIMENSION(:,:,:)    ::   ssh0     !: Tidal constituents : SSH0   (read in file)
37      REAL(wp), POINTER, DIMENSION(:,:,:)    ::   u0, v0   !: Tidal constituents : U0, V0 (read in file)
38      REAL(wp), POINTER, DIMENSION(:,:,:)    ::   ssh      !: Tidal constituents : SSH    (after nodal cor.)
39      REAL(wp), POINTER, DIMENSION(:,:,:)    ::   u , v    !: Tidal constituents : U , V  (after nodal cor.)
40   END TYPE TIDES_DATA
41
42!$AGRIF_DO_NOT_TREAT
43   TYPE(TIDES_DATA), PUBLIC, DIMENSION(jp_bdy), TARGET :: tides  !: External tidal harmonics data
44!$AGRIF_END_DO_NOT_TREAT
45   TYPE(OBC_DATA)  , PUBLIC, DIMENSION(jp_bdy) :: dta_bdy_s  !: bdy external data (slow component)
46
47   INTEGER ::   kt_tide
48
49   !!----------------------------------------------------------------------
50   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
51   !! $Id$
52   !! Software governed by the CeCILL license (see ./LICENSE)
53   !!----------------------------------------------------------------------
54CONTAINS
55
56   SUBROUTINE bdytide_init
57      !!----------------------------------------------------------------------
58      !!                    ***  SUBROUTINE bdytide_init  ***
59      !!                     
60      !! ** Purpose : - Read in namelist for tides and initialise external
61      !!                tidal harmonics data
62      !!
63      !!----------------------------------------------------------------------
64      !! namelist variables
65      !!-------------------
66      CHARACTER(len=80)                         ::   filtide             !: Filename root for tidal input files
67      LOGICAL                                   ::   ln_bdytide_2ddta    !: If true, read 2d harmonic data
68      !!
69      INTEGER                                   ::   ib_bdy, itide, ib   !: dummy loop indices
70      INTEGER                                   ::   ii, ij              !: dummy loop indices
71      INTEGER                                   ::   inum, igrd
72      INTEGER, DIMENSION(3)                     ::   ilen0       !: length of boundary data (from OBC arrays)
73      INTEGER                                   ::   ios                 ! Local integer output status for namelist read
74      CHARACTER(len=80)                         ::   clfile              !: full file name for tidal input file
75      REAL(wp),ALLOCATABLE, DIMENSION(:,:,:)    ::   dta_read            !: work space to read in tidal harmonics data
76      REAL(wp),ALLOCATABLE, DIMENSION(:,:)      ::   ztr, zti            !:  "     "    "   "   "   "        "      "
77      !!
78      TYPE(TIDES_DATA),  POINTER                ::   td                  !: local short cut   
79      !!
80      NAMELIST/nambdy_tide/filtide, ln_bdytide_2ddta
81      !!----------------------------------------------------------------------
82      !
83      IF(lwp) WRITE(numout,*)
84      IF(lwp) WRITE(numout,*) 'bdytide_init : initialization of tidal harmonic forcing at open boundaries'
85      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~'
86
87      REWIND(numnam_cfg)
88
89      DO ib_bdy = 1, nb_bdy
90         IF( nn_dyn2d_dta(ib_bdy) >= 2 ) THEN
91            !
92            td => tides(ib_bdy)
93
94            ! Namelist nambdy_tide : tidal harmonic forcing at open boundaries
95            filtide(:) = ''
96
97            REWIND( numnam_ref )
98            READ  ( numnam_ref, nambdy_tide, IOSTAT = ios, ERR = 901)
99901         IF( ios /= 0 )   CALL ctl_nam ( ios , 'nambdy_tide in reference namelist' )
100            ! Don't REWIND here - may need to read more than one of these namelists.
101            READ  ( numnam_cfg, nambdy_tide, IOSTAT = ios, ERR = 902 )
102902         IF( ios >  0 )   CALL ctl_nam ( ios , 'nambdy_tide in configuration namelist' )
103            IF(lwm) WRITE ( numond, nambdy_tide )
104            !                                               ! Parameter control and print
105            IF(lwp) WRITE(numout,*) '  '
106            IF(lwp) WRITE(numout,*) '          Namelist nambdy_tide : tidal harmonic forcing at open boundaries'
107            IF(lwp) WRITE(numout,*) '             read tidal data in 2d files: ', ln_bdytide_2ddta
108            IF(lwp) WRITE(numout,*) '             Number of tidal components to read: ', nb_harmo
109            IF(lwp) THEN
110                    WRITE(numout,*) '             Tidal components: ' 
111               DO itide = 1, nb_harmo
112                  WRITE(numout,*)  '                 ', tide_harmonics(itide)%cname_tide 
113               END DO
114            ENDIF
115            IF(lwp) WRITE(numout,*) ' '
116
117            ! Allocate space for tidal harmonics data - get size from OBC data arrays
118            ! -----------------------------------------------------------------------
119
120            ! JC: If FRS scheme is used, we assume that tidal is needed over the whole
121            ! relaxation area     
122            IF( cn_dyn2d(ib_bdy) == 'frs' ) THEN   ;   ilen0(:) = idx_bdy(ib_bdy)%nblen   (:)
123            ELSE                                   ;   ilen0(:) = idx_bdy(ib_bdy)%nblenrim(:)
124            ENDIF
125
126            ALLOCATE( td%ssh0( ilen0(1), nb_harmo, 2 ) )
127            ALLOCATE( td%ssh ( ilen0(1), nb_harmo, 2 ) )
128
129            ALLOCATE( td%u0( ilen0(2), nb_harmo, 2 ) )
130            ALLOCATE( td%u ( ilen0(2), nb_harmo, 2 ) )
131
132            ALLOCATE( td%v0( ilen0(3), nb_harmo, 2 ) )
133            ALLOCATE( td%v ( ilen0(3), nb_harmo, 2 ) )
134
135            td%ssh0(:,:,:) = 0._wp
136            td%ssh (:,:,:) = 0._wp
137            td%u0  (:,:,:) = 0._wp
138            td%u   (:,:,:) = 0._wp
139            td%v0  (:,:,:) = 0._wp
140            td%v   (:,:,:) = 0._wp
141
142            IF( ln_bdytide_2ddta ) THEN
143               ! It is assumed that each data file contains all complex harmonic amplitudes
144               ! given on the global domain (ie global, jpiglo x jpjglo)
145               !
146               ALLOCATE( zti(jpi,jpj), ztr(jpi,jpj) )
147               !
148               ! SSH fields
149               clfile = TRIM(filtide)//'_grid_T.nc'
150               CALL iom_open( clfile , inum ) 
151               igrd = 1                       ! Everything is at T-points here
152               DO itide = 1, nb_harmo
153                  CALL iom_get( inum, jpdom_autoglo, TRIM(tide_harmonics(itide)%cname_tide)//'_z1', ztr(:,:) )
154                  CALL iom_get( inum, jpdom_autoglo, TRIM(tide_harmonics(itide)%cname_tide)//'_z2', zti(:,:) ) 
155                  DO ib = 1, ilen0(igrd)
156                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
157                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
158                     IF( ii == 1 .OR. ii == jpi .OR. ij == 1 .OR. ij == jpj )  CYCLE   ! to remove?
159                     td%ssh0(ib,itide,1) = ztr(ii,ij)
160                     td%ssh0(ib,itide,2) = zti(ii,ij)
161                  END DO
162               END DO
163               CALL iom_close( inum )
164               !
165               ! U fields
166               clfile = TRIM(filtide)//'_grid_U.nc'
167               CALL iom_open( clfile , inum ) 
168               igrd = 2                       ! Everything is at U-points here
169               DO itide = 1, nb_harmo
170                  CALL iom_get  ( inum, jpdom_autoglo, TRIM(tide_harmonics(itide)%cname_tide)//'_u1', ztr(:,:) )
171                  CALL iom_get  ( inum, jpdom_autoglo, TRIM(tide_harmonics(itide)%cname_tide)//'_u2', zti(:,:) )
172                  DO ib = 1, ilen0(igrd)
173                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
174                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
175                     IF( ii == 1 .OR. ii == jpi .OR. ij == 1 .OR. ij == jpj )  CYCLE   ! to remove?
176                     td%u0(ib,itide,1) = ztr(ii,ij)
177                     td%u0(ib,itide,2) = zti(ii,ij)
178                  END DO
179               END DO
180               CALL iom_close( inum )
181               !
182               ! V fields
183               clfile = TRIM(filtide)//'_grid_V.nc'
184               CALL iom_open( clfile , inum ) 
185               igrd = 3                       ! Everything is at V-points here
186               DO itide = 1, nb_harmo
187                  CALL iom_get  ( inum, jpdom_autoglo, TRIM(tide_harmonics(itide)%cname_tide)//'_v1', ztr(:,:) )
188                  CALL iom_get  ( inum, jpdom_autoglo, TRIM(tide_harmonics(itide)%cname_tide)//'_v2', zti(:,:) )
189                  DO ib = 1, ilen0(igrd)
190                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
191                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
192                     IF( ii == 1 .OR. ii == jpi .OR. ij == 1 .OR. ij == jpj )  CYCLE   ! to remove?
193                     td%v0(ib,itide,1) = ztr(ii,ij)
194                     td%v0(ib,itide,2) = zti(ii,ij)
195                  END DO
196               END DO 
197               CALL iom_close( inum )
198               !
199               DEALLOCATE( ztr, zti ) 
200               !
201            ELSE           
202               !
203               ! Read tidal data only on bdy segments
204               !
205               ALLOCATE( dta_read( MAXVAL(ilen0(1:3)), 1, 1 ) )
206               !
207               ! Open files and read in tidal forcing data
208               ! -----------------------------------------
209
210               DO itide = 1, nb_harmo
211                  !                                                              ! SSH fields
212                  clfile = TRIM(filtide)//TRIM(tide_harmonics(itide)%cname_tide)//'_grid_T.nc'
213                  CALL iom_open( clfile, inum )
214                  CALL fld_map( inum, 'z1' , dta_read(1:ilen0(1),1:1,1:1) , 1, idx_bdy(ib_bdy)%nbmap(:,1) )
215                  td%ssh0(:,itide,1) = dta_read(1:ilen0(1),1,1)
216                  CALL fld_map( inum, 'z2' , dta_read(1:ilen0(1),1:1,1:1) , 1, idx_bdy(ib_bdy)%nbmap(:,1) )
217                  td%ssh0(:,itide,2) = dta_read(1:ilen0(1),1,1)
218                  CALL iom_close( inum )
219                  !                                                              ! U fields
220                  clfile = TRIM(filtide)//TRIM(tide_harmonics(itide)%cname_tide)//'_grid_U.nc'
221                  CALL iom_open( clfile, inum )
222                  CALL fld_map( inum, 'u1' , dta_read(1:ilen0(2),1:1,1:1) , 1, idx_bdy(ib_bdy)%nbmap(:,2) )
223                  td%u0(:,itide,1) = dta_read(1:ilen0(2),1,1)
224                  CALL fld_map( inum, 'u2' , dta_read(1:ilen0(2),1:1,1:1) , 1, idx_bdy(ib_bdy)%nbmap(:,2) )
225                  td%u0(:,itide,2) = dta_read(1:ilen0(2),1,1)
226                  CALL iom_close( inum )
227                  !                                                              ! V fields
228                  clfile = TRIM(filtide)//TRIM(tide_harmonics(itide)%cname_tide)//'_grid_V.nc'
229                  CALL iom_open( clfile, inum )
230                  CALL fld_map( inum, 'v1' , dta_read(1:ilen0(3),1:1,1:1) , 1, idx_bdy(ib_bdy)%nbmap(:,3) )
231                  td%v0(:,itide,1) = dta_read(1:ilen0(3),1,1)
232                  CALL fld_map( inum, 'v2' , dta_read(1:ilen0(3),1:1,1:1) , 1, idx_bdy(ib_bdy)%nbmap(:,3) )
233                  td%v0(:,itide,2) = dta_read(1:ilen0(3),1,1)
234                  CALL iom_close( inum )
235                  !
236               END DO ! end loop on tidal components
237               !
238               DEALLOCATE( dta_read )
239               !
240            ENDIF ! ln_bdytide_2ddta=.true.
241            !
242            ! Allocate slow varying data in the case of time splitting:
243            ! Do it anyway because at this stage knowledge of free surface scheme is unknown
244            ALLOCATE( dta_bdy_s(ib_bdy)%ssh ( ilen0(1) ) )
245            ALLOCATE( dta_bdy_s(ib_bdy)%u2d ( ilen0(2) ) )
246            ALLOCATE( dta_bdy_s(ib_bdy)%v2d ( ilen0(3) ) )
247            dta_bdy_s(ib_bdy)%ssh(:) = 0._wp
248            dta_bdy_s(ib_bdy)%u2d(:) = 0._wp
249            dta_bdy_s(ib_bdy)%v2d(:) = 0._wp
250            !
251         ENDIF ! nn_dyn2d_dta(ib_bdy) >= 2
252         !
253      END DO ! loop on ib_bdy
254      !
255   END SUBROUTINE bdytide_init
256
257
258   SUBROUTINE bdytide_update( kt, idx, dta, td, kit, kt_offset )
259      !!----------------------------------------------------------------------
260      !!                 ***  SUBROUTINE bdytide_update  ***
261      !!               
262      !! ** Purpose : - Add tidal forcing to ssh, u2d and v2d OBC data arrays.
263      !!               
264      !!----------------------------------------------------------------------
265      INTEGER          , INTENT(in   ) ::   kt          ! Main timestep counter
266      TYPE(OBC_INDEX)  , INTENT(in   ) ::   idx         ! OBC indices
267      TYPE(OBC_DATA)   , INTENT(inout) ::   dta         ! OBC external data
268      TYPE(TIDES_DATA) , INTENT(inout) ::   td          ! tidal harmonics data
269      INTEGER, OPTIONAL, INTENT(in   ) ::   kit         ! Barotropic timestep counter (for timesplitting option)
270      INTEGER, OPTIONAL, INTENT(in   ) ::   kt_offset   ! time offset in units of timesteps. NB. if kit
271      !                                                 ! is present then units = subcycle timesteps.
272      !                                                 ! kt_offset = 0  => get data at "now"    time level
273      !                                                 ! kt_offset = -1 => get data at "before" time level
274      !                                                 ! kt_offset = +1 => get data at "after"  time level
275      !                                                 ! etc.
276      !
277      INTEGER  ::   itide, igrd, ib       ! dummy loop indices
278      INTEGER  ::   time_add              ! time offset in units of timesteps
279      INTEGER, DIMENSION(3) ::   ilen0    ! length of boundary data (from OBC arrays)
280      REAL(wp) ::   z_arg, z_sarg, zflag, zramp   ! local scalars   
281      REAL(wp), DIMENSION(jpmax_harmo) :: z_sist, z_cost
282      !!----------------------------------------------------------------------
283      !
284      ilen0(1) =  SIZE(td%ssh(:,1,1))
285      ilen0(2) =  SIZE(td%u(:,1,1))
286      ilen0(3) =  SIZE(td%v(:,1,1))
287
288      zflag=1
289      IF ( PRESENT(kit) ) THEN
290        IF ( kit /= 1 ) zflag=0
291      ENDIF
292
293      IF ( (nsec_day == NINT(0.5_wp * rdt) .OR. kt==nit000) .AND. zflag==1 ) THEN
294        !
295        kt_tide = kt - (nsec_day - 0.5_wp * rdt)/rdt
296        !
297        IF(lwp) THEN
298           WRITE(numout,*)
299           WRITE(numout,*) 'bdytide_update : (re)Initialization of the tidal bdy forcing at kt=',kt
300           WRITE(numout,*) '~~~~~~~~~~~~~~ '
301        ENDIF
302        !
303        CALL tide_init_elevation ( idx, td )
304        CALL tide_init_velocities( idx, td )
305        !
306      ENDIF
307
308      time_add = 0
309      IF( PRESENT(kt_offset) ) THEN
310         time_add = kt_offset
311      ENDIF
312         
313      IF( PRESENT(kit) ) THEN 
314         z_arg = ((kt-kt_tide) * rdt + (kit+0.5_wp*(time_add-1)) * rdt / REAL(nn_baro,wp) )
315      ELSE                             
316         z_arg = ((kt-kt_tide)+time_add) * rdt
317      ENDIF
318
319      ! Linear ramp on tidal component at open boundaries
320      zramp = 1._wp
321      IF (ln_tide_ramp) zramp = MIN(MAX( (z_arg + (kt_tide-nit000)*rdt)/(rn_tide_ramp_dt*rday),0._wp),1._wp)
322
323      DO itide = 1, nb_harmo
324         z_sarg = z_arg * tide_harmonics(itide)%omega
325         z_cost(itide) = COS( z_sarg )
326         z_sist(itide) = SIN( z_sarg )
327      END DO
328
329      DO itide = 1, nb_harmo
330         igrd=1                              ! SSH on tracer grid
331         DO ib = 1, ilen0(igrd)
332            dta%ssh(ib) = dta%ssh(ib) + zramp*(td%ssh(ib,itide,1)*z_cost(itide) + td%ssh(ib,itide,2)*z_sist(itide))
333         END DO
334         igrd=2                              ! U grid
335         DO ib = 1, ilen0(igrd)
336            dta%u2d(ib) = dta%u2d(ib) + zramp*(td%u  (ib,itide,1)*z_cost(itide) + td%u  (ib,itide,2)*z_sist(itide))
337         END DO
338         igrd=3                              ! V grid
339         DO ib = 1, ilen0(igrd) 
340            dta%v2d(ib) = dta%v2d(ib) + zramp*(td%v  (ib,itide,1)*z_cost(itide) + td%v  (ib,itide,2)*z_sist(itide))
341         END DO
342      END DO
343      !
344   END SUBROUTINE bdytide_update
345
346
347   SUBROUTINE bdy_dta_tides( kt, kit, kt_offset )
348      !!----------------------------------------------------------------------
349      !!                 ***  SUBROUTINE bdy_dta_tides  ***
350      !!               
351      !! ** Purpose : - Add tidal forcing to ssh, u2d and v2d OBC data arrays.
352      !!               
353      !!----------------------------------------------------------------------
354      INTEGER,           INTENT(in) ::   kt          ! Main timestep counter
355      INTEGER, OPTIONAL, INTENT(in) ::   kit         ! Barotropic timestep counter (for timesplitting option)
356      INTEGER, OPTIONAL, INTENT(in) ::   kt_offset   ! time offset in units of timesteps. NB. if kit
357      !                                              ! is present then units = subcycle timesteps.
358      !                                              ! kt_offset = 0  => get data at "now"    time level
359      !                                              ! kt_offset = -1 => get data at "before" time level
360      !                                              ! kt_offset = +1 => get data at "after"  time level
361      !                                              ! etc.
362      !
363      LOGICAL  ::   lk_first_btstp            ! =.TRUE. if time splitting and first barotropic step
364      INTEGER  ::   itide, ib_bdy, ib, igrd   ! loop indices
365      INTEGER  ::   time_add                  ! time offset in units of timesteps
366      INTEGER, DIMENSION(jpbgrd)   ::   ilen0 
367      INTEGER, DIMENSION(1:jpbgrd) ::   nblen, nblenrim  ! short cuts
368      REAL(wp) ::   z_arg, z_sarg, zramp, zoff, z_cost, z_sist     
369      !!----------------------------------------------------------------------
370      !
371      lk_first_btstp=.TRUE.
372      IF ( PRESENT(kit).AND.( kit /= 1 ) ) THEN ; lk_first_btstp=.FALSE. ; ENDIF
373
374      time_add = 0
375      IF( PRESENT(kt_offset) ) THEN
376         time_add = kt_offset
377      ENDIF
378     
379      ! Absolute time from model initialization:   
380      IF( PRESENT(kit) ) THEN 
381         z_arg = ( kt + (kit+time_add-1) / REAL(nn_baro,wp) ) * rdt
382      ELSE                             
383         z_arg = ( kt + time_add ) * rdt
384      ENDIF
385
386      ! Linear ramp on tidal component at open boundaries
387      zramp = 1.
388      IF (ln_tide_ramp) zramp = MIN(MAX( (z_arg - nit000*rdt)/(rn_tide_ramp_dt*rday),0.),1.)
389
390      DO ib_bdy = 1,nb_bdy
391         !
392         IF( nn_dyn2d_dta(ib_bdy) >= 2 ) THEN
393            !
394            nblen(1:jpbgrd) = idx_bdy(ib_bdy)%nblen(1:jpbgrd)
395            nblenrim(1:jpbgrd) = idx_bdy(ib_bdy)%nblenrim(1:jpbgrd)
396            !
397            IF( cn_dyn2d(ib_bdy) == 'frs' ) THEN   ;   ilen0(:) = nblen   (:)
398            ELSE                                   ;   ilen0(:) = nblenrim(:)
399            ENDIF     
400            !
401            ! We refresh nodal factors every day below
402            ! This should be done somewhere else
403            IF ( ( nsec_day == NINT(0.5_wp * rdt) .OR. kt==nit000 ) .AND. lk_first_btstp ) THEN
404               !
405               kt_tide = kt - (nsec_day - 0.5_wp * rdt)/rdt
406               !
407               IF(lwp) THEN
408               WRITE(numout,*)
409               WRITE(numout,*) 'bdy_tide_dta : Refresh nodal factors for tidal open bdy data at kt=',kt
410               WRITE(numout,*) '~~~~~~~~~~~~~~ '
411               ENDIF
412               !
413               CALL tide_init_elevation ( idx=idx_bdy(ib_bdy), td=tides(ib_bdy) )
414               CALL tide_init_velocities( idx=idx_bdy(ib_bdy), td=tides(ib_bdy) )
415               !
416            ENDIF
417            zoff = -kt_tide * rdt ! time offset relative to nodal factor computation time
418            !
419            ! If time splitting, initialize arrays from slow varying open boundary data:
420            IF ( PRESENT(kit) ) THEN           
421               IF ( dta_bdy(ib_bdy)%lneed_ssh   ) dta_bdy(ib_bdy)%ssh(1:ilen0(1)) = dta_bdy_s(ib_bdy)%ssh(1:ilen0(1))
422               IF ( dta_bdy(ib_bdy)%lneed_dyn2d ) dta_bdy(ib_bdy)%u2d(1:ilen0(2)) = dta_bdy_s(ib_bdy)%u2d(1:ilen0(2))
423               IF ( dta_bdy(ib_bdy)%lneed_dyn2d ) dta_bdy(ib_bdy)%v2d(1:ilen0(3)) = dta_bdy_s(ib_bdy)%v2d(1:ilen0(3))
424            ENDIF
425            !
426            ! Update open boundary data arrays:
427            DO itide = 1, nb_harmo
428               !
429               z_sarg = (z_arg + zoff) * tide_harmonics(itide)%omega
430               z_cost = zramp * COS( z_sarg )
431               z_sist = zramp * SIN( z_sarg )
432               !
433               IF ( dta_bdy(ib_bdy)%lneed_ssh ) THEN
434                  igrd=1                              ! SSH on tracer grid
435                  DO ib = 1, ilen0(igrd)
436                     dta_bdy(ib_bdy)%ssh(ib) = dta_bdy(ib_bdy)%ssh(ib) + &
437                        &                      ( tides(ib_bdy)%ssh(ib,itide,1)*z_cost + &
438                        &                        tides(ib_bdy)%ssh(ib,itide,2)*z_sist )
439                  END DO
440               ENDIF
441               !
442               IF ( dta_bdy(ib_bdy)%lneed_dyn2d ) THEN
443                  igrd=2                              ! U grid
444                  DO ib = 1, ilen0(igrd)
445                     dta_bdy(ib_bdy)%u2d(ib) = dta_bdy(ib_bdy)%u2d(ib) + &
446                        &                      ( tides(ib_bdy)%u(ib,itide,1)*z_cost + &
447                        &                        tides(ib_bdy)%u(ib,itide,2)*z_sist )
448                  END DO
449                  igrd=3                              ! V grid
450                  DO ib = 1, ilen0(igrd) 
451                     dta_bdy(ib_bdy)%v2d(ib) = dta_bdy(ib_bdy)%v2d(ib) + &
452                        &                      ( tides(ib_bdy)%v(ib,itide,1)*z_cost + &
453                        &                        tides(ib_bdy)%v(ib,itide,2)*z_sist )
454                  END DO
455               ENDIF
456            END DO             
457         END IF
458      END DO
459      !
460   END SUBROUTINE bdy_dta_tides
461
462
463   SUBROUTINE tide_init_elevation( idx, td )
464      !!----------------------------------------------------------------------
465      !!                 ***  ROUTINE tide_init_elevation  ***
466      !!----------------------------------------------------------------------
467      TYPE(OBC_INDEX) , INTENT(in   ) ::   idx   ! OBC indices
468      TYPE(TIDES_DATA), INTENT(inout) ::   td    ! tidal harmonics data
469      !
470      INTEGER ::   itide, igrd, ib       ! dummy loop indices
471      INTEGER, DIMENSION(1) ::   ilen0   ! length of boundary data (from OBC arrays)
472      REAL(wp),ALLOCATABLE, DIMENSION(:) ::   mod_tide, phi_tide
473      !!----------------------------------------------------------------------
474      !
475      igrd=1   
476                              ! SSH on tracer grid.
477      ilen0(1) =  SIZE(td%ssh0(:,1,1))
478      !
479      ALLOCATE( mod_tide(ilen0(igrd)), phi_tide(ilen0(igrd)) )
480      !
481      DO itide = 1, nb_harmo
482         DO ib = 1, ilen0(igrd)
483            mod_tide(ib)=SQRT(td%ssh0(ib,itide,1)**2.+td%ssh0(ib,itide,2)**2.)
484            phi_tide(ib)=ATAN2(-td%ssh0(ib,itide,2),td%ssh0(ib,itide,1))
485         END DO
486         DO ib = 1 , ilen0(igrd)
487            mod_tide(ib)=mod_tide(ib)*tide_harmonics(itide)%f
488            phi_tide(ib)=phi_tide(ib)+tide_harmonics(itide)%v0+tide_harmonics(itide)%u
489         ENDDO
490         DO ib = 1 , ilen0(igrd)
491            td%ssh(ib,itide,1)= mod_tide(ib)*COS(phi_tide(ib))
492            td%ssh(ib,itide,2)=-mod_tide(ib)*SIN(phi_tide(ib))
493         ENDDO
494      END DO
495      !
496      DEALLOCATE( mod_tide, phi_tide )
497      !
498   END SUBROUTINE tide_init_elevation
499
500
501   SUBROUTINE tide_init_velocities( idx, td )
502      !!----------------------------------------------------------------------
503      !!                 ***  ROUTINE tide_init_elevation  ***
504      !!----------------------------------------------------------------------
505      TYPE(OBC_INDEX) , INTENT(in   ) ::   idx   ! OBC indices
506      TYPE(TIDES_DATA), INTENT(inout) ::   td    ! tidal harmonics data
507      !
508      INTEGER ::   itide, igrd, ib       ! dummy loop indices
509      INTEGER, DIMENSION(3) ::   ilen0   ! length of boundary data (from OBC arrays)
510      REAL(wp),ALLOCATABLE, DIMENSION(:) ::   mod_tide, phi_tide
511      !!----------------------------------------------------------------------
512      !
513      ilen0(2) =  SIZE(td%u0(:,1,1))
514      ilen0(3) =  SIZE(td%v0(:,1,1))
515      !
516      igrd=2                                 ! U grid.
517      !
518      ALLOCATE( mod_tide(ilen0(igrd)) , phi_tide(ilen0(igrd)) )
519      !
520      DO itide = 1, nb_harmo
521         DO ib = 1, ilen0(igrd)
522            mod_tide(ib)=SQRT(td%u0(ib,itide,1)**2.+td%u0(ib,itide,2)**2.)
523            phi_tide(ib)=ATAN2(-td%u0(ib,itide,2),td%u0(ib,itide,1))
524         END DO
525         DO ib = 1, ilen0(igrd)
526            mod_tide(ib)=mod_tide(ib)*tide_harmonics(itide)%f
527            phi_tide(ib)=phi_tide(ib)+tide_harmonics(itide)%v0 + tide_harmonics(itide)%u
528         ENDDO
529         DO ib = 1, ilen0(igrd)
530            td%u(ib,itide,1)= mod_tide(ib)*COS(phi_tide(ib))
531            td%u(ib,itide,2)=-mod_tide(ib)*SIN(phi_tide(ib))
532         ENDDO
533      END DO
534      !
535      DEALLOCATE( mod_tide , phi_tide )
536      !
537      igrd=3                                 ! V grid.
538      !
539      ALLOCATE( mod_tide(ilen0(igrd)) , phi_tide(ilen0(igrd)) )
540
541      DO itide = 1, nb_harmo
542         DO ib = 1, ilen0(igrd)
543            mod_tide(ib)=SQRT(td%v0(ib,itide,1)**2.+td%v0(ib,itide,2)**2.)
544            phi_tide(ib)=ATAN2(-td%v0(ib,itide,2),td%v0(ib,itide,1))
545         END DO
546         DO ib = 1, ilen0(igrd)
547            mod_tide(ib)=mod_tide(ib)*tide_harmonics(itide)%f
548            phi_tide(ib)=phi_tide(ib)+tide_harmonics(itide)%v0 + tide_harmonics(itide)%u
549         ENDDO
550         DO ib = 1, ilen0(igrd)
551            td%v(ib,itide,1)= mod_tide(ib)*COS(phi_tide(ib))
552            td%v(ib,itide,2)=-mod_tide(ib)*SIN(phi_tide(ib))
553         ENDDO
554      END DO
555      !
556      DEALLOCATE( mod_tide, phi_tide )
557      !
558  END SUBROUTINE tide_init_velocities
559
560   !!======================================================================
561END MODULE bdytides
562
Note: See TracBrowser for help on using the repository browser.