New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
tide_mod.F90 in NEMO/branches/2019/dev_r10742_ENHANCE-12_SimonM-Tides/src/OCE/TDE – NEMO

source: NEMO/branches/2019/dev_r10742_ENHANCE-12_SimonM-Tides/src/OCE/TDE/tide_mod.F90 @ 11663

Last change on this file since 11663 was 11663, checked in by smueller, 5 years ago

Addition of a namelist parameter to enable the selectability of alternative tidal parameter sets and tide-potential computations
  • Property svn:keywords set to Id
File size: 32.6 KB
Line 
1MODULE tide_mod
2   !!======================================================================
3   !!                       ***  MODULE  tide_mod  ***
4   !! Compute nodal modulations corrections and pulsations
5   !!======================================================================
6   !! History :  1.0  !  2007  (O. Le Galloudec)  Original code
7   !!----------------------------------------------------------------------
8   USE oce            ! ocean dynamics and tracers variables
9   USE dom_oce        ! ocean space and time domain
10   USE phycst         ! physical constant
11   USE daymod         ! calendar
12   !
13   USE in_out_manager ! I/O units
14   USE iom            ! xIOs server
15   USE ioipsl         ! NetCDF IPSL library
16   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
17
18   IMPLICIT NONE
19   PRIVATE
20
21   PUBLIC   tide_init
22   PUBLIC   tide_update          ! called by stp
23   PUBLIC   tide_init_harmonics  ! called internally and by module diaharm
24   PUBLIC   upd_tide         ! called in dynspg_... modules
25
26   INTEGER, PUBLIC, PARAMETER ::   jpmax_harmo = 64   !: maximum number of harmonic components
27
28   TYPE ::    tide
29      CHARACTER(LEN=4) ::   cname_tide = ''
30      REAL(wp)         ::   equitide
31      INTEGER          ::   nutide
32      INTEGER          ::   nt, ns, nh, np, np1, shift
33      INTEGER          ::   nksi, nnu0, nnu1, nnu2, R
34      INTEGER          ::   nformula
35   END TYPE tide
36
37   TYPE(tide), DIMENSION(:), POINTER ::   tide_components !: Array of selected tidal component parameters
38
39   TYPE, PUBLIC ::   tide_harmonic       !:   Oscillation parameters of harmonic tidal components
40      CHARACTER(LEN=4) ::   cname_tide   !    Name of component
41      REAL(wp)         ::   equitide     !    Amplitude of equilibrium tide
42      REAL(wp)         ::   f            !    Node factor
43      REAL(wp)         ::   omega        !    Angular velocity
44      REAL(wp)         ::   v0           !    Initial phase at prime meridian
45      REAL(wp)         ::   u            !    Phase correction
46   END type tide_harmonic
47
48   TYPE(tide_harmonic), PUBLIC, DIMENSION(:), POINTER ::   tide_harmonics !: Oscillation parameters of selected tidal components
49
50   LOGICAL , PUBLIC ::   ln_tide         !:
51   LOGICAL , PUBLIC ::   ln_tide_pot     !:
52   INTEGER          ::   nn_tide_var     !  Variant of tidal parameter set and tide-potential computation
53   LOGICAL          ::   ln_read_load    !:
54   LOGICAL , PUBLIC ::   ln_scal_load    !:
55   LOGICAL , PUBLIC ::   ln_tide_ramp    !:
56   INTEGER , PUBLIC ::   nb_harmo        !: Number of active tidal components
57   REAL(wp), PUBLIC ::   rn_tide_ramp_dt     !:
58   REAL(wp), PUBLIC ::   rn_scal_load    !:
59   CHARACTER(lc), PUBLIC ::   cn_tide_load   !:
60   REAL(wp)         ::   rn_tide_gamma   ! Tidal tilt factor
61
62   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   pot_astro !: tidal potential
63   REAL(wp),         ALLOCATABLE, DIMENSION(:,:,:) ::   amp_pot, phi_pot
64   REAL(wp),         ALLOCATABLE, DIMENSION(:,:,:) ::   amp_load, phi_load
65
66   REAL(wp) ::   rn_tide_ramp_t !   Elapsed time in seconds
67
68   REAL(wp) ::   sh_T, sh_s, sh_h, sh_p, sh_p1             ! astronomic angles
69   REAL(wp) ::   sh_xi, sh_nu, sh_nuprim, sh_nusec, sh_R   !
70   REAL(wp) ::   sh_I, sh_x1ra, sh_N                       !
71
72   !!----------------------------------------------------------------------
73   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
74   !! $Id$
75   !! Software governed by the CeCILL license (see ./LICENSE)
76   !!----------------------------------------------------------------------
77CONTAINS
78
79   SUBROUTINE tide_init
80      !!----------------------------------------------------------------------
81      !!                 ***  ROUTINE tide_init  ***
82      !!----------------------------------------------------------------------     
83      INTEGER  :: ji, jk
84      CHARACTER(LEN=4), DIMENSION(jpmax_harmo) :: sn_tide_cnames ! Names of selected tidal components
85      INTEGER  ::   ios                 ! Local integer output status for namelist read
86      !
87      NAMELIST/nam_tide/ln_tide, nn_tide_var, ln_tide_pot, rn_tide_gamma, &
88         &              ln_scal_load, ln_read_load, cn_tide_load,         &
89         &              ln_tide_ramp, rn_scal_load, rn_tide_ramp_dt,      &
90         &              sn_tide_cnames
91      !!----------------------------------------------------------------------
92      !
93      ! Initialise all array elements of sn_tide_cnames, as some of them
94      ! typically do not appear in namelist_ref or namelist_cfg
95      sn_tide_cnames(:) = ''
96      ! Read Namelist nam_tide
97      REWIND( numnam_ref )              ! Namelist nam_tide in reference namelist : Tides
98      READ  ( numnam_ref, nam_tide, IOSTAT = ios, ERR = 901)
99901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nam_tide in reference namelist', lwp )
100      !
101      REWIND( numnam_cfg )              ! Namelist nam_tide in configuration namelist : Tides
102      READ  ( numnam_cfg, nam_tide, IOSTAT = ios, ERR = 902 )
103902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nam_tide in configuration namelist', lwp )
104      IF(lwm) WRITE ( numond, nam_tide )
105      !
106      IF( ln_tide ) THEN
107         IF (lwp) THEN
108            WRITE(numout,*)
109            WRITE(numout,*) 'tide_init : Initialization of the tidal components'
110            WRITE(numout,*) '~~~~~~~~~ '
111            WRITE(numout,*) '   Namelist nam_tide'
112            WRITE(numout,*) '      Use tidal components                       ln_tide         = ', ln_tide
113            WRITE(numout,*) '         Variant (0: legacy option)              nn_tide_var     = ', nn_tide_var
114            WRITE(numout,*) '         Apply astronomical potential            ln_tide_pot     = ', ln_tide_pot
115            WRITE(numout,*) '         Tidal tilt factor                       rn_tide_gamma   = ', rn_tide_gamma
116            WRITE(numout,*) '         Use scalar approx. for load potential   ln_scal_load    = ', ln_scal_load
117            WRITE(numout,*) '         Read load potential from file           ln_read_load    = ', ln_read_load
118            WRITE(numout,*) '         Apply ramp on tides at startup          ln_tide_ramp    = ', ln_tide_ramp
119            WRITE(numout,*) '         Fraction of SSH used in scal. approx.   rn_scal_load    = ', rn_scal_load
120            WRITE(numout,*) '         Duration (days) of ramp                 rn_tide_ramp_dt = ', rn_tide_ramp_dt
121         ENDIF
122      ELSE
123         rn_scal_load = 0._wp 
124
125         IF(lwp) WRITE(numout,*)
126         IF(lwp) WRITE(numout,*) 'tide_init : tidal components not used (ln_tide = F)'
127         IF(lwp) WRITE(numout,*) '~~~~~~~~~ '
128         RETURN
129      ENDIF
130      !
131      IF( ln_read_load.AND.(.NOT.ln_tide_pot) ) &
132          &   CALL ctl_stop('ln_read_load requires ln_tide_pot')
133      IF( ln_scal_load.AND.(.NOT.ln_tide_pot) ) &
134          &   CALL ctl_stop('ln_scal_load requires ln_tide_pot')
135      IF( ln_scal_load.AND.ln_read_load ) &
136          &   CALL ctl_stop('Choose between ln_scal_load and ln_read_load')
137      IF( ln_tide_ramp.AND.((nitend-nit000+1)*rdt/rday < rn_tide_ramp_dt) )   &
138         &   CALL ctl_stop('rn_tide_ramp_dt must be lower than run duration')
139      IF( ln_tide_ramp.AND.(rn_tide_ramp_dt<0.) ) &
140         &   CALL ctl_stop('rn_tide_ramp_dt must be positive')
141      !
142      ! Initialise array used to store tidal oscillation parameters (frequency,
143      ! amplitude, phase); also retrieve and store array of information about
144      ! selected tidal components
145      CALL tide_init_harmonics(sn_tide_cnames, tide_harmonics, tide_components)
146      !
147      ! Number of active tidal components
148      nb_harmo = size(tide_components)
149      !       
150      ! Ensure that tidal components have been set in namelist_cfg
151      IF( nb_harmo == 0 )   CALL ctl_stop( 'tide_init : No tidal components set in nam_tide' )
152      !
153      IF (.NOT.ln_scal_load ) rn_scal_load = 0._wp
154      !
155      ALLOCATE( amp_pot(jpi,jpj,nb_harmo),                      &
156           &      phi_pot(jpi,jpj,nb_harmo), pot_astro(jpi,jpj)   )
157      IF( ln_read_load ) THEN
158         ALLOCATE( amp_load(jpi,jpj,nb_harmo), phi_load(jpi,jpj,nb_harmo) )
159         CALL tide_init_load
160         amp_pot(:,:,:) = amp_load(:,:,:)
161         phi_pot(:,:,:) = phi_load(:,:,:)
162      ELSE     
163         amp_pot(:,:,:) = 0._wp
164         phi_pot(:,:,:) = 0._wp   
165      ENDIF
166      !
167   END SUBROUTINE tide_init
168
169
170   SUBROUTINE tide_init_components(pcnames, ptide_comp)
171      !!----------------------------------------------------------------------
172      !!                 ***  ROUTINE tide_init_components  ***
173      !!
174      !! Returns pointer to array of variables of type 'tide' that contain
175      !! information about the selected tidal components
176      !! ----------------------------------------------------------------------
177      CHARACTER(LEN=4),              DIMENSION(jpmax_harmo), INTENT(in)  ::   pcnames         ! Names of selected components
178      TYPE(tide),       POINTER,     DIMENSION(:),           INTENT(out) ::   ptide_comp      ! Selected components
179      INTEGER,          ALLOCATABLE, DIMENSION(:)                        ::   kcomppos        ! Indices of selected components
180      INTEGER                                                            ::   kcomp, jk, ji   ! Miscellaneous integers
181      TYPE(tide),       POINTER,     DIMENSION(:)                        ::   tide_components ! All available components
182     
183      ! Populate local array with information about all available tidal
184      ! components
185      !
186      ! Note, here 'tide_components' locally overrides the global module
187      ! variable of the same name to enable the use of the global name in the
188      ! include file that contains the initialisation of elements of array
189      ! 'tide_components'
190      ALLOCATE(tide_components(jpmax_harmo), kcomppos(jpmax_harmo))
191      ! Initialise array of indices of the selected componenents
192      kcomppos(:) = 0
193      ! Include tidal component parameters for all available components
194#include "tide.h90"
195     
196      ! Identify the selected components that are availble
197      kcomp = 0
198      DO jk = 1, jpmax_harmo
199         IF (TRIM(pcnames(jk)) /= '') THEN
200            DO ji = 1, jpmax_harmo
201               IF (TRIM(pcnames(jk)) == tide_components(ji)%cname_tide) THEN
202                  kcomp = kcomp + 1
203                  WRITE(numout, '(10X,"Tidal component #",I2.2,36X,"= ",A4)') kcomp, pcnames(jk)
204                  kcomppos(kcomp) = ji
205                  EXIT
206               END IF
207            END DO
208         END IF
209      END DO
210     
211      ! Allocate and populate reduced list of components
212      ALLOCATE(ptide_comp(kcomp))
213      DO jk = 1, kcomp
214         ptide_comp(jk) = tide_components(kcomppos(jk))
215      END DO
216     
217      ! Release local array of available components and list of selected
218      ! components
219      DEALLOCATE(tide_components, kcomppos)
220     
221   END SUBROUTINE tide_init_components
222
223
224   SUBROUTINE tide_init_harmonics(pcnames, ptide_harmo, ptide_comp)
225      !!----------------------------------------------------------------------
226      !!                 ***  ROUTINE tide_init_harmonics  ***
227      !!
228      !! Returns pointer to array of variables of type 'tide_harmonics' that
229      !! contain oscillation parameters of the selected harmonic tidal
230      !! components
231      !! ----------------------------------------------------------------------
232      CHARACTER(LEN=4),             DIMENSION(jpmax_harmo), INTENT(in) ::   pcnames     ! Names of selected components
233      TYPE(tide_harmonic), POINTER, DIMENSION(:)                       ::   ptide_harmo ! Oscillation parameters of tidal components
234      TYPE(tide),          POINTER, DIMENSION(:), OPTIONAL             ::   ptide_comp  ! Selected components
235      TYPE(tide),          POINTER, DIMENSION(:)                       ::   ztcomp      ! Selected components
236
237      ! Retrieve information about selected tidal components
238      ! If requested, prepare tidal component array for returning
239      IF (PRESENT(ptide_comp)) THEN
240         CALL tide_init_components(pcnames, ptide_comp)
241         ztcomp => ptide_comp
242      ELSE
243         CALL tide_init_components(pcnames, ztcomp)
244      END IF
245
246      ! Allocate and populate array of oscillation parameters
247      ALLOCATE(ptide_harmo(size(ztcomp)))
248      ptide_harmo(:)%cname_tide = ztcomp(:)%cname_tide
249      ptide_harmo(:)%equitide = ztcomp(:)%equitide
250      CALL tide_harmo(ztcomp, ptide_harmo)
251
252   END SUBROUTINE tide_init_harmonics
253
254
255   SUBROUTINE tide_init_potential
256      !!----------------------------------------------------------------------
257      !!                 ***  ROUTINE tide_init_potential  ***
258      !!----------------------------------------------------------------------
259      INTEGER  ::   ji, jj, jk   ! dummy loop indices
260      REAL(wp) ::   zcons, ztmp1, ztmp2, zlat, zlon, ztmp, zamp, zcs   ! local scalar
261      !!----------------------------------------------------------------------
262
263      IF( ln_read_load ) THEN
264    amp_pot(:,:,:) = amp_load(:,:,:)
265    phi_pot(:,:,:) = phi_load(:,:,:)
266      ELSE     
267         amp_pot(:,:,:) = 0._wp
268         phi_pot(:,:,:) = 0._wp   
269      ENDIF
270      DO jk = 1, nb_harmo
271         zcons = rn_tide_gamma * tide_components(jk)%equitide * tide_harmonics(jk)%f
272         DO ji = 1, jpi
273            DO jj = 1, jpj
274               ztmp1 =  tide_harmonics(jk)%f * amp_pot(ji,jj,jk) * COS( phi_pot(ji,jj,jk) &
275                  &                                                   + tide_harmonics(jk)%v0 + tide_harmonics(jk)%u )
276               ztmp2 = -tide_harmonics(jk)%f * amp_pot(ji,jj,jk) * SIN( phi_pot(ji,jj,jk) &
277                  &                                                   + tide_harmonics(jk)%v0 + tide_harmonics(jk)%u )
278               zlat = gphit(ji,jj)*rad !! latitude en radian
279               zlon = glamt(ji,jj)*rad !! longitude en radian
280               ztmp = tide_harmonics(jk)%v0 + tide_harmonics(jk)%u + tide_components(jk)%nutide * zlon
281               ! le potentiel est composé des effets des astres:
282               IF    ( tide_components(jk)%nutide == 1 )  THEN  ;  zcs = zcons * SIN( 2._wp*zlat )
283               ELSEIF( tide_components(jk)%nutide == 2 )  THEN  ;  zcs = zcons * COS( zlat )**2
284               ELSE                                         ;  zcs = 0._wp
285               ENDIF
286               ztmp1 = ztmp1 + zcs * COS( ztmp )
287               ztmp2 = ztmp2 - zcs * SIN( ztmp )
288               zamp = SQRT( ztmp1*ztmp1 + ztmp2*ztmp2 )
289               amp_pot(ji,jj,jk) = zamp
290               phi_pot(ji,jj,jk) = ATAN2( -ztmp2 / MAX( 1.e-10_wp , zamp ) ,   &
291                  &                        ztmp1 / MAX( 1.e-10_wp,  zamp )   )
292            END DO
293         END DO
294      END DO
295      !
296   END SUBROUTINE tide_init_potential
297
298
299   SUBROUTINE tide_init_load
300      !!----------------------------------------------------------------------
301      !!                 ***  ROUTINE tide_init_load  ***
302      !!----------------------------------------------------------------------
303      INTEGER :: inum                 ! Logical unit of input file
304      INTEGER :: ji, jj, itide        ! dummy loop indices
305      REAL(wp), DIMENSION(jpi,jpj) ::   ztr, zti   !: workspace to read in tidal harmonics data
306      !!----------------------------------------------------------------------
307      IF(lwp) THEN
308         WRITE(numout,*)
309         WRITE(numout,*) 'tide_init_load : Initialization of load potential from file'
310         WRITE(numout,*) '~~~~~~~~~~~~~~ '
311      ENDIF
312      !
313      CALL iom_open ( cn_tide_load , inum )
314      !
315      DO itide = 1, nb_harmo
316         CALL iom_get  ( inum, jpdom_data,TRIM(tide_components(itide)%cname_tide)//'_z1', ztr(:,:) )
317         CALL iom_get  ( inum, jpdom_data,TRIM(tide_components(itide)%cname_tide)//'_z2', zti(:,:) )
318         !
319         DO ji=1,jpi
320            DO jj=1,jpj
321               amp_load(ji,jj,itide) =  SQRT( ztr(ji,jj)**2. + zti(ji,jj)**2. )
322               phi_load(ji,jj,itide) = ATAN2(-zti(ji,jj), ztr(ji,jj) )
323            END DO
324         END DO
325         !
326      END DO
327      CALL iom_close( inum )
328      !
329   END SUBROUTINE tide_init_load
330
331
332   SUBROUTINE tide_update( kt )
333      !!----------------------------------------------------------------------
334      !!                 ***  ROUTINE tide_update  ***
335      !!----------------------------------------------------------------------     
336      INTEGER, INTENT( in ) ::   kt     ! ocean time-step
337      INTEGER               ::   jk     ! dummy loop index
338      !!----------------------------------------------------------------------
339     
340      IF( nsec_day == NINT(0.5_wp * rdt) .OR. kt == nit000 ) THEN      ! start a new day
341         !
342         CALL tide_harmo(tide_components, tide_harmonics, ndt05) ! Update oscillation parameters of tidal components for start of current day
343         !
344         !
345         IF(lwp) THEN
346            WRITE(numout,*)
347            WRITE(numout,*) 'tide_update : Update of the components and (re)Init. the potential at kt=', kt
348            WRITE(numout,*) '~~~~~~~~~~~ '
349            DO jk = 1, nb_harmo
350               WRITE(numout,*) tide_harmonics(jk)%cname_tide, tide_harmonics(jk)%u, &
351                  &            tide_harmonics(jk)%f,tide_harmonics(jk)%v0, tide_harmonics(jk)%omega
352            END DO
353         ENDIF
354         !
355         IF( ln_tide_pot )   CALL tide_init_potential
356         !
357         rn_tide_ramp_t = (kt - nit000)*rdt !   Elapsed time in seconds
358      ENDIF
359      !
360   END SUBROUTINE tide_update
361
362
363   SUBROUTINE tide_harmo( ptide_comp, ptide_harmo, psec_day )
364      !
365      TYPE(tide),          DIMENSION(:), POINTER ::   ptide_comp   ! Array of selected tidal component parameters
366      TYPE(tide_harmonic), DIMENSION(:), POINTER ::   ptide_harmo  ! Oscillation parameters of selected tidal components
367      INTEGER, OPTIONAL ::   psec_day                              ! Number of seconds since the start of the current day
368      !
369      IF (PRESENT(psec_day)) THEN
370         CALL astronomic_angle(psec_day)
371      ELSE
372         CALL astronomic_angle(nsec_day)
373      END IF
374      CALL tide_pulse( ptide_comp, ptide_harmo )
375      CALL tide_vuf(   ptide_comp, ptide_harmo )
376      !
377   END SUBROUTINE tide_harmo
378
379
380   SUBROUTINE astronomic_angle(psec_day)
381      !!----------------------------------------------------------------------
382      !!  tj is time elapsed since 1st January 1900, 0 hour, counted in julian
383      !!  century (e.g. time in days divide by 36525)
384      !!----------------------------------------------------------------------
385      INTEGER  ::   psec_day !   Number of seconds from midnight
386      REAL(wp) ::   cosI, p, q, t2, t4, sin2I, s2, tgI2, P1, sh_tgn2, at1, at2
387      REAL(wp) ::   zqy , zsy, zday, zdj, zhfrac
388      !!----------------------------------------------------------------------
389      !
390      zqy = AINT( (nyear-1901.)/4. )
391      zsy = nyear - 1900.
392      !
393      zdj  = dayjul( nyear, nmonth, nday )
394      zday = zdj + zqy - 1.
395      !
396      zhfrac = psec_day / 3600.
397      !
398      !----------------------------------------------------------------------
399      !  Sh_n Longitude of ascending lunar node
400      !----------------------------------------------------------------------
401      sh_N=(259.1560564-19.328185764*zsy-.0529539336*zday-.0022064139*zhfrac)*rad
402      !----------------------------------------------------------------------
403      ! T mean solar angle (Greenwhich time)
404      !----------------------------------------------------------------------
405      sh_T=(180.+zhfrac*(360./24.))*rad
406      !----------------------------------------------------------------------
407      ! h mean solar Longitude
408      !----------------------------------------------------------------------
409      sh_h=(280.1895014-.238724988*zsy+.9856473288*zday+.0410686387*zhfrac)*rad
410      !----------------------------------------------------------------------
411      ! s mean lunar Longitude
412      !----------------------------------------------------------------------
413      sh_s=(277.0256206+129.38482032*zsy+13.176396768*zday+.549016532*zhfrac)*rad
414      !----------------------------------------------------------------------
415      ! p1 Longitude of solar perigee
416      !----------------------------------------------------------------------
417      sh_p1=(281.2208569+.01717836*zsy+.000047064*zday+.000001961*zhfrac)*rad
418      !----------------------------------------------------------------------
419      ! p Longitude of lunar perigee
420      !----------------------------------------------------------------------
421      sh_p=(334.3837214+40.66246584*zsy+.111404016*zday+.004641834*zhfrac)*rad
422
423      sh_N = MOD( sh_N ,2*rpi )
424      sh_s = MOD( sh_s ,2*rpi )
425      sh_h = MOD( sh_h, 2*rpi )
426      sh_p = MOD( sh_p, 2*rpi )
427      sh_p1= MOD( sh_p1,2*rpi )
428
429      cosI = 0.913694997 -0.035692561 *cos(sh_N)
430
431      sh_I = ACOS( cosI )
432
433      sin2I   = sin(sh_I)
434      sh_tgn2 = tan(sh_N/2.0)
435
436      at1=atan(1.01883*sh_tgn2)
437      at2=atan(0.64412*sh_tgn2)
438
439      sh_xi=-at1-at2+sh_N
440
441      IF( sh_N > rpi )   sh_xi=sh_xi-2.0*rpi
442
443      sh_nu = at1 - at2
444
445      !----------------------------------------------------------------------
446      ! For constituents l2 k1 k2
447      !----------------------------------------------------------------------
448
449      tgI2 = tan(sh_I/2.0)
450      P1   = sh_p-sh_xi
451
452      t2 = tgI2*tgI2
453      t4 = t2*t2
454      sh_x1ra = sqrt( 1.0-12.0*t2*cos(2.0*P1)+36.0*t4 )
455
456      p = sin(2.0*P1)
457      q = 1.0/(6.0*t2)-cos(2.0*P1)
458      sh_R = atan(p/q)
459
460      p = sin(2.0*sh_I)*sin(sh_nu)
461      q = sin(2.0*sh_I)*cos(sh_nu)+0.3347
462      sh_nuprim = atan(p/q)
463
464      s2 = sin(sh_I)*sin(sh_I)
465      p  = s2*sin(2.0*sh_nu)
466      q  = s2*cos(2.0*sh_nu)+0.0727
467      sh_nusec = 0.5*atan(p/q)
468      !
469   END SUBROUTINE astronomic_angle
470
471
472   SUBROUTINE tide_pulse( ptide_comp, ptide_harmo )
473      !!----------------------------------------------------------------------
474      !!                     ***  ROUTINE tide_pulse  ***
475      !!                     
476      !! ** Purpose : Compute tidal frequencies
477      !!----------------------------------------------------------------------
478      TYPE(tide),          DIMENSION(:), POINTER ::   ptide_comp   ! Array of selected tidal component parameters
479      TYPE(tide_harmonic), DIMENSION(:), POINTER ::   ptide_harmo  ! Oscillation parameters of selected tidal components
480      !
481      INTEGER  ::   jh
482      REAL(wp) ::   zscale
483      REAL(wp) ::   zomega_T =  13149000.0_wp
484      REAL(wp) ::   zomega_s =    481267.892_wp
485      REAL(wp) ::   zomega_h =     36000.76892_wp
486      REAL(wp) ::   zomega_p =      4069.0322056_wp
487      REAL(wp) ::   zomega_n =      1934.1423972_wp
488      REAL(wp) ::   zomega_p1=         1.719175_wp
489      !!----------------------------------------------------------------------
490      !
491      zscale =  rad / ( 36525._wp * 86400._wp ) 
492      !
493      DO jh = 1, size(ptide_harmo)
494         ptide_harmo(jh)%omega = (  zomega_T * ptide_comp( jh )%nT   &
495            &                         + zomega_s * ptide_comp( jh )%ns   &
496            &                         + zomega_h * ptide_comp( jh )%nh   &
497            &                         + zomega_p * ptide_comp( jh )%np   &
498            &                         + zomega_p1* ptide_comp( jh )%np1  ) * zscale
499      END DO
500      !
501   END SUBROUTINE tide_pulse
502
503
504   SUBROUTINE tide_vuf( ptide_comp, ptide_harmo )
505      !!----------------------------------------------------------------------
506      !!                     ***  ROUTINE tide_vuf  ***
507      !!                     
508      !! ** Purpose : Compute nodal modulation corrections
509      !!
510      !! ** Outputs : vt: Phase of tidal potential relative to Greenwich (radians)
511      !!              ut: Phase correction u due to nodal motion (radians)
512      !!              ft: Nodal correction factor
513      !!----------------------------------------------------------------------
514      TYPE(tide),          DIMENSION(:), POINTER ::   ptide_comp   ! Array of selected tidal component parameters
515      TYPE(tide_harmonic), DIMENSION(:), POINTER ::   ptide_harmo  ! Oscillation parameters of selected tidal components
516      !
517      INTEGER ::   jh   ! dummy loop index
518      !!----------------------------------------------------------------------
519      !
520      DO jh = 1, size(ptide_harmo)
521         !  Phase of the tidal potential relative to the Greenwhich
522         !  meridian (e.g. the position of the fictuous celestial body). Units are radian:
523         ptide_harmo(jh)%v0 = sh_T * ptide_comp( jh )%nT    &
524            &                   + sh_s * ptide_comp( jh )%ns    &
525            &                   + sh_h * ptide_comp( jh )%nh    &
526            &                   + sh_p * ptide_comp( jh )%np    &
527            &                   + sh_p1* ptide_comp( jh )%np1   &
528            &                   +        ptide_comp( jh )%shift * rad
529         !
530         !  Phase correction u due to nodal motion. Units are radian:
531         ptide_harmo(jh)%u = sh_xi     * ptide_comp( jh )%nksi   &
532            &                  + sh_nu     * ptide_comp( jh )%nnu0   &
533            &                  + sh_nuprim * ptide_comp( jh )%nnu1   &
534            &                  + sh_nusec  * ptide_comp( jh )%nnu2   &
535            &                  + sh_R      * ptide_comp( jh )%R
536
537         !  Nodal correction factor:
538         ptide_harmo(jh)%f = nodal_factort( ptide_comp( jh )%nformula )
539      END DO
540      !
541   END SUBROUTINE tide_vuf
542
543
544   RECURSIVE FUNCTION nodal_factort( kformula ) RESULT( zf )
545      !!----------------------------------------------------------------------
546      !!----------------------------------------------------------------------
547      INTEGER, INTENT(in) :: kformula
548      !
549      REAL(wp) :: zf
550      REAL(wp) :: zs, zf1, zf2
551      !!----------------------------------------------------------------------
552      !
553      SELECT CASE( kformula )
554      !
555      CASE( 0 )                  !==  formule 0, solar waves
556         zf = 1.0
557         !
558      CASE( 1 )                  !==  formule 1, compound waves (78 x 78)
559         zf=nodal_factort(78)
560         zf = zf * zf
561         !
562      CASE ( 2 )                 !==  formule 2, compound waves (78 x 0)  ===  (78)
563       zf1= nodal_factort(78)
564       zf = nodal_factort( 0)
565       zf = zf1 * zf
566       !
567      CASE ( 4 )                 !==  formule 4,  compound waves (78 x 235)
568         zf1 = nodal_factort( 78)
569         zf  = nodal_factort(235)
570         zf  = zf1 * zf
571         !
572      CASE ( 5 )                 !==  formule 5,  compound waves (78 *78 x 235)
573         zf1 = nodal_factort( 78)
574         zf  = nodal_factort(235)
575         zf  = zf * zf1 * zf1
576         !
577      CASE ( 6 )                 !==  formule 6,  compound waves (78 *78 x 0)
578         zf1 = nodal_factort(78)
579         zf  = nodal_factort( 0)
580         zf  = zf * zf1 * zf1 
581         !
582      CASE( 7 )                  !==  formule 7, compound waves (75 x 75)
583         zf = nodal_factort(75)
584         zf = zf * zf
585         !
586      CASE( 8 )                  !==  formule 8,  compound waves (78 x 0 x 235)
587         zf  = nodal_factort( 78)
588         zf1 = nodal_factort(  0)
589         zf2 = nodal_factort(235)
590         zf  = zf * zf1 * zf2
591         !
592      CASE( 9 )                  !==  formule 9,  compound waves (78 x 0 x 227)
593         zf  = nodal_factort( 78)
594         zf1 = nodal_factort(  0)
595         zf2 = nodal_factort(227)
596         zf  = zf * zf1 * zf2
597         !
598      CASE( 10 )                 !==  formule 10,  compound waves (78 x 227)
599         zf  = nodal_factort( 78)
600         zf1 = nodal_factort(227)
601         zf  = zf * zf1
602         !
603      CASE( 11 )                 !==  formule 11,  compound waves (75 x 0)
604!!gm bug???? zf 2 fois !
605         zf = nodal_factort(75)
606         zf1 = nodal_factort( 0)
607         zf = zf * zf1
608         !
609      CASE( 12 )                 !==  formule 12,  compound waves (78 x 78 x 78 x 0)
610         zf1 = nodal_factort(78)
611         zf  = nodal_factort( 0)
612         zf  = zf * zf1 * zf1 * zf1
613         !
614      CASE( 13 )                 !==  formule 13, compound waves (78 x 75)
615         zf1 = nodal_factort(78)
616         zf  = nodal_factort(75)
617         zf  = zf * zf1
618         !
619      CASE( 14 )                 !==  formule 14, compound waves (235 x 0)  ===  (235)
620         zf  = nodal_factort(235)
621         zf1 = nodal_factort(  0)
622         zf  = zf * zf1
623         !
624      CASE( 15 )                 !==  formule 15, compound waves (235 x 75)
625         zf  = nodal_factort(235)
626         zf1 = nodal_factort( 75)
627         zf  = zf * zf1
628         !
629      CASE( 16 )                 !==  formule 16, compound waves (78 x 0 x 0)  ===  (78)
630         zf  = nodal_factort(78)
631         zf1 = nodal_factort( 0)
632         zf  = zf * zf1 * zf1
633         !
634      CASE( 17 )                 !==  formule 17,  compound waves (227 x 0)
635         zf1 = nodal_factort(227)
636         zf  = nodal_factort(  0)
637         zf  = zf * zf1
638         !
639      CASE( 18 )                 !==  formule 18,  compound waves (78 x 78 x 78 )
640         zf1 = nodal_factort(78)
641         zf  = zf1 * zf1 * zf1
642         !
643      CASE( 19 )                 !==  formule 19, compound waves (78 x 0 x 0 x 0)  ===  (78)
644!!gm bug2 ==>>>   here identical to formule 16,  a third multiplication by zf1 is missing
645         zf  = nodal_factort(78)
646         zf1 = nodal_factort( 0)
647         zf = zf * zf1 * zf1
648         !
649      CASE( 73 )                 !==  formule 73
650         zs = sin(sh_I)
651         zf = (2./3.-zs*zs)/0.5021
652         !
653      CASE( 74 )                 !==  formule 74
654         zs = sin(sh_I)
655         zf = zs * zs / 0.1578
656         !
657      CASE( 75 )                 !==  formule 75
658         zs = cos(sh_I/2)
659         zf = sin(sh_I) * zs * zs / 0.3800
660         !
661      CASE( 76 )                 !==  formule 76
662         zf = sin(2*sh_I) / 0.7214
663         !
664      CASE( 77 )                 !==  formule 77
665         zs = sin(sh_I/2)
666         zf = sin(sh_I) * zs * zs / 0.0164
667         !
668      CASE( 78 )                 !==  formule 78
669         zs = cos(sh_I/2)
670         zf = zs * zs * zs * zs / 0.9154
671         !
672      CASE( 79 )                 !==  formule 79
673         zs = sin(sh_I)
674         zf = zs * zs / 0.1565
675         !
676      CASE( 144 )                !==  formule 144
677         zs = sin(sh_I/2)
678         zf = ( 1-10*zs*zs+15*zs*zs*zs*zs ) * cos(sh_I/2) / 0.5873
679         !
680      CASE( 149 )                !==  formule 149
681         zs = cos(sh_I/2)
682         zf = zs*zs*zs*zs*zs*zs / 0.8758
683         !
684      CASE( 215 )                !==  formule 215
685         zs = cos(sh_I/2)
686         zf = zs*zs*zs*zs / 0.9154 * sh_x1ra
687         !
688      CASE( 227 )                !==  formule 227
689         zs = sin(2*sh_I)
690         zf = sqrt( 0.8965*zs*zs+0.6001*zs*cos (sh_nu)+0.1006 )
691         !
692      CASE ( 235 )               !==  formule 235
693         zs = sin(sh_I)
694         zf = sqrt( 19.0444*zs*zs*zs*zs + 2.7702*zs*zs*cos(2*sh_nu) + .0981 )
695         !
696      END SELECT
697      !
698   END FUNCTION nodal_factort
699
700
701   FUNCTION dayjul( kyr, kmonth, kday )
702      !!----------------------------------------------------------------------
703      !!  *** THIS ROUTINE COMPUTES THE JULIAN DAY (AS A REAL VARIABLE)
704      !!----------------------------------------------------------------------
705      INTEGER,INTENT(in) ::   kyr, kmonth, kday
706      !
707      INTEGER,DIMENSION(12) ::  idayt, idays
708      INTEGER  ::   inc, ji
709      REAL(wp) ::   dayjul, zyq
710      !
711      DATA idayt/0.,31.,59.,90.,120.,151.,181.,212.,243.,273.,304.,334./
712      !!----------------------------------------------------------------------
713      !
714      idays(1) = 0.
715      idays(2) = 31.
716      inc = 0.
717      zyq = MOD( kyr-1900. , 4. )
718      IF( zyq == 0.)   inc = 1.
719      DO ji = 3, 12
720         idays(ji)=idayt(ji)+inc
721      END DO
722      dayjul = idays(kmonth) + kday
723      !
724   END FUNCTION dayjul
725
726
727   SUBROUTINE upd_tide(pdelta)
728      !!----------------------------------------------------------------------
729      !!                 ***  ROUTINE upd_tide  ***
730      !!
731      !! ** Purpose :   provide at each time step the astronomical potential
732      !!
733      !! ** Method  :   computed from pulsation and amplitude of all tide components
734      !!
735      !! ** Action  :   pot_astro   actronomical potential
736      !!----------------------------------------------------------------------     
737      REAL, INTENT(in)              ::   pdelta      ! Temporal offset in seconds
738      INTEGER                       ::   jk          ! Dummy loop index
739      REAL(wp)                      ::   zt, zramp   ! Local scalars
740      REAL(wp), DIMENSION(nb_harmo) ::   zwt         ! Temporary array
741      !!----------------------------------------------------------------------     
742      !
743      zwt(:) = tide_harmonics(:)%omega * pdelta
744      !
745      pot_astro(:,:) = 0._wp          ! update tidal potential (sum of all harmonics)
746      DO jk = 1, nb_harmo   
747         pot_astro(:,:) = pot_astro(:,:) + amp_pot(:,:,jk) * COS( zwt(jk) + phi_pot(:,:,jk) )     
748      END DO
749      !
750      IF( ln_tide_ramp ) THEN         ! linear increase if asked
751         zt = rn_tide_ramp_t + pdelta
752         zramp = MIN(  MAX( zt / (rn_tide_ramp_dt*rday) , 0._wp ) , 1._wp  )
753         pot_astro(:,:) = zramp * pot_astro(:,:)
754      ENDIF
755      !
756   END SUBROUTINE upd_tide
757
758   !!======================================================================
759END MODULE tide_mod
Note: See TracBrowser for help on using the repository browser.