New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
tide_mod.F90 in NEMO/branches/2019/dev_r10742_ENHANCE-12_SimonM-Tides/src/OCE/TDE – NEMO

source: NEMO/branches/2019/dev_r10742_ENHANCE-12_SimonM-Tides/src/OCE/TDE/tide_mod.F90 @ 11664

Last change on this file since 11664 was 11664, checked in by smueller, 5 years ago

Inclusion of selected long-periodic tidal constituents in the computation of the tidal potential (ticket #2194)
  • Property svn:keywords set to Id
File size: 33.2 KB
Line 
1MODULE tide_mod
2   !!======================================================================
3   !!                       ***  MODULE  tide_mod  ***
4   !! Compute nodal modulations corrections and pulsations
5   !!======================================================================
6   !! History :  1.0  !  2007  (O. Le Galloudec)  Original code
7   !!----------------------------------------------------------------------
8   USE oce            ! ocean dynamics and tracers variables
9   USE dom_oce        ! ocean space and time domain
10   USE phycst         ! physical constant
11   USE daymod         ! calendar
12   !
13   USE in_out_manager ! I/O units
14   USE iom            ! xIOs server
15   USE ioipsl         ! NetCDF IPSL library
16   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
17
18   IMPLICIT NONE
19   PRIVATE
20
21   PUBLIC   tide_init
22   PUBLIC   tide_update          ! called by stp
23   PUBLIC   tide_init_harmonics  ! called internally and by module diaharm
24   PUBLIC   upd_tide         ! called in dynspg_... modules
25
26   INTEGER, PUBLIC, PARAMETER ::   jpmax_harmo = 64   !: maximum number of harmonic components
27
28   TYPE ::    tide
29      CHARACTER(LEN=4) ::   cname_tide = ''
30      REAL(wp)         ::   equitide
31      INTEGER          ::   nutide
32      INTEGER          ::   nt, ns, nh, np, np1, shift
33      INTEGER          ::   nksi, nnu0, nnu1, nnu2, R
34      INTEGER          ::   nformula
35   END TYPE tide
36
37   TYPE(tide), DIMENSION(:), POINTER ::   tide_components !: Array of selected tidal component parameters
38
39   TYPE, PUBLIC ::   tide_harmonic       !:   Oscillation parameters of harmonic tidal components
40      CHARACTER(LEN=4) ::   cname_tide   !    Name of component
41      REAL(wp)         ::   equitide     !    Amplitude of equilibrium tide
42      REAL(wp)         ::   f            !    Node factor
43      REAL(wp)         ::   omega        !    Angular velocity
44      REAL(wp)         ::   v0           !    Initial phase at prime meridian
45      REAL(wp)         ::   u            !    Phase correction
46   END type tide_harmonic
47
48   TYPE(tide_harmonic), PUBLIC, DIMENSION(:), POINTER ::   tide_harmonics !: Oscillation parameters of selected tidal components
49
50   LOGICAL , PUBLIC ::   ln_tide         !:
51   LOGICAL , PUBLIC ::   ln_tide_pot     !:
52   INTEGER          ::   nn_tide_var     !  Variant of tidal parameter set and tide-potential computation
53   LOGICAL          ::   ln_read_load    !:
54   LOGICAL , PUBLIC ::   ln_scal_load    !:
55   LOGICAL , PUBLIC ::   ln_tide_ramp    !:
56   INTEGER , PUBLIC ::   nb_harmo        !: Number of active tidal components
57   REAL(wp), PUBLIC ::   rn_tide_ramp_dt     !:
58   REAL(wp), PUBLIC ::   rn_scal_load    !:
59   CHARACTER(lc), PUBLIC ::   cn_tide_load   !:
60   REAL(wp)         ::   rn_tide_gamma   ! Tidal tilt factor
61
62   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   pot_astro !: tidal potential
63   REAL(wp),         ALLOCATABLE, DIMENSION(:,:,:) ::   amp_pot, phi_pot
64   REAL(wp),         ALLOCATABLE, DIMENSION(:,:,:) ::   amp_load, phi_load
65
66   REAL(wp) ::   rn_tide_ramp_t !   Elapsed time in seconds
67
68   REAL(wp) ::   sh_T, sh_s, sh_h, sh_p, sh_p1             ! astronomic angles
69   REAL(wp) ::   sh_xi, sh_nu, sh_nuprim, sh_nusec, sh_R   !
70   REAL(wp) ::   sh_I, sh_x1ra, sh_N                       !
71
72   !!----------------------------------------------------------------------
73   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
74   !! $Id$
75   !! Software governed by the CeCILL license (see ./LICENSE)
76   !!----------------------------------------------------------------------
77CONTAINS
78
79   SUBROUTINE tide_init
80      !!----------------------------------------------------------------------
81      !!                 ***  ROUTINE tide_init  ***
82      !!----------------------------------------------------------------------     
83      INTEGER  :: ji, jk
84      CHARACTER(LEN=4), DIMENSION(jpmax_harmo) :: sn_tide_cnames ! Names of selected tidal components
85      INTEGER  ::   ios                 ! Local integer output status for namelist read
86      !
87      NAMELIST/nam_tide/ln_tide, nn_tide_var, ln_tide_pot, rn_tide_gamma, &
88         &              ln_scal_load, ln_read_load, cn_tide_load,         &
89         &              ln_tide_ramp, rn_scal_load, rn_tide_ramp_dt,      &
90         &              sn_tide_cnames
91      !!----------------------------------------------------------------------
92      !
93      ! Initialise all array elements of sn_tide_cnames, as some of them
94      ! typically do not appear in namelist_ref or namelist_cfg
95      sn_tide_cnames(:) = ''
96      ! Read Namelist nam_tide
97      REWIND( numnam_ref )              ! Namelist nam_tide in reference namelist : Tides
98      READ  ( numnam_ref, nam_tide, IOSTAT = ios, ERR = 901)
99901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nam_tide in reference namelist', lwp )
100      !
101      REWIND( numnam_cfg )              ! Namelist nam_tide in configuration namelist : Tides
102      READ  ( numnam_cfg, nam_tide, IOSTAT = ios, ERR = 902 )
103902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nam_tide in configuration namelist', lwp )
104      IF(lwm) WRITE ( numond, nam_tide )
105      !
106      IF( ln_tide ) THEN
107         IF (lwp) THEN
108            WRITE(numout,*)
109            WRITE(numout,*) 'tide_init : Initialization of the tidal components'
110            WRITE(numout,*) '~~~~~~~~~ '
111            WRITE(numout,*) '   Namelist nam_tide'
112            WRITE(numout,*) '      Use tidal components                       ln_tide         = ', ln_tide
113            WRITE(numout,*) '         Variant (1: default; 0: legacy option)  nn_tide_var     = ', nn_tide_var
114            WRITE(numout,*) '         Apply astronomical potential            ln_tide_pot     = ', ln_tide_pot
115            WRITE(numout,*) '         Tidal tilt factor                       rn_tide_gamma   = ', rn_tide_gamma
116            WRITE(numout,*) '         Use scalar approx. for load potential   ln_scal_load    = ', ln_scal_load
117            WRITE(numout,*) '         Read load potential from file           ln_read_load    = ', ln_read_load
118            WRITE(numout,*) '         Apply ramp on tides at startup          ln_tide_ramp    = ', ln_tide_ramp
119            WRITE(numout,*) '         Fraction of SSH used in scal. approx.   rn_scal_load    = ', rn_scal_load
120            WRITE(numout,*) '         Duration (days) of ramp                 rn_tide_ramp_dt = ', rn_tide_ramp_dt
121         ENDIF
122      ELSE
123         rn_scal_load = 0._wp 
124
125         IF(lwp) WRITE(numout,*)
126         IF(lwp) WRITE(numout,*) 'tide_init : tidal components not used (ln_tide = F)'
127         IF(lwp) WRITE(numout,*) '~~~~~~~~~ '
128         RETURN
129      ENDIF
130      !
131      IF( ln_read_load.AND.(.NOT.ln_tide_pot) ) &
132          &   CALL ctl_stop('ln_read_load requires ln_tide_pot')
133      IF( ln_scal_load.AND.(.NOT.ln_tide_pot) ) &
134          &   CALL ctl_stop('ln_scal_load requires ln_tide_pot')
135      IF( ln_scal_load.AND.ln_read_load ) &
136          &   CALL ctl_stop('Choose between ln_scal_load and ln_read_load')
137      IF( ln_tide_ramp.AND.((nitend-nit000+1)*rdt/rday < rn_tide_ramp_dt) )   &
138         &   CALL ctl_stop('rn_tide_ramp_dt must be lower than run duration')
139      IF( ln_tide_ramp.AND.(rn_tide_ramp_dt<0.) ) &
140         &   CALL ctl_stop('rn_tide_ramp_dt must be positive')
141      !
142      ! Initialise array used to store tidal oscillation parameters (frequency,
143      ! amplitude, phase); also retrieve and store array of information about
144      ! selected tidal components
145      CALL tide_init_harmonics(sn_tide_cnames, tide_harmonics, tide_components)
146      !
147      ! Number of active tidal components
148      nb_harmo = size(tide_components)
149      !       
150      ! Ensure that tidal components have been set in namelist_cfg
151      IF( nb_harmo == 0 )   CALL ctl_stop( 'tide_init : No tidal components set in nam_tide' )
152      !
153      IF (.NOT.ln_scal_load ) rn_scal_load = 0._wp
154      !
155      ALLOCATE( amp_pot(jpi,jpj,nb_harmo),                      &
156           &      phi_pot(jpi,jpj,nb_harmo), pot_astro(jpi,jpj)   )
157      IF( ln_read_load ) THEN
158         ALLOCATE( amp_load(jpi,jpj,nb_harmo), phi_load(jpi,jpj,nb_harmo) )
159         CALL tide_init_load
160         amp_pot(:,:,:) = amp_load(:,:,:)
161         phi_pot(:,:,:) = phi_load(:,:,:)
162      ELSE     
163         amp_pot(:,:,:) = 0._wp
164         phi_pot(:,:,:) = 0._wp   
165      ENDIF
166      !
167   END SUBROUTINE tide_init
168
169
170   SUBROUTINE tide_init_components(pcnames, ptide_comp)
171      !!----------------------------------------------------------------------
172      !!                 ***  ROUTINE tide_init_components  ***
173      !!
174      !! Returns pointer to array of variables of type 'tide' that contain
175      !! information about the selected tidal components
176      !! ----------------------------------------------------------------------
177      CHARACTER(LEN=4),              DIMENSION(jpmax_harmo), INTENT(in)  ::   pcnames         ! Names of selected components
178      TYPE(tide),       POINTER,     DIMENSION(:),           INTENT(out) ::   ptide_comp      ! Selected components
179      INTEGER,          ALLOCATABLE, DIMENSION(:)                        ::   kcomppos        ! Indices of selected components
180      INTEGER                                                            ::   kcomp, jk, ji   ! Miscellaneous integers
181      TYPE(tide),       POINTER,     DIMENSION(:)                        ::   tide_components ! All available components
182     
183      ! Populate local array with information about all available tidal
184      ! components
185      !
186      ! Note, here 'tide_components' locally overrides the global module
187      ! variable of the same name to enable the use of the global name in the
188      ! include file that contains the initialisation of elements of array
189      ! 'tide_components'
190      ALLOCATE(tide_components(jpmax_harmo), kcomppos(jpmax_harmo))
191      ! Initialise array of indices of the selected componenents
192      kcomppos(:) = 0
193      ! Include tidal component parameters for all available components
194#include "tide.h90"
195     
196      ! Identify the selected components that are availble
197      kcomp = 0
198      DO jk = 1, jpmax_harmo
199         IF (TRIM(pcnames(jk)) /= '') THEN
200            DO ji = 1, jpmax_harmo
201               IF (TRIM(pcnames(jk)) == tide_components(ji)%cname_tide) THEN
202                  kcomp = kcomp + 1
203                  WRITE(numout, '(10X,"Tidal component #",I2.2,36X,"= ",A4)') kcomp, pcnames(jk)
204                  kcomppos(kcomp) = ji
205                  EXIT
206               END IF
207            END DO
208         END IF
209      END DO
210     
211      ! Allocate and populate reduced list of components
212      ALLOCATE(ptide_comp(kcomp))
213      DO jk = 1, kcomp
214         ptide_comp(jk) = tide_components(kcomppos(jk))
215      END DO
216     
217      ! Release local array of available components and list of selected
218      ! components
219      DEALLOCATE(tide_components, kcomppos)
220     
221   END SUBROUTINE tide_init_components
222
223
224   SUBROUTINE tide_init_harmonics(pcnames, ptide_harmo, ptide_comp)
225      !!----------------------------------------------------------------------
226      !!                 ***  ROUTINE tide_init_harmonics  ***
227      !!
228      !! Returns pointer to array of variables of type 'tide_harmonics' that
229      !! contain oscillation parameters of the selected harmonic tidal
230      !! components
231      !! ----------------------------------------------------------------------
232      CHARACTER(LEN=4),             DIMENSION(jpmax_harmo), INTENT(in) ::   pcnames     ! Names of selected components
233      TYPE(tide_harmonic), POINTER, DIMENSION(:)                       ::   ptide_harmo ! Oscillation parameters of tidal components
234      TYPE(tide),          POINTER, DIMENSION(:), OPTIONAL             ::   ptide_comp  ! Selected components
235      TYPE(tide),          POINTER, DIMENSION(:)                       ::   ztcomp      ! Selected components
236
237      ! Retrieve information about selected tidal components
238      ! If requested, prepare tidal component array for returning
239      IF (PRESENT(ptide_comp)) THEN
240         CALL tide_init_components(pcnames, ptide_comp)
241         ztcomp => ptide_comp
242      ELSE
243         CALL tide_init_components(pcnames, ztcomp)
244      END IF
245
246      ! Allocate and populate array of oscillation parameters
247      ALLOCATE(ptide_harmo(size(ztcomp)))
248      ptide_harmo(:)%cname_tide = ztcomp(:)%cname_tide
249      ptide_harmo(:)%equitide = ztcomp(:)%equitide
250      CALL tide_harmo(ztcomp, ptide_harmo)
251
252   END SUBROUTINE tide_init_harmonics
253
254
255   SUBROUTINE tide_init_potential
256      !!----------------------------------------------------------------------
257      !!                 ***  ROUTINE tide_init_potential  ***
258      !!----------------------------------------------------------------------
259      INTEGER  ::   ji, jj, jk   ! dummy loop indices
260      REAL(wp) ::   zcons, ztmp1, ztmp2, zlat, zlon, ztmp, zamp, zcs   ! local scalar
261      !!----------------------------------------------------------------------
262
263      IF( ln_read_load ) THEN
264    amp_pot(:,:,:) = amp_load(:,:,:)
265    phi_pot(:,:,:) = phi_load(:,:,:)
266      ELSE     
267         amp_pot(:,:,:) = 0._wp
268         phi_pot(:,:,:) = 0._wp   
269      ENDIF
270      DO jk = 1, nb_harmo
271         zcons = rn_tide_gamma * tide_components(jk)%equitide * tide_harmonics(jk)%f
272         DO ji = 1, jpi
273            DO jj = 1, jpj
274               ztmp1 =  tide_harmonics(jk)%f * amp_pot(ji,jj,jk) * COS( phi_pot(ji,jj,jk) &
275                  &                                                   + tide_harmonics(jk)%v0 + tide_harmonics(jk)%u )
276               ztmp2 = -tide_harmonics(jk)%f * amp_pot(ji,jj,jk) * SIN( phi_pot(ji,jj,jk) &
277                  &                                                   + tide_harmonics(jk)%v0 + tide_harmonics(jk)%u )
278               zlat = gphit(ji,jj)*rad !! latitude en radian
279               zlon = glamt(ji,jj)*rad !! longitude en radian
280               ztmp = tide_harmonics(jk)%v0 + tide_harmonics(jk)%u + tide_components(jk)%nutide * zlon
281               ! le potentiel est composé des effets des astres:
282               SELECT CASE( tide_components(jk)%nutide )
283               CASE( 0 )                                                  !   long-periodic tidal constituents (included unless
284                  zcs = zcons * ( 0.5_wp - 1.5_wp * SIN( zlat )**2 )      !   compatibility with original formulation is requested)
285                  IF ( nn_tide_var < 1 ) zcs = 0.0_wp
286               CASE( 1 )                                                  !   diurnal tidal constituents
287                  zcs = zcons * SIN( 2.0_wp*zlat )
288               CASE( 2 )                                                  !   semi-diurnal tidal constituents
289                  zcs = zcons * COS( zlat )**2
290               CASE DEFAULT                                               !   constituents of higher frequency are not included
291                  zcs = 0.0_wp
292               END SELECT
293               ztmp1 = ztmp1 + zcs * COS( ztmp )
294               ztmp2 = ztmp2 - zcs * SIN( ztmp )
295               zamp = SQRT( ztmp1*ztmp1 + ztmp2*ztmp2 )
296               amp_pot(ji,jj,jk) = zamp
297               phi_pot(ji,jj,jk) = ATAN2( -ztmp2 / MAX( 1.e-10_wp , zamp ) ,   &
298                  &                        ztmp1 / MAX( 1.e-10_wp,  zamp )   )
299            END DO
300         END DO
301      END DO
302      !
303   END SUBROUTINE tide_init_potential
304
305
306   SUBROUTINE tide_init_load
307      !!----------------------------------------------------------------------
308      !!                 ***  ROUTINE tide_init_load  ***
309      !!----------------------------------------------------------------------
310      INTEGER :: inum                 ! Logical unit of input file
311      INTEGER :: ji, jj, itide        ! dummy loop indices
312      REAL(wp), DIMENSION(jpi,jpj) ::   ztr, zti   !: workspace to read in tidal harmonics data
313      !!----------------------------------------------------------------------
314      IF(lwp) THEN
315         WRITE(numout,*)
316         WRITE(numout,*) 'tide_init_load : Initialization of load potential from file'
317         WRITE(numout,*) '~~~~~~~~~~~~~~ '
318      ENDIF
319      !
320      CALL iom_open ( cn_tide_load , inum )
321      !
322      DO itide = 1, nb_harmo
323         CALL iom_get  ( inum, jpdom_data,TRIM(tide_components(itide)%cname_tide)//'_z1', ztr(:,:) )
324         CALL iom_get  ( inum, jpdom_data,TRIM(tide_components(itide)%cname_tide)//'_z2', zti(:,:) )
325         !
326         DO ji=1,jpi
327            DO jj=1,jpj
328               amp_load(ji,jj,itide) =  SQRT( ztr(ji,jj)**2. + zti(ji,jj)**2. )
329               phi_load(ji,jj,itide) = ATAN2(-zti(ji,jj), ztr(ji,jj) )
330            END DO
331         END DO
332         !
333      END DO
334      CALL iom_close( inum )
335      !
336   END SUBROUTINE tide_init_load
337
338
339   SUBROUTINE tide_update( kt )
340      !!----------------------------------------------------------------------
341      !!                 ***  ROUTINE tide_update  ***
342      !!----------------------------------------------------------------------     
343      INTEGER, INTENT( in ) ::   kt     ! ocean time-step
344      INTEGER               ::   jk     ! dummy loop index
345      !!----------------------------------------------------------------------
346     
347      IF( nsec_day == NINT(0.5_wp * rdt) .OR. kt == nit000 ) THEN      ! start a new day
348         !
349         CALL tide_harmo(tide_components, tide_harmonics, ndt05) ! Update oscillation parameters of tidal components for start of current day
350         !
351         !
352         IF(lwp) THEN
353            WRITE(numout,*)
354            WRITE(numout,*) 'tide_update : Update of the components and (re)Init. the potential at kt=', kt
355            WRITE(numout,*) '~~~~~~~~~~~ '
356            DO jk = 1, nb_harmo
357               WRITE(numout,*) tide_harmonics(jk)%cname_tide, tide_harmonics(jk)%u, &
358                  &            tide_harmonics(jk)%f,tide_harmonics(jk)%v0, tide_harmonics(jk)%omega
359            END DO
360         ENDIF
361         !
362         IF( ln_tide_pot )   CALL tide_init_potential
363         !
364         rn_tide_ramp_t = (kt - nit000)*rdt !   Elapsed time in seconds
365      ENDIF
366      !
367   END SUBROUTINE tide_update
368
369
370   SUBROUTINE tide_harmo( ptide_comp, ptide_harmo, psec_day )
371      !
372      TYPE(tide),          DIMENSION(:), POINTER ::   ptide_comp   ! Array of selected tidal component parameters
373      TYPE(tide_harmonic), DIMENSION(:), POINTER ::   ptide_harmo  ! Oscillation parameters of selected tidal components
374      INTEGER, OPTIONAL ::   psec_day                              ! Number of seconds since the start of the current day
375      !
376      IF (PRESENT(psec_day)) THEN
377         CALL astronomic_angle(psec_day)
378      ELSE
379         CALL astronomic_angle(nsec_day)
380      END IF
381      CALL tide_pulse( ptide_comp, ptide_harmo )
382      CALL tide_vuf(   ptide_comp, ptide_harmo )
383      !
384   END SUBROUTINE tide_harmo
385
386
387   SUBROUTINE astronomic_angle(psec_day)
388      !!----------------------------------------------------------------------
389      !!  tj is time elapsed since 1st January 1900, 0 hour, counted in julian
390      !!  century (e.g. time in days divide by 36525)
391      !!----------------------------------------------------------------------
392      INTEGER  ::   psec_day !   Number of seconds from midnight
393      REAL(wp) ::   cosI, p, q, t2, t4, sin2I, s2, tgI2, P1, sh_tgn2, at1, at2
394      REAL(wp) ::   zqy , zsy, zday, zdj, zhfrac
395      !!----------------------------------------------------------------------
396      !
397      zqy = AINT( (nyear-1901.)/4. )
398      zsy = nyear - 1900.
399      !
400      zdj  = dayjul( nyear, nmonth, nday )
401      zday = zdj + zqy - 1.
402      !
403      zhfrac = psec_day / 3600.
404      !
405      !----------------------------------------------------------------------
406      !  Sh_n Longitude of ascending lunar node
407      !----------------------------------------------------------------------
408      sh_N=(259.1560564-19.328185764*zsy-.0529539336*zday-.0022064139*zhfrac)*rad
409      !----------------------------------------------------------------------
410      ! T mean solar angle (Greenwhich time)
411      !----------------------------------------------------------------------
412      sh_T=(180.+zhfrac*(360./24.))*rad
413      !----------------------------------------------------------------------
414      ! h mean solar Longitude
415      !----------------------------------------------------------------------
416      sh_h=(280.1895014-.238724988*zsy+.9856473288*zday+.0410686387*zhfrac)*rad
417      !----------------------------------------------------------------------
418      ! s mean lunar Longitude
419      !----------------------------------------------------------------------
420      sh_s=(277.0256206+129.38482032*zsy+13.176396768*zday+.549016532*zhfrac)*rad
421      !----------------------------------------------------------------------
422      ! p1 Longitude of solar perigee
423      !----------------------------------------------------------------------
424      sh_p1=(281.2208569+.01717836*zsy+.000047064*zday+.000001961*zhfrac)*rad
425      !----------------------------------------------------------------------
426      ! p Longitude of lunar perigee
427      !----------------------------------------------------------------------
428      sh_p=(334.3837214+40.66246584*zsy+.111404016*zday+.004641834*zhfrac)*rad
429
430      sh_N = MOD( sh_N ,2*rpi )
431      sh_s = MOD( sh_s ,2*rpi )
432      sh_h = MOD( sh_h, 2*rpi )
433      sh_p = MOD( sh_p, 2*rpi )
434      sh_p1= MOD( sh_p1,2*rpi )
435
436      cosI = 0.913694997 -0.035692561 *cos(sh_N)
437
438      sh_I = ACOS( cosI )
439
440      sin2I   = sin(sh_I)
441      sh_tgn2 = tan(sh_N/2.0)
442
443      at1=atan(1.01883*sh_tgn2)
444      at2=atan(0.64412*sh_tgn2)
445
446      sh_xi=-at1-at2+sh_N
447
448      IF( sh_N > rpi )   sh_xi=sh_xi-2.0*rpi
449
450      sh_nu = at1 - at2
451
452      !----------------------------------------------------------------------
453      ! For constituents l2 k1 k2
454      !----------------------------------------------------------------------
455
456      tgI2 = tan(sh_I/2.0)
457      P1   = sh_p-sh_xi
458
459      t2 = tgI2*tgI2
460      t4 = t2*t2
461      sh_x1ra = sqrt( 1.0-12.0*t2*cos(2.0*P1)+36.0*t4 )
462
463      p = sin(2.0*P1)
464      q = 1.0/(6.0*t2)-cos(2.0*P1)
465      sh_R = atan(p/q)
466
467      p = sin(2.0*sh_I)*sin(sh_nu)
468      q = sin(2.0*sh_I)*cos(sh_nu)+0.3347
469      sh_nuprim = atan(p/q)
470
471      s2 = sin(sh_I)*sin(sh_I)
472      p  = s2*sin(2.0*sh_nu)
473      q  = s2*cos(2.0*sh_nu)+0.0727
474      sh_nusec = 0.5*atan(p/q)
475      !
476   END SUBROUTINE astronomic_angle
477
478
479   SUBROUTINE tide_pulse( ptide_comp, ptide_harmo )
480      !!----------------------------------------------------------------------
481      !!                     ***  ROUTINE tide_pulse  ***
482      !!                     
483      !! ** Purpose : Compute tidal frequencies
484      !!----------------------------------------------------------------------
485      TYPE(tide),          DIMENSION(:), POINTER ::   ptide_comp   ! Array of selected tidal component parameters
486      TYPE(tide_harmonic), DIMENSION(:), POINTER ::   ptide_harmo  ! Oscillation parameters of selected tidal components
487      !
488      INTEGER  ::   jh
489      REAL(wp) ::   zscale
490      REAL(wp) ::   zomega_T =  13149000.0_wp
491      REAL(wp) ::   zomega_s =    481267.892_wp
492      REAL(wp) ::   zomega_h =     36000.76892_wp
493      REAL(wp) ::   zomega_p =      4069.0322056_wp
494      REAL(wp) ::   zomega_n =      1934.1423972_wp
495      REAL(wp) ::   zomega_p1=         1.719175_wp
496      !!----------------------------------------------------------------------
497      !
498      zscale =  rad / ( 36525._wp * 86400._wp ) 
499      !
500      DO jh = 1, size(ptide_harmo)
501         ptide_harmo(jh)%omega = (  zomega_T * ptide_comp( jh )%nT   &
502            &                         + zomega_s * ptide_comp( jh )%ns   &
503            &                         + zomega_h * ptide_comp( jh )%nh   &
504            &                         + zomega_p * ptide_comp( jh )%np   &
505            &                         + zomega_p1* ptide_comp( jh )%np1  ) * zscale
506      END DO
507      !
508   END SUBROUTINE tide_pulse
509
510
511   SUBROUTINE tide_vuf( ptide_comp, ptide_harmo )
512      !!----------------------------------------------------------------------
513      !!                     ***  ROUTINE tide_vuf  ***
514      !!                     
515      !! ** Purpose : Compute nodal modulation corrections
516      !!
517      !! ** Outputs : vt: Phase of tidal potential relative to Greenwich (radians)
518      !!              ut: Phase correction u due to nodal motion (radians)
519      !!              ft: Nodal correction factor
520      !!----------------------------------------------------------------------
521      TYPE(tide),          DIMENSION(:), POINTER ::   ptide_comp   ! Array of selected tidal component parameters
522      TYPE(tide_harmonic), DIMENSION(:), POINTER ::   ptide_harmo  ! Oscillation parameters of selected tidal components
523      !
524      INTEGER ::   jh   ! dummy loop index
525      !!----------------------------------------------------------------------
526      !
527      DO jh = 1, size(ptide_harmo)
528         !  Phase of the tidal potential relative to the Greenwhich
529         !  meridian (e.g. the position of the fictuous celestial body). Units are radian:
530         ptide_harmo(jh)%v0 = sh_T * ptide_comp( jh )%nT    &
531            &                   + sh_s * ptide_comp( jh )%ns    &
532            &                   + sh_h * ptide_comp( jh )%nh    &
533            &                   + sh_p * ptide_comp( jh )%np    &
534            &                   + sh_p1* ptide_comp( jh )%np1   &
535            &                   +        ptide_comp( jh )%shift * rad
536         !
537         !  Phase correction u due to nodal motion. Units are radian:
538         ptide_harmo(jh)%u = sh_xi     * ptide_comp( jh )%nksi   &
539            &                  + sh_nu     * ptide_comp( jh )%nnu0   &
540            &                  + sh_nuprim * ptide_comp( jh )%nnu1   &
541            &                  + sh_nusec  * ptide_comp( jh )%nnu2   &
542            &                  + sh_R      * ptide_comp( jh )%R
543
544         !  Nodal correction factor:
545         ptide_harmo(jh)%f = nodal_factort( ptide_comp( jh )%nformula )
546      END DO
547      !
548   END SUBROUTINE tide_vuf
549
550
551   RECURSIVE FUNCTION nodal_factort( kformula ) RESULT( zf )
552      !!----------------------------------------------------------------------
553      !!----------------------------------------------------------------------
554      INTEGER, INTENT(in) :: kformula
555      !
556      REAL(wp) :: zf
557      REAL(wp) :: zs, zf1, zf2
558      !!----------------------------------------------------------------------
559      !
560      SELECT CASE( kformula )
561      !
562      CASE( 0 )                  !==  formule 0, solar waves
563         zf = 1.0
564         !
565      CASE( 1 )                  !==  formule 1, compound waves (78 x 78)
566         zf=nodal_factort(78)
567         zf = zf * zf
568         !
569      CASE ( 2 )                 !==  formule 2, compound waves (78 x 0)  ===  (78)
570       zf1= nodal_factort(78)
571       zf = nodal_factort( 0)
572       zf = zf1 * zf
573       !
574      CASE ( 4 )                 !==  formule 4,  compound waves (78 x 235)
575         zf1 = nodal_factort( 78)
576         zf  = nodal_factort(235)
577         zf  = zf1 * zf
578         !
579      CASE ( 5 )                 !==  formule 5,  compound waves (78 *78 x 235)
580         zf1 = nodal_factort( 78)
581         zf  = nodal_factort(235)
582         zf  = zf * zf1 * zf1
583         !
584      CASE ( 6 )                 !==  formule 6,  compound waves (78 *78 x 0)
585         zf1 = nodal_factort(78)
586         zf  = nodal_factort( 0)
587         zf  = zf * zf1 * zf1 
588         !
589      CASE( 7 )                  !==  formule 7, compound waves (75 x 75)
590         zf = nodal_factort(75)
591         zf = zf * zf
592         !
593      CASE( 8 )                  !==  formule 8,  compound waves (78 x 0 x 235)
594         zf  = nodal_factort( 78)
595         zf1 = nodal_factort(  0)
596         zf2 = nodal_factort(235)
597         zf  = zf * zf1 * zf2
598         !
599      CASE( 9 )                  !==  formule 9,  compound waves (78 x 0 x 227)
600         zf  = nodal_factort( 78)
601         zf1 = nodal_factort(  0)
602         zf2 = nodal_factort(227)
603         zf  = zf * zf1 * zf2
604         !
605      CASE( 10 )                 !==  formule 10,  compound waves (78 x 227)
606         zf  = nodal_factort( 78)
607         zf1 = nodal_factort(227)
608         zf  = zf * zf1
609         !
610      CASE( 11 )                 !==  formule 11,  compound waves (75 x 0)
611!!gm bug???? zf 2 fois !
612         zf = nodal_factort(75)
613         zf1 = nodal_factort( 0)
614         zf = zf * zf1
615         !
616      CASE( 12 )                 !==  formule 12,  compound waves (78 x 78 x 78 x 0)
617         zf1 = nodal_factort(78)
618         zf  = nodal_factort( 0)
619         zf  = zf * zf1 * zf1 * zf1
620         !
621      CASE( 13 )                 !==  formule 13, compound waves (78 x 75)
622         zf1 = nodal_factort(78)
623         zf  = nodal_factort(75)
624         zf  = zf * zf1
625         !
626      CASE( 14 )                 !==  formule 14, compound waves (235 x 0)  ===  (235)
627         zf  = nodal_factort(235)
628         zf1 = nodal_factort(  0)
629         zf  = zf * zf1
630         !
631      CASE( 15 )                 !==  formule 15, compound waves (235 x 75)
632         zf  = nodal_factort(235)
633         zf1 = nodal_factort( 75)
634         zf  = zf * zf1
635         !
636      CASE( 16 )                 !==  formule 16, compound waves (78 x 0 x 0)  ===  (78)
637         zf  = nodal_factort(78)
638         zf1 = nodal_factort( 0)
639         zf  = zf * zf1 * zf1
640         !
641      CASE( 17 )                 !==  formule 17,  compound waves (227 x 0)
642         zf1 = nodal_factort(227)
643         zf  = nodal_factort(  0)
644         zf  = zf * zf1
645         !
646      CASE( 18 )                 !==  formule 18,  compound waves (78 x 78 x 78 )
647         zf1 = nodal_factort(78)
648         zf  = zf1 * zf1 * zf1
649         !
650      CASE( 19 )                 !==  formule 19, compound waves (78 x 0 x 0 x 0)  ===  (78)
651!!gm bug2 ==>>>   here identical to formule 16,  a third multiplication by zf1 is missing
652         zf  = nodal_factort(78)
653         zf1 = nodal_factort( 0)
654         zf = zf * zf1 * zf1
655         !
656      CASE( 73 )                 !==  formule 73
657         zs = sin(sh_I)
658         zf = (2./3.-zs*zs)/0.5021
659         !
660      CASE( 74 )                 !==  formule 74
661         zs = sin(sh_I)
662         zf = zs * zs / 0.1578
663         !
664      CASE( 75 )                 !==  formule 75
665         zs = cos(sh_I/2)
666         zf = sin(sh_I) * zs * zs / 0.3800
667         !
668      CASE( 76 )                 !==  formule 76
669         zf = sin(2*sh_I) / 0.7214
670         !
671      CASE( 77 )                 !==  formule 77
672         zs = sin(sh_I/2)
673         zf = sin(sh_I) * zs * zs / 0.0164
674         !
675      CASE( 78 )                 !==  formule 78
676         zs = cos(sh_I/2)
677         zf = zs * zs * zs * zs / 0.9154
678         !
679      CASE( 79 )                 !==  formule 79
680         zs = sin(sh_I)
681         zf = zs * zs / 0.1565
682         !
683      CASE( 144 )                !==  formule 144
684         zs = sin(sh_I/2)
685         zf = ( 1-10*zs*zs+15*zs*zs*zs*zs ) * cos(sh_I/2) / 0.5873
686         !
687      CASE( 149 )                !==  formule 149
688         zs = cos(sh_I/2)
689         zf = zs*zs*zs*zs*zs*zs / 0.8758
690         !
691      CASE( 215 )                !==  formule 215
692         zs = cos(sh_I/2)
693         zf = zs*zs*zs*zs / 0.9154 * sh_x1ra
694         !
695      CASE( 227 )                !==  formule 227
696         zs = sin(2*sh_I)
697         zf = sqrt( 0.8965*zs*zs+0.6001*zs*cos (sh_nu)+0.1006 )
698         !
699      CASE ( 235 )               !==  formule 235
700         zs = sin(sh_I)
701         zf = sqrt( 19.0444*zs*zs*zs*zs + 2.7702*zs*zs*cos(2*sh_nu) + .0981 )
702         !
703      END SELECT
704      !
705   END FUNCTION nodal_factort
706
707
708   FUNCTION dayjul( kyr, kmonth, kday )
709      !!----------------------------------------------------------------------
710      !!  *** THIS ROUTINE COMPUTES THE JULIAN DAY (AS A REAL VARIABLE)
711      !!----------------------------------------------------------------------
712      INTEGER,INTENT(in) ::   kyr, kmonth, kday
713      !
714      INTEGER,DIMENSION(12) ::  idayt, idays
715      INTEGER  ::   inc, ji
716      REAL(wp) ::   dayjul, zyq
717      !
718      DATA idayt/0.,31.,59.,90.,120.,151.,181.,212.,243.,273.,304.,334./
719      !!----------------------------------------------------------------------
720      !
721      idays(1) = 0.
722      idays(2) = 31.
723      inc = 0.
724      zyq = MOD( kyr-1900. , 4. )
725      IF( zyq == 0.)   inc = 1.
726      DO ji = 3, 12
727         idays(ji)=idayt(ji)+inc
728      END DO
729      dayjul = idays(kmonth) + kday
730      !
731   END FUNCTION dayjul
732
733
734   SUBROUTINE upd_tide(pdelta)
735      !!----------------------------------------------------------------------
736      !!                 ***  ROUTINE upd_tide  ***
737      !!
738      !! ** Purpose :   provide at each time step the astronomical potential
739      !!
740      !! ** Method  :   computed from pulsation and amplitude of all tide components
741      !!
742      !! ** Action  :   pot_astro   actronomical potential
743      !!----------------------------------------------------------------------     
744      REAL, INTENT(in)              ::   pdelta      ! Temporal offset in seconds
745      INTEGER                       ::   jk          ! Dummy loop index
746      REAL(wp)                      ::   zt, zramp   ! Local scalars
747      REAL(wp), DIMENSION(nb_harmo) ::   zwt         ! Temporary array
748      !!----------------------------------------------------------------------     
749      !
750      zwt(:) = tide_harmonics(:)%omega * pdelta
751      !
752      pot_astro(:,:) = 0._wp          ! update tidal potential (sum of all harmonics)
753      DO jk = 1, nb_harmo   
754         pot_astro(:,:) = pot_astro(:,:) + amp_pot(:,:,jk) * COS( zwt(jk) + phi_pot(:,:,jk) )     
755      END DO
756      !
757      IF( ln_tide_ramp ) THEN         ! linear increase if asked
758         zt = rn_tide_ramp_t + pdelta
759         zramp = MIN(  MAX( zt / (rn_tide_ramp_dt*rday) , 0._wp ) , 1._wp  )
760         pot_astro(:,:) = zramp * pot_astro(:,:)
761      ENDIF
762      !
763   END SUBROUTINE upd_tide
764
765   !!======================================================================
766END MODULE tide_mod
Note: See TracBrowser for help on using the repository browser.