New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
bdytra.F90 in NEMO/branches/2019/dev_r10973_AGRIF-01_jchanut_small_jpi_jpj/src/OCE/BDY – NEMO

source: NEMO/branches/2019/dev_r10973_AGRIF-01_jchanut_small_jpi_jpj/src/OCE/BDY/bdytra.F90 @ 11564

Last change on this file since 11564 was 11564, checked in by jchanut, 5 years ago

#2199, merged with trunk

  • Property svn:keywords set to Id
File size: 8.7 KB
Line 
1MODULE bdytra
2   !!======================================================================
3   !!                       ***  MODULE  bdytra  ***
4   !! Ocean tracers:   Apply boundary conditions for tracers
5   !!======================================================================
6   !! History :  1.0  !  2005-01  (J. Chanut, A. Sellar)  Original code
7   !!            3.0  !  2008-04  (NEMO team)  add in the reference version
8   !!            3.4  !  2011     (D. Storkey) rewrite in preparation for OBC-BDY merge
9   !!            3.5  !  2012     (S. Mocavero, I. Epicoco) Optimization of BDY communications
10   !!            4.0  !  2016     (T. Lovato) Generalize OBC structure
11   !!----------------------------------------------------------------------
12   !!   bdy_tra       : Apply open boundary conditions & damping to T and S
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers variables
15   USE dom_oce        ! ocean space and time domain variables
16   USE bdy_oce        ! ocean open boundary conditions
17   USE bdylib         ! for orlanski library routines
18   !
19   USE in_out_manager ! I/O manager
20   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
21   USE lib_mpp, ONLY: ctl_stop
22   USE timing         ! Timing
23
24   IMPLICIT NONE
25   PRIVATE
26
27   ! Local structure to rearrange tracers data
28   TYPE, PUBLIC ::   ztrabdy
29      REAL(wp), POINTER, DIMENSION(:,:) ::  tra
30   END TYPE
31
32   PUBLIC   bdy_tra      ! called in tranxt.F90
33   PUBLIC   bdy_tra_dmp  ! called in step.F90
34
35   !!----------------------------------------------------------------------
36   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
37   !! $Id$
38   !! Software governed by the CeCILL license (see ./LICENSE)
39   !!----------------------------------------------------------------------
40CONTAINS
41
42   SUBROUTINE bdy_tra( kt )
43      !!----------------------------------------------------------------------
44      !!                  ***  SUBROUTINE bdy_tra  ***
45      !!
46      !! ** Purpose : - Apply open boundary conditions for temperature and salinity
47      !!
48      !!----------------------------------------------------------------------
49      INTEGER, INTENT(in) ::   kt   ! Main time step counter
50      !
51      INTEGER                        :: ib_bdy, jn, igrd, ir   ! Loop indeces
52      TYPE(ztrabdy), DIMENSION(jpts) :: zdta                   ! Temporary data structure
53      LOGICAL                        :: llrim0                 ! indicate if rim 0 is treated
54      LOGICAL, DIMENSION(4)          :: llsend1, llrecv1       ! indicate how communications are to be carried out
55      !!----------------------------------------------------------------------
56      igrd = 1 
57      llsend1(:) = .false.  ;   llrecv1(:) = .false.
58      DO ir = 1, 0, -1   ! treat rim 1 before rim 0
59         IF( ir == 0 ) THEN   ;   llrim0 = .TRUE.
60         ELSE                 ;   llrim0 = .FALSE.
61         END IF
62         DO ib_bdy=1, nb_bdy
63            !
64            zdta(1)%tra => dta_bdy(ib_bdy)%tem
65            zdta(2)%tra => dta_bdy(ib_bdy)%sal
66            !
67            DO jn = 1, jpts
68               !
69               SELECT CASE( TRIM(cn_tra(ib_bdy)) )
70               CASE('none'        )   ;   CYCLE
71               CASE('frs'         )   ! treat the whole boundary at once
72                  IF( ir == 0 ) CALL bdy_frs ( idx_bdy(ib_bdy),                tsa(:,:,:,jn), zdta(jn)%tra )
73               CASE('specified'   )   ! treat the whole rim      at once
74                  IF( ir == 0 ) CALL bdy_spe ( idx_bdy(ib_bdy),                tsa(:,:,:,jn), zdta(jn)%tra )
75               CASE('neumann'     )   ;   CALL bdy_nmn ( idx_bdy(ib_bdy), igrd         , tsa(:,:,:,jn), llrim0 )   ! tsa masked
76               CASE('orlanski'    )   ;   CALL bdy_orl ( idx_bdy(ib_bdy), tsb(:,:,:,jn), tsa(:,:,:,jn), &
77                    & zdta(jn)%tra, llrim0, ll_npo=.false. )
78               CASE('orlanski_npo')   ;   CALL bdy_orl ( idx_bdy(ib_bdy), tsb(:,:,:,jn), tsa(:,:,:,jn), &
79                    & zdta(jn)%tra, llrim0, ll_npo=.true.  )
80               CASE('runoff'      )   ;   CALL bdy_rnf ( idx_bdy(ib_bdy),                tsa(:,:,:,jn), jn, llrim0 )
81               CASE DEFAULT           ;   CALL ctl_stop( 'bdy_tra : unrecognised option for open boundaries for T and S' )
82               END SELECT
83               !
84            END DO
85         END DO
86         !
87         IF( nn_hls > 1 .AND. ir == 1 ) CYCLE   ! at least 2 halos will be corrected -> no need to correct rim 1 before rim 0
88         IF( nn_hls == 1 ) THEN   ;   llsend1(:) = .false.   ;   llrecv1(:) = .false.   ;   END IF
89         DO ib_bdy=1, nb_bdy
90            SELECT CASE( TRIM(cn_tra(ib_bdy)) )
91            CASE('neumann','runoff')
92               llsend1(:) = llsend1(:) .OR. lsend_bdyint(ib_bdy,1,:,ir)   ! possibly every direction, T points
93               llrecv1(:) = llrecv1(:) .OR. lrecv_bdyint(ib_bdy,1,:,ir)   ! possibly every direction, T points
94            CASE('orlanski', 'orlanski_npo')
95               llsend1(:) = llsend1(:) .OR. lsend_bdy(ib_bdy,1,:,ir)   ! possibly every direction, T points
96               llrecv1(:) = llrecv1(:) .OR. lrecv_bdy(ib_bdy,1,:,ir)   ! possibly every direction, T points
97            END SELECT
98         END DO
99         IF( ANY(llsend1) .OR. ANY(llrecv1) ) THEN   ! if need to send/recv in at least one direction
100            CALL lbc_lnk( 'bdytra', tsa, 'T',  1., kfillmode=jpfillnothing ,lsend=llsend1, lrecv=llrecv1 )
101         END IF
102         !
103      END DO   ! ir
104      !
105   END SUBROUTINE bdy_tra
106
107
108   SUBROUTINE bdy_rnf( idx, pta, jpa, llrim0 )
109      !!----------------------------------------------------------------------
110      !!                 ***  SUBROUTINE bdy_rnf  ***
111      !!                   
112      !! ** Purpose : Specialized routine to apply TRA runoff values at OBs:
113      !!                  - duplicate the neighbour value for the temperature
114      !!                  - specified to 0.1 PSU for the salinity
115      !!
116      !!----------------------------------------------------------------------
117      TYPE(OBC_INDEX),                     INTENT(in) ::   idx      ! OBC indices
118      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pta      ! tracer trend
119      INTEGER,                             INTENT(in) ::   jpa      ! TRA index
120      LOGICAL,                             INTENT(in) ::   llrim0   ! indicate if rim 0 is treated
121      !
122      INTEGER  ::   ib, ii, ij, igrd   ! dummy loop indices
123      INTEGER  ::   ik, ip, jp ! 2D addresses
124      !!----------------------------------------------------------------------
125      !
126      igrd = 1                       ! Everything is at T-points here
127      IF(      jpa == jp_tem ) THEN
128         CALL bdy_nmn( idx, igrd, pta, llrim0 )
129      ELSE IF( jpa == jp_sal ) THEN
130         IF( .NOT. llrim0 )   RETURN
131         DO ib = 1, idx%nblenrim(igrd)   ! if llrim0 then treat the whole rim
132            ii = idx%nbi(ib,igrd)
133            ij = idx%nbj(ib,igrd)
134            pta(ii,ij,1:jpkm1) = 0.1 * tmask(ii,ij,1:jpkm1)
135         END DO
136      END IF
137      !
138   END SUBROUTINE bdy_rnf
139
140
141   SUBROUTINE bdy_tra_dmp( kt )
142      !!----------------------------------------------------------------------
143      !!                 ***  SUBROUTINE bdy_tra_dmp  ***
144      !!                   
145      !! ** Purpose : Apply damping for tracers at open boundaries.
146      !!
147      !!----------------------------------------------------------------------
148      INTEGER, INTENT(in) ::   kt   !
149      !
150      REAL(wp) ::   zwgt           ! boundary weight
151      REAL(wp) ::   zta, zsa, ztime
152      INTEGER  ::   ib, ik, igrd   ! dummy loop indices
153      INTEGER  ::   ii, ij         ! 2D addresses
154      INTEGER  ::   ib_bdy         ! Loop index
155      !!----------------------------------------------------------------------
156      !
157      IF( ln_timing )   CALL timing_start('bdy_tra_dmp')
158      !
159      DO ib_bdy = 1, nb_bdy
160         IF( ln_tra_dmp(ib_bdy) ) THEN
161            igrd = 1                       ! Everything is at T-points here
162            DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
163               ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
164               ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
165               zwgt = idx_bdy(ib_bdy)%nbd(ib,igrd)
166               DO ik = 1, jpkm1
167                  zta = zwgt * ( dta_bdy(ib_bdy)%tem(ib,ik) - tsb(ii,ij,ik,jp_tem) ) * tmask(ii,ij,ik)
168                  zsa = zwgt * ( dta_bdy(ib_bdy)%sal(ib,ik) - tsb(ii,ij,ik,jp_sal) ) * tmask(ii,ij,ik)
169                  tsa(ii,ij,ik,jp_tem) = tsa(ii,ij,ik,jp_tem) + zta
170                  tsa(ii,ij,ik,jp_sal) = tsa(ii,ij,ik,jp_sal) + zsa
171               END DO
172            END DO
173         ENDIF
174      END DO
175      !
176      IF( ln_timing )   CALL timing_stop('bdy_tra_dmp')
177      !
178   END SUBROUTINE bdy_tra_dmp
179 
180   !!======================================================================
181END MODULE bdytra
Note: See TracBrowser for help on using the repository browser.