source: NEMO/branches/2019/dev_r10984_HPC-13_IRRMANN_BDY_optimization/src/OCE/BDY/bdytra.F90 @ 11048

Last change on this file since 11048 was 11048, checked in by girrmann, 19 months ago

dev_r10984_HPC-13 : Step 1, boundary is now detected all over the local domain, this does not change the result. Improve bdy treatment for bdy_rnf in bdytra.F90, this changes the result when keyword runoff is specified in namelist

  • Property svn:keywords set to Id
File size: 7.0 KB
Line 
1MODULE bdytra
2   !!======================================================================
3   !!                       ***  MODULE  bdytra  ***
4   !! Ocean tracers:   Apply boundary conditions for tracers
5   !!======================================================================
6   !! History :  1.0  !  2005-01  (J. Chanut, A. Sellar)  Original code
7   !!            3.0  !  2008-04  (NEMO team)  add in the reference version
8   !!            3.4  !  2011     (D. Storkey) rewrite in preparation for OBC-BDY merge
9   !!            3.5  !  2012     (S. Mocavero, I. Epicoco) Optimization of BDY communications
10   !!            4.0  !  2016     (T. Lovato) Generalize OBC structure
11   !!----------------------------------------------------------------------
12   !!   bdy_tra       : Apply open boundary conditions & damping to T and S
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers variables
15   USE dom_oce        ! ocean space and time domain variables
16   USE bdy_oce        ! ocean open boundary conditions
17   USE bdylib         ! for orlanski library routines
18   !
19   USE in_out_manager ! I/O manager
20   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
21   USE lib_mpp, ONLY: ctl_stop
22   USE timing         ! Timing
23
24   IMPLICIT NONE
25   PRIVATE
26
27   ! Local structure to rearrange tracers data
28   TYPE, PUBLIC ::   ztrabdy
29      REAL(wp), POINTER, DIMENSION(:,:) ::  tra
30   END TYPE
31
32   PUBLIC   bdy_tra      ! called in tranxt.F90
33   PUBLIC   bdy_tra_dmp  ! called in step.F90
34
35   !!----------------------------------------------------------------------
36   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
37   !! $Id$
38   !! Software governed by the CeCILL license (see ./LICENSE)
39   !!----------------------------------------------------------------------
40CONTAINS
41
42   SUBROUTINE bdy_tra( kt )
43      !!----------------------------------------------------------------------
44      !!                  ***  SUBROUTINE bdy_tra  ***
45      !!
46      !! ** Purpose : - Apply open boundary conditions for temperature and salinity
47      !!
48      !!----------------------------------------------------------------------
49      INTEGER, INTENT(in) ::   kt   ! Main time step counter
50      !
51      INTEGER                        :: ib_bdy, jn, igrd   ! Loop indeces
52      TYPE(ztrabdy), DIMENSION(jpts) :: zdta               ! Temporary data structure
53      !!----------------------------------------------------------------------
54      igrd = 1 
55
56      DO ib_bdy=1, nb_bdy
57         !
58         zdta(1)%tra => dta_bdy(ib_bdy)%tem
59         zdta(2)%tra => dta_bdy(ib_bdy)%sal
60         !
61         DO jn = 1, jpts
62            !
63            SELECT CASE( TRIM(cn_tra(ib_bdy)) )
64            CASE('none'        )   ;   CYCLE
65            CASE('frs'         )   ;   CALL bdy_frs ( idx_bdy(ib_bdy),                tsa(:,:,:,jn), zdta(jn)%tra )
66            CASE('specified'   )   ;   CALL bdy_spe ( idx_bdy(ib_bdy),                tsa(:,:,:,jn), zdta(jn)%tra )
67            CASE('neumann'     )   ;   CALL bdy_nmn ( idx_bdy(ib_bdy), igrd         , tsa(:,:,:,jn)               )   ! tsa masked
68            CASE('orlanski'    )   ;   CALL bdy_orl ( idx_bdy(ib_bdy), tsb(:,:,:,jn), tsa(:,:,:,jn), zdta(jn)%tra, ll_npo=.false. )
69            CASE('orlanski_npo')   ;   CALL bdy_orl ( idx_bdy(ib_bdy), tsb(:,:,:,jn), tsa(:,:,:,jn), zdta(jn)%tra, ll_npo=.true. )
70            CASE('runoff'      )   ;   CALL bdy_rnf ( idx_bdy(ib_bdy),                tsa(:,:,:,jn),               jn )
71            CASE DEFAULT           ;   CALL ctl_stop( 'bdy_tra : unrecognised option for open boundaries for T and S' )
72            END SELECT
73            ! Boundary points should be updated
74            CALL lbc_bdy_lnk( 'bdytra', tsa(:,:,:,jn), 'T', 1., ib_bdy )
75            !
76         END DO
77      END DO
78      !
79   END SUBROUTINE bdy_tra
80
81
82   SUBROUTINE bdy_rnf( idx, pta, jpa )
83      !!----------------------------------------------------------------------
84      !!                 ***  SUBROUTINE bdy_rnf  ***
85      !!                   
86      !! ** Purpose : Specialized routine to apply TRA runoff values at OBs:
87      !!                  - duplicate the neighbour value for the temperature
88      !!                  - specified to 0.1 PSU for the salinity
89      !!
90      !!----------------------------------------------------------------------
91      TYPE(OBC_INDEX),                     INTENT(in) ::   idx  ! OBC indices
92      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pta  ! tracer trend
93      INTEGER,                             INTENT(in) ::   jpa  ! TRA index
94      !
95      INTEGER  ::   ib, ii, ij, igrd   ! dummy loop indices
96      INTEGER  ::   ik, ip, jp ! 2D addresses
97      !!----------------------------------------------------------------------
98      !
99      igrd = 1                       ! Everything is at T-points here
100      IF(      jpa == jp_tem )   THEN
101         CALL bdy_nmn( idx, igrd, pta )
102      ELSE IF( jpa == jp_sal )   THEN
103         DO ib = 1, idx%nblenrim(igrd)
104            ii = idx%nbi(ib,igrd)
105            ij = idx%nbj(ib,igrd)
106            IF( ii == 1 .OR. ii == jpi .OR. ij == 1 .OR. ij == jpj )  CYCLE   ! to remove
107            pta(ii,ij,1:jpkm1) = 0.1 * tmask(ii,ij,1:jpkm1)
108         END DO
109      END IF
110      !
111   END SUBROUTINE bdy_rnf
112
113
114   SUBROUTINE bdy_tra_dmp( kt )
115      !!----------------------------------------------------------------------
116      !!                 ***  SUBROUTINE bdy_tra_dmp  ***
117      !!                   
118      !! ** Purpose : Apply damping for tracers at open boundaries.
119      !!
120      !!----------------------------------------------------------------------
121      INTEGER, INTENT(in) ::   kt   !
122      !
123      REAL(wp) ::   zwgt           ! boundary weight
124      REAL(wp) ::   zta, zsa, ztime
125      INTEGER  ::   ib, ik, igrd   ! dummy loop indices
126      INTEGER  ::   ii, ij         ! 2D addresses
127      INTEGER  ::   ib_bdy         ! Loop index
128      !!----------------------------------------------------------------------
129      !
130      IF( ln_timing )   CALL timing_start('bdy_tra_dmp')
131      !
132      DO ib_bdy = 1, nb_bdy
133         IF( ln_tra_dmp(ib_bdy) ) THEN
134            igrd = 1                       ! Everything is at T-points here
135            DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
136               ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
137               ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
138               IF( ii == 1 .OR. ii == jpi .OR. ij == 1 .OR. ij == jpj )  CYCLE   ! to remove
139               zwgt = idx_bdy(ib_bdy)%nbd(ib,igrd)
140               DO ik = 1, jpkm1
141                  zta = zwgt * ( dta_bdy(ib_bdy)%tem(ib,ik) - tsb(ii,ij,ik,jp_tem) ) * tmask(ii,ij,ik)
142                  zsa = zwgt * ( dta_bdy(ib_bdy)%sal(ib,ik) - tsb(ii,ij,ik,jp_sal) ) * tmask(ii,ij,ik)
143                  tsa(ii,ij,ik,jp_tem) = tsa(ii,ij,ik,jp_tem) + zta
144                  tsa(ii,ij,ik,jp_sal) = tsa(ii,ij,ik,jp_sal) + zsa
145               END DO
146            END DO
147         ENDIF
148      END DO
149      !
150      IF( ln_timing )   CALL timing_stop('bdy_tra_dmp')
151      !
152   END SUBROUTINE bdy_tra_dmp
153 
154   !!======================================================================
155END MODULE bdytra
Note: See TracBrowser for help on using the repository browser.