New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
bdydta.F90 in NEMO/branches/2019/dev_r10984_HPC-13_IRRMANN_BDY_optimization/src/OCE/BDY – NEMO

source: NEMO/branches/2019/dev_r10984_HPC-13_IRRMANN_BDY_optimization/src/OCE/BDY/bdydta.F90 @ 11223

Last change on this file since 11223 was 11223, checked in by smasson, 5 years ago

dev_r10984_HPC-13 : cleaning of rewriting of bdydta, see #2285
  • Property svn:keywords set to Id
File size: 30.6 KB
Line 
1MODULE bdydta
2   !!======================================================================
3   !!                       ***  MODULE bdydta  ***
4   !! Open boundary data : read the data for the unstructured open boundaries.
5   !!======================================================================
6   !! History :  1.0  !  2005-01  (J. Chanut, A. Sellar)  Original code
7   !!             -   !  2007-01  (D. Storkey) Update to use IOM module
8   !!             -   !  2007-07  (D. Storkey) add bdy_dta_fla
9   !!            3.0  !  2008-04  (NEMO team)  add in the reference version
10   !!            3.3  !  2010-09  (E.O'Dea) modifications for Shelf configurations
11   !!            3.3  !  2010-09  (D.Storkey) add ice boundary conditions
12   !!            3.4  !  2011     (D. Storkey) rewrite in preparation for OBC-BDY merge
13   !!            3.6  !  2012-01  (C. Rousset) add ice boundary conditions for sea ice
14   !!            4.0  !  2018     (C. Rousset) SI3 compatibility
15   !!----------------------------------------------------------------------
16
17   !!----------------------------------------------------------------------
18   !!    bdy_dta      : read external data along open boundaries from file
19   !!    bdy_dta_init : initialise arrays etc for reading of external data
20   !!----------------------------------------------------------------------
21   USE oce            ! ocean dynamics and tracers
22   USE dom_oce        ! ocean space and time domain
23   USE phycst         ! physical constants
24   USE sbcapr         ! atmospheric pressure forcing
25   USE sbctide        ! Tidal forcing or not
26   USE bdy_oce        ! ocean open boundary conditions 
27   USE bdytides       ! tidal forcing at boundaries
28#if defined key_si3
29   USE ice            ! sea-ice variables
30   USE icevar         ! redistribute ice input into categories
31#endif
32   !
33   USE lib_mpp, ONLY: ctl_stop, ctl_nam
34   USE fldread        ! read input fields
35   USE iom            ! IOM library
36   USE in_out_manager ! I/O logical units
37   USE timing         ! Timing
38
39   IMPLICIT NONE
40   PRIVATE
41
42   PUBLIC   bdy_dta          ! routine called by step.F90 and dynspg_ts.F90
43   PUBLIC   bdy_dta_init     ! routine called by nemogcm.F90
44
45   INTEGER , PARAMETER ::   jpbdyfld  = 10    ! maximum number of files to read
46   INTEGER , PARAMETER ::   jp_bdyssh = 1     !
47   INTEGER , PARAMETER ::   jp_bdyu2d = 2     !
48   INTEGER , PARAMETER ::   jp_bdyv2d = 3     !
49   INTEGER , PARAMETER ::   jp_bdyu3d = 4     !
50   INTEGER , PARAMETER ::   jp_bdyv3d = 5     !
51   INTEGER , PARAMETER ::   jp_bdytem = 6     !
52   INTEGER , PARAMETER ::   jp_bdysal = 7     !
53   INTEGER , PARAMETER ::   jp_bdya_i = 8     !
54   INTEGER , PARAMETER ::   jp_bdyh_i = 9     !
55   INTEGER , PARAMETER ::   jp_bdyh_S = 10    !
56                                                              ! =F => baroclinic velocities in 3D boundary conditions
57!$AGRIF_DO_NOT_TREAT
58   TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:,:), TARGET ::   bf   ! structure of input fields (file informations, fields read)
59!$AGRIF_END_DO_NOT_TREAT
60
61   !!----------------------------------------------------------------------
62   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
63   !! $Id$
64   !! Software governed by the CeCILL license (see ./LICENSE)
65   !!----------------------------------------------------------------------
66CONTAINS
67
68   SUBROUTINE bdy_dta( kt, kit, kt_offset )
69      !!----------------------------------------------------------------------
70      !!                   ***  SUBROUTINE bdy_dta  ***
71      !!                   
72      !! ** Purpose :   Update external data for open boundary conditions
73      !!
74      !! ** Method  :   Use fldread.F90
75      !!               
76      !!----------------------------------------------------------------------
77      INTEGER, INTENT(in)           ::   kt           ! ocean time-step index
78      INTEGER, INTENT(in), OPTIONAL ::   kit          ! subcycle time-step index (for timesplitting option)
79      INTEGER, INTENT(in), OPTIONAL ::   kt_offset    ! time offset in units of timesteps. NB. if kit
80      !                                               ! is present then units = subcycle timesteps.
81      !                                               ! kt_offset = 0 => get data at "now" time level
82      !                                               ! kt_offset = -1 => get data at "before" time level
83      !                                               ! kt_offset = +1 => get data at "after" time level
84      !                                               ! etc.
85      !
86      INTEGER ::  jbdy, jfld, jstart, jend, ib, jl    ! dummy loop indices
87      INTEGER ::  ii, ij, ik, igrd, ipl               ! local integers
88      INTEGER,   DIMENSION(jpbgrd)     ::   ilen1 
89      INTEGER,   DIMENSION(:), POINTER ::   nblen, nblenrim  ! short cuts
90      TYPE(OBC_DATA)         , POINTER ::   dta_alias        ! short cut
91      TYPE(FLD), DIMENSION(:), POINTER ::   bf_alias
92      !!---------------------------------------------------------------------------
93      !
94      IF( ln_timing )   CALL timing_start('bdy_dta')
95      !
96      ! Initialise data arrays once for all from initial conditions where required
97      !---------------------------------------------------------------------------
98      IF( kt == nit000 .AND. .NOT.PRESENT(kit) ) THEN
99
100         ! Calculate depth-mean currents
101         !-----------------------------
102
103         DO jbdy = 1, nb_bdy
104            !
105            nblen    => idx_bdy(jbdy)%nblen
106            nblenrim => idx_bdy(jbdy)%nblenrim
107            !
108            IF( nn_dyn2d_dta(jbdy) == 0 ) THEN
109               ilen1(:) = nblen(:)
110               IF( dta_bdy(jbdy)%lneed_ssh ) THEN
111                  igrd = 1
112                  DO ib = 1, ilen1(igrd)
113                     ii = idx_bdy(jbdy)%nbi(ib,igrd)
114                     ij = idx_bdy(jbdy)%nbj(ib,igrd)
115                     dta_bdy(jbdy)%ssh(ib) = sshn(ii,ij) * tmask(ii,ij,1)         
116                  END DO
117               ENDIF
118               IF( dta_bdy(jbdy)%lneed_dyn2d) THEN
119                  igrd = 2
120                  DO ib = 1, ilen1(igrd)
121                     ii = idx_bdy(jbdy)%nbi(ib,igrd)
122                     ij = idx_bdy(jbdy)%nbj(ib,igrd)
123                     dta_bdy(jbdy)%u2d(ib) = un_b(ii,ij) * umask(ii,ij,1)         
124                  END DO
125                  igrd = 3
126                  DO ib = 1, ilen1(igrd)
127                     ii = idx_bdy(jbdy)%nbi(ib,igrd)
128                     ij = idx_bdy(jbdy)%nbj(ib,igrd)
129                     dta_bdy(jbdy)%v2d(ib) = vn_b(ii,ij) * vmask(ii,ij,1)         
130                  END DO
131               ENDIF
132            ENDIF
133            !
134            IF( nn_dyn3d_dta(jbdy) == 0 ) THEN
135               ilen1(:) = nblen(:)
136               IF( dta_bdy(jbdy)%lneed_dyn3d ) THEN
137                  igrd = 2 
138                  DO ib = 1, ilen1(igrd)
139                     DO ik = 1, jpkm1
140                        ii = idx_bdy(jbdy)%nbi(ib,igrd)
141                        ij = idx_bdy(jbdy)%nbj(ib,igrd)
142                        dta_bdy(jbdy)%u3d(ib,ik) =  ( un(ii,ij,ik) - un_b(ii,ij) ) * umask(ii,ij,ik)         
143                     END DO
144                  END DO
145                  igrd = 3 
146                  DO ib = 1, ilen1(igrd)
147                     DO ik = 1, jpkm1
148                        ii = idx_bdy(jbdy)%nbi(ib,igrd)
149                        ij = idx_bdy(jbdy)%nbj(ib,igrd)
150                        dta_bdy(jbdy)%v3d(ib,ik) =  ( vn(ii,ij,ik) - vn_b(ii,ij) ) * vmask(ii,ij,ik)         
151                     END DO
152                  END DO
153               ENDIF
154            ENDIF
155
156            IF( nn_tra_dta(jbdy) == 0 ) THEN
157               ilen1(:) = nblen(:)
158               IF( dta_bdy(jbdy)%lneed_tra ) THEN
159                  igrd = 1 
160                  DO ib = 1, ilen1(igrd)
161                     DO ik = 1, jpkm1
162                        ii = idx_bdy(jbdy)%nbi(ib,igrd)
163                        ij = idx_bdy(jbdy)%nbj(ib,igrd)
164                        dta_bdy(jbdy)%tem(ib,ik) = tsn(ii,ij,ik,jp_bdytem) * tmask(ii,ij,ik)         
165                        dta_bdy(jbdy)%sal(ib,ik) = tsn(ii,ij,ik,jp_bdysal) * tmask(ii,ij,ik)         
166                     END DO
167                  END DO
168               ENDIF
169            ENDIF
170
171#if defined key_si3
172            IF( nn_ice_dta(jbdy) == 0 ) THEN    ! set ice to initial values
173               ilen1(:) = nblen(:)
174               IF( dta_bdy(jbdy)%lneed_ice ) THEN
175                  igrd = 1   
176                  DO jl = 1, jpl
177                     DO ib = 1, ilen1(igrd)
178                        ii = idx_bdy(jbdy)%nbi(ib,igrd)
179                        ij = idx_bdy(jbdy)%nbj(ib,igrd)
180                        dta_bdy(jbdy)%a_i (ib,jl) =  a_i(ii,ij,jl) * tmask(ii,ij,1) 
181                        dta_bdy(jbdy)%h_i (ib,jl) =  h_i(ii,ij,jl) * tmask(ii,ij,1) 
182                        dta_bdy(jbdy)%h_s (ib,jl) =  h_s(ii,ij,jl) * tmask(ii,ij,1) 
183                     END DO
184                  END DO
185               ENDIF
186            ENDIF
187#endif
188         END DO ! jbdy
189         !
190      ENDIF ! kt == nit000
191
192      ! update external data from files
193      !--------------------------------
194
195      DO jbdy = 1, nb_bdy
196
197         dta_alias => dta_bdy(jbdy)
198         bf_alias  => bf(:,jbdy)
199
200         ! read/update all bdy data
201         ! ------------------------
202         CALL fld_read( kt, 1, bf_alias, kit = kit, kt_offset = kt_offset )
203
204         ! apply some corrections in some specific cases...
205         ! --------------------------------------------------
206         !
207         ! if runoff condition: change river flow we read (in m3/s) into barotropic velocity (m/s)
208         IF( cn_tra(jbdy) == 'runoff' .AND. TRIM(bf_alias(jp_bdyu2d)%clrootname) /= 'NOT USED' ) THEN   ! runoff and we read u/v2d
209            !
210            igrd = 2                      ! zonal flow (m3/s) to barotropic zonal velocity (m/s)
211            DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
212               ii   = idx_bdy(jbdy)%nbi(ib,igrd)
213               ij   = idx_bdy(jbdy)%nbj(ib,igrd)
214               dta_alias%u2d(ib) = dta_alias%u2d(ib) / ( e2u(ii,ij) * hu_0(ii,ij) )
215            END DO
216            igrd = 3                      ! meridional flow (m3/s) to barotropic meridional velocity (m/s)
217            DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
218               ii   = idx_bdy(jbdy)%nbi(ib,igrd)
219               ij   = idx_bdy(jbdy)%nbj(ib,igrd)
220               dta_alias%v2d(ib) = dta_alias%v2d(ib) / ( e1v(ii,ij) * hv_0(ii,ij) )
221            END DO
222         ENDIF
223
224         ! tidal harmonic forcing ONLY: initialise arrays
225         IF( nn_dyn2d_dta(jbdy) == 2 ) THEN   ! we did not read ssh, u/v2d
226            IF( dta_alias%lneed_ssh   ) dta_alias%ssh(:) = 0._wp
227            IF( dta_alias%lneed_dyn2d ) dta_alias%u2d(:) = 0._wp
228            IF( dta_alias%lneed_dyn2d ) dta_alias%v2d(:) = 0._wp
229         ENDIF
230
231         ! If full velocities in boundary data, then split it into barotropic and baroclinic component
232         IF( bf_alias(jp_bdyu3d)%ltotvel ) THEN     ! if we read 3D total velocity (can be true only if u3d was read)
233            !
234            igrd = 2                       ! zonal velocity
235            dta_alias%u2d(:) = 0._wp       ! compute barotrope zonal velocity and put it in u2d
236            DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
237               ii   = idx_bdy(jbdy)%nbi(ib,igrd)
238               ij   = idx_bdy(jbdy)%nbj(ib,igrd)
239               DO ik = 1, jpkm1
240                  dta_alias%u2d(ib) = dta_alias%u2d(ib) + e3u_n(ii,ij,ik) * umask(ii,ij,ik) * dta_alias%u3d(ib,ik)
241               END DO
242               dta_alias%u2d(ib) =  dta_alias%u2d(ib) * r1_hu_n(ii,ij)
243               DO ik = 1, jpkm1            ! compute barocline zonal velocity and put it in u3d
244                  dta_alias%u3d(ib,ik) = dta_alias%u3d(ib,ik) - dta_alias%u2d(ib)
245               END DO
246            END DO
247            igrd = 3                       ! meridional velocity
248            dta_alias%v2d(:) = 0._wp       ! compute barotrope meridional velocity and put it in v2d
249            DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
250               ii   = idx_bdy(jbdy)%nbi(ib,igrd)
251               ij   = idx_bdy(jbdy)%nbj(ib,igrd)
252               DO ik = 1, jpkm1
253                  dta_alias%v2d(ib) = dta_alias%v2d(ib) + e3v_n(ii,ij,ik) * vmask(ii,ij,ik) * dta_alias%v3d(ib,ik)
254               END DO
255               dta_alias%v2d(ib) =  dta_alias%v2d(ib) * r1_hv_n(ii,ij)
256               DO ik = 1, jpkm1            ! compute barocline meridional velocity and put it in v3d
257                  dta_alias%v3d(ib,ik) = dta_alias%v3d(ib,ik) - dta_alias%v2d(ib)
258               END DO
259            END DO
260         ENDIF   ! ltotvel
261
262         ! update tidal harmonic forcing
263         IF( PRESENT(kit) .AND. nn_dyn2d_dta(jbdy) .GE. 2 ) THEN
264            CALL bdytide_update( kt = kt, idx = idx_bdy(jbdy), dta = dta_alias, td = tides(jbdy),   & 
265               &                 kit = kit, kt_offset = kt_offset )
266         ENDIF
267
268         !  atm surface pressure : add inverted barometer effect to ssh if it was read
269         IF ( ln_apr_obc .AND. TRIM(bf_alias(jp_bdyssh)%clrootname) /= 'NOT USED' ) THEN
270            igrd = 1
271            DO ib = 1, idx_bdy(jbdy)%nblenrim(igrd)   ! ssh is used only on the rim
272               ii   = idx_bdy(jbdy)%nbi(ib,igrd)
273               ij   = idx_bdy(jbdy)%nbj(ib,igrd)
274               dta_alias%ssh(ib) = dta_alias%ssh(ib) + ssh_ib(ii,ij)
275            END DO
276         ENDIF
277
278#if defined key_si3
279         ! ice: convert N-cat fields (input) into jpl-cat (output)
280         IF( dta_alias%lneed_ice ) THEN
281            ipl = SIZE(bf_alias(jp_bdya_i)%fnow, 3)
282            IF( ipl /= jpl ) THEN      ! ice: convert N-cat fields (input) into jpl-cat (output)
283               CALL ice_var_itd(bf_alias(jp_bdyh_i)%fnow(:,1,:), bf_alias(jp_bdyh_s)%fnow(:,1,:), bf_alias(jp_bdya_i)%fnow(:,1,:), &
284                  &              dta_alias%h_i               , dta_alias%h_s               , dta_alias%a_i                 )
285            ENDIF
286         ENDIF
287#endif
288      END DO  ! jbdy
289
290      IF ( ln_tide ) THEN
291         IF (ln_dynspg_ts) THEN      ! Fill temporary arrays with slow-varying bdy data                           
292            DO jbdy = 1, nb_bdy      ! Tidal component added in ts loop
293               IF ( nn_dyn2d_dta(jbdy) .GE. 2 ) THEN
294                  nblen => idx_bdy(jbdy)%nblen
295                  nblenrim => idx_bdy(jbdy)%nblenrim
296                  IF( cn_dyn2d(jbdy) == 'frs' ) THEN ; ilen1(:)=nblen(:) ; ELSE ; ilen1(:)=nblenrim(:) ; ENDIF
297                     IF ( dta_bdy(jbdy)%lneed_ssh   ) dta_bdy_s(jbdy)%ssh(1:ilen1(1)) = dta_bdy(jbdy)%ssh(1:ilen1(1))
298                     IF ( dta_bdy(jbdy)%lneed_dyn2d ) dta_bdy_s(jbdy)%u2d(1:ilen1(2)) = dta_bdy(jbdy)%u2d(1:ilen1(2))
299                     IF ( dta_bdy(jbdy)%lneed_dyn2d ) dta_bdy_s(jbdy)%v2d(1:ilen1(3)) = dta_bdy(jbdy)%v2d(1:ilen1(3))
300                  ENDIF
301               END DO
302            ELSE ! Add tides if not split-explicit free surface else this is done in ts loop
303               !
304               CALL bdy_dta_tides( kt=kt, kt_offset=kt_offset )
305            ENDIF
306         ENDIF
307         !
308         IF( ln_timing )   CALL timing_stop('bdy_dta')
309         !
310      END SUBROUTINE bdy_dta
311
312
313   SUBROUTINE bdy_dta_init
314      !!----------------------------------------------------------------------
315      !!                   ***  SUBROUTINE bdy_dta_init  ***
316      !!                   
317      !! ** Purpose :   Initialise arrays for reading of external data
318      !!                for open boundary conditions
319      !!
320      !! ** Method  :   
321      !!               
322      !!----------------------------------------------------------------------
323      INTEGER ::   jbdy, jfld    ! Local integers
324      INTEGER ::   ierror, ios     !
325      !
326      CHARACTER(len=3)                       ::   cl3           !
327      CHARACTER(len=100)                     ::   cn_dir        ! Root directory for location of data files
328      LOGICAL                                ::   ln_full_vel   ! =T => full velocities in 3D boundary data
329      !                                                         ! =F => baroclinic velocities in 3D boundary data
330      INTEGER                                ::   ipk,ipl           !
331      INTEGER                                ::   idvar         ! variable ID
332      INTEGER                                ::   indims        ! number of dimensions of the variable
333      INTEGER                                ::   iszdim        ! number of dimensions of the variable
334      INTEGER, DIMENSION(4)                  ::   i4dimsz       ! size of variable dimensions
335      INTEGER                                ::   igrd          ! index for grid type (1,2,3 = T,U,V)
336      LOGICAL                                ::   lluld         ! is the variable using the unlimited dimension
337      LOGICAL                                ::   llneed        !
338      LOGICAL                                ::   llread        !
339      TYPE(FLD_N), DIMENSION(1), TARGET ::   bn_tem, bn_sal, bn_u3d, bn_v3d   ! must be an array to be used with fld_fill
340      TYPE(FLD_N), DIMENSION(1), TARGET ::   bn_ssh, bn_u2d, bn_v2d           ! informations about the fields to be read
341      TYPE(FLD_N), DIMENSION(1), TARGET ::   bn_a_i, bn_h_i, bn_h_s     
342      TYPE(FLD_N), DIMENSION(:), POINTER ::   bn_alias                        ! must be an array to be used with fld_fill
343      TYPE(FLD  ), DIMENSION(:), POINTER ::   bf_alias
344      !
345      NAMELIST/nambdy_dta/ cn_dir, bn_tem, bn_sal, bn_u3d, bn_v3d, bn_ssh, bn_u2d, bn_v2d 
346      NAMELIST/nambdy_dta/ bn_a_i, bn_h_i, bn_h_s
347      NAMELIST/nambdy_dta/ ln_full_vel
348      !!---------------------------------------------------------------------------
349      !
350      IF(lwp) WRITE(numout,*)
351      IF(lwp) WRITE(numout,*) 'bdy_dta_ini : initialization of data at the open boundaries'
352      IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
353      IF(lwp) WRITE(numout,*) ''
354
355      ALLOCATE( bf(jpbdyfld,nb_bdy), STAT=ierror )
356      IF( ierror > 0 ) THEN   
357         CALL ctl_stop( 'bdy_dta: unable to allocate bf structure' )   ;   RETURN 
358      ENDIF
359      bf(:,:)%clrootname = 'NOT USED'   ! default definition used as a flag in fld_read to do nothing.
360      bf(:,:)%ltotvel = .FALSE.         ! default definition
361 
362      ! Read namelists
363      ! --------------
364      REWIND(numnam_cfg)
365      DO jbdy = 1, nb_bdy
366
367         WRITE(ctmp1, '(a,i2)') 'BDY number ', jbdy
368         WRITE(ctmp2, '(a,i2)') 'block nambdy_dta number ', jbdy
369
370         ! There is only one nambdy_dta block in namelist_ref -> use it for each bdy so we do a rewind
371         REWIND(numnam_ref)
372         READ  ( numnam_ref, nambdy_dta, IOSTAT = ios, ERR = 901)
373901      IF( ios /= 0 )   CALL ctl_nam ( ios , 'nambdy_dta in reference namelist', lwp )
374
375         !   by-pass nambdy_dta reading if no input data used in this bdy   
376         IF(       ( dta_bdy(jbdy)%lneed_dyn2d .AND. MOD(nn_dyn2d_dta(jbdy),2) == 1 )   &
377            & .OR. ( dta_bdy(jbdy)%lneed_dyn3d .AND.     nn_dyn3d_dta(jbdy)    == 1 )   &
378            & .OR. ( dta_bdy(jbdy)%lneed_tra   .AND.       nn_tra_dta(jbdy)    == 1 )   &
379            & .OR. ( dta_bdy(jbdy)%lneed_ice   .AND.       nn_ice_dta(jbdy)    == 1 )   )   THEN
380            ! WARNING: we don't do a rewind here, each bdy reads its own nambdy_dta block one after another
381            READ  ( numnam_cfg, nambdy_dta, IOSTAT = ios, ERR = 902 )
382902         IF( ios >  0 )   CALL ctl_nam ( ios , 'nambdy_dta in configuration namelist', lwp )
383            IF(lwm) WRITE( numond, nambdy_dta )           
384         ENDIF
385
386         ! get the number of ice categories in bdy data file (use a_i information to do this)
387         ipl = jpl   ! default definition
388         IF( dta_bdy(jbdy)%lneed_ice ) THEN    ! if we need ice bdy data
389            IF( nn_ice_dta(jbdy) == 1 ) THEN   ! if we get ice bdy data from netcdf file
390               CALL fld_fill(  bf(jp_bdya_i,jbdy:jbdy), bn_a_i, cn_dir, 'bdy_dta', 'a_i'//' '//ctmp1, ctmp2 )   ! use namelist info
391               CALL fld_clopn( bf(jp_bdya_i,jbdy), nyear, nmonth, nday )   ! not a problem when we call it again after
392               idvar = iom_varid( bf(jp_bdya_i,jbdy)%num, bf(jp_bdya_i,jbdy)%clvar, kndims=indims, kdimsz=i4dimsz, lduld=lluld )
393               IF( indims == 4 .OR. ( indims == 3 .AND. .NOT. lluld ) ) THEN   ;   ipl = i4dimsz(3)   ! xylt or xyl
394               ELSE                                                            ;   ipl = 1            ! xy or xyt
395               ENDIF
396            ENDIF
397         ENDIF
398
399         DO jfld = 1, jpbdyfld
400
401            ! =====================
402            !          ssh
403            ! =====================
404            IF( jfld == jp_bdyssh ) THEN
405               cl3 = 'ssh'
406               igrd = 1                                                    ! T point
407               ipk = 1                                                     ! surface data
408               llneed = dta_bdy(jbdy)%lneed_ssh                            ! dta_bdy(jbdy)%ssh will be needed
409               llread = MOD(nn_dyn2d_dta(jbdy),2) == 1                     ! get data from NetCDF file
410               bf_alias => bf(jp_bdyssh,jbdy:jbdy)                         ! alias for ssh structure of bdy number jbdy
411               bn_alias => bn_ssh                                          ! alias for ssh structure of nambdy_dta
412            ENDIF
413            ! =====================
414            !         dyn2d
415            ! =====================
416            IF( jfld == jp_bdyu2d ) THEN
417               cl3 = 'u2d'
418               igrd = 2                                                    ! U point
419               ipk = 1                                                     ! surface data
420               llneed = dta_bdy(jbdy)%lneed_dyn2d                          ! dta_bdy(jbdy)%ssh will be needed
421               llread = .NOT. ln_full_vel .AND. MOD(nn_dyn2d_dta(jbdy),2) == 1   ! don't get u2d from u3d and read NetCDF file
422               bf_alias => bf(jp_bdyu2d,jbdy:jbdy)                         ! alias for u2d structure of bdy number jbdy
423               bn_alias => bn_u2d                                          ! alias for u2d structure of nambdy_dta
424            ENDIF
425            IF( jfld == jp_bdyv2d ) THEN
426               cl3 = 'v2d'
427               igrd = 3                                                    ! V point
428               ipk = 1                                                     ! surface data
429               llneed = dta_bdy(jbdy)%lneed_dyn2d                          ! dta_bdy(jbdy)%ssh will be needed
430               llread = .NOT. ln_full_vel .AND. MOD(nn_dyn2d_dta(jbdy),2) == 1   ! don't get v2d from v3d and read NetCDF file
431               bf_alias => bf(jp_bdyv2d,jbdy:jbdy)                         ! alias for v2d structure of bdy number jbdy
432               bn_alias => bn_v2d                                          ! alias for v2d structure of nambdy_dta
433            ENDIF
434            ! =====================
435            !         dyn3d
436            ! =====================
437            IF( jfld == jp_bdyu3d ) THEN
438               cl3 = 'u3d'
439               igrd = 2                                                    ! U point
440               ipk = jpk                                                   ! 3d data
441               llneed = dta_bdy(jbdy)%lneed_dyn3d .OR.               &     ! dta_bdy(jbdy)%u3d will be needed
442                  &   ( dta_bdy(jbdy)%lneed_dyn2d .AND. ln_full_vel )      !   u3d needed to compute u2d
443               llread = nn_dyn3d_dta(jbdy) == 1                            ! get data from NetCDF file
444               bf_alias => bf(jp_bdyu3d,jbdy:jbdy)                         ! alias for u3d structure of bdy number jbdy
445               bn_alias => bn_u3d                                          ! alias for u3d structure of nambdy_dta
446            ENDIF
447            IF( jfld == jp_bdyv3d ) THEN
448               cl3 = 'v3d'
449               igrd = 3                                                    ! V point
450               ipk = jpk                                                   ! 3d data
451               llneed = dta_bdy(jbdy)%lneed_dyn3d .OR.               &     ! dta_bdy(jbdy)%v3d will be needed
452                  &   ( dta_bdy(jbdy)%lneed_dyn2d .AND. ln_full_vel )      !   v3d needed to compute v2d
453               llread = nn_dyn3d_dta(jbdy) == 1                            ! get data from NetCDF file
454               bf_alias => bf(jp_bdyv3d,jbdy:jbdy)                         ! alias for v3d structure of bdy number jbdy
455               bn_alias => bn_v3d                                          ! alias for v3d structure of nambdy_dta
456            ENDIF
457
458            ! =====================
459            !          tra
460            ! =====================
461            IF( jfld == jp_bdytem ) THEN
462               cl3 = 'tem'
463               igrd = 1                                                    ! T point
464               ipk = jpk                                                   ! 3d data
465               llneed = dta_bdy(jbdy)%lneed_tra                            ! dta_bdy(jbdy)%tem will be needed
466               llread = nn_tra_dta(jbdy) == 1                              ! get data from NetCDF file
467               bf_alias => bf(jp_bdytem,jbdy:jbdy)                         ! alias for ssh structure of bdy number jbdy
468               bn_alias => bn_tem                                          ! alias for ssh structure of nambdy_dta
469            ENDIF
470            IF( jfld == jp_bdysal ) THEN
471               cl3 = 'sal'
472               igrd = 1                                                    ! T point
473               ipk = jpk                                                   ! 3d data
474               llneed = dta_bdy(jbdy)%lneed_tra                            ! dta_bdy(jbdy)%sal will be needed
475               llread = nn_tra_dta(jbdy) == 1                              ! get data from NetCDF file
476               bf_alias => bf(jp_bdysal,jbdy:jbdy)                         ! alias for ssh structure of bdy number jbdy
477               bn_alias => bn_sal                                          ! alias for ssh structure of nambdy_dta
478            ENDIF
479
480            ! =====================
481            !          ice
482            ! =====================
483            IF( jfld == jp_bdya_i ) THEN
484               cl3 = 'a_i'
485               igrd = 1                                                    ! T point
486               ipk = ipl                                                   !
487               llneed = dta_bdy(jbdy)%lneed_ice                            ! dta_bdy(jbdy)%a_i will be needed
488               llread = nn_ice_dta(jbdy) == 1                              ! get data from NetCDF file
489               bf_alias => bf(jp_bdya_i,jbdy:jbdy)                         ! alias for ssh structure of bdy number jbdy
490               bn_alias => bn_a_i                                          ! alias for ssh structure of nambdy_dta
491            ENDIF
492            IF( jfld == jp_bdyh_i ) THEN
493               cl3 = 'h_i'
494               igrd = 1                                                    ! T point
495               ipk = ipl                                                   !
496               llneed = dta_bdy(jbdy)%lneed_ice                            ! dta_bdy(jbdy)%h_i will be needed
497               llread = nn_ice_dta(jbdy) == 1                              ! get data from NetCDF file
498               bf_alias => bf(jp_bdyh_i,jbdy:jbdy)                         ! alias for ssh structure of bdy number jbdy
499               bn_alias => bn_h_i                                          ! alias for ssh structure of nambdy_dta
500            ENDIF
501            IF( jfld == jp_bdyh_s ) THEN
502               cl3 = 'h_s'
503               igrd = 1                                                    ! T point
504               ipk = ipl                                                   !
505               llneed = dta_bdy(jbdy)%lneed_ice                            ! dta_bdy(jbdy)%h_s will be needed
506               llread = nn_ice_dta(jbdy) == 1                              ! get data from NetCDF file
507               bf_alias => bf(jp_bdyh_s,jbdy:jbdy)                         ! alias for ssh structure of bdy number jbdy
508               bn_alias => bn_h_s                                          ! alias for ssh structure of nambdy_dta
509            ENDIF
510
511
512            IF( llneed ) THEN                                              ! dta_bdy(jbdy)%xxx will be needed
513               !                                                           !   -> must be associated with an allocated target
514               iszdim = idx_bdy(jbdy)%nblen(igrd)                          ! length of this bdy on this MPI processus
515               ALLOCATE( bf_alias(1)%fnow( iszdim, 1, ipk ) )              ! allocate the target
516               !
517               IF( llread ) THEN                                           ! get data from NetCDF file
518                  CALL fld_fill( bf_alias, bn_alias, cn_dir, 'bdy_dta', cl3//' '//ctmp1, ctmp2 )   ! use namelist info
519                  IF( bf_alias(1)%ln_tint ) ALLOCATE( bf_alias(1)%fdta( iszdim, 1, ipk, 2 ) )
520                  bf_alias(1)%imap => idx_bdy(jbdy)%nbmap(1:iszdim,igrd)      ! associate the mapping used for this bdy
521                  bf_alias(1)%igrd = igrd                                     ! used only for vertical integration of 3D arrays
522                  bf_alias(1)%ltotvel = ln_full_vel                           ! T if u3d is full velocity
523               ENDIF
524
525               ! associate the pointer and get rid of the dimensions with a size equal to 1
526               IF( jfld == jp_bdyssh           ) dta_bdy(jbdy)%ssh => bf_alias(1)%fnow(:,1,1)
527               IF( jfld == jp_bdyu2d           ) dta_bdy(jbdy)%u2d => bf_alias(1)%fnow(:,1,1)
528               IF( jfld == jp_bdyv2d           ) dta_bdy(jbdy)%v2d => bf_alias(1)%fnow(:,1,1)
529               IF( jfld == jp_bdyu3d           ) dta_bdy(jbdy)%u3d => bf_alias(1)%fnow(:,1,:)
530               IF( jfld == jp_bdyv3d           ) dta_bdy(jbdy)%v3d => bf_alias(1)%fnow(:,1,:)
531               IF( jfld == jp_bdytem           ) dta_bdy(jbdy)%tem => bf_alias(1)%fnow(:,1,:)
532               IF( jfld == jp_bdysal           ) dta_bdy(jbdy)%sal => bf_alias(1)%fnow(:,1,:)
533               IF( jfld == jp_bdya_i ) THEN
534                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%a_i => bf_alias(1)%fnow(:,1,:)
535                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%a_i(iszdim,jpl) )
536                  ENDIF
537               ENDIF
538               IF( jfld == jp_bdyh_i ) THEN
539                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%h_i => bf_alias(1)%fnow(:,1,:)
540                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%h_i(iszdim,jpl) )
541                  ENDIF
542               ENDIF
543               IF( jfld == jp_bdyh_s ) THEN
544                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%h_s => bf_alias(1)%fnow(:,1,:)
545                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%h_s(iszdim,jpl) )
546                  ENDIF
547               ENDIF
548            ENDIF
549
550         END DO   ! jpbdyfld
551         !
552      END DO ! jbdy
553      !
554   END SUBROUTINE bdy_dta_init
555   
556   !!==============================================================================
557END MODULE bdydta
Note: See TracBrowser for help on using the repository browser.