source: NEMO/branches/2019/dev_r10984_HPC-13_IRRMANN_BDY_optimization/src/ICE/icesbc.F90 @ 11317

Last change on this file since 11317 was 11317, checked in by smasson, 14 months ago

dev_r10984_HPC-13 : improve error handling, see #2307 and #2285

  • Property svn:keywords set to Id
File size: 16.9 KB
Line 
1MODULE icesbc
2   !!======================================================================
3   !!                       ***  MODULE  icesbc  ***
4   !! Sea-Ice :   air-ice sbc fields
5   !!=====================================================================
6   !! History :  4.0  !  2017-08  (C. Rousset)       Original code
7   !!            4.0  !  2018     (many people)      SI3 [aka Sea Ice cube]
8   !!----------------------------------------------------------------------
9#if defined key_si3
10   !!----------------------------------------------------------------------
11   !!   'key_si3' :                                     SI3 sea-ice model
12   !!----------------------------------------------------------------------
13   USE oce            ! ocean dynamics and tracers
14   USE dom_oce        ! ocean space and time domain
15   USE ice            ! sea-ice: variables
16   USE sbc_oce        ! Surface boundary condition: ocean fields
17   USE sbc_ice        ! Surface boundary condition: ice   fields
18   USE usrdef_sbc     ! Surface boundary condition: user defined
19   USE sbcblk         ! Surface boundary condition: bulk
20   USE sbccpl         ! Surface boundary condition: coupled interface
21   USE icealb         ! sea-ice: albedo
22   !
23   USE in_out_manager ! I/O manager
24   USE iom            ! I/O manager library
25   USE lib_mpp        ! MPP library
26   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
27   USE lbclnk         ! lateral boundary conditions (or mpp links)
28   USE timing         ! Timing
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC ice_sbc_tau   ! called by icestp.F90
34   PUBLIC ice_sbc_flx   ! called by icestp.F90
35   PUBLIC ice_sbc_init  ! called by icestp.F90
36
37   !! * Substitutions
38#  include "vectopt_loop_substitute.h90"
39   !!----------------------------------------------------------------------
40   !! NEMO/ICE 4.0 , NEMO Consortium (2018)
41   !! $Id$
42   !! Software governed by the CeCILL license (see ./LICENSE)
43   !!----------------------------------------------------------------------
44CONTAINS
45
46   SUBROUTINE ice_sbc_tau( kt, ksbc, utau_ice, vtau_ice )
47      !!-------------------------------------------------------------------
48      !!                  ***  ROUTINE ice_sbc_tau  ***
49      !!
50      !! ** Purpose : provide surface boundary condition for sea ice (momentum)
51      !!
52      !! ** Action  : It provides the following fields:
53      !!              utau_ice, vtau_ice : surface ice stress (U- & V-points) [N/m2]
54      !!-------------------------------------------------------------------
55      INTEGER                     , INTENT(in   ) ::   kt                   ! ocean time step
56      INTEGER                     , INTENT(in   ) ::   ksbc                 ! type of sbc flux
57      REAL(wp), DIMENSION(jpi,jpj), INTENT(  out) ::   utau_ice, vtau_ice   ! air-ice stress   [N/m2]
58      !!
59      INTEGER  ::   ji, jj                 ! dummy loop index
60      REAL(wp), DIMENSION(jpi,jpj) ::   zutau_ice, zvtau_ice 
61      !!-------------------------------------------------------------------
62      !
63      IF( ln_timing )   CALL timing_start('ice_sbc')
64      !
65      IF( kt == nit000 .AND. lwp ) THEN
66         WRITE(numout,*)
67         WRITE(numout,*)'ice_sbc_tau: Surface boundary condition for sea ice (momentum)'
68         WRITE(numout,*)'~~~~~~~~~~~~~~~'
69      ENDIF
70      !
71      SELECT CASE( ksbc )
72         CASE( jp_usr     )   ;    CALL usrdef_sbc_ice_tau( kt )                 ! user defined formulation
73         CASE( jp_blk     )   ;    CALL blk_ice_tau                              ! Bulk         formulation
74         CASE( jp_purecpl )   ;    CALL sbc_cpl_ice_tau( utau_ice , vtau_ice )   ! Coupled      formulation
75      END SELECT
76      !
77      IF( ln_mixcpl) THEN                                                        ! Case of a mixed Bulk/Coupled formulation
78                                   CALL sbc_cpl_ice_tau( zutau_ice , zvtau_ice )
79         DO jj = 2, jpjm1
80            DO ji = 2, jpim1
81               utau_ice(ji,jj) = utau_ice(ji,jj) * xcplmask(ji,jj,0) + zutau_ice(ji,jj) * ( 1. - xcplmask(ji,jj,0) )
82               vtau_ice(ji,jj) = vtau_ice(ji,jj) * xcplmask(ji,jj,0) + zvtau_ice(ji,jj) * ( 1. - xcplmask(ji,jj,0) )
83            END DO
84         END DO
85         CALL lbc_lnk_multi( 'icesbc', utau_ice, 'U', -1., vtau_ice, 'V', -1. )
86      ENDIF
87      !
88      IF( ln_timing )   CALL timing_stop('ice_sbc')
89      !
90   END SUBROUTINE ice_sbc_tau
91
92   
93   SUBROUTINE ice_sbc_flx( kt, ksbc )
94      !!-------------------------------------------------------------------
95      !!                  ***  ROUTINE ice_sbc_flx  ***
96      !!
97      !! ** Purpose : provide surface boundary condition for sea ice (flux)
98      !!
99      !! ** Action  : It provides the following fields used in sea ice model:
100      !!                emp_oce , emp_ice                        = E-P over ocean and sea ice                    [Kg/m2/s]
101      !!                sprecip                                  = solid precipitation                           [Kg/m2/s]
102      !!                evap_ice                                 = sublimation                                   [Kg/m2/s]
103      !!                qsr_tot , qns_tot                        = solar & non solar heat flux (total)           [W/m2]
104      !!                qsr_ice , qns_ice                        = solar & non solar heat flux over ice          [W/m2]
105      !!                dqns_ice                                 = non solar  heat sensistivity                  [W/m2]
106      !!                qemp_oce, qemp_ice, qprec_ice, qevap_ice = sensible heat (associated with evap & precip) [W/m2]
107      !!            + some fields that are not used outside this module:
108      !!                qla_ice                                  = latent heat flux over ice                     [W/m2]
109      !!                dqla_ice                                 = latent heat sensistivity                      [W/m2]
110      !!                tprecip                                  = total  precipitation                          [Kg/m2/s]
111      !!                alb_ice                                  = albedo above sea ice
112      !!-------------------------------------------------------------------
113      INTEGER, INTENT(in) ::   kt     ! ocean time step
114      INTEGER, INTENT(in) ::   ksbc   ! flux formulation (user defined, bulk or Pure Coupled)
115      !
116      INTEGER  ::   ji, jj, jl                                ! dummy loop index
117      REAL(wp), DIMENSION(jpi,jpj,jpl) ::   zalb_os, zalb_cs  ! ice albedo under overcast/clear sky
118      REAL(wp), DIMENSION(jpi,jpj)     ::   zalb              ! 2D workspace
119      !!--------------------------------------------------------------------
120      !
121      IF( ln_timing )   CALL timing_start('ice_sbc_flx')
122
123      IF( kt == nit000 .AND. lwp ) THEN
124         WRITE(numout,*)
125         WRITE(numout,*)'ice_sbc_flx: Surface boundary condition for sea ice (flux)'
126         WRITE(numout,*)'~~~~~~~~~~~~~~~'
127      ENDIF
128
129      ! --- cloud-sky and overcast-sky ice albedos --- !
130      CALL ice_alb( t_su, h_i, h_s, ln_pnd_alb, a_ip_frac, h_ip, zalb_cs, zalb_os )
131
132      ! albedo depends on cloud fraction because of non-linear spectral effects
133!!gm cldf_ice is a real, DOCTOR naming rule: start with cd means CHARACTER passed in argument !
134      alb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
135      !
136      !
137      SELECT CASE( ksbc )   !== fluxes over sea ice ==!
138      !
139      CASE( jp_usr )              !--- user defined formulation
140                                  CALL usrdef_sbc_ice_flx( kt, h_s, h_i )
141      CASE( jp_blk )              !--- bulk formulation
142                                  CALL blk_ice_flx    ( t_su, h_s, h_i, alb_ice )    !
143         IF( ln_mixcpl        )   CALL sbc_cpl_ice_flx( picefr=at_i_b, palbi=alb_ice, psst=sst_m, pist=t_su, phs=h_s, phi=h_i )
144         IF( nn_flxdist /= -1 )   CALL ice_flx_dist   ( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_flxdist )
145         !                        !    compute conduction flux and surface temperature (as in Jules surface module)
146         IF( ln_cndflx .AND. .NOT.ln_cndemulate ) &
147            &                     CALL blk_ice_qcn    ( ln_virtual_itd, t_su, t_bo, h_s, h_i )
148      CASE ( jp_purecpl )         !--- coupled formulation
149                                  CALL sbc_cpl_ice_flx( picefr=at_i_b, palbi=alb_ice, psst=sst_m, pist=t_su, phs=h_s, phi=h_i )
150         IF( nn_flxdist /= -1 )   CALL ice_flx_dist   ( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_flxdist )
151      END SELECT
152
153      !--- output ice albedo and surface albedo ---!
154      IF( iom_use('icealb') ) THEN
155         WHERE( at_i_b <= epsi06 )   ;   zalb(:,:) = rn_alb_oce
156         ELSEWHERE                   ;   zalb(:,:) = SUM( alb_ice * a_i_b, dim=3 ) / at_i_b
157         END WHERE
158         CALL iom_put( "icealb" , zalb(:,:) )
159      ENDIF
160      IF( iom_use('albedo') ) THEN
161         zalb(:,:) = SUM( alb_ice * a_i_b, dim=3 ) + rn_alb_oce * ( 1._wp - at_i_b )
162         CALL iom_put( "albedo" , zalb(:,:) )
163      ENDIF
164      !
165      IF( ln_timing )   CALL timing_stop('ice_sbc_flx')
166      !
167   END SUBROUTINE ice_sbc_flx
168
169
170   SUBROUTINE ice_flx_dist( ptn_ice, palb_ice, pqns_ice, pqsr_ice, pdqn_ice, pevap_ice, pdevap_ice, k_flxdist )
171      !!-------------------------------------------------------------------
172      !!                  ***  ROUTINE ice_flx_dist  ***
173      !!
174      !! ** Purpose :   update the ice surface boundary condition by averaging
175      !!              and/or redistributing fluxes on ice categories
176      !!
177      !! ** Method  :   average then redistribute
178      !!
179      !! ** Action  :   depends on k_flxdist
180      !!                = -1  Do nothing (needs N(cat) fluxes)
181      !!                =  0  Average N(cat) fluxes then apply the average over the N(cat) ice
182      !!                =  1  Average N(cat) fluxes then redistribute over the N(cat) ice
183      !!                                                 using T-ice and albedo sensitivity
184      !!                =  2  Redistribute a single flux over categories
185      !!-------------------------------------------------------------------
186      INTEGER                   , INTENT(in   ) ::   k_flxdist  ! redistributor
187      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   ptn_ice    ! ice surface temperature
188      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   palb_ice   ! ice albedo
189      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pqns_ice   ! non solar flux
190      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pqsr_ice   ! net solar flux
191      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pdqn_ice   ! non solar flux sensitivity
192      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pevap_ice  ! sublimation
193      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pdevap_ice ! sublimation sensitivity
194      !
195      INTEGER  ::   jl      ! dummy loop index
196      !
197      REAL(wp), DIMENSION(jpi,jpj) ::   z1_at_i   ! inverse of concentration
198      !
199      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   z_qsr_m   ! Mean solar heat flux over all categories
200      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   z_qns_m   ! Mean non solar heat flux over all categories
201      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   z_evap_m  ! Mean sublimation over all categories
202      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   z_dqn_m   ! Mean d(qns)/dT over all categories
203      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   z_devap_m ! Mean d(evap)/dT over all categories
204      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   zalb_m    ! Mean albedo over all categories
205      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   ztem_m    ! Mean temperature over all categories
206      !!----------------------------------------------------------------------
207      !
208      WHERE ( at_i (:,:) > 0._wp )   ; z1_at_i(:,:) = 1._wp / at_i (:,:)
209      ELSEWHERE                      ; z1_at_i(:,:) = 0._wp
210      END WHERE
211     
212      SELECT CASE( k_flxdist )       !==  averaged on all ice categories  ==!
213      !
214      CASE( 0 , 1 )
215         !
216         ALLOCATE( z_qns_m(jpi,jpj), z_qsr_m(jpi,jpj), z_dqn_m(jpi,jpj), z_evap_m(jpi,jpj), z_devap_m(jpi,jpj) ) 
217         !
218         z_qns_m  (:,:) = SUM( a_i(:,:,:) * pqns_ice  (:,:,:) , dim=3 ) * z1_at_i(:,:)
219         z_qsr_m  (:,:) = SUM( a_i(:,:,:) * pqsr_ice  (:,:,:) , dim=3 ) * z1_at_i(:,:)
220         z_dqn_m  (:,:) = SUM( a_i(:,:,:) * pdqn_ice  (:,:,:) , dim=3 ) * z1_at_i(:,:)
221         z_evap_m (:,:) = SUM( a_i(:,:,:) * pevap_ice (:,:,:) , dim=3 ) * z1_at_i(:,:)
222         z_devap_m(:,:) = SUM( a_i(:,:,:) * pdevap_ice(:,:,:) , dim=3 ) * z1_at_i(:,:)
223         DO jl = 1, jpl
224            pqns_ice  (:,:,jl) = z_qns_m (:,:)
225            pqsr_ice  (:,:,jl) = z_qsr_m (:,:)
226            pdqn_ice  (:,:,jl) = z_dqn_m  (:,:)
227            pevap_ice (:,:,jl) = z_evap_m(:,:)
228            pdevap_ice(:,:,jl) = z_devap_m(:,:)
229         END DO
230         !
231         DEALLOCATE( z_qns_m, z_qsr_m, z_dqn_m, z_evap_m, z_devap_m ) 
232         !
233      END SELECT
234      !
235      SELECT CASE( k_flxdist )       !==  redistribution on all ice categories  ==!
236      !
237      CASE( 1 , 2 )
238         !
239         ALLOCATE( zalb_m(jpi,jpj), ztem_m(jpi,jpj) ) 
240         !
241         zalb_m(:,:) = SUM( a_i(:,:,:) * palb_ice(:,:,:) , dim=3 ) * z1_at_i(:,:)
242         ztem_m(:,:) = SUM( a_i(:,:,:) * ptn_ice (:,:,:) , dim=3 ) * z1_at_i(:,:)
243         DO jl = 1, jpl
244            pqns_ice (:,:,jl) = pqns_ice (:,:,jl) + pdqn_ice  (:,:,jl) * ( ptn_ice(:,:,jl) - ztem_m(:,:) )
245            pevap_ice(:,:,jl) = pevap_ice(:,:,jl) + pdevap_ice(:,:,jl) * ( ptn_ice(:,:,jl) - ztem_m(:,:) )
246            pqsr_ice (:,:,jl) = pqsr_ice (:,:,jl) * ( 1._wp - palb_ice(:,:,jl) ) / ( 1._wp - zalb_m(:,:) )
247         END DO
248         !
249         DEALLOCATE( zalb_m, ztem_m ) 
250         !
251      END SELECT
252      !
253   END SUBROUTINE ice_flx_dist
254
255
256   SUBROUTINE ice_sbc_init
257      !!-------------------------------------------------------------------
258      !!                  ***  ROUTINE ice_sbc_init  ***
259      !!
260      !! ** Purpose :   Physical constants and parameters linked to the ice dynamics
261      !!     
262      !! ** Method  :   Read the namsbc namelist and check the ice-dynamic
263      !!              parameter values called at the first timestep (nit000)
264      !!
265      !! ** input   :   Namelist namsbc
266      !!-------------------------------------------------------------------
267      INTEGER ::   ios, ioptio   ! Local integer
268      !!
269      NAMELIST/namsbc/ rn_cio, rn_blow_s, nn_flxdist, ln_cndflx, ln_cndemulate
270      !!-------------------------------------------------------------------
271      !
272      REWIND( numnam_ice_ref )         ! Namelist namsbc in reference namelist : Ice dynamics
273      READ  ( numnam_ice_ref, namsbc, IOSTAT = ios, ERR = 901)
274901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namsbc in reference namelist' )
275      REWIND( numnam_ice_cfg )         ! Namelist namsbc in configuration namelist : Ice dynamics
276      READ  ( numnam_ice_cfg, namsbc, IOSTAT = ios, ERR = 902 )
277902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namsbc in configuration namelist' )
278      IF(lwm) WRITE( numoni, namsbc )
279      !
280      IF(lwp) THEN                     ! control print
281         WRITE(numout,*)
282         WRITE(numout,*) 'ice_sbc_init: ice parameters for ice dynamics '
283         WRITE(numout,*) '~~~~~~~~~~~~~~~~'
284         WRITE(numout,*) '   Namelist namsbc:'
285         WRITE(numout,*) '      drag coefficient for oceanic stress              rn_cio        = ', rn_cio
286         WRITE(numout,*) '      coefficient for ice-lead partition of snowfall   rn_blow_s     = ', rn_blow_s
287         WRITE(numout,*) '      Multicategory heat flux formulation              nn_flxdist    = ', nn_flxdist
288         WRITE(numout,*) '      Use conduction flux as surface condition         ln_cndflx     = ', ln_cndflx
289         WRITE(numout,*) '         emulate conduction flux                       ln_cndemulate = ', ln_cndemulate
290      ENDIF
291      !
292      IF(lwp) WRITE(numout,*)
293      SELECT CASE( nn_flxdist )         ! SI3 Multi-category heat flux formulation
294      CASE( -1  )
295         IF(lwp) WRITE(numout,*) '   SI3: use per-category fluxes (nn_flxdist = -1) '
296      CASE(  0  )
297         IF(lwp) WRITE(numout,*) '   SI3: use average per-category fluxes (nn_flxdist = 0) '
298      CASE(  1  )
299         IF(lwp) WRITE(numout,*) '   SI3: use average then redistribute per-category fluxes (nn_flxdist = 1) '
300         IF( ln_cpl )         CALL ctl_stop( 'ice_thd_init: the chosen nn_flxdist for SI3 in coupled mode must be /=1' )
301      CASE(  2  )
302         IF(lwp) WRITE(numout,*) '   SI3: Redistribute a single flux over categories (nn_flxdist = 2) '
303         IF( .NOT. ln_cpl )   CALL ctl_stop( 'ice_thd_init: the chosen nn_flxdist for SI3 in forced mode must be /=2' )
304      CASE DEFAULT
305         CALL ctl_stop( 'ice_thd_init: SI3 option, nn_flxdist, should be between -1 and 2' )
306      END SELECT
307      !
308   END SUBROUTINE ice_sbc_init
309
310#else
311   !!----------------------------------------------------------------------
312   !!   Default option :         Empty module         NO SI3 sea-ice model
313   !!----------------------------------------------------------------------
314#endif
315
316   !!======================================================================
317END MODULE icesbc
Note: See TracBrowser for help on using the repository browser.