New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
diaharm.F90 in NEMO/branches/2019/dev_r10984_HPC-13_IRRMANN_BDY_optimization/src/OCE/DIA – NEMO

source: NEMO/branches/2019/dev_r10984_HPC-13_IRRMANN_BDY_optimization/src/OCE/DIA/diaharm.F90 @ 11365

Last change on this file since 11365 was 11365, checked in by clem, 5 years ago

Remove key_diaharm and key_diadct. Replace namdct by nam_diadct

  • Property svn:keywords set to Id
File size: 18.5 KB
Line 
1MODULE diaharm 
2   !!======================================================================
3   !!                       ***  MODULE  diaharm  ***
4   !! Harmonic analysis of tidal constituents
5   !!======================================================================
6   !! History :  3.1  !  2007  (O. Le Galloudec, J. Chanut)  Original code
7   !!----------------------------------------------------------------------
8   USE oce             ! ocean dynamics and tracers variables
9   USE dom_oce         ! ocean space and time domain
10   USE phycst
11   USE daymod
12   USE tide_mod
13   USE sbctide         ! Tidal forcing or not
14   !
15   USE in_out_manager  ! I/O units
16   USE iom             ! I/0 library
17   USE ioipsl          ! NetCDF IPSL library
18   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
19   USE timing          ! preformance summary
20   USE lib_mpp           ! MPP library
21
22   IMPLICIT NONE
23   PRIVATE
24   
25   INTEGER, PARAMETER :: jpincomax    = 2.*jpmax_harmo
26   INTEGER, PARAMETER :: jpdimsparse  = jpincomax*300*24
27
28   !                         !!** namelist variables **
29   LOGICAL, PUBLIC ::   ln_diaharm    ! Choose tidal harmonic output or not
30   INTEGER         ::   nit000_han    ! First time step used for harmonic analysis
31   INTEGER         ::   nitend_han    ! Last time step used for harmonic analysis
32   INTEGER         ::   nstep_han     ! Time step frequency for harmonic analysis
33   INTEGER         ::   nb_ana        ! Number of harmonics to analyse
34
35   INTEGER , ALLOCATABLE, DIMENSION(:)       ::   name
36   REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:) ::   ana_temp
37   REAL(wp), ALLOCATABLE, DIMENSION(:)       ::   ana_freq, ut   , vt   , ft
38   REAL(wp), ALLOCATABLE, DIMENSION(:,:,:)   ::   out_eta , out_u, out_v
39
40   INTEGER ::   ninco, nsparse
41   INTEGER ,       DIMENSION(jpdimsparse)         ::   njsparse, nisparse
42   INTEGER , SAVE, DIMENSION(jpincomax)           ::   ipos1
43   REAL(wp),       DIMENSION(jpdimsparse)         ::   valuesparse
44   REAL(wp),       DIMENSION(jpincomax)           ::   ztmp4 , ztmp7
45   REAL(wp), SAVE, DIMENSION(jpincomax,jpincomax) ::   ztmp3 , zpilier
46   REAL(wp), SAVE, DIMENSION(jpincomax)           ::   zpivot
47
48   CHARACTER (LEN=4), DIMENSION(jpmax_harmo) ::   tname   ! Names of tidal constituents ('M2', 'K1',...)
49
50   PUBLIC   dia_harm        ! routine called by step.F90
51   PUBLIC   dia_harm_init   ! routine called by nemogcm.F90
52
53   !!----------------------------------------------------------------------
54   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
55   !! $Id$
56   !! Software governed by the CeCILL license (see ./LICENSE)
57   !!----------------------------------------------------------------------
58CONTAINS
59
60   SUBROUTINE dia_harm_init 
61      !!----------------------------------------------------------------------
62      !!                 ***  ROUTINE dia_harm_init  ***
63      !!         
64      !! ** Purpose :   Initialization of tidal harmonic analysis
65      !!
66      !! ** Method  :   Initialize frequency array and  nodal factor for nit000_han
67      !!
68      !!--------------------------------------------------------------------
69      INTEGER ::   jh, nhan, ji
70      INTEGER ::   ios                 ! Local integer output status for namelist read
71
72      NAMELIST/nam_diaharm/ ln_diaharm, nit000_han, nitend_han, nstep_han, tname
73      !!----------------------------------------------------------------------
74
75      IF(lwp) THEN
76         WRITE(numout,*)
77         WRITE(numout,*) 'dia_harm_init: Tidal harmonic analysis initialization'
78         WRITE(numout,*) '~~~~~~~ '
79      ENDIF
80      !
81      IF( .NOT. ln_tide )   CALL ctl_stop( 'dia_harm_init : ln_tide must be true for harmonic analysis')
82      !
83      REWIND( numnam_ref )              ! Namelist nam_diaharm in reference namelist : Tidal harmonic analysis
84      READ  ( numnam_ref, nam_diaharm, IOSTAT = ios, ERR = 901)
85901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nam_diaharm in reference namelist' )
86      REWIND( numnam_cfg )              ! Namelist nam_diaharm in configuration namelist : Tidal harmonic analysis
87      READ  ( numnam_cfg, nam_diaharm, IOSTAT = ios, ERR = 902 )
88902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nam_diaharm in configuration namelist' )
89      IF(lwm) WRITE ( numond, nam_diaharm )
90      !
91      IF(lwp) THEN
92         WRITE(numout,*) 'Tidal diagnostics = ', ln_diaharm
93         WRITE(numout,*) '   First time step used for analysis:         nit000_han= ', nit000_han
94         WRITE(numout,*) '   Last  time step used for analysis:         nitend_han= ', nitend_han
95         WRITE(numout,*) '   Time step frequency for harmonic analysis: nstep_han = ', nstep_han
96      ENDIF
97
98      IF( ln_diaharm ) THEN
99
100         CALL tide_init_Wave
101         !
102         ! Basic checks on harmonic analysis time window:
103         ! ----------------------------------------------
104         IF( nit000 > nit000_han )   CALL ctl_stop( 'dia_harm_init : nit000_han must be greater than nit000',   &
105            &                                       ' restart capability not implemented' )
106         IF( nitend < nitend_han )   CALL ctl_stop( 'dia_harm_init : nitend_han must be lower than nitend',   &
107            &                                       'restart capability not implemented' )
108
109         IF( MOD( nitend_han-nit000_han+1 , nstep_han ) /= 0 )   &
110            &                        CALL ctl_stop( 'dia_harm_init : analysis time span must be a multiple of nstep_han' )
111         !
112         nb_ana = 0
113         DO jh=1,jpmax_harmo
114            DO ji=1,jpmax_harmo
115               IF(TRIM(tname(jh)) == Wave(ji)%cname_tide) THEN
116                  nb_ana=nb_ana+1
117               ENDIF
118            END DO
119         END DO
120         !
121         IF(lwp) THEN
122            WRITE(numout,*) '        Namelist nam_diaharm'
123            WRITE(numout,*) '        nb_ana    = ', nb_ana
124            CALL flush(numout)
125         ENDIF
126         !
127         IF (nb_ana > jpmax_harmo) THEN
128            WRITE(ctmp1,*) ' nb_ana must be lower than jpmax_harmo'
129            WRITE(ctmp2,*) ' jpmax_harmo= ', jpmax_harmo
130            CALL ctl_stop( 'dia_harm_init', ctmp1, ctmp2 )
131         ENDIF
132
133         ALLOCATE(name    (nb_ana))
134         DO jh=1,nb_ana
135            DO ji=1,jpmax_harmo
136               IF (TRIM(tname(jh)) ==  Wave(ji)%cname_tide) THEN
137                  name(jh) = ji
138                  EXIT
139               END IF
140            END DO
141         END DO
142
143         ! Initialize frequency array:
144         ! ---------------------------
145         ALLOCATE( ana_freq(nb_ana), ut(nb_ana), vt(nb_ana), ft(nb_ana) )
146
147         CALL tide_harmo( ana_freq, vt, ut, ft, name, nb_ana )
148
149         IF(lwp) WRITE(numout,*) 'Analysed frequency  : ',nb_ana ,'Frequency '
150
151         DO jh = 1, nb_ana
152            IF(lwp) WRITE(numout,*) '                    : ',tname(jh),' ',ana_freq(jh)
153         END DO
154
155         ! Initialize temporary arrays:
156         ! ----------------------------
157         ALLOCATE( ana_temp(jpi,jpj,2*nb_ana,3) )
158         ana_temp(:,:,:,:) = 0._wp
159
160      ENDIF
161
162   END SUBROUTINE dia_harm_init
163
164
165   SUBROUTINE dia_harm ( kt )
166      !!----------------------------------------------------------------------
167      !!                 ***  ROUTINE dia_harm  ***
168      !!         
169      !! ** Purpose :   Tidal harmonic analysis main routine
170      !!
171      !! ** Action  :   Sums ssh/u/v over time analysis [nit000_han,nitend_han]
172      !!
173      !!--------------------------------------------------------------------
174      INTEGER, INTENT( IN ) :: kt
175      !
176      INTEGER  :: ji, jj, jh, jc, nhc
177      REAL(wp) :: ztime, ztemp
178      !!--------------------------------------------------------------------
179      IF( ln_timing )   CALL timing_start('dia_harm')
180      !
181      IF( kt >= nit000_han .AND. kt <= nitend_han .AND. MOD(kt,nstep_han) == 0 ) THEN
182         !
183         ztime = (kt-nit000+1) * rdt 
184         !
185         nhc = 0
186         DO jh = 1, nb_ana
187            DO jc = 1, 2
188               nhc = nhc+1
189               ztemp =(     MOD(jc,2) * ft(jh) *COS(ana_freq(jh)*ztime + vt(jh) + ut(jh))  &
190                  &    +(1.-MOD(jc,2))* ft(jh) *SIN(ana_freq(jh)*ztime + vt(jh) + ut(jh)))
191                  !
192               DO jj = 1,jpj
193                  DO ji = 1,jpi
194                     ! Elevation
195                     ana_temp(ji,jj,nhc,1) = ana_temp(ji,jj,nhc,1) + ztemp*sshn(ji,jj)*ssmask (ji,jj)       
196                     ana_temp(ji,jj,nhc,2) = ana_temp(ji,jj,nhc,2) + ztemp*un_b(ji,jj)*ssumask(ji,jj)
197                     ana_temp(ji,jj,nhc,3) = ana_temp(ji,jj,nhc,3) + ztemp*vn_b(ji,jj)*ssvmask(ji,jj)
198                  END DO
199               END DO
200               !
201            END DO
202         END DO
203         !       
204      END IF
205      !
206      IF( kt == nitend_han )   CALL dia_harm_end
207      !
208      IF( ln_timing )   CALL timing_stop('dia_harm')
209      !
210   END SUBROUTINE dia_harm
211
212
213   SUBROUTINE dia_harm_end
214      !!----------------------------------------------------------------------
215      !!                 ***  ROUTINE diaharm_end  ***
216      !!         
217      !! ** Purpose :  Compute the Real and Imaginary part of tidal constituents
218      !!
219      !! ** Action  :  Decompose the signal on the harmonic constituents
220      !!
221      !!--------------------------------------------------------------------
222      INTEGER :: ji, jj, jh, jc, jn, nhan, jl
223      INTEGER :: ksp, kun, keq
224      REAL(wp) :: ztime, ztime_ini, ztime_end
225      REAL(wp) :: X1, X2
226      REAL(wp), DIMENSION(jpi,jpj,jpmax_harmo,2) ::   ana_amp   ! workspace
227      !!--------------------------------------------------------------------
228      !
229      IF(lwp) WRITE(numout,*)
230      IF(lwp) WRITE(numout,*) 'anharmo_end: kt=nitend_han: Perform harmonic analysis'
231      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~'
232
233      ztime_ini = nit000_han*rdt                 ! Initial time in seconds at the beginning of analysis
234      ztime_end = nitend_han*rdt                 ! Final time in seconds at the end of analysis
235      nhan = (nitend_han-nit000_han+1)/nstep_han ! Number of dumps used for analysis
236
237      ninco = 2*nb_ana
238
239      ksp = 0
240      keq = 0       
241      DO jn = 1, nhan
242         ztime=( (nhan-jn)*ztime_ini + (jn-1)*ztime_end )/FLOAT(nhan-1)
243         keq = keq + 1
244         kun = 0
245         DO jh = 1, nb_ana
246            DO jc = 1, 2
247               kun = kun + 1
248               ksp = ksp + 1
249               nisparse(ksp) = keq
250               njsparse(ksp) = kun
251               valuesparse(ksp) = (   MOD(jc,2) * ft(jh) * COS(ana_freq(jh)*ztime + vt(jh) + ut(jh))   &
252                  &             + (1.-MOD(jc,2))* ft(jh) * SIN(ana_freq(jh)*ztime + vt(jh) + ut(jh)) )
253            END DO
254         END DO
255      END DO
256
257      nsparse = ksp
258
259      ! Elevation:
260      DO jj = 1, jpj
261         DO ji = 1, jpi
262            ! Fill input array
263            kun = 0
264            DO jh = 1, nb_ana
265               DO jc = 1, 2
266                  kun = kun + 1
267                  ztmp4(kun)=ana_temp(ji,jj,kun,1)
268               END DO
269            END DO
270
271            CALL SUR_DETERMINE(jj)
272
273            ! Fill output array
274            DO jh = 1, nb_ana
275               ana_amp(ji,jj,jh,1)=ztmp7((jh-1)*2+1)
276               ana_amp(ji,jj,jh,2)=ztmp7((jh-1)*2+2)
277            END DO
278         END DO
279      END DO
280
281      ALLOCATE( out_eta(jpi,jpj,2*nb_ana),   & 
282         &      out_u  (jpi,jpj,2*nb_ana),   &
283         &      out_v  (jpi,jpj,2*nb_ana)  )
284
285      DO jj = 1, jpj
286         DO ji = 1, jpi
287            DO jh = 1, nb_ana 
288               X1 = ana_amp(ji,jj,jh,1)
289               X2 =-ana_amp(ji,jj,jh,2)
290               out_eta(ji,jj,jh       ) = X1 * tmask_i(ji,jj)
291               out_eta(ji,jj,jh+nb_ana) = X2 * tmask_i(ji,jj)
292            END DO
293         END DO
294      END DO
295
296      ! ubar:
297      DO jj = 1, jpj
298         DO ji = 1, jpi
299            ! Fill input array
300            kun=0
301            DO jh = 1,nb_ana
302               DO jc = 1,2
303                  kun = kun + 1
304                  ztmp4(kun)=ana_temp(ji,jj,kun,2)
305               END DO
306            END DO
307
308            CALL SUR_DETERMINE(jj+1)
309
310            ! Fill output array
311            DO jh = 1, nb_ana
312               ana_amp(ji,jj,jh,1) = ztmp7((jh-1)*2+1)
313               ana_amp(ji,jj,jh,2) = ztmp7((jh-1)*2+2)
314            END DO
315
316         END DO
317      END DO
318
319      DO jj = 1, jpj
320         DO ji = 1, jpi
321            DO jh = 1, nb_ana 
322               X1= ana_amp(ji,jj,jh,1)
323               X2=-ana_amp(ji,jj,jh,2)
324               out_u(ji,jj,       jh) = X1 * ssumask(ji,jj)
325               out_u(ji,jj,nb_ana+jh) = X2 * ssumask(ji,jj)
326            ENDDO
327         ENDDO
328      ENDDO
329
330      ! vbar:
331      DO jj = 1, jpj
332         DO ji = 1, jpi
333            ! Fill input array
334            kun=0
335            DO jh = 1,nb_ana
336               DO jc = 1,2
337                  kun = kun + 1
338                  ztmp4(kun)=ana_temp(ji,jj,kun,3)
339               END DO
340            END DO
341
342            CALL SUR_DETERMINE(jj+1)
343
344            ! Fill output array
345            DO jh = 1, nb_ana
346               ana_amp(ji,jj,jh,1)=ztmp7((jh-1)*2+1)
347               ana_amp(ji,jj,jh,2)=ztmp7((jh-1)*2+2)
348            END DO
349
350         END DO
351      END DO
352
353      DO jj = 1, jpj
354         DO ji = 1, jpi
355            DO jh = 1, nb_ana 
356               X1=ana_amp(ji,jj,jh,1)
357               X2=-ana_amp(ji,jj,jh,2)
358               out_v(ji,jj,       jh)=X1 * ssvmask(ji,jj)
359               out_v(ji,jj,nb_ana+jh)=X2 * ssvmask(ji,jj)
360            END DO
361         END DO
362      END DO
363      !
364      CALL dia_wri_harm ! Write results in files
365      !
366   END SUBROUTINE dia_harm_end
367
368
369   SUBROUTINE dia_wri_harm
370      !!--------------------------------------------------------------------
371      !!                 ***  ROUTINE dia_wri_harm  ***
372      !!         
373      !! ** Purpose : Write tidal harmonic analysis results in a netcdf file
374      !!--------------------------------------------------------------------
375      CHARACTER(LEN=lc) :: cltext
376      CHARACTER(LEN=lc) ::   &
377         cdfile_name_T   ,   & ! name of the file created (T-points)
378         cdfile_name_U   ,   & ! name of the file created (U-points)
379         cdfile_name_V         ! name of the file created (V-points)
380      INTEGER  ::   jh
381      !!----------------------------------------------------------------------
382
383      IF(lwp) WRITE(numout,*) '  '
384      IF(lwp) WRITE(numout,*) 'dia_wri_harm : Write harmonic analysis results'
385      IF(lwp) WRITE(numout,*) '  '
386
387      ! A) Elevation
388      !/////////////
389      !
390      DO jh = 1, nb_ana
391      CALL iom_put( TRIM(tname(jh))//'x', out_eta(:,:,jh) )
392      CALL iom_put( TRIM(tname(jh))//'y', out_eta(:,:,nb_ana+jh) )
393      END DO
394
395      ! B) ubar
396      !/////////
397      !
398      DO jh = 1, nb_ana
399      CALL iom_put( TRIM(tname(jh))//'x_u', out_u(:,:,jh) )
400      CALL iom_put( TRIM(tname(jh))//'y_u', out_u(:,:,nb_ana+jh) )
401      END DO
402
403      ! C) vbar
404      !/////////
405      !
406      DO jh = 1, nb_ana
407         CALL iom_put( TRIM(tname(jh))//'x_v', out_v(:,:,jh       ) )
408         CALL iom_put( TRIM(tname(jh))//'y_v', out_v(:,:,jh+nb_ana) )
409      END DO
410      !
411   END SUBROUTINE dia_wri_harm
412
413
414   SUBROUTINE SUR_DETERMINE(init)
415      !!---------------------------------------------------------------------------------
416      !!                      *** ROUTINE SUR_DETERMINE ***
417      !!   
418      !!   
419      !!       
420      !!---------------------------------------------------------------------------------
421      INTEGER, INTENT(in) ::   init 
422      !
423      INTEGER                         :: ji_sd, jj_sd, ji1_sd, ji2_sd, jh1_sd, jh2_sd
424      REAL(wp)                        :: zval1, zval2, zx1
425      REAL(wp), DIMENSION(jpincomax) :: ztmpx, zcol1, zcol2
426      INTEGER , DIMENSION(jpincomax) :: ipos2, ipivot
427      !---------------------------------------------------------------------------------
428      !           
429      IF( init == 1 ) THEN
430         IF( nsparse > jpdimsparse )   CALL ctl_stop( 'STOP', 'SUR_DETERMINE : nsparse .GT. jpdimsparse')
431         IF( ninco   > jpincomax   )   CALL ctl_stop( 'STOP', 'SUR_DETERMINE : ninco .GT. jpincomax')
432         !
433         ztmp3(:,:) = 0._wp
434         !
435         DO jh1_sd = 1, nsparse
436            DO jh2_sd = 1, nsparse
437               nisparse(jh2_sd) = nisparse(jh2_sd)
438               njsparse(jh2_sd) = njsparse(jh2_sd)
439               IF( nisparse(jh2_sd) == nisparse(jh1_sd) ) THEN
440                  ztmp3(njsparse(jh1_sd),njsparse(jh2_sd)) = ztmp3(njsparse(jh1_sd),njsparse(jh2_sd))  &
441                     &                                     + valuesparse(jh1_sd)*valuesparse(jh2_sd)
442               ENDIF
443            END DO
444         END DO
445         !
446         DO jj_sd = 1 ,ninco
447            ipos1(jj_sd) = jj_sd
448            ipos2(jj_sd) = jj_sd
449         END DO
450         !
451         DO ji_sd = 1 , ninco
452            !
453            !find greatest non-zero pivot:
454            zval1 = ABS(ztmp3(ji_sd,ji_sd))
455            !
456            ipivot(ji_sd) = ji_sd
457            DO jj_sd = ji_sd, ninco
458               zval2 = ABS(ztmp3(ji_sd,jj_sd))
459               IF( zval2 >= zval1 )THEN
460                  ipivot(ji_sd) = jj_sd
461                  zval1         = zval2
462               ENDIF
463            END DO
464            !
465            DO ji1_sd = 1, ninco
466               zcol1(ji1_sd)               = ztmp3(ji1_sd,ji_sd)
467               zcol2(ji1_sd)               = ztmp3(ji1_sd,ipivot(ji_sd))
468               ztmp3(ji1_sd,ji_sd)         = zcol2(ji1_sd)
469               ztmp3(ji1_sd,ipivot(ji_sd)) = zcol1(ji1_sd)
470            END DO
471            !
472            ipos2(ji_sd)         = ipos1(ipivot(ji_sd))
473            ipos2(ipivot(ji_sd)) = ipos1(ji_sd)
474            ipos1(ji_sd)         = ipos2(ji_sd)
475            ipos1(ipivot(ji_sd)) = ipos2(ipivot(ji_sd))
476            zpivot(ji_sd)        = ztmp3(ji_sd,ji_sd)
477            DO jj_sd = 1, ninco
478               ztmp3(ji_sd,jj_sd) = ztmp3(ji_sd,jj_sd) / zpivot(ji_sd)
479            END DO
480            !
481            DO ji2_sd = ji_sd+1, ninco
482               zpilier(ji2_sd,ji_sd)=ztmp3(ji2_sd,ji_sd)
483               DO jj_sd=1,ninco
484                  ztmp3(ji2_sd,jj_sd)=  ztmp3(ji2_sd,jj_sd) - ztmp3(ji_sd,jj_sd) * zpilier(ji2_sd,ji_sd)
485               END DO
486            END DO
487            !
488         END DO
489         !
490      ENDIF ! End init==1
491
492      DO ji_sd = 1, ninco
493         ztmp4(ji_sd) = ztmp4(ji_sd) / zpivot(ji_sd)
494         DO ji2_sd = ji_sd+1, ninco
495            ztmp4(ji2_sd) = ztmp4(ji2_sd) - ztmp4(ji_sd) * zpilier(ji2_sd,ji_sd)
496         END DO
497      END DO
498
499      !system solving:
500      ztmpx(ninco) = ztmp4(ninco) / ztmp3(ninco,ninco)
501      ji_sd = ninco
502      DO ji_sd = ninco-1, 1, -1
503         zx1 = 0._wp
504         DO jj_sd = ji_sd+1, ninco
505            zx1 = zx1 + ztmpx(jj_sd) * ztmp3(ji_sd,jj_sd)
506         END DO
507         ztmpx(ji_sd) = ztmp4(ji_sd)-zx1
508      END DO
509
510      DO jj_sd =1, ninco
511         ztmp7(ipos1(jj_sd))=ztmpx(jj_sd)
512      END DO
513      !
514   END SUBROUTINE SUR_DETERMINE
515
516   !!======================================================================
517END MODULE diaharm
Note: See TracBrowser for help on using the repository browser.