New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
bdylib.F90 in NEMO/branches/2019/dev_r10984_HPC-13_IRRMANN_BDY_optimization/src/OCE/BDY – NEMO

source: NEMO/branches/2019/dev_r10984_HPC-13_IRRMANN_BDY_optimization/src/OCE/BDY/bdylib.F90 @ 11183

Last change on this file since 11183 was 11183, checked in by girrmann, 5 years ago

dev_r10984_HPC-13 : improvement of neumann boundary condition, changes the results, see #2285
  • Property svn:keywords set to Id
File size: 25.7 KB
Line 
1MODULE bdylib
2   !!======================================================================
3   !!                       ***  MODULE  bdylib  ***
4   !! Unstructured Open Boundary Cond. :  Library module of generic boundary algorithms.
5   !!======================================================================
6   !! History :  3.6  !  2013     (D. Storkey) original code
7   !!            4.0  !  2014     (T. Lovato) Generalize OBC structure
8   !!----------------------------------------------------------------------
9   !!----------------------------------------------------------------------
10   !!   bdy_orlanski_2d
11   !!   bdy_orlanski_3d
12   !!----------------------------------------------------------------------
13   USE oce            ! ocean dynamics and tracers
14   USE dom_oce        ! ocean space and time domain
15   USE bdy_oce        ! ocean open boundary conditions
16   USE phycst         ! physical constants
17   USE bdyini
18   !
19   USE in_out_manager !
20   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
21   USE lib_mpp, ONLY: ctl_stop
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   bdy_frs, bdy_spe, bdy_nmn, bdy_orl
27   PUBLIC   bdy_orlanski_2d
28   PUBLIC   bdy_orlanski_3d
29
30   !!----------------------------------------------------------------------
31   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
32   !! $Id$
33   !! Software governed by the CeCILL license (see ./LICENSE)
34   !!----------------------------------------------------------------------
35CONTAINS
36
37   SUBROUTINE bdy_frs( idx, pta, dta )
38      !!----------------------------------------------------------------------
39      !!                 ***  SUBROUTINE bdy_frs  ***
40      !!
41      !! ** Purpose : Apply the Flow Relaxation Scheme for tracers at open boundaries.
42      !!
43      !! Reference : Engedahl H., 1995, Tellus, 365-382.
44      !!----------------------------------------------------------------------
45      TYPE(OBC_INDEX),                     INTENT(in) ::   idx  ! OBC indices
46      REAL(wp), DIMENSION(:,:),            INTENT(in) ::   dta  ! OBC external data
47      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pta  ! tracer trend
48      !!
49      REAL(wp) ::   zwgt           ! boundary weight
50      INTEGER  ::   ib, ik, igrd   ! dummy loop indices
51      INTEGER  ::   ii, ij         ! 2D addresses
52      !!----------------------------------------------------------------------
53      !
54      igrd = 1                       ! Everything is at T-points here
55      DO ib = 1, idx%nblen(igrd)
56         DO ik = 1, jpkm1
57            ii = idx%nbi(ib,igrd) 
58            ij = idx%nbj(ib,igrd)
59            zwgt = idx%nbw(ib,igrd)
60            pta(ii,ij,ik) = ( pta(ii,ij,ik) + zwgt * (dta(ib,ik) - pta(ii,ij,ik) ) ) * tmask(ii,ij,ik)
61         END DO
62      END DO
63      !
64   END SUBROUTINE bdy_frs
65
66
67   SUBROUTINE bdy_spe( idx, pta, dta )
68      !!----------------------------------------------------------------------
69      !!                 ***  SUBROUTINE bdy_spe  ***
70      !!
71      !! ** Purpose : Apply a specified value for tracers at open boundaries.
72      !!
73      !!----------------------------------------------------------------------
74      TYPE(OBC_INDEX),                     INTENT(in) ::   idx  ! OBC indices
75      REAL(wp), DIMENSION(:,:),            INTENT(in) ::   dta  ! OBC external data
76      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pta  ! tracer trend
77      !!
78      INTEGER  ::   ib, ik, igrd   ! dummy loop indices
79      INTEGER  ::   ii, ij         ! 2D addresses
80      !!----------------------------------------------------------------------
81      !
82      igrd = 1                       ! Everything is at T-points here
83      DO ib = 1, idx%nblenrim(igrd)
84         ii = idx%nbi(ib,igrd)
85         ij = idx%nbj(ib,igrd)
86         DO ik = 1, jpkm1
87            pta(ii,ij,ik) = dta(ib,ik) * tmask(ii,ij,ik)
88         END DO
89      END DO
90      !
91   END SUBROUTINE bdy_spe
92
93
94   SUBROUTINE bdy_orl( idx, ptb, pta, dta, ll_npo )
95      !!----------------------------------------------------------------------
96      !!                 ***  SUBROUTINE bdy_orl  ***
97      !!
98      !! ** Purpose : Apply Orlanski radiation for tracers at open boundaries.
99      !!              This is a wrapper routine for bdy_orlanski_3d below
100      !!
101      !!----------------------------------------------------------------------
102      TYPE(OBC_INDEX),                     INTENT(in) ::   idx  ! OBC indices
103      REAL(wp), DIMENSION(:,:),            INTENT(in) ::   dta  ! OBC external data
104      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   ptb  ! before tracer field
105      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pta  ! tracer trend
106      LOGICAL,                             INTENT(in) ::   ll_npo  ! switch for NPO version
107      !!
108      INTEGER  ::   igrd                                    ! grid index
109      !!----------------------------------------------------------------------
110      !
111      igrd = 1                       ! Everything is at T-points here
112      !
113      CALL bdy_orlanski_3d( idx, igrd, ptb(:,:,:), pta(:,:,:), dta, ll_npo )
114      !
115   END SUBROUTINE bdy_orl
116
117
118   SUBROUTINE bdy_orlanski_2d( idx, igrd, phib, phia, phi_ext, ll_npo )
119      !!----------------------------------------------------------------------
120      !!                 ***  SUBROUTINE bdy_orlanski_2d  ***
121      !!             
122      !!              - Apply Orlanski radiation condition adaptively to 2D fields:
123      !!                  - radiation plus weak nudging at outflow points
124      !!                  - no radiation and strong nudging at inflow points
125      !!
126      !!
127      !! References:  Marchesiello, McWilliams and Shchepetkin, Ocean Modelling vol. 3 (2001)   
128      !!----------------------------------------------------------------------
129      TYPE(OBC_INDEX),          INTENT(in   ) ::   idx      ! BDY indices
130      INTEGER ,                 INTENT(in   ) ::   igrd     ! grid index
131      REAL(wp), DIMENSION(:,:), INTENT(in   ) ::   phib     ! model before 2D field
132      REAL(wp), DIMENSION(:,:), INTENT(inout) ::   phia     ! model after 2D field (to be updated)
133      REAL(wp), DIMENSION(:)  , INTENT(in   ) ::   phi_ext  ! external forcing data
134      LOGICAL ,                 INTENT(in   ) ::   ll_npo   ! switch for NPO version
135      !
136      INTEGER  ::   jb                                     ! dummy loop indices
137      INTEGER  ::   ii, ij, iibm1, iibm2, ijbm1, ijbm2     ! 2D addresses
138      INTEGER  ::   iijm1, iijp1, ijjm1, ijjp1             ! 2D addresses
139      INTEGER  ::   iibm1jp1, iibm1jm1, ijbm1jp1, ijbm1jm1 ! 2D addresses
140      INTEGER  ::   ii_offset, ij_offset                   ! offsets for mask indices
141      INTEGER  ::   flagu, flagv                           ! short cuts
142      REAL(wp) ::   zmask_x, zmask_y1, zmask_y2
143      REAL(wp) ::   zex1, zex2, zey, zey1, zey2
144      REAL(wp) ::   zdt, zdx, zdy, znor2, zrx, zry         ! intermediate calculations
145      REAL(wp) ::   zout, zwgt, zdy_centred
146      REAL(wp) ::   zdy_1, zdy_2, zsign_ups
147      REAL(wp), PARAMETER :: zepsilon = 1.e-30                 ! local small value
148      REAL(wp), POINTER, DIMENSION(:,:)          :: pmask      ! land/sea mask for field
149      REAL(wp), POINTER, DIMENSION(:,:)          :: pmask_xdif ! land/sea mask for x-derivatives
150      REAL(wp), POINTER, DIMENSION(:,:)          :: pmask_ydif ! land/sea mask for y-derivatives
151      REAL(wp), POINTER, DIMENSION(:,:)          :: pe_xdif    ! scale factors for x-derivatives
152      REAL(wp), POINTER, DIMENSION(:,:)          :: pe_ydif    ! scale factors for y-derivatives
153      !!----------------------------------------------------------------------
154      !
155      ! ----------------------------------!
156      ! Orlanski boundary conditions     :!
157      ! ----------------------------------!
158     
159      SELECT CASE(igrd)
160         CASE(1)
161            pmask      => tmask(:,:,1)
162            pmask_xdif => umask(:,:,1)
163            pmask_ydif => vmask(:,:,1)
164            pe_xdif    => e1u(:,:)
165            pe_ydif    => e2v(:,:)
166            ii_offset = 0
167            ij_offset = 0
168         CASE(2)
169            pmask      => umask(:,:,1)
170            pmask_xdif => tmask(:,:,1)
171            pmask_ydif => fmask(:,:,1)
172            pe_xdif    => e1t(:,:)
173            pe_ydif    => e2f(:,:)
174            ii_offset = 1
175            ij_offset = 0
176         CASE(3)
177            pmask      => vmask(:,:,1)
178            pmask_xdif => fmask(:,:,1)
179            pmask_ydif => tmask(:,:,1)
180            pe_xdif    => e1f(:,:)
181            pe_ydif    => e2t(:,:)
182            ii_offset = 0
183            ij_offset = 1
184         CASE DEFAULT ;   CALL ctl_stop( 'unrecognised value for igrd in bdy_orlanksi_2d' )
185      END SELECT
186      !
187      DO jb = 1, idx%nblenrim(igrd)
188         ii  = idx%nbi(jb,igrd)
189         ij  = idx%nbj(jb,igrd) 
190         IF( ii == 1 .OR. ii == jpi .OR. ij == 1 .OR. ij == jpj )   CYCLE
191         flagu = int( idx%flagu(jb,igrd) )
192         flagv = int( idx%flagv(jb,igrd) )
193         !
194         ! Calculate positions of b-1 and b-2 points for this rim point
195         ! also (b-1,j-1) and (b-1,j+1) points
196         iibm1 = ii + flagu ; iibm2 = ii + 2*flagu 
197         ijbm1 = ij + flagv ; ijbm2 = ij + 2*flagv
198          !
199         iijm1 = ii - abs(flagv) ; iijp1 = ii + abs(flagv) 
200         ijjm1 = ij - abs(flagu) ; ijjp1 = ij + abs(flagu)
201         !
202         iibm1jm1 = ii + flagu - abs(flagv) ; iibm1jp1 = ii + flagu + abs(flagv) 
203         ijbm1jm1 = ij + flagv - abs(flagu) ; ijbm1jp1 = ij + flagv + abs(flagu) 
204         !
205         ! Calculate scale factors for calculation of spatial derivatives.       
206         zex1 = ( abs(iibm1-iibm2) * pe_xdif(iibm1+ii_offset,ijbm1          )         &
207        &       + abs(ijbm1-ijbm2) * pe_ydif(iibm1          ,ijbm1+ij_offset) ) 
208         zex2 = ( abs(iibm1-iibm2) * pe_xdif(iibm2+ii_offset,ijbm2          )         &
209        &       + abs(ijbm1-ijbm2) * pe_ydif(iibm2          ,ijbm2+ij_offset) ) 
210         zey1 = ( (iibm1-iibm1jm1) * pe_xdif(iibm1jm1+ii_offset,ijbm1jm1          )  & 
211        &      +  (ijbm1-ijbm1jm1) * pe_ydif(iibm1jm1          ,ijbm1jm1+ij_offset) ) 
212         zey2 = ( (iibm1jp1-iibm1) * pe_xdif(iibm1+ii_offset,ijbm1)                  &
213        &      +  (ijbm1jp1-ijbm1) * pe_ydif(iibm1          ,ijbm1+ij_offset) ) 
214         ! make sure scale factors are nonzero
215         if( zey1 .lt. rsmall ) zey1 = zey2
216         if( zey2 .lt. rsmall ) zey2 = zey1
217         zex1 = max(zex1,rsmall); zex2 = max(zex2,rsmall)
218         zey1 = max(zey1,rsmall); zey2 = max(zey2,rsmall); 
219         !
220         ! Calculate masks for calculation of spatial derivatives.       
221         zmask_x = ( abs(iibm1-iibm2) * pmask_xdif(iibm2+ii_offset,ijbm2          )         &
222        &          + abs(ijbm1-ijbm2) * pmask_ydif(iibm2          ,ijbm2+ij_offset) ) 
223         zmask_y1 = ( (iibm1-iibm1jm1) * pmask_xdif(iibm1jm1+ii_offset,ijbm1jm1          )  & 
224        &          +  (ijbm1-ijbm1jm1) * pmask_ydif(iibm1jm1          ,ijbm1jm1+ij_offset) ) 
225         zmask_y2 = ( (iibm1jp1-iibm1) * pmask_xdif(iibm1+ii_offset,ijbm1)                  &
226        &          +  (ijbm1jp1-ijbm1) * pmask_ydif(iibm1          ,ijbm1+ij_offset) ) 
227
228         ! Calculation of terms required for both versions of the scheme.
229         ! Mask derivatives to ensure correct land boundary conditions for each variable.
230         ! Centred derivative is calculated as average of "left" and "right" derivatives for
231         ! this reason.
232         ! Note no rdt factor in expression for zdt because it cancels in the expressions for
233         ! zrx and zry.
234         zdt = phia(iibm1,ijbm1) - phib(iibm1,ijbm1)
235         zdx = ( ( phia(iibm1,ijbm1) - phia(iibm2,ijbm2) ) / zex2 ) * zmask_x 
236         zdy_1 = ( ( phib(iibm1   ,ijbm1   ) - phib(iibm1jm1,ijbm1jm1) ) / zey1 ) * zmask_y1   
237         zdy_2 = ( ( phib(iibm1jp1,ijbm1jp1) - phib(iibm1   ,ijbm1)    ) / zey2 ) * zmask_y2 
238         zdy_centred = 0.5 * ( zdy_1 + zdy_2 )
239!!$         zdy_centred = phib(iibm1jp1,ijbm1jp1) - phib(iibm1jm1,ijbm1jm1)
240         ! upstream differencing for tangential derivatives
241         zsign_ups = sign( 1., zdt * zdy_centred )
242         zsign_ups = 0.5*( zsign_ups + abs(zsign_ups) )
243         zdy = zsign_ups * zdy_1 + (1. - zsign_ups) * zdy_2
244         znor2 = zdx * zdx + zdy * zdy
245         znor2 = max(znor2,zepsilon)
246         !
247         zrx = zdt * zdx / ( zex1 * znor2 ) 
248!!$         zrx = min(zrx,2.0_wp)
249         zout = sign( 1., zrx )
250         zout = 0.5*( zout + abs(zout) )
251         zwgt = 2.*rdt*( (1.-zout) * idx%nbd(jb,igrd) + zout * idx%nbdout(jb,igrd) )
252         ! only apply radiation on outflow points
253         if( ll_npo ) then     !! NPO version !!
254            phia(ii,ij) = (1.-zout) * ( phib(ii,ij) + zwgt * ( phi_ext(jb) - phib(ii,ij) ) )        &
255           &            + zout      * ( phib(ii,ij) + zrx*phia(iibm1,ijbm1)                         &
256           &                            + zwgt * ( phi_ext(jb) - phib(ii,ij) ) ) / ( 1. + zrx ) 
257         else                  !! full oblique radiation !!
258            zsign_ups = sign( 1., zdt * zdy )
259            zsign_ups = 0.5*( zsign_ups + abs(zsign_ups) )
260            zey = zsign_ups * zey1 + (1.-zsign_ups) * zey2 
261            zry = zdt * zdy / ( zey * znor2 ) 
262            phia(ii,ij) = (1.-zout) * ( phib(ii,ij) + zwgt * ( phi_ext(jb) - phib(ii,ij) ) )        &
263           &            + zout      * ( phib(ii,ij) + zrx*phia(iibm1,ijbm1)                         &
264           &                    - zsign_ups      * zry * ( phib(ii   ,ij   ) - phib(iijm1,ijjm1 ) ) &
265           &                    - (1.-zsign_ups) * zry * ( phib(iijp1,ijjp1) - phib(ii   ,ij    ) ) &
266           &                    + zwgt * ( phi_ext(jb) - phib(ii,ij) ) ) / ( 1. + zrx ) 
267         end if
268         phia(ii,ij) = phia(ii,ij) * pmask(ii,ij)
269      END DO
270      !
271   END SUBROUTINE bdy_orlanski_2d
272
273
274   SUBROUTINE bdy_orlanski_3d( idx, igrd, phib, phia, phi_ext, ll_npo )
275      !!----------------------------------------------------------------------
276      !!                 ***  SUBROUTINE bdy_orlanski_3d  ***
277      !!             
278      !!              - Apply Orlanski radiation condition adaptively to 3D fields:
279      !!                  - radiation plus weak nudging at outflow points
280      !!                  - no radiation and strong nudging at inflow points
281      !!
282      !!
283      !! References:  Marchesiello, McWilliams and Shchepetkin, Ocean Modelling vol. 3 (2001)   
284      !!----------------------------------------------------------------------
285      TYPE(OBC_INDEX),            INTENT(in   ) ::   idx      ! BDY indices
286      INTEGER ,                   INTENT(in   ) ::   igrd     ! grid index
287      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   phib     ! model before 3D field
288      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   phia     ! model after 3D field (to be updated)
289      REAL(wp), DIMENSION(:,:)  , INTENT(in   ) ::   phi_ext  ! external forcing data
290      LOGICAL ,                   INTENT(in   ) ::   ll_npo   ! switch for NPO version
291      !
292      INTEGER  ::   jb, jk                                 ! dummy loop indices
293      INTEGER  ::   ii, ij, iibm1, iibm2, ijbm1, ijbm2     ! 2D addresses
294      INTEGER  ::   iijm1, iijp1, ijjm1, ijjp1             ! 2D addresses
295      INTEGER  ::   iibm1jp1, iibm1jm1, ijbm1jp1, ijbm1jm1 ! 2D addresses
296      INTEGER  ::   ii_offset, ij_offset                   ! offsets for mask indices
297      INTEGER  ::   flagu, flagv                           ! short cuts
298      REAL(wp) ::   zmask_x, zmask_y1, zmask_y2
299      REAL(wp) ::   zex1, zex2, zey, zey1, zey2
300      REAL(wp) ::   zdt, zdx, zdy, znor2, zrx, zry         ! intermediate calculations
301      REAL(wp) ::   zout, zwgt, zdy_centred
302      REAL(wp) ::   zdy_1, zdy_2,  zsign_ups
303      REAL(wp), PARAMETER :: zepsilon = 1.e-30                 ! local small value
304      REAL(wp), POINTER, DIMENSION(:,:,:)        :: pmask      ! land/sea mask for field
305      REAL(wp), POINTER, DIMENSION(:,:,:)        :: pmask_xdif ! land/sea mask for x-derivatives
306      REAL(wp), POINTER, DIMENSION(:,:,:)        :: pmask_ydif ! land/sea mask for y-derivatives
307      REAL(wp), POINTER, DIMENSION(:,:)          :: pe_xdif    ! scale factors for x-derivatives
308      REAL(wp), POINTER, DIMENSION(:,:)          :: pe_ydif    ! scale factors for y-derivatives
309      !!----------------------------------------------------------------------
310      !
311      ! ----------------------------------!
312      ! Orlanski boundary conditions     :!
313      ! ----------------------------------!
314      !
315      SELECT CASE(igrd)
316         CASE(1)
317            pmask      => tmask(:,:,:)
318            pmask_xdif => umask(:,:,:)
319            pmask_ydif => vmask(:,:,:)
320            pe_xdif    => e1u(:,:)
321            pe_ydif    => e2v(:,:)
322            ii_offset = 0
323            ij_offset = 0
324         CASE(2)
325            pmask      => umask(:,:,:)
326            pmask_xdif => tmask(:,:,:)
327            pmask_ydif => fmask(:,:,:)
328            pe_xdif    => e1t(:,:)
329            pe_ydif    => e2f(:,:)
330            ii_offset = 1
331            ij_offset = 0
332         CASE(3)
333            pmask      => vmask(:,:,:)
334            pmask_xdif => fmask(:,:,:)
335            pmask_ydif => tmask(:,:,:)
336            pe_xdif    => e1f(:,:)
337            pe_ydif    => e2t(:,:)
338            ii_offset = 0
339            ij_offset = 1
340         CASE DEFAULT ;   CALL ctl_stop( 'unrecognised value for igrd in bdy_orlanksi_2d' )
341      END SELECT
342
343      DO jk = 1, jpk
344         !           
345         DO jb = 1, idx%nblenrim(igrd)
346            ii  = idx%nbi(jb,igrd)
347            ij  = idx%nbj(jb,igrd) 
348            IF( ii == 1 .OR. ii == jpi .OR. ij == 1 .OR. ij == jpj )   CYCLE
349            flagu = int( idx%flagu(jb,igrd) )
350            flagv = int( idx%flagv(jb,igrd) )
351            !
352            ! calculate positions of b-1 and b-2 points for this rim point
353            ! also (b-1,j-1) and (b-1,j+1) points
354            iibm1 = ii + flagu ; iibm2 = ii + 2*flagu 
355            ijbm1 = ij + flagv ; ijbm2 = ij + 2*flagv
356            !
357            iijm1 = ii - abs(flagv) ; iijp1 = ii + abs(flagv) 
358            ijjm1 = ij - abs(flagu) ; ijjp1 = ij + abs(flagu)
359            !
360            iibm1jm1 = ii + flagu - abs(flagv) ; iibm1jp1 = ii + flagu + abs(flagv) 
361            ijbm1jm1 = ij + flagv - abs(flagu) ; ijbm1jp1 = ij + flagv + abs(flagu) 
362            !
363            ! Calculate scale factors for calculation of spatial derivatives.       
364            zex1 = ( abs(iibm1-iibm2) * pe_xdif(iibm1+ii_offset,ijbm1          )         &
365           &       + abs(ijbm1-ijbm2) * pe_ydif(iibm1          ,ijbm1+ij_offset) ) 
366            zex2 = ( abs(iibm1-iibm2) * pe_xdif(iibm2+ii_offset,ijbm2          )         &
367           &       + abs(ijbm1-ijbm2) * pe_ydif(iibm2          ,ijbm2+ij_offset) ) 
368            zey1 = ( (iibm1-iibm1jm1) * pe_xdif(iibm1jm1+ii_offset,ijbm1jm1          )  & 
369           &      +  (ijbm1-ijbm1jm1) * pe_ydif(iibm1jm1          ,ijbm1jm1+ij_offset) ) 
370            zey2 = ( (iibm1jp1-iibm1) * pe_xdif(iibm1+ii_offset,ijbm1)                  &
371           &      +  (ijbm1jp1-ijbm1) * pe_ydif(iibm1          ,ijbm1+ij_offset) ) 
372            ! make sure scale factors are nonzero
373            if( zey1 .lt. rsmall ) zey1 = zey2
374            if( zey2 .lt. rsmall ) zey2 = zey1
375            zex1 = max(zex1,rsmall); zex2 = max(zex2,rsmall); 
376            zey1 = max(zey1,rsmall); zey2 = max(zey2,rsmall); 
377            !
378            ! Calculate masks for calculation of spatial derivatives.       
379            zmask_x = ( abs(iibm1-iibm2) * pmask_xdif(iibm2+ii_offset,ijbm2          ,jk)          &
380           &          + abs(ijbm1-ijbm2) * pmask_ydif(iibm2          ,ijbm2+ij_offset,jk) ) 
381            zmask_y1 = ( (iibm1-iibm1jm1) * pmask_xdif(iibm1jm1+ii_offset,ijbm1jm1          ,jk)   & 
382           &          +  (ijbm1-ijbm1jm1) * pmask_ydif(iibm1jm1          ,ijbm1jm1+ij_offset,jk) ) 
383            zmask_y2 = ( (iibm1jp1-iibm1) * pmask_xdif(iibm1+ii_offset,ijbm1          ,jk)         &
384           &          +  (ijbm1jp1-ijbm1) * pmask_ydif(iibm1          ,ijbm1+ij_offset,jk) ) 
385            !
386            ! Calculate normal (zrx) and tangential (zry) components of radiation velocities.
387            ! Mask derivatives to ensure correct land boundary conditions for each variable.
388            ! Centred derivative is calculated as average of "left" and "right" derivatives for
389            ! this reason.
390            zdt = phia(iibm1,ijbm1,jk) - phib(iibm1,ijbm1,jk)
391            zdx = ( ( phia(iibm1,ijbm1,jk) - phia(iibm2,ijbm2,jk) ) / zex2 ) * zmask_x                 
392            zdy_1 = ( ( phib(iibm1   ,ijbm1   ,jk) - phib(iibm1jm1,ijbm1jm1,jk) ) / zey1 ) * zmask_y1 
393            zdy_2 = ( ( phib(iibm1jp1,ijbm1jp1,jk) - phib(iibm1   ,ijbm1   ,jk) ) / zey2 ) * zmask_y2     
394            zdy_centred = 0.5 * ( zdy_1 + zdy_2 )
395!!$            zdy_centred = phib(iibm1jp1,ijbm1jp1,jk) - phib(iibm1jm1,ijbm1jm1,jk)
396            ! upstream differencing for tangential derivatives
397            zsign_ups = sign( 1., zdt * zdy_centred )
398            zsign_ups = 0.5*( zsign_ups + abs(zsign_ups) )
399            zdy = zsign_ups * zdy_1 + (1. - zsign_ups) * zdy_2
400            znor2 = zdx * zdx + zdy * zdy
401            znor2 = max(znor2,zepsilon)
402            !
403            ! update boundary value:
404            zrx = zdt * zdx / ( zex1 * znor2 )
405!!$            zrx = min(zrx,2.0_wp)
406            zout = sign( 1., zrx )
407            zout = 0.5*( zout + abs(zout) )
408            zwgt = 2.*rdt*( (1.-zout) * idx%nbd(jb,igrd) + zout * idx%nbdout(jb,igrd) )
409            ! only apply radiation on outflow points
410            if( ll_npo ) then     !! NPO version !!
411               phia(ii,ij,jk) = (1.-zout) * ( phib(ii,ij,jk) + zwgt * ( phi_ext(jb,jk) - phib(ii,ij,jk) ) ) &
412              &               + zout      * ( phib(ii,ij,jk) + zrx*phia(iibm1,ijbm1,jk)                     &
413              &                            + zwgt * ( phi_ext(jb,jk) - phib(ii,ij,jk) ) ) / ( 1. + zrx ) 
414            else                  !! full oblique radiation !!
415               zsign_ups = sign( 1., zdt * zdy )
416               zsign_ups = 0.5*( zsign_ups + abs(zsign_ups) )
417               zey = zsign_ups * zey1 + (1.-zsign_ups) * zey2 
418               zry = zdt * zdy / ( zey * znor2 ) 
419               phia(ii,ij,jk) = (1.-zout) * ( phib(ii,ij,jk) + zwgt * ( phi_ext(jb,jk) - phib(ii,ij,jk) ) )    &
420              &               + zout      * ( phib(ii,ij,jk) + zrx*phia(iibm1,ijbm1,jk)                        &
421              &                       - zsign_ups      * zry * ( phib(ii   ,ij   ,jk) - phib(iijm1,ijjm1,jk) ) &
422              &                       - (1.-zsign_ups) * zry * ( phib(iijp1,ijjp1,jk) - phib(ii   ,ij   ,jk) ) &
423              &                       + zwgt * ( phi_ext(jb,jk) - phib(ii,ij,jk) ) ) / ( 1. + zrx ) 
424            end if
425            phia(ii,ij,jk) = phia(ii,ij,jk) * pmask(ii,ij,jk)
426         END DO
427         !
428      END DO
429      !
430   END SUBROUTINE bdy_orlanski_3d
431
432   SUBROUTINE bdy_nmn( idx, igrd, phia )
433      !!----------------------------------------------------------------------
434      !!                 ***  SUBROUTINE bdy_nmn  ***
435      !!                   
436      !! ** Purpose : Duplicate the value at open boundaries, zero gradient.
437      !!
438      !!
439      !! ** Method  : - take the average of free ocean neighbours
440      !!
441      !!      ___   !   |_____|   !   ___|    !   __|x o   !   |_   _|     ! |     
442      !!   __|x     !      x      !     x o   !      o     !     |_|       ! |x o   
443      !!      o     !      o      !     o     !            !    o x o      ! |x_x_
444      !!                                                   !      o     
445      !!----------------------------------------------------------------------
446      INTEGER,                    INTENT(in)     ::   igrd     ! grid index
447      REAL(wp), DIMENSION(:,:,:), INTENT(inout)  ::   phia     ! model after 3D field (to be updated), must be masked
448      TYPE(OBC_INDEX), INTENT(in) ::   idx  ! OBC indices
449      !!
450      REAL(wp) ::   zweight
451      REAL(wp), POINTER, DIMENSION(:,:,:)      :: pmask         ! land/sea mask for field
452      INTEGER  ::   ib, ik   ! dummy loop indices
453      INTEGER  ::   ii, ij   ! 2D addresses
454      INTEGER  ::   ipkm1    ! size of phia third dimension minus 1
455      INTEGER  ::   ii1, ii2, ii3, ij1, ij2, ij3, itreat
456      !!----------------------------------------------------------------------
457      !
458      ipkm1 = MAX( SIZE(phia,3) - 1, 1 ) 
459      !
460      SELECT CASE(igrd)
461         CASE(1)   ;   pmask => tmask(:,:,:)
462         CASE(2)   ;   pmask => umask(:,:,:)
463         CASE(3)   ;   pmask => vmask(:,:,:)
464         CASE DEFAULT ;   CALL ctl_stop( 'unrecognised value for igrd in bdy_nmn' )
465      END SELECT
466      !
467      DO ib = 1, idx%nblenrim(igrd)
468         ii = idx%nbi(ib,igrd)
469         ij = idx%nbj(ib,igrd)
470         itreat = idx%ntreat(ib,igrd)
471         CALL find_neib( ii, ij, itreat, ii1, ij1, ii2, ij2, ii3, ij3 )
472         SELECT CASE( itreat )
473         CASE( 1:8 )
474            IF( ii1 < 1 .OR. ii1 > jpi .OR. ij1 < 1 .OR. ij1 > jpj )   CYCLE
475            DO ik = 1, ipkm1
476               IF( pmask(ii1,ij1,ik) /= 0. )   phia(ii,ij,ik) = phia(ii1,ij1,ik) 
477            END DO
478         CASE( 9:12 )
479            IF( ii1 < 1 .OR. ii1 > jpi .OR. ij1 < 1 .OR. ij1 > jpj )   CYCLE
480            IF( ii2 < 1 .OR. ii2 > jpi .OR. ij2 < 1 .OR. ij2 > jpj )   CYCLE
481            DO ik = 1, ipkm1
482               zweight = pmask(ii1,ij1,ik) + pmask(ii2,ij2,ik)
483               IF( zweight /= 0. )   phia(ii,ij,ik) = ( phia(ii1,ij1,ik) + phia(ii2,ij2,ik) ) / zweight
484            END DO
485         CASE( 13:16 )
486            IF( ii1 < 1 .OR. ii1 > jpi .OR. ij1 < 1 .OR. ij1 > jpj )   CYCLE
487            IF( ii2 < 1 .OR. ii2 > jpi .OR. ij2 < 1 .OR. ij2 > jpj )   CYCLE
488            IF( ii3 < 1 .OR. ii3 > jpi .OR. ij3 < 1 .OR. ij3 > jpj )   CYCLE
489            DO ik = 1, ipkm1
490               zweight = pmask(ii1,ij1,ik) + pmask(ii2,ij2,ik) + pmask(ii3,ij3,ik)
491               IF( zweight /= 0. )   phia(ii,ij,ik) = ( phia(ii1,ij1,ik) + phia(ii2,ij2,ik) + phia(ii3,ij3,ik) ) / zweight
492            END DO
493         END SELECT
494      END DO
495      !
496   END SUBROUTINE bdy_nmn
497
498   !!======================================================================
499END MODULE bdylib
Note: See TracBrowser for help on using the repository browser.