New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
bdylib.F90 in NEMO/branches/2019/dev_r10984_HPC-13_IRRMANN_BDY_optimization/src/OCE/BDY – NEMO

source: NEMO/branches/2019/dev_r10984_HPC-13_IRRMANN_BDY_optimization/src/OCE/BDY/bdylib.F90 @ 11071

Last change on this file since 11071 was 11071, checked in by girrmann, 5 years ago

dev_r10984_HPC-13 : step 2, remove unneeded communications, see #2285
  • Property svn:keywords set to Id
File size: 27.8 KB
Line 
1MODULE bdylib
2   !!======================================================================
3   !!                       ***  MODULE  bdylib  ***
4   !! Unstructured Open Boundary Cond. :  Library module of generic boundary algorithms.
5   !!======================================================================
6   !! History :  3.6  !  2013     (D. Storkey) original code
7   !!            4.0  !  2014     (T. Lovato) Generalize OBC structure
8   !!----------------------------------------------------------------------
9   !!----------------------------------------------------------------------
10   !!   bdy_orlanski_2d
11   !!   bdy_orlanski_3d
12   !!----------------------------------------------------------------------
13   USE oce            ! ocean dynamics and tracers
14   USE dom_oce        ! ocean space and time domain
15   USE bdy_oce        ! ocean open boundary conditions
16   USE phycst         ! physical constants
17   !
18   USE in_out_manager !
19   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
20   USE lib_mpp, ONLY: ctl_stop
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC   bdy_frs, bdy_spe, bdy_nmn, bdy_orl
26   PUBLIC   bdy_orlanski_2d
27   PUBLIC   bdy_orlanski_3d
28
29   !!----------------------------------------------------------------------
30   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
31   !! $Id$
32   !! Software governed by the CeCILL license (see ./LICENSE)
33   !!----------------------------------------------------------------------
34CONTAINS
35
36   SUBROUTINE bdy_frs( idx, pta, dta )
37      !!----------------------------------------------------------------------
38      !!                 ***  SUBROUTINE bdy_frs  ***
39      !!
40      !! ** Purpose : Apply the Flow Relaxation Scheme for tracers at open boundaries.
41      !!
42      !! Reference : Engedahl H., 1995, Tellus, 365-382.
43      !!----------------------------------------------------------------------
44      TYPE(OBC_INDEX),                     INTENT(in) ::   idx  ! OBC indices
45      REAL(wp), DIMENSION(:,:),            INTENT(in) ::   dta  ! OBC external data
46      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pta  ! tracer trend
47      !!
48      REAL(wp) ::   zwgt           ! boundary weight
49      INTEGER  ::   ib, ik, igrd   ! dummy loop indices
50      INTEGER  ::   ii, ij         ! 2D addresses
51      !!----------------------------------------------------------------------
52      !
53      igrd = 1                       ! Everything is at T-points here
54      DO ib = 1, idx%nblen(igrd)
55         DO ik = 1, jpkm1
56            ii = idx%nbi(ib,igrd) 
57            ij = idx%nbj(ib,igrd)
58            zwgt = idx%nbw(ib,igrd)
59            pta(ii,ij,ik) = ( pta(ii,ij,ik) + zwgt * (dta(ib,ik) - pta(ii,ij,ik) ) ) * tmask(ii,ij,ik)
60         END DO
61      END DO
62      !
63   END SUBROUTINE bdy_frs
64
65
66   SUBROUTINE bdy_spe( idx, pta, dta )
67      !!----------------------------------------------------------------------
68      !!                 ***  SUBROUTINE bdy_spe  ***
69      !!
70      !! ** Purpose : Apply a specified value for tracers at open boundaries.
71      !!
72      !!----------------------------------------------------------------------
73      TYPE(OBC_INDEX),                     INTENT(in) ::   idx  ! OBC indices
74      REAL(wp), DIMENSION(:,:),            INTENT(in) ::   dta  ! OBC external data
75      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pta  ! tracer trend
76      !!
77      INTEGER  ::   ib, ik, igrd   ! dummy loop indices
78      INTEGER  ::   ii, ij         ! 2D addresses
79      !!----------------------------------------------------------------------
80      !
81      igrd = 1                       ! Everything is at T-points here
82      DO ib = 1, idx%nblenrim(igrd)
83         ii = idx%nbi(ib,igrd)
84         ij = idx%nbj(ib,igrd)
85         DO ik = 1, jpkm1
86            pta(ii,ij,ik) = dta(ib,ik) * tmask(ii,ij,ik)
87         END DO
88      END DO
89      !
90   END SUBROUTINE bdy_spe
91
92
93   SUBROUTINE bdy_orl( idx, ptb, pta, dta, ll_npo )
94      !!----------------------------------------------------------------------
95      !!                 ***  SUBROUTINE bdy_orl  ***
96      !!
97      !! ** Purpose : Apply Orlanski radiation for tracers at open boundaries.
98      !!              This is a wrapper routine for bdy_orlanski_3d below
99      !!
100      !!----------------------------------------------------------------------
101      TYPE(OBC_INDEX),                     INTENT(in) ::   idx  ! OBC indices
102      REAL(wp), DIMENSION(:,:),            INTENT(in) ::   dta  ! OBC external data
103      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   ptb  ! before tracer field
104      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pta  ! tracer trend
105      LOGICAL,                             INTENT(in) ::   ll_npo  ! switch for NPO version
106      !!
107      INTEGER  ::   igrd                                    ! grid index
108      !!----------------------------------------------------------------------
109      !
110      igrd = 1                       ! Everything is at T-points here
111      !
112      CALL bdy_orlanski_3d( idx, igrd, ptb(:,:,:), pta(:,:,:), dta, ll_npo )
113      !
114   END SUBROUTINE bdy_orl
115
116
117   SUBROUTINE bdy_orlanski_2d( idx, igrd, phib, phia, phi_ext, ll_npo )
118      !!----------------------------------------------------------------------
119      !!                 ***  SUBROUTINE bdy_orlanski_2d  ***
120      !!             
121      !!              - Apply Orlanski radiation condition adaptively to 2D fields:
122      !!                  - radiation plus weak nudging at outflow points
123      !!                  - no radiation and strong nudging at inflow points
124      !!
125      !!
126      !! References:  Marchesiello, McWilliams and Shchepetkin, Ocean Modelling vol. 3 (2001)   
127      !!----------------------------------------------------------------------
128      TYPE(OBC_INDEX),          INTENT(in   ) ::   idx      ! BDY indices
129      INTEGER ,                 INTENT(in   ) ::   igrd     ! grid index
130      REAL(wp), DIMENSION(:,:), INTENT(in   ) ::   phib     ! model before 2D field
131      REAL(wp), DIMENSION(:,:), INTENT(inout) ::   phia     ! model after 2D field (to be updated)
132      REAL(wp), DIMENSION(:)  , INTENT(in   ) ::   phi_ext  ! external forcing data
133      LOGICAL ,                 INTENT(in   ) ::   ll_npo   ! switch for NPO version
134      !
135      INTEGER  ::   jb                                     ! dummy loop indices
136      INTEGER  ::   ii, ij, iibm1, iibm2, ijbm1, ijbm2     ! 2D addresses
137      INTEGER  ::   iijm1, iijp1, ijjm1, ijjp1             ! 2D addresses
138      INTEGER  ::   iibm1jp1, iibm1jm1, ijbm1jp1, ijbm1jm1 ! 2D addresses
139      INTEGER  ::   ii_offset, ij_offset                   ! offsets for mask indices
140      INTEGER  ::   flagu, flagv                           ! short cuts
141      REAL(wp) ::   zmask_x, zmask_y1, zmask_y2
142      REAL(wp) ::   zex1, zex2, zey, zey1, zey2
143      REAL(wp) ::   zdt, zdx, zdy, znor2, zrx, zry         ! intermediate calculations
144      REAL(wp) ::   zout, zwgt, zdy_centred
145      REAL(wp) ::   zdy_1, zdy_2, zsign_ups
146      REAL(wp), PARAMETER :: zepsilon = 1.e-30                 ! local small value
147      REAL(wp), POINTER, DIMENSION(:,:)          :: pmask      ! land/sea mask for field
148      REAL(wp), POINTER, DIMENSION(:,:)          :: pmask_xdif ! land/sea mask for x-derivatives
149      REAL(wp), POINTER, DIMENSION(:,:)          :: pmask_ydif ! land/sea mask for y-derivatives
150      REAL(wp), POINTER, DIMENSION(:,:)          :: pe_xdif    ! scale factors for x-derivatives
151      REAL(wp), POINTER, DIMENSION(:,:)          :: pe_ydif    ! scale factors for y-derivatives
152      !!----------------------------------------------------------------------
153      !
154      ! ----------------------------------!
155      ! Orlanski boundary conditions     :!
156      ! ----------------------------------!
157     
158      SELECT CASE(igrd)
159         CASE(1)
160            pmask      => tmask(:,:,1)
161            pmask_xdif => umask(:,:,1)
162            pmask_ydif => vmask(:,:,1)
163            pe_xdif    => e1u(:,:)
164            pe_ydif    => e2v(:,:)
165            ii_offset = 0
166            ij_offset = 0
167         CASE(2)
168            pmask      => umask(:,:,1)
169            pmask_xdif => tmask(:,:,1)
170            pmask_ydif => fmask(:,:,1)
171            pe_xdif    => e1t(:,:)
172            pe_ydif    => e2f(:,:)
173            ii_offset = 1
174            ij_offset = 0
175         CASE(3)
176            pmask      => vmask(:,:,1)
177            pmask_xdif => fmask(:,:,1)
178            pmask_ydif => tmask(:,:,1)
179            pe_xdif    => e1f(:,:)
180            pe_ydif    => e2t(:,:)
181            ii_offset = 0
182            ij_offset = 1
183         CASE DEFAULT ;   CALL ctl_stop( 'unrecognised value for igrd in bdy_orlanksi_2d' )
184      END SELECT
185      !
186      DO jb = 1, idx%nblenrim(igrd)
187         ii  = idx%nbi(jb,igrd)
188         ij  = idx%nbj(jb,igrd) 
189         IF( ii == 1 .OR. ii == jpi .OR. ij == 1 .OR. ij == jpj )   CYCLE
190         flagu = int( idx%flagu(jb,igrd) )
191         flagv = int( idx%flagv(jb,igrd) )
192         !
193         ! Calculate positions of b-1 and b-2 points for this rim point
194         ! also (b-1,j-1) and (b-1,j+1) points
195         iibm1 = ii + flagu ; iibm2 = ii + 2*flagu 
196         ijbm1 = ij + flagv ; ijbm2 = ij + 2*flagv
197          !
198         iijm1 = ii - abs(flagv) ; iijp1 = ii + abs(flagv) 
199         ijjm1 = ij - abs(flagu) ; ijjp1 = ij + abs(flagu)
200         !
201         iibm1jm1 = ii + flagu - abs(flagv) ; iibm1jp1 = ii + flagu + abs(flagv) 
202         ijbm1jm1 = ij + flagv - abs(flagu) ; ijbm1jp1 = ij + flagv + abs(flagu) 
203         !
204         ! Calculate scale factors for calculation of spatial derivatives.       
205         zex1 = ( abs(iibm1-iibm2) * pe_xdif(iibm1+ii_offset,ijbm1          )         &
206        &       + abs(ijbm1-ijbm2) * pe_ydif(iibm1          ,ijbm1+ij_offset) ) 
207         zex2 = ( abs(iibm1-iibm2) * pe_xdif(iibm2+ii_offset,ijbm2          )         &
208        &       + abs(ijbm1-ijbm2) * pe_ydif(iibm2          ,ijbm2+ij_offset) ) 
209         zey1 = ( (iibm1-iibm1jm1) * pe_xdif(iibm1jm1+ii_offset,ijbm1jm1          )  & 
210        &      +  (ijbm1-ijbm1jm1) * pe_ydif(iibm1jm1          ,ijbm1jm1+ij_offset) ) 
211         zey2 = ( (iibm1jp1-iibm1) * pe_xdif(iibm1+ii_offset,ijbm1)                  &
212        &      +  (ijbm1jp1-ijbm1) * pe_ydif(iibm1          ,ijbm1+ij_offset) ) 
213         ! make sure scale factors are nonzero
214         if( zey1 .lt. rsmall ) zey1 = zey2
215         if( zey2 .lt. rsmall ) zey2 = zey1
216         zex1 = max(zex1,rsmall); zex2 = max(zex2,rsmall)
217         zey1 = max(zey1,rsmall); zey2 = max(zey2,rsmall); 
218         !
219         ! Calculate masks for calculation of spatial derivatives.       
220         zmask_x = ( abs(iibm1-iibm2) * pmask_xdif(iibm2+ii_offset,ijbm2          )         &
221        &          + abs(ijbm1-ijbm2) * pmask_ydif(iibm2          ,ijbm2+ij_offset) ) 
222         zmask_y1 = ( (iibm1-iibm1jm1) * pmask_xdif(iibm1jm1+ii_offset,ijbm1jm1          )  & 
223        &          +  (ijbm1-ijbm1jm1) * pmask_ydif(iibm1jm1          ,ijbm1jm1+ij_offset) ) 
224         zmask_y2 = ( (iibm1jp1-iibm1) * pmask_xdif(iibm1+ii_offset,ijbm1)                  &
225        &          +  (ijbm1jp1-ijbm1) * pmask_ydif(iibm1          ,ijbm1+ij_offset) ) 
226
227         ! Calculation of terms required for both versions of the scheme.
228         ! Mask derivatives to ensure correct land boundary conditions for each variable.
229         ! Centred derivative is calculated as average of "left" and "right" derivatives for
230         ! this reason.
231         ! Note no rdt factor in expression for zdt because it cancels in the expressions for
232         ! zrx and zry.
233         zdt = phia(iibm1,ijbm1) - phib(iibm1,ijbm1)
234         zdx = ( ( phia(iibm1,ijbm1) - phia(iibm2,ijbm2) ) / zex2 ) * zmask_x 
235         zdy_1 = ( ( phib(iibm1   ,ijbm1   ) - phib(iibm1jm1,ijbm1jm1) ) / zey1 ) * zmask_y1   
236         zdy_2 = ( ( phib(iibm1jp1,ijbm1jp1) - phib(iibm1   ,ijbm1)    ) / zey2 ) * zmask_y2 
237         zdy_centred = 0.5 * ( zdy_1 + zdy_2 )
238!!$         zdy_centred = phib(iibm1jp1,ijbm1jp1) - phib(iibm1jm1,ijbm1jm1)
239         ! upstream differencing for tangential derivatives
240         zsign_ups = sign( 1., zdt * zdy_centred )
241         zsign_ups = 0.5*( zsign_ups + abs(zsign_ups) )
242         zdy = zsign_ups * zdy_1 + (1. - zsign_ups) * zdy_2
243         znor2 = zdx * zdx + zdy * zdy
244         znor2 = max(znor2,zepsilon)
245         !
246         zrx = zdt * zdx / ( zex1 * znor2 ) 
247!!$         zrx = min(zrx,2.0_wp)
248         zout = sign( 1., zrx )
249         zout = 0.5*( zout + abs(zout) )
250         zwgt = 2.*rdt*( (1.-zout) * idx%nbd(jb,igrd) + zout * idx%nbdout(jb,igrd) )
251         ! only apply radiation on outflow points
252         if( ll_npo ) then     !! NPO version !!
253            phia(ii,ij) = (1.-zout) * ( phib(ii,ij) + zwgt * ( phi_ext(jb) - phib(ii,ij) ) )        &
254           &            + zout      * ( phib(ii,ij) + zrx*phia(iibm1,ijbm1)                         &
255           &                            + zwgt * ( phi_ext(jb) - phib(ii,ij) ) ) / ( 1. + zrx ) 
256         else                  !! full oblique radiation !!
257            zsign_ups = sign( 1., zdt * zdy )
258            zsign_ups = 0.5*( zsign_ups + abs(zsign_ups) )
259            zey = zsign_ups * zey1 + (1.-zsign_ups) * zey2 
260            zry = zdt * zdy / ( zey * znor2 ) 
261            phia(ii,ij) = (1.-zout) * ( phib(ii,ij) + zwgt * ( phi_ext(jb) - phib(ii,ij) ) )        &
262           &            + zout      * ( phib(ii,ij) + zrx*phia(iibm1,ijbm1)                         &
263           &                    - zsign_ups      * zry * ( phib(ii   ,ij   ) - phib(iijm1,ijjm1 ) ) &
264           &                    - (1.-zsign_ups) * zry * ( phib(iijp1,ijjp1) - phib(ii   ,ij    ) ) &
265           &                    + zwgt * ( phi_ext(jb) - phib(ii,ij) ) ) / ( 1. + zrx ) 
266         end if
267         phia(ii,ij) = phia(ii,ij) * pmask(ii,ij)
268      END DO
269      !
270   END SUBROUTINE bdy_orlanski_2d
271
272
273   SUBROUTINE bdy_orlanski_3d( idx, igrd, phib, phia, phi_ext, ll_npo )
274      !!----------------------------------------------------------------------
275      !!                 ***  SUBROUTINE bdy_orlanski_3d  ***
276      !!             
277      !!              - Apply Orlanski radiation condition adaptively to 3D fields:
278      !!                  - radiation plus weak nudging at outflow points
279      !!                  - no radiation and strong nudging at inflow points
280      !!
281      !!
282      !! References:  Marchesiello, McWilliams and Shchepetkin, Ocean Modelling vol. 3 (2001)   
283      !!----------------------------------------------------------------------
284      TYPE(OBC_INDEX),            INTENT(in   ) ::   idx      ! BDY indices
285      INTEGER ,                   INTENT(in   ) ::   igrd     ! grid index
286      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   phib     ! model before 3D field
287      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   phia     ! model after 3D field (to be updated)
288      REAL(wp), DIMENSION(:,:)  , INTENT(in   ) ::   phi_ext  ! external forcing data
289      LOGICAL ,                   INTENT(in   ) ::   ll_npo   ! switch for NPO version
290      !
291      INTEGER  ::   jb, jk                                 ! dummy loop indices
292      INTEGER  ::   ii, ij, iibm1, iibm2, ijbm1, ijbm2     ! 2D addresses
293      INTEGER  ::   iijm1, iijp1, ijjm1, ijjp1             ! 2D addresses
294      INTEGER  ::   iibm1jp1, iibm1jm1, ijbm1jp1, ijbm1jm1 ! 2D addresses
295      INTEGER  ::   ii_offset, ij_offset                   ! offsets for mask indices
296      INTEGER  ::   flagu, flagv                           ! short cuts
297      REAL(wp) ::   zmask_x, zmask_y1, zmask_y2
298      REAL(wp) ::   zex1, zex2, zey, zey1, zey2
299      REAL(wp) ::   zdt, zdx, zdy, znor2, zrx, zry         ! intermediate calculations
300      REAL(wp) ::   zout, zwgt, zdy_centred
301      REAL(wp) ::   zdy_1, zdy_2,  zsign_ups
302      REAL(wp), PARAMETER :: zepsilon = 1.e-30                 ! local small value
303      REAL(wp), POINTER, DIMENSION(:,:,:)        :: pmask      ! land/sea mask for field
304      REAL(wp), POINTER, DIMENSION(:,:,:)        :: pmask_xdif ! land/sea mask for x-derivatives
305      REAL(wp), POINTER, DIMENSION(:,:,:)        :: pmask_ydif ! land/sea mask for y-derivatives
306      REAL(wp), POINTER, DIMENSION(:,:)          :: pe_xdif    ! scale factors for x-derivatives
307      REAL(wp), POINTER, DIMENSION(:,:)          :: pe_ydif    ! scale factors for y-derivatives
308      !!----------------------------------------------------------------------
309      !
310      ! ----------------------------------!
311      ! Orlanski boundary conditions     :!
312      ! ----------------------------------!
313      !
314      SELECT CASE(igrd)
315         CASE(1)
316            pmask      => tmask(:,:,:)
317            pmask_xdif => umask(:,:,:)
318            pmask_ydif => vmask(:,:,:)
319            pe_xdif    => e1u(:,:)
320            pe_ydif    => e2v(:,:)
321            ii_offset = 0
322            ij_offset = 0
323         CASE(2)
324            pmask      => umask(:,:,:)
325            pmask_xdif => tmask(:,:,:)
326            pmask_ydif => fmask(:,:,:)
327            pe_xdif    => e1t(:,:)
328            pe_ydif    => e2f(:,:)
329            ii_offset = 1
330            ij_offset = 0
331         CASE(3)
332            pmask      => vmask(:,:,:)
333            pmask_xdif => fmask(:,:,:)
334            pmask_ydif => tmask(:,:,:)
335            pe_xdif    => e1f(:,:)
336            pe_ydif    => e2t(:,:)
337            ii_offset = 0
338            ij_offset = 1
339         CASE DEFAULT ;   CALL ctl_stop( 'unrecognised value for igrd in bdy_orlanksi_2d' )
340      END SELECT
341
342      DO jk = 1, jpk
343         !           
344         DO jb = 1, idx%nblenrim(igrd)
345            ii  = idx%nbi(jb,igrd)
346            ij  = idx%nbj(jb,igrd) 
347            IF( ii == 1 .OR. ii == jpi .OR. ij == 1 .OR. ij == jpj )   CYCLE
348            flagu = int( idx%flagu(jb,igrd) )
349            flagv = int( idx%flagv(jb,igrd) )
350            !
351            ! calculate positions of b-1 and b-2 points for this rim point
352            ! also (b-1,j-1) and (b-1,j+1) points
353            iibm1 = ii + flagu ; iibm2 = ii + 2*flagu 
354            ijbm1 = ij + flagv ; ijbm2 = ij + 2*flagv
355            !
356            iijm1 = ii - abs(flagv) ; iijp1 = ii + abs(flagv) 
357            ijjm1 = ij - abs(flagu) ; ijjp1 = ij + abs(flagu)
358            !
359            iibm1jm1 = ii + flagu - abs(flagv) ; iibm1jp1 = ii + flagu + abs(flagv) 
360            ijbm1jm1 = ij + flagv - abs(flagu) ; ijbm1jp1 = ij + flagv + abs(flagu) 
361            !
362            ! Calculate scale factors for calculation of spatial derivatives.       
363            zex1 = ( abs(iibm1-iibm2) * pe_xdif(iibm1+ii_offset,ijbm1          )         &
364           &       + abs(ijbm1-ijbm2) * pe_ydif(iibm1          ,ijbm1+ij_offset) ) 
365            zex2 = ( abs(iibm1-iibm2) * pe_xdif(iibm2+ii_offset,ijbm2          )         &
366           &       + abs(ijbm1-ijbm2) * pe_ydif(iibm2          ,ijbm2+ij_offset) ) 
367            zey1 = ( (iibm1-iibm1jm1) * pe_xdif(iibm1jm1+ii_offset,ijbm1jm1          )  & 
368           &      +  (ijbm1-ijbm1jm1) * pe_ydif(iibm1jm1          ,ijbm1jm1+ij_offset) ) 
369            zey2 = ( (iibm1jp1-iibm1) * pe_xdif(iibm1+ii_offset,ijbm1)                  &
370           &      +  (ijbm1jp1-ijbm1) * pe_ydif(iibm1          ,ijbm1+ij_offset) ) 
371            ! make sure scale factors are nonzero
372            if( zey1 .lt. rsmall ) zey1 = zey2
373            if( zey2 .lt. rsmall ) zey2 = zey1
374            zex1 = max(zex1,rsmall); zex2 = max(zex2,rsmall); 
375            zey1 = max(zey1,rsmall); zey2 = max(zey2,rsmall); 
376            !
377            ! Calculate masks for calculation of spatial derivatives.       
378            zmask_x = ( abs(iibm1-iibm2) * pmask_xdif(iibm2+ii_offset,ijbm2          ,jk)          &
379           &          + abs(ijbm1-ijbm2) * pmask_ydif(iibm2          ,ijbm2+ij_offset,jk) ) 
380            zmask_y1 = ( (iibm1-iibm1jm1) * pmask_xdif(iibm1jm1+ii_offset,ijbm1jm1          ,jk)   & 
381           &          +  (ijbm1-ijbm1jm1) * pmask_ydif(iibm1jm1          ,ijbm1jm1+ij_offset,jk) ) 
382            zmask_y2 = ( (iibm1jp1-iibm1) * pmask_xdif(iibm1+ii_offset,ijbm1          ,jk)         &
383           &          +  (ijbm1jp1-ijbm1) * pmask_ydif(iibm1          ,ijbm1+ij_offset,jk) ) 
384            !
385            ! Calculate normal (zrx) and tangential (zry) components of radiation velocities.
386            ! Mask derivatives to ensure correct land boundary conditions for each variable.
387            ! Centred derivative is calculated as average of "left" and "right" derivatives for
388            ! this reason.
389            zdt = phia(iibm1,ijbm1,jk) - phib(iibm1,ijbm1,jk)
390            zdx = ( ( phia(iibm1,ijbm1,jk) - phia(iibm2,ijbm2,jk) ) / zex2 ) * zmask_x                 
391            zdy_1 = ( ( phib(iibm1   ,ijbm1   ,jk) - phib(iibm1jm1,ijbm1jm1,jk) ) / zey1 ) * zmask_y1 
392            zdy_2 = ( ( phib(iibm1jp1,ijbm1jp1,jk) - phib(iibm1   ,ijbm1   ,jk) ) / zey2 ) * zmask_y2     
393            zdy_centred = 0.5 * ( zdy_1 + zdy_2 )
394!!$            zdy_centred = phib(iibm1jp1,ijbm1jp1,jk) - phib(iibm1jm1,ijbm1jm1,jk)
395            ! upstream differencing for tangential derivatives
396            zsign_ups = sign( 1., zdt * zdy_centred )
397            zsign_ups = 0.5*( zsign_ups + abs(zsign_ups) )
398            zdy = zsign_ups * zdy_1 + (1. - zsign_ups) * zdy_2
399            znor2 = zdx * zdx + zdy * zdy
400            znor2 = max(znor2,zepsilon)
401            !
402            ! update boundary value:
403            zrx = zdt * zdx / ( zex1 * znor2 )
404!!$            zrx = min(zrx,2.0_wp)
405            zout = sign( 1., zrx )
406            zout = 0.5*( zout + abs(zout) )
407            zwgt = 2.*rdt*( (1.-zout) * idx%nbd(jb,igrd) + zout * idx%nbdout(jb,igrd) )
408            ! only apply radiation on outflow points
409            if( ll_npo ) then     !! NPO version !!
410               phia(ii,ij,jk) = (1.-zout) * ( phib(ii,ij,jk) + zwgt * ( phi_ext(jb,jk) - phib(ii,ij,jk) ) ) &
411              &               + zout      * ( phib(ii,ij,jk) + zrx*phia(iibm1,ijbm1,jk)                     &
412              &                            + zwgt * ( phi_ext(jb,jk) - phib(ii,ij,jk) ) ) / ( 1. + zrx ) 
413            else                  !! full oblique radiation !!
414               zsign_ups = sign( 1., zdt * zdy )
415               zsign_ups = 0.5*( zsign_ups + abs(zsign_ups) )
416               zey = zsign_ups * zey1 + (1.-zsign_ups) * zey2 
417               zry = zdt * zdy / ( zey * znor2 ) 
418               phia(ii,ij,jk) = (1.-zout) * ( phib(ii,ij,jk) + zwgt * ( phi_ext(jb,jk) - phib(ii,ij,jk) ) )    &
419              &               + zout      * ( phib(ii,ij,jk) + zrx*phia(iibm1,ijbm1,jk)                        &
420              &                       - zsign_ups      * zry * ( phib(ii   ,ij   ,jk) - phib(iijm1,ijjm1,jk) ) &
421              &                       - (1.-zsign_ups) * zry * ( phib(iijp1,ijjp1,jk) - phib(ii   ,ij   ,jk) ) &
422              &                       + zwgt * ( phi_ext(jb,jk) - phib(ii,ij,jk) ) ) / ( 1. + zrx ) 
423            end if
424            phia(ii,ij,jk) = phia(ii,ij,jk) * pmask(ii,ij,jk)
425         END DO
426         !
427      END DO
428      !
429   END SUBROUTINE bdy_orlanski_3d
430
431   SUBROUTINE bdy_nmn( idx, igrd, phia )
432      !!----------------------------------------------------------------------
433      !!                 ***  SUBROUTINE bdy_nmn  ***
434      !!                   
435      !! ** Purpose : Duplicate the value at open boundaries, zero gradient.
436      !!
437      !!
438      !! ** Method  : - take the average of free ocean neighbours
439      !!
440      !!      ___   !   |_____|   !   ___|    !   __|x o   !   |_   _|     ! |     
441      !!   __|x     !      x      !     x o   !      o     !     |_|       ! |x o   
442      !!      o     !      o      !     o     !            !    o x o      ! |x_x_
443      !!                                                   !      o     
444      !!----------------------------------------------------------------------
445      INTEGER,                    INTENT(in)     ::   igrd     ! grid index
446      REAL(wp), DIMENSION(:,:,:), INTENT(inout)  ::   phia     ! model after 3D field (to be updated), must be masked
447      TYPE(OBC_INDEX), INTENT(in) ::   idx  ! OBC indices
448      !!
449      REAL(wp) ::   zweight
450      REAL(wp), POINTER, DIMENSION(:,:,:)      :: pmask         ! land/sea mask for field
451      INTEGER  ::   ib, ik   ! dummy loop indices
452      INTEGER  ::   ii, ij   ! 2D addresses
453      INTEGER  ::   ipkm1    ! size of phia third dimension minus 1
454      INTEGER  ::   flagu, flagv                        ! short cuts
455      INTEGER  ::   ii1, ii2, ii3, ij1, ij2, ij3
456      !!----------------------------------------------------------------------
457      !
458      ipkm1 = MAX( SIZE(phia,3) - 1, 1 ) 
459      !
460      SELECT CASE(igrd)
461         CASE(1)   ;   pmask => tmask(:,:,:)
462         CASE(2)   ;   pmask => umask(:,:,:)
463         CASE(3)   ;   pmask => vmask(:,:,:)
464         CASE DEFAULT ;   CALL ctl_stop( 'unrecognised value for igrd in bdy_nmn' )
465      END SELECT
466      !
467      DO ib = 1, idx%nblenrim(igrd)
468         ii = idx%nbi(ib,igrd)
469         ij = idx%nbj(ib,igrd)
470         !
471         SELECT CASE( idx%ntreat(ib,igrd) )   ! select free ocean neighbours
472            !     o
473            !  ___x___         ! either flagu or flagv = 0
474            CASE( 0 )   ;   flagu = NINT( idx%flagu(ib,igrd) )   ;   ii1 = ii+flagu
475                            flagv = NINT( idx%flagv(ib,igrd) )   ;   ij1 = ij+flagv
476            !               !              !     _____     !     _____     
477            !  1 |   o      !  2  o   |    !  3 | x        !  4     x |   
478            !    |_x_ _     !    _ _x_|    !    |   o      !      o   |
479            CASE( 1 )   ;   ii1 = ii+1   ;   ij1 = ij+1
480            CASE( 2 )   ;   ii1 = ii-1   ;   ij1 = ij+1
481            CASE( 3 )   ;   ii1 = ii+1   ;   ij1 = ij-1
482            CASE( 4 )   ;   ii1 = ii-1   ;   ij1 = ij-1
483            !        o      !        o      !    _____|       !       |_____ 
484            !  5 ____x o    !  6   o x___   ! 7      x o      !  8   o x     
485            !         |     !       |       !        o        !        o     
486            CASE( 5 )   ;   ii1 = ii   ;   ij1 = ij+1   ;   ii2 = ii+1   ;   ij2 = ij   
487            CASE( 6 )   ;   ii1 = ii   ;   ij1 = ij+1   ;   ii2 = ii-1   ;   ij2 = ij
488            CASE( 7 )   ;   ii1 = ii   ;   ij1 = ij-1   ;   ii2 = ii+1   ;   ij2 = ij 
489            CASE( 8 )   ;   ii1 = ii   ;   ij1 = ij-1   ;   ii2 = ii-1   ;   ij2 = ij 
490            !    |_  o      !        o  _|  !     ¨¨|_|¨¨   !       o         
491            !  9  _| x o    !  10  o x |_   !  11  o x o    ! 12  o x o       
492            !    |   o      !        o   |  !        o      !    __|¨|__
493            CASE( 9  )   ;   ii1 = ii     ;   ij1 = ij+1   ;   ii2 = ii+1   ;   ij2 = ij     ;   ii3 = ii     ;   ij3 = ij-1   
494            CASE( 10 )   ;   ii1 = ii     ;   ij1 = ij+1   ;   ii2 = ii-1   ;   ij2 = ij     ;   ii3 = ii     ;   ij3 = ij-1 
495            CASE( 11 )   ;   ii1 = ii-1   ;   ij1 = ij     ;   ii2 = ii     ;   ij2 = ij-1   ;   ii3 = ii+1   ;   ij3 = ij   
496            CASE( 12 )   ;   ii1 = ii-1   ;   ij1 = ij     ;   ii2 = ii     ;   ij2 = ij+1   ;   ii3 = ii+1   ;   ij3 = ij
497         END SELECT
498         !
499         SELECT CASE( idx%ntreat(ib,igrd) )
500            CASE( 0:4 )
501               IF( ii1 < 1 .OR. ii1 > jpi .OR. ij1 < 1 .OR. ij1 > jpj )   CYCLE
502               DO ik = 1, ipkm1
503                  IF( pmask(ii1,ij1,ik) /= 0. )   phia(ii,ij,ik) = phia(ii1,ij1,ik) 
504               END DO
505            CASE( 5:8 )
506               IF( ii1 < 1 .OR. ii1 > jpi .OR. ij1 < 1 .OR. ij1 > jpj )   CYCLE
507               IF( ii2 < 1 .OR. ii2 > jpi .OR. ij2 < 1 .OR. ij2 > jpj )   CYCLE
508               DO ik = 1, ipkm1
509                  zweight = pmask(ii1,ij1,ik) + pmask(ii2,ij2,ik)
510                  IF( zweight /= 0. )   phia(ii,ij,ik) = ( phia(ii1,ij1,ik) + phia (ii2,ij2,ik) ) / zweight
511               END DO
512            CASE( 9:12 )
513               IF( ii1 < 1 .OR. ii1 > jpi .OR. ij1 < 1 .OR. ij1 > jpj )   CYCLE
514               IF( ii2 < 1 .OR. ii2 > jpi .OR. ij2 < 1 .OR. ij2 > jpj )   CYCLE
515               IF( ii3 < 1 .OR. ii3 > jpi .OR. ij3 < 1 .OR. ij3 > jpj )   CYCLE
516               DO ik = 1, ipkm1
517                  zweight = pmask(ii1,ij1,ik) + pmask(ii2,ij2,ik) + pmask(ii3,ij3,ik)
518                  IF( zweight /= 0. )   phia(ii,ij,ik) = ( phia(ii1,ij1,ik) + phia (ii2,ij2,ik) + phia (ii3,ij3,ik) ) / zweight
519               END DO
520         END SELECT
521         !
522      END DO
523      !
524   END SUBROUTINE bdy_nmn
525
526   !!======================================================================
527END MODULE bdylib
Note: See TracBrowser for help on using the repository browser.