New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
bdytra.F90 in NEMO/branches/2019/dev_r10984_HPC-13_IRRMANN_BDY_optimization/src/OCE/BDY – NEMO

source: NEMO/branches/2019/dev_r10984_HPC-13_IRRMANN_BDY_optimization/src/OCE/BDY/bdytra.F90 @ 11071

Last change on this file since 11071 was 11071, checked in by girrmann, 5 years ago

dev_r10984_HPC-13 : step 2, remove unneeded communications, see #2285

  • Property svn:keywords set to Id
File size: 7.7 KB
Line 
1MODULE bdytra
2   !!======================================================================
3   !!                       ***  MODULE  bdytra  ***
4   !! Ocean tracers:   Apply boundary conditions for tracers
5   !!======================================================================
6   !! History :  1.0  !  2005-01  (J. Chanut, A. Sellar)  Original code
7   !!            3.0  !  2008-04  (NEMO team)  add in the reference version
8   !!            3.4  !  2011     (D. Storkey) rewrite in preparation for OBC-BDY merge
9   !!            3.5  !  2012     (S. Mocavero, I. Epicoco) Optimization of BDY communications
10   !!            4.0  !  2016     (T. Lovato) Generalize OBC structure
11   !!----------------------------------------------------------------------
12   !!   bdy_tra       : Apply open boundary conditions & damping to T and S
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers variables
15   USE dom_oce        ! ocean space and time domain variables
16   USE bdy_oce        ! ocean open boundary conditions
17   USE bdylib         ! for orlanski library routines
18   !
19   USE in_out_manager ! I/O manager
20   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
21   USE lib_mpp, ONLY: ctl_stop
22   USE timing         ! Timing
23
24   IMPLICIT NONE
25   PRIVATE
26
27   ! Local structure to rearrange tracers data
28   TYPE, PUBLIC ::   ztrabdy
29      REAL(wp), POINTER, DIMENSION(:,:) ::  tra
30   END TYPE
31
32   PUBLIC   bdy_tra      ! called in tranxt.F90
33   PUBLIC   bdy_tra_dmp  ! called in step.F90
34
35   !!----------------------------------------------------------------------
36   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
37   !! $Id$
38   !! Software governed by the CeCILL license (see ./LICENSE)
39   !!----------------------------------------------------------------------
40CONTAINS
41
42   SUBROUTINE bdy_tra( kt )
43      !!----------------------------------------------------------------------
44      !!                  ***  SUBROUTINE bdy_tra  ***
45      !!
46      !! ** Purpose : - Apply open boundary conditions for temperature and salinity
47      !!
48      !!----------------------------------------------------------------------
49      INTEGER, INTENT(in) ::   kt   ! Main time step counter
50      !
51      INTEGER                        :: ib_bdy, jn, igrd   ! Loop indeces
52      TYPE(ztrabdy), DIMENSION(jpts) :: zdta               ! Temporary data structure
53      LOGICAL, DIMENSION(4)          :: llsend1, llrecv1     ! indicate how communications are to be carried out
54      !!----------------------------------------------------------------------
55      igrd = 1 
56
57      DO ib_bdy=1, nb_bdy
58         !
59         zdta(1)%tra => dta_bdy(ib_bdy)%tem
60         zdta(2)%tra => dta_bdy(ib_bdy)%sal
61         !
62         DO jn = 1, jpts
63            !
64            SELECT CASE( TRIM(cn_tra(ib_bdy)) )
65            CASE('none'        )   ;   CYCLE
66            CASE('frs'         )   ;   CALL bdy_frs ( idx_bdy(ib_bdy),                tsa(:,:,:,jn), zdta(jn)%tra )
67            CASE('specified'   )   ;   CALL bdy_spe ( idx_bdy(ib_bdy),                tsa(:,:,:,jn), zdta(jn)%tra )
68            CASE('neumann'     )   ;   CALL bdy_nmn ( idx_bdy(ib_bdy), igrd         , tsa(:,:,:,jn)               )   ! tsa masked
69            CASE('orlanski'    )   ;   CALL bdy_orl ( idx_bdy(ib_bdy), tsb(:,:,:,jn), tsa(:,:,:,jn), zdta(jn)%tra, ll_npo=.false. )
70            CASE('orlanski_npo')   ;   CALL bdy_orl ( idx_bdy(ib_bdy), tsb(:,:,:,jn), tsa(:,:,:,jn), zdta(jn)%tra, ll_npo=.true. )
71            CASE('runoff'      )   ;   CALL bdy_rnf ( idx_bdy(ib_bdy),                tsa(:,:,:,jn),               jn )
72            CASE DEFAULT           ;   CALL ctl_stop( 'bdy_tra : unrecognised option for open boundaries for T and S' )
73            END SELECT
74            !
75         END DO
76      END DO
77      !
78      llsend1(:) = .false.
79      llrecv1(:) = .false.
80      DO ib_bdy=1, nb_bdy
81         SELECT CASE( TRIM(cn_tra(ib_bdy)) )
82         CASE('neumann','runoff')
83            llsend1(:) = llsend1(:) .OR. lsend_bdyint(ib_bdy,1,:)   ! possibly every direction, T points
84            llrecv1(:) = llrecv1(:) .OR. lrecv_bdyint(ib_bdy,1,:)   ! possibly every direction, T points
85         CASE('orlanski', 'orlanski_npo')
86            llsend1(:) = llsend1(:) .OR. lsend_bdy(ib_bdy,1,:)   ! possibly every direction, T points
87            llrecv1(:) = llrecv1(:) .OR. lrecv_bdy(ib_bdy,1,:)   ! possibly every direction, T points
88         END SELECT
89      END DO
90      IF( ANY(llsend1) .OR. ANY(llrecv1) ) THEN   ! if need to send/recv in at least one direction
91         CALL lbc_bdy_lnk( 'bdytra', llsend1, llrecv1, tsa, 'T',  1. )
92      END IF
93      !
94   END SUBROUTINE bdy_tra
95
96
97   SUBROUTINE bdy_rnf( idx, pta, jpa )
98      !!----------------------------------------------------------------------
99      !!                 ***  SUBROUTINE bdy_rnf  ***
100      !!                   
101      !! ** Purpose : Specialized routine to apply TRA runoff values at OBs:
102      !!                  - duplicate the neighbour value for the temperature
103      !!                  - specified to 0.1 PSU for the salinity
104      !!
105      !!----------------------------------------------------------------------
106      TYPE(OBC_INDEX),                     INTENT(in) ::   idx  ! OBC indices
107      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pta  ! tracer trend
108      INTEGER,                             INTENT(in) ::   jpa  ! TRA index
109      !
110      INTEGER  ::   ib, ii, ij, igrd   ! dummy loop indices
111      INTEGER  ::   ik, ip, jp ! 2D addresses
112      !!----------------------------------------------------------------------
113      !
114      igrd = 1                       ! Everything is at T-points here
115      IF(      jpa == jp_tem )   THEN
116         CALL bdy_nmn( idx, igrd, pta )
117      ELSE IF( jpa == jp_sal )   THEN
118         DO ib = 1, idx%nblenrim(igrd)
119            ii = idx%nbi(ib,igrd)
120            ij = idx%nbj(ib,igrd)
121            pta(ii,ij,1:jpkm1) = 0.1 * tmask(ii,ij,1:jpkm1)
122         END DO
123      END IF
124      !
125   END SUBROUTINE bdy_rnf
126
127
128   SUBROUTINE bdy_tra_dmp( kt )
129      !!----------------------------------------------------------------------
130      !!                 ***  SUBROUTINE bdy_tra_dmp  ***
131      !!                   
132      !! ** Purpose : Apply damping for tracers at open boundaries.
133      !!
134      !!----------------------------------------------------------------------
135      INTEGER, INTENT(in) ::   kt   !
136      !
137      REAL(wp) ::   zwgt           ! boundary weight
138      REAL(wp) ::   zta, zsa, ztime
139      INTEGER  ::   ib, ik, igrd   ! dummy loop indices
140      INTEGER  ::   ii, ij         ! 2D addresses
141      INTEGER  ::   ib_bdy         ! Loop index
142      !!----------------------------------------------------------------------
143      !
144      IF( ln_timing )   CALL timing_start('bdy_tra_dmp')
145      !
146      DO ib_bdy = 1, nb_bdy
147         IF( ln_tra_dmp(ib_bdy) ) THEN
148            igrd = 1                       ! Everything is at T-points here
149            DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
150               ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
151               ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
152               zwgt = idx_bdy(ib_bdy)%nbd(ib,igrd)
153               DO ik = 1, jpkm1
154                  zta = zwgt * ( dta_bdy(ib_bdy)%tem(ib,ik) - tsb(ii,ij,ik,jp_tem) ) * tmask(ii,ij,ik)
155                  zsa = zwgt * ( dta_bdy(ib_bdy)%sal(ib,ik) - tsb(ii,ij,ik,jp_sal) ) * tmask(ii,ij,ik)
156                  tsa(ii,ij,ik,jp_tem) = tsa(ii,ij,ik,jp_tem) + zta
157                  tsa(ii,ij,ik,jp_sal) = tsa(ii,ij,ik,jp_sal) + zsa
158               END DO
159            END DO
160         ENDIF
161      END DO
162      !
163      IF( ln_timing )   CALL timing_stop('bdy_tra_dmp')
164      !
165   END SUBROUTINE bdy_tra_dmp
166 
167   !!======================================================================
168END MODULE bdytra
Note: See TracBrowser for help on using the repository browser.