New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
icedyn.F90 in NEMO/branches/2019/dev_r10984_HPC-13_IRRMANN_BDY_optimization/src/ICE – NEMO

source: NEMO/branches/2019/dev_r10984_HPC-13_IRRMANN_BDY_optimization/src/ICE/icedyn.F90 @ 11362

Last change on this file since 11362 was 11362, checked in by clem, 5 years ago

debug the ice output by adding a missing value to the outputed fields. Unfortunately this method imposes a value of 1.e20 where there is no ice, which is annoying when using ncview for example, but this is the only way (from what I know) to output averages
  • Property svn:keywords set to Id
File size: 15.3 KB
Line 
1MODULE icedyn
2   !!======================================================================
3   !!                     ***  MODULE  icedyn  ***
4   !!   Sea-Ice dynamics : master routine for sea ice dynamics
5   !!======================================================================
6   !! history :  4.0  ! 2018  (C. Rousset)  original code SI3 [aka Sea Ice cube]
7   !!----------------------------------------------------------------------
8#if defined key_si3
9   !!----------------------------------------------------------------------
10   !!   'key_si3'                                       SI3 sea-ice model
11   !!----------------------------------------------------------------------
12   !!   ice_dyn       : dynamics of sea ice
13   !!   ice_dyn_init  : initialization and namelist read
14   !!----------------------------------------------------------------------
15   USE phycst         ! physical constants
16   USE dom_oce        ! ocean space and time domain
17   USE ice            ! sea-ice: variables
18   USE icedyn_rhg     ! sea-ice: rheology
19   USE icedyn_adv     ! sea-ice: advection
20   USE icedyn_rdgrft  ! sea-ice: ridging/rafting
21   USE icecor         ! sea-ice: corrections
22   USE icevar         ! sea-ice: operations
23   USE icectl         ! sea-ice: control prints
24   !
25   USE in_out_manager ! I/O manager
26   USE iom            ! I/O manager library
27   USE lib_mpp        ! MPP library
28   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
29   USE lbclnk         ! lateral boundary conditions (or mpp links)
30   USE timing         ! Timing
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   ice_dyn        ! called by icestp.F90
36   PUBLIC   ice_dyn_init   ! called by icestp.F90
37   
38   INTEGER ::              nice_dyn   ! choice of the type of dynamics
39   !                                        ! associated indices:
40   INTEGER, PARAMETER ::   np_dynALL     = 1   ! full ice dynamics               (rheology + advection + ridging/rafting + correction)
41   INTEGER, PARAMETER ::   np_dynRHGADV  = 2   ! pure dynamics                   (rheology + advection)
42   INTEGER, PARAMETER ::   np_dynADV1D   = 3   ! only advection 1D - test case from Schar & Smolarkiewicz 1996
43   INTEGER, PARAMETER ::   np_dynADV2D   = 4   ! only advection 2D w prescribed vel.(rn_uvice + advection)
44   !
45   ! ** namelist (namdyn) **
46   LOGICAL  ::   ln_dynALL        ! full ice dynamics                      (rheology + advection + ridging/rafting + correction)
47   LOGICAL  ::   ln_dynRHGADV     ! no ridge/raft & no corrections         (rheology + advection)
48   LOGICAL  ::   ln_dynADV1D      ! only advection in 1D w ice convergence (test case from Schar & Smolarkiewicz 1996)
49   LOGICAL  ::   ln_dynADV2D      ! only advection in 2D w prescribed vel. (rn_uvice + advection)
50   REAL(wp) ::   rn_uice          !    prescribed u-vel (case np_dynADV1D & np_dynADV2D)
51   REAL(wp) ::   rn_vice          !    prescribed v-vel (case np_dynADV1D & np_dynADV2D)
52   
53   !! * Substitutions
54#  include "vectopt_loop_substitute.h90"
55   !!----------------------------------------------------------------------
56   !! NEMO/ICE 4.0 , NEMO Consortium (2018)
57   !! $Id$
58   !! Software governed by the CeCILL licence     (./LICENSE)
59   !!----------------------------------------------------------------------
60CONTAINS
61
62   SUBROUTINE ice_dyn( kt )
63      !!-------------------------------------------------------------------
64      !!               ***  ROUTINE ice_dyn  ***
65      !!               
66      !! ** Purpose :   this routine manages sea ice dynamics
67      !!
68      !! ** Action : - calculation of friction in case of landfast ice
69      !!             - call ice_dyn_rhg    = rheology
70      !!             - call ice_dyn_adv    = advection
71      !!             - call ice_dyn_rdgrft = ridging/rafting
72      !!             - call ice_cor        = corrections if fields are out of bounds
73      !!--------------------------------------------------------------------
74      INTEGER, INTENT(in) ::   kt     ! ice time step
75      !!
76      INTEGER  ::   ji, jj        ! dummy loop indices
77      REAL(wp) ::   zmiss_val     ! missing value retrieved from xios
78      REAL(wp) ::   zcoefu, zcoefv
79      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   zdivu_i, zmsk00
80      !!--------------------------------------------------------------------
81      !
82      ! controls
83      IF( ln_timing )   CALL timing_start('icedyn')
84      !
85      IF( kt == nit000 .AND. lwp ) THEN
86         WRITE(numout,*)
87         WRITE(numout,*)'ice_dyn: sea-ice dynamics'
88         WRITE(numout,*)'~~~~~~~'
89      ENDIF
90      !                     
91      ! get missing value from xml
92      CALL iom_miss_val( "icethic", zmiss_val )
93      !
94      ! retrieve thickness from volume for landfast param. and UMx advection scheme
95      WHERE( a_i(:,:,:) >= epsi20 )
96         h_i(:,:,:) = v_i(:,:,:) / a_i_b(:,:,:)
97         h_s(:,:,:) = v_s(:,:,:) / a_i_b(:,:,:)
98      ELSEWHERE
99         h_i(:,:,:) = 0._wp
100         h_s(:,:,:) = 0._wp
101      END WHERE
102      !
103      WHERE( a_ip(:,:,:) >= epsi20 )
104         h_ip(:,:,:) = v_ip(:,:,:) / a_ip(:,:,:)
105      ELSEWHERE
106         h_ip(:,:,:) = 0._wp
107      END WHERE
108      !
109      !
110      SELECT CASE( nice_dyn )          !-- Set which dynamics is running
111
112      CASE ( np_dynALL )           !==  all dynamical processes  ==!
113         !
114         CALL ice_dyn_rhg   ( kt )                                          ! -- rheology 
115         CALL ice_dyn_adv   ( kt )                                          ! -- advection of ice
116         CALL ice_dyn_rdgrft( kt )                                          ! -- ridging/rafting
117         CALL ice_cor       ( kt , 1 )                                      ! -- Corrections
118         !
119      CASE ( np_dynRHGADV  )       !==  no ridge/raft & no corrections ==!
120         !
121         CALL ice_dyn_rhg   ( kt )                                          ! -- rheology 
122         CALL ice_dyn_adv   ( kt )                                          ! -- advection of ice
123         CALL Hpiling                                                       ! -- simple pile-up (replaces ridging/rafting)
124         CALL ice_var_zapsmall                                              ! -- zap small areas
125         !
126      CASE ( np_dynADV1D )         !==  pure advection ==!   (1D)
127         !
128         ! --- monotonicity test from Schar & Smolarkiewicz 1996 --- !
129         ! CFL = 0.5 at a distance from the bound of 1/6 of the basin length
130         ! Then for dx = 2m and dt = 1s => rn_uice = u (1/6th) = 1m/s
131         DO jj = 1, jpj
132            DO ji = 1, jpi
133               zcoefu = ( REAL(jpiglo+1)*0.5 - REAL(ji+nimpp-1) ) / ( REAL(jpiglo+1)*0.5 - 1. )
134               zcoefv = ( REAL(jpjglo+1)*0.5 - REAL(jj+njmpp-1) ) / ( REAL(jpjglo+1)*0.5 - 1. )
135               u_ice(ji,jj) = rn_uice * 1.5 * SIGN( 1., zcoefu ) * ABS( zcoefu ) * umask(ji,jj,1)
136               v_ice(ji,jj) = rn_vice * 1.5 * SIGN( 1., zcoefv ) * ABS( zcoefv ) * vmask(ji,jj,1)
137            END DO
138         END DO
139         ! ---
140         CALL ice_dyn_adv   ( kt )                                          ! -- advection of ice
141         !
142      CASE ( np_dynADV2D )         !==  pure advection ==!   (2D w prescribed velocities)
143         !
144         u_ice(:,:) = rn_uice * umask(:,:,1)
145         v_ice(:,:) = rn_vice * vmask(:,:,1)
146         !CALL RANDOM_NUMBER(u_ice(:,:)) ; u_ice(:,:) = u_ice(:,:) * 0.1 + rn_uice * 0.9 * umask(:,:,1)
147         !CALL RANDOM_NUMBER(v_ice(:,:)) ; v_ice(:,:) = v_ice(:,:) * 0.1 + rn_vice * 0.9 * vmask(:,:,1)
148         ! ---
149         CALL ice_dyn_adv   ( kt )                                          ! -- advection of ice
150
151      END SELECT
152      !
153      !
154      ! diagnostics: divergence at T points
155      IF( iom_use('icediv') ) THEN
156         !
157         SELECT CASE( nice_dyn )
158
159         CASE ( np_dynADV1D , np_dynADV2D )
160
161            ALLOCATE( zdivu_i(jpi,jpj), zmsk00(jpi,jpj) )
162
163            DO jj = 1, jpj
164               DO ji = 1, jpi
165                  zmsk00(ji,jj) = MAX( 0._wp , SIGN( 1._wp , at_i(ji,jj) - epsi06  ) ) ! 1 if ice    , 0 if no ice
166               END DO
167            END DO
168            DO jj = 2, jpjm1
169               DO ji = 2, jpim1
170                  zdivu_i(ji,jj) = ( e2u(ji,jj) * u_ice(ji,jj) - e2u(ji-1,jj) * u_ice(ji-1,jj)   &
171                     &             + e1v(ji,jj) * v_ice(ji,jj) - e1v(ji,jj-1) * v_ice(ji,jj-1) ) * r1_e1e2t(ji,jj)
172               END DO
173            END DO
174            CALL lbc_lnk( 'icedyn', zdivu_i, 'T', 1. )
175            ! output
176            CALL iom_put( "icediv" , zdivu_i * zmsk00 + zmiss_val * ( 1._wp - zmsk00 ) )
177
178            DEALLOCATE( zdivu_i, zmsk00 )
179
180         END SELECT
181         !
182      ENDIF
183      !
184      ! controls
185      IF( ln_timing )   CALL timing_stop ('icedyn')
186      !
187   END SUBROUTINE ice_dyn
188
189
190   SUBROUTINE Hpiling
191      !!-------------------------------------------------------------------
192      !!                  ***  ROUTINE Hpiling  ***
193      !!
194      !! ** Purpose : Simple conservative piling comparable with 1-cat models
195      !!
196      !! ** Method  : pile-up ice when no ridging/rafting
197      !!
198      !! ** input   : a_i
199      !!-------------------------------------------------------------------
200      INTEGER ::   jl         ! dummy loop indices
201      !!-------------------------------------------------------------------
202      ! controls
203      IF( ln_icediachk )   CALL ice_cons_hsm(0, 'Hpiling', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft) ! conservation
204      !
205      at_i(:,:) = SUM( a_i(:,:,:), dim=3 )
206      DO jl = 1, jpl
207         WHERE( at_i(:,:) > epsi20 )
208            a_i(:,:,jl) = a_i(:,:,jl) * (  1._wp + MIN( rn_amax_2d(:,:) - at_i(:,:) , 0._wp ) / at_i(:,:)  )
209         END WHERE
210      END DO
211      ! controls
212      IF( ln_icediachk )   CALL ice_cons_hsm(1, 'Hpiling', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft) ! conservation
213      !
214   END SUBROUTINE Hpiling
215
216
217   SUBROUTINE ice_dyn_init
218      !!-------------------------------------------------------------------
219      !!                  ***  ROUTINE ice_dyn_init  ***
220      !!
221      !! ** Purpose : Physical constants and parameters linked to the ice
222      !!      dynamics
223      !!
224      !! ** Method  :  Read the namdyn namelist and check the ice-dynamic
225      !!       parameter values called at the first timestep (nit000)
226      !!
227      !! ** input   :   Namelist namdyn
228      !!-------------------------------------------------------------------
229      INTEGER ::   ios, ioptio   ! Local integer output status for namelist read
230      !!
231      NAMELIST/namdyn/ ln_dynALL, ln_dynRHGADV, ln_dynADV1D, ln_dynADV2D, rn_uice, rn_vice,  &
232         &             rn_ishlat ,                                                           &
233         &             ln_landfast_L16, ln_landfast_home, rn_depfra, rn_icebfr, rn_lfrelax, rn_tensile
234      !!-------------------------------------------------------------------
235      !
236      REWIND( numnam_ice_ref )         ! Namelist namdyn in reference namelist : Ice dynamics
237      READ  ( numnam_ice_ref, namdyn, IOSTAT = ios, ERR = 901)
238901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namdyn in reference namelist' )
239      REWIND( numnam_ice_cfg )         ! Namelist namdyn in configuration namelist : Ice dynamics
240      READ  ( numnam_ice_cfg, namdyn, IOSTAT = ios, ERR = 902 )
241902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namdyn in configuration namelist' )
242      IF(lwm) WRITE( numoni, namdyn )
243      !
244      IF(lwp) THEN                     ! control print
245         WRITE(numout,*)
246         WRITE(numout,*) 'ice_dyn_init: ice parameters for ice dynamics '
247         WRITE(numout,*) '~~~~~~~~~~~~'
248         WRITE(numout,*) '   Namelist namdyn:'
249         WRITE(numout,*) '      Full ice dynamics      (rhg + adv + ridge/raft + corr) ln_dynALL       = ', ln_dynALL
250         WRITE(numout,*) '      No ridge/raft & No cor (rhg + adv)                     ln_dynRHGADV    = ', ln_dynRHGADV
251         WRITE(numout,*) '      Advection 1D only      (Schar & Smolarkiewicz 1996)    ln_dynADV1D     = ', ln_dynADV1D
252         WRITE(numout,*) '      Advection 2D only      (rn_uvice + adv)                ln_dynADV2D     = ', ln_dynADV2D
253         WRITE(numout,*) '         with prescribed velocity given by   (u,v)_ice = (rn_uice,rn_vice)   = (', rn_uice,',',rn_vice,')'
254         WRITE(numout,*) '      lateral boundary condition for sea ice dynamics        rn_ishlat       = ', rn_ishlat
255         WRITE(numout,*) '      Landfast: param from Lemieux 2016                      ln_landfast_L16 = ', ln_landfast_L16
256         WRITE(numout,*) '      Landfast: param from home made                         ln_landfast_home= ', ln_landfast_home
257         WRITE(numout,*) '         fraction of ocean depth that ice must reach         rn_depfra       = ', rn_depfra
258         WRITE(numout,*) '         maximum bottom stress per unit area of contact      rn_icebfr       = ', rn_icebfr
259         WRITE(numout,*) '         relax time scale (s-1) to reach static friction     rn_lfrelax      = ', rn_lfrelax
260         WRITE(numout,*) '         isotropic tensile strength                          rn_tensile      = ', rn_tensile
261         WRITE(numout,*)
262      ENDIF
263      !                             !== set the choice of ice dynamics ==!
264      ioptio = 0 
265      !      !--- full dynamics                               (rheology + advection + ridging/rafting + correction)
266      IF( ln_dynALL    ) THEN   ;   ioptio = ioptio + 1   ;   nice_dyn = np_dynALL       ;   ENDIF
267      !      !--- dynamics without ridging/rafting and corr   (rheology + advection)
268      IF( ln_dynRHGADV ) THEN   ;   ioptio = ioptio + 1   ;   nice_dyn = np_dynRHGADV    ;   ENDIF
269      !      !--- advection 1D only - test case from Schar & Smolarkiewicz 1996
270      IF( ln_dynADV1D  ) THEN   ;   ioptio = ioptio + 1   ;   nice_dyn = np_dynADV1D     ;   ENDIF
271      !      !--- advection 2D only with prescribed ice velocities (from namelist)
272      IF( ln_dynADV2D  ) THEN   ;   ioptio = ioptio + 1   ;   nice_dyn = np_dynADV2D     ;   ENDIF
273      !
274      IF( ioptio /= 1 )    CALL ctl_stop( 'ice_dyn_init: one and only one ice dynamics option has to be defined ' )
275      !
276      !                                      !--- Lateral boundary conditions
277      IF     (      rn_ishlat == 0.                ) THEN   ;   IF(lwp) WRITE(numout,*) '   ===>>>   ice lateral  free-slip'
278      ELSEIF (      rn_ishlat == 2.                ) THEN   ;   IF(lwp) WRITE(numout,*) '   ===>>>   ice lateral  no-slip'
279      ELSEIF ( 0. < rn_ishlat .AND. rn_ishlat < 2. ) THEN   ;   IF(lwp) WRITE(numout,*) '   ===>>>   ice lateral  partial-slip'
280      ELSEIF ( 2. < rn_ishlat                      ) THEN   ;   IF(lwp) WRITE(numout,*) '   ===>>>   ice lateral  strong-slip'
281      ENDIF
282      !                                      !--- Landfast ice
283      IF( .NOT.ln_landfast_L16 .AND. .NOT.ln_landfast_home )   tau_icebfr(:,:) = 0._wp
284      !
285      IF ( ln_landfast_L16 .AND. ln_landfast_home ) THEN
286         CALL ctl_stop( 'ice_dyn_init: choose one and only one landfast parameterization (ln_landfast_L16 or ln_landfast_home)' )
287      ENDIF
288      !
289      CALL ice_dyn_rdgrft_init          ! set ice ridging/rafting parameters
290      CALL ice_dyn_rhg_init             ! set ice rheology parameters
291      CALL ice_dyn_adv_init             ! set ice advection parameters
292      !
293   END SUBROUTINE ice_dyn_init
294
295#else
296   !!----------------------------------------------------------------------
297   !!   Default option         Empty module           NO SI3 sea-ice model
298   !!----------------------------------------------------------------------
299#endif 
300
301   !!======================================================================
302END MODULE icedyn
Note: See TracBrowser for help on using the repository browser.