New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

nemogcm.F90 in NEMO/branches/2019/dev_r10984_HPC-13_IRRMANN_BDY_optimization/src/OCE – NEMO

Context Navigation

source: NEMO/branches/2019/dev_r10984_HPC-13_IRRMANN_BDY_optimization/src/OCE/nemogcm.F90 @ 11317

Last change on this file since 11317 was 11317, checked in by smasson, 5 years ago
dev_r10984_HPC-13 : improve error handling, see #2307 and #2285
Property svn:keywords set to `Id`
File size: 35.1 KB

Line
1	MODULE nemogcm
2	!!======================================================================
3	!! * MODULE nemogcm *
4	!! Ocean system : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5	!!======================================================================
6	!! History : OPA ! 1990-10 (C. Levy, G. Madec) Original code
7	!! 7.0 ! 1991-11 (M. Imbard, C. Levy, G. Madec)
8	!! 7.1 ! 1993-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9	!! P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10	!! - ! 1992-06 (L.Terray) coupling implementation
11	!! - ! 1993-11 (M.A. Filiberti) IGLOO sea-ice
12	!! 8.0 ! 1996-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13	!! P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14	!! 8.1 ! 1997-06 (M. Imbard, G. Madec)
15	!! 8.2 ! 1999-11 (M. Imbard, H. Goosse) sea-ice model
16	!! ! 1999-12 (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols) OPEN-MP
17	!! ! 2000-07 (J-M Molines, M. Imbard) Open Boundary Conditions (CLIPPER)
18	!! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form and modules
19	!! - ! 2004-06 (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20	!! - ! 2004-08 (C. Talandier) New trends organization
21	!! - ! 2005-06 (C. Ethe) Add the 1D configuration possibility
22	!! - ! 2005-11 (V. Garnier) Surface pressure gradient organization
23	!! - ! 2006-03 (L. Debreu, C. Mazauric) Agrif implementation
24	!! - ! 2006-04 (G. Madec, R. Benshila) Step reorganization
25	!! - ! 2007-07 (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26	!! 3.2 ! 2009-08 (S. Masson) open/write in the listing file in mpp
27	!! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28	!! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
29	!! 3.3.1! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
30	!! - ! 2011-11 (C. Harris) decomposition changes for running with CICE
31	!! 3.6 ! 2012-05 (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32	!! - ! 2014-12 (G. Madec) remove KPP scheme and cross-land advection (cla)
33	!! 4.0 ! 2016-10 (G. Madec, S. Flavoni) domain configuration / user defined interface
34	!!----------------------------------------------------------------------
35
36	!!----------------------------------------------------------------------
37	!! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
38	!! nemo_init : initialization of the NEMO system
39	!! nemo_ctl : initialisation of the contol print
40	!! nemo_closefile: close remaining open files
41	!! nemo_alloc : dynamical allocation
42	!!----------------------------------------------------------------------
43	USE step_oce ! module used in the ocean time stepping module (step.F90)
44	USE phycst ! physical constant (par_cst routine)
45	USE domain ! domain initialization (dom_init & dom_cfg routines)
46	USE closea ! treatment of closed seas (for ln_closea)
47	USE usrdef_nam ! user defined configuration
48	USE tideini ! tidal components initialization (tide_ini routine)
49	USE bdy_oce, ONLY : ln_bdy
50	USE bdyini ! open boundary cond. setting (bdy_init routine)
51	USE istate ! initial state setting (istate_init routine)
52	USE ldfdyn ! lateral viscosity setting (ldfdyn_init routine)
53	USE ldftra ! lateral diffusivity setting (ldftra_init routine)
54	USE trdini ! dyn/tra trends initialization (trd_init routine)
55	USE asminc ! assimilation increments
56	USE asmbkg ! writing out state trajectory
57	USE diaptr ! poleward transports (dia_ptr_init routine)
58	USE diadct ! sections transports (dia_dct_init routine)
59	USE diaobs ! Observation diagnostics (dia_obs_init routine)
60	USE diacfl ! CFL diagnostics (dia_cfl_init routine)
61	USE step ! NEMO time-stepping (stp routine)
62	USE icbini ! handle bergs, initialisation
63	USE icbstp ! handle bergs, calving, themodynamics and transport
64	USE cpl_oasis3 ! OASIS3 coupling
65	USE c1d ! 1D configuration
66	USE step_c1d ! Time stepping loop for the 1D configuration
67	USE dyndmp ! Momentum damping
68	USE stopar ! Stochastic param.: ???
69	USE stopts ! Stochastic param.: ???
70	USE diurnal_bulk ! diurnal bulk SST
71	USE step_diu ! diurnal bulk SST timestepping (called from here if run offline)
72	USE crsini ! initialise grid coarsening utility
73	USE diatmb ! Top,middle,bottom output
74	USE dia25h ! 25h mean output
75	USE sbc_oce , ONLY : lk_oasis
76	USE wet_dry ! Wetting and drying setting (wad_init routine)
77	#if defined key_top
78	USE trcini ! passive tracer initialisation
79	#endif
80	#if defined key_nemocice_decomp
81	USE ice_domain_size, only: nx_global, ny_global
82	#endif
83	!
84	USE lib_mpp ! distributed memory computing
85	USE mppini ! shared/distributed memory setting (mpp_init routine)
86	USE lbcnfd , ONLY : isendto, nsndto, nfsloop, nfeloop ! Setup of north fold exchanges
87	USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
88	#if defined key_iomput
89	USE xios ! xIOserver
90	#endif
91	#if defined key_agrif
92	USE agrif_all_update ! Master Agrif update
93	#endif
94
95	IMPLICIT NONE
96	PRIVATE
97
98	PUBLIC nemo_gcm ! called by model.F90
99	PUBLIC nemo_init ! needed by AGRIF
100	PUBLIC nemo_alloc ! needed by TAM
101
102	CHARACTER(lc) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing
103
104	#if defined key_mpp_mpi
105	! need MPI_Wtime
106	INCLUDE 'mpif.h'
107	#endif
108
109	!!----------------------------------------------------------------------
110	!! NEMO/OCE 4.0 , NEMO Consortium (2018)
111	!! $Id$
112	!! Software governed by the CeCILL license (see ./LICENSE)
113	!!----------------------------------------------------------------------
114	CONTAINS
115
116	SUBROUTINE nemo_gcm
117	!!----------------------------------------------------------------------
118	!! * ROUTINE nemo_gcm *
119	!!
120	!! ** Purpose : NEMO solves the primitive equations on an orthogonal
121	!! curvilinear mesh on the sphere.
122	!!
123	!! ** Method : - model general initialization
124	!! - launch the time-stepping (stp routine)
125	!! - finalize the run by closing files and communications
126	!!
127	!! References : Madec, Delecluse, Imbard, and Levy, 1997: internal report, IPSL.
128	!! Madec, 2008, internal report, IPSL.
129	!!----------------------------------------------------------------------
130	INTEGER :: istp ! time step index
131	!!----------------------------------------------------------------------
132	!
133	#if defined key_agrif
134	CALL Agrif_Init_Grids() ! AGRIF: set the meshes
135	#endif
136	! !-----------------------!
137	CALL nemo_init !== Initialisations ==!
138	! !-----------------------!
139	#if defined key_agrif
140	CALL Agrif_Declare_Var_dom ! AGRIF: set the meshes for DOM
141	CALL Agrif_Declare_Var ! " " " " " DYN/TRA
142	# if defined key_top
143	CALL Agrif_Declare_Var_top ! " " " " " TOP
144	# endif
145	# if defined key_si3
146	CALL Agrif_Declare_Var_ice ! " " " " " Sea ice
147	# endif
148	#endif
149	! check that all process are still there... If some process have an error,
150	! they will never enter in step and other processes will wait until the end of the cpu time!
151	CALL mpp_max( 'nemogcm', nstop )
152
153	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
154
155	! !-----------------------!
156	! !== time stepping ==!
157	! !-----------------------!
158	istp = nit000
159	!
160	#if defined key_c1d
161	DO WHILE ( istp <= nitend .AND. nstop == 0 ) !== C1D time-stepping ==!
162	CALL stp_c1d( istp )
163	istp = istp + 1
164	END DO
165	#else
166	!
167	# if defined key_agrif
168	! !== AGRIF time-stepping ==!
169	CALL Agrif_Regrid()
170	!
171	! Recursive update from highest nested level to lowest:
172	CALL Agrif_step_child_adj(Agrif_Update_All)
173	!
174	DO WHILE( istp <= nitend .AND. nstop == 0 )
175	CALL stp
176	istp = istp + 1
177	END DO
178	!
179	IF( .NOT. Agrif_Root() ) THEN
180	CALL Agrif_ParentGrid_To_ChildGrid()
181	IF( ln_diaobs ) CALL dia_obs_wri
182	IF( ln_timing ) CALL timing_finalize
183	CALL Agrif_ChildGrid_To_ParentGrid()
184	ENDIF
185	!
186	# else
187	!
188	IF( .NOT.ln_diurnal_only ) THEN !== Standard time-stepping ==!
189	!
190	DO WHILE( istp <= nitend .AND. nstop == 0 )
191	#if defined key_mpp_mpi
192	ncom_stp = istp
193	IF ( istp == ( nit000 + 1 ) ) elapsed_time = MPI_Wtime()
194	IF ( istp == nitend ) elapsed_time = MPI_Wtime() - elapsed_time
195	#endif
196	CALL stp ( istp )
197	istp = istp + 1
198	END DO
199	!
200	ELSE !== diurnal SST time-steeping only ==!
201	!
202	DO WHILE( istp <= nitend .AND. nstop == 0 )
203	CALL stp_diurnal( istp ) ! time step only the diurnal SST
204	istp = istp + 1
205	END DO
206	!
207	ENDIF
208	!
209	# endif
210	!
211	#endif
212	!
213	IF( ln_diaobs ) CALL dia_obs_wri
214	!
215	IF( ln_icebergs ) CALL icb_end( nitend )
216
217	! !------------------------!
218	! !== finalize the run ==!
219	! !------------------------!
220	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
221	!
222	IF( nstop /= 0 .AND. lwp ) THEN ! error print
223	WRITE(ctmp1,*) ' ==>>> nemo_gcm: a total of ', nstop, ' errors have been found'
224	CALL ctl_stop( ctmp1 )
225	ENDIF
226	!
227	IF( ln_timing ) CALL timing_finalize
228	!
229	CALL nemo_closefile
230	!
231	#if defined key_iomput
232	CALL xios_finalize ! end mpp communications with xios
233	IF( lk_oasis ) CALL cpl_finalize ! end coupling and mpp communications with OASIS
234	#else
235	IF ( lk_oasis ) THEN ; CALL cpl_finalize ! end coupling and mpp communications with OASIS
236	ELSEIF( lk_mpp ) THEN ; CALL mppstop( ldfinal = .TRUE. ) ! end mpp communications
237	ENDIF
238	#endif
239	!
240	IF(lwm) THEN
241	IF( nstop == 0 ) THEN ; STOP 0
242	ELSE ; STOP 123
243	ENDIF
244	ENDIF
245	!
246	END SUBROUTINE nemo_gcm
247
248
249	SUBROUTINE nemo_init
250	!!----------------------------------------------------------------------
251	!! * ROUTINE nemo_init *
252	!!
253	!! ** Purpose : initialization of the NEMO GCM
254	!!----------------------------------------------------------------------
255	INTEGER :: ios, ilocal_comm ! local integers
256	!!
257	NAMELIST/namctl/ ln_ctl , sn_cfctl, nn_print, nn_ictls, nn_ictle, &
258	& nn_isplt , nn_jsplt, nn_jctls, nn_jctle, &
259	& ln_timing, ln_diacfl
260	NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
261	!!----------------------------------------------------------------------
262	!
263	cxios_context = 'nemo'
264	!
265	! !-------------------------------------------------!
266	! ! set communicator & select the local rank !
267	! ! must be done as soon as possible to get narea !
268	! !-------------------------------------------------!
269	!
270	#if defined key_iomput
271	IF( Agrif_Root() ) THEN
272	IF( lk_oasis ) THEN
273	CALL cpl_init( "oceanx", ilocal_comm ) ! nemo local communicator given by oasis
274	CALL xios_initialize( "not used" , local_comm =ilocal_comm ) ! send nemo communicator to xios
275	ELSE
276	CALL xios_initialize( "for_xios_mpi_id", return_comm=ilocal_comm ) ! nemo local communicator given by xios
277	ENDIF
278	ENDIF
279	CALL mpp_start( ilocal_comm )
280	#else
281	IF( lk_oasis ) THEN
282	IF( Agrif_Root() ) THEN
283	CALL cpl_init( "oceanx", ilocal_comm ) ! nemo local communicator given by oasis
284	ENDIF
285	CALL mpp_start( ilocal_comm )
286	ELSE
287	CALL mpp_start( )
288	ENDIF
289	#endif
290	!
291	narea = mpprank + 1 ! mpprank: the rank of proc (0 --> mppsize -1 )
292	lwm = (narea == 1) ! control of output namelists
293	!
294	! !---------------------------------------------------------------!
295	! ! Open output files, reference and configuration namelist files !
296	! !---------------------------------------------------------------!
297	!
298	! open ocean.output as soon as possible to get all output prints (including errors messages)
299	IF( lwm ) CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
300	! open reference and configuration namelist files
301	CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
302	CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
303	IF( lwm ) CALL ctl_opn( numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
304	! open /dev/null file to be able to supress output write easily
305	CALL ctl_opn( numnul, '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
306	!
307	! !--------------------!
308	! ! Open listing units ! -> need ln_ctl from namctl to define lwp
309	! !--------------------!
310	!
311	REWIND( numnam_ref ) ! Namelist namctl in reference namelist
312	READ ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
313	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist' )
314	REWIND( numnam_cfg ) ! Namelist namctl in confguration namelist
315	READ ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
316	902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist' )
317	!
318	lwp = (narea == 1) .OR. ln_ctl ! control of all listing output print
319	!
320	IF(lwp) THEN ! open listing units
321	!
322	IF( .NOT. lwm ) & ! alreay opened for narea == 1
323	& CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE., narea )
324	!
325	WRITE(numout,*)
326	WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - CMCC'
327	WRITE(numout,*) ' NEMO team'
328	WRITE(numout,*) ' Ocean General Circulation Model'
329	WRITE(numout,*) ' NEMO version 4.0 (2019) '
330	WRITE(numout,*)
331	WRITE(numout,*) " ._ ._ ._ ._ ._ "
332	WRITE(numout,*) " _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ "
333	WRITE(numout,*)
334	WRITE(numout,*) " o _, _, "
335	WRITE(numout,*) " o .' ( .-' / "
336	WRITE(numout,*) " o _/..._'. .' / "
337	WRITE(numout,*) " ( o .-'` ` '-./ _.' "
338	WRITE(numout,*) " ) ( o) ;= <_ ( "
339	WRITE(numout,*) " ( '-.,\\__ __.-;`\ '. ) "
340	WRITE(numout,*) " ) ) \) \|`\ \) '. \ ( ( "
341	WRITE(numout,*) " ( ( \_/ '-._\ ) ) "
342	WRITE(numout,*) " ) ) jgs ` ( ( "
343	WRITE(numout,*) " ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ "
344	WRITE(numout,*)
345	!
346	WRITE(numout,cform_aaa) ! Flag AAAAAAA
347	!
348	ENDIF
349	!
350	! finalize the definition of namctl variables
351	IF( sn_cfctl%l_config ) THEN
352	! Activate finer control of report outputs
353	! optionally switch off output from selected areas (note this only
354	! applies to output which does not involve global communications)
355	IF( ( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax ) .OR. &
356	& ( MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 ) ) &
357	& CALL nemo_set_cfctl( sn_cfctl, .FALSE., .FALSE. )
358	ELSE
359	! Use ln_ctl to turn on or off all options.
360	CALL nemo_set_cfctl( sn_cfctl, ln_ctl, .TRUE. )
361	ENDIF
362	!
363	IF(lwm) WRITE( numond, namctl )
364	!
365	! !------------------------------------!
366	! ! Set global domain size parameters !
367	! !------------------------------------!
368	!
369	REWIND( numnam_ref ) ! Namelist namcfg in reference namelist
370	READ ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
371	903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist' )
372	REWIND( numnam_cfg ) ! Namelist namcfg in confguration namelist
373	READ ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
374	904 IF( ios > 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist' )
375	!
376	IF( ln_read_cfg ) THEN ! Read sizes in domain configuration file
377	CALL domain_cfg ( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
378	ELSE ! user-defined namelist
379	CALL usr_def_nam( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
380	ENDIF
381	!
382	IF(lwm) WRITE( numond, namcfg )
383	!
384	! !-----------------------------------------!
385	! ! mpp parameters and domain decomposition !
386	! !-----------------------------------------!
387	CALL mpp_init
388
389	! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
390	CALL nemo_alloc()
391
392	! !-------------------------------!
393	! ! NEMO general initialization !
394	! !-------------------------------!
395
396	CALL nemo_ctl ! Control prints
397	!
398	! ! General initialization
399	IF( ln_timing ) CALL timing_init ! timing
400	IF( ln_timing ) CALL timing_start( 'nemo_init')
401	!
402	CALL phy_cst ! Physical constants
403	CALL eos_init ! Equation of state
404	IF( lk_c1d ) CALL c1d_init ! 1D column configuration
405	CALL wad_init ! Wetting and drying options
406	CALL dom_init("OPA") ! Domain
407	IF( ln_crs ) CALL crs_init ! coarsened grid: domain initialization
408	IF( ln_ctl ) CALL prt_ctl_init ! Print control
409
410	CALL diurnal_sst_bulk_init ! diurnal sst
411	IF( ln_diurnal ) CALL diurnal_sst_coolskin_init ! cool skin
412	!
413	IF( ln_diurnal_only ) THEN ! diurnal only: a subset of the initialisation routines
414	CALL istate_init ! ocean initial state (Dynamics and tracers)
415	CALL sbc_init ! Forcings : surface module
416	CALL tra_qsr_init ! penetrative solar radiation qsr
417	IF( ln_diaobs ) THEN ! Observation & model comparison
418	CALL dia_obs_init ! Initialize observational data
419	CALL dia_obs( nit000 - 1 ) ! Observation operator for restart
420	ENDIF
421	IF( lk_asminc ) CALL asm_inc_init ! Assimilation increments
422	!
423	RETURN ! end of initialization
424	ENDIF
425
426	CALL istate_init ! ocean initial state (Dynamics and tracers)
427
428	! ! external forcing
429	CALL tide_init ! tidal harmonics
430	CALL sbc_init ! surface boundary conditions (including sea-ice)
431	CALL bdy_init ! Open boundaries initialisation
432
433	! ! Ocean physics
434	CALL zdf_phy_init ! Vertical physics
435
436	! ! Lateral physics
437	CALL ldf_tra_init ! Lateral ocean tracer physics
438	CALL ldf_eiv_init ! eddy induced velocity param.
439	CALL ldf_dyn_init ! Lateral ocean momentum physics
440
441	! ! Active tracers
442	IF( ln_traqsr ) CALL tra_qsr_init ! penetrative solar radiation qsr
443	CALL tra_bbc_init ! bottom heat flux
444	CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme
445	CALL tra_dmp_init ! internal tracer damping
446	CALL tra_adv_init ! horizontal & vertical advection
447	CALL tra_ldf_init ! lateral mixing
448
449	! ! Dynamics
450	IF( lk_c1d ) CALL dyn_dmp_init ! internal momentum damping
451	CALL dyn_adv_init ! advection (vector or flux form)
452	CALL dyn_vor_init ! vorticity term including Coriolis
453	CALL dyn_ldf_init ! lateral mixing
454	CALL dyn_hpg_init ! horizontal gradient of Hydrostatic pressure
455	CALL dyn_spg_init ! surface pressure gradient
456
457	#if defined key_top
458	! ! Passive tracers
459	CALL trc_init
460	#endif
461	IF( l_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing
462
463	! ! Icebergs
464	CALL icb_init( rdt, nit000) ! initialise icebergs instance
465
466	! ! Misc. options
467	CALL sto_par_init ! Stochastic parametrization
468	IF( ln_sto_eos ) CALL sto_pts_init ! RRandom T/S fluctuations
469
470	! ! Diagnostics
471	IF( lk_floats ) CALL flo_init ! drifting Floats
472	IF( ln_diacfl ) CALL dia_cfl_init ! Initialise CFL diagnostics
473	CALL dia_ptr_init ! Poleward TRansports initialization
474	IF( lk_diadct ) CALL dia_dct_init ! Sections tranports
475	CALL dia_hsb_init ! heat content, salt content and volume budgets
476	CALL trd_init ! Mixed-layer/Vorticity/Integral constraints trends
477	CALL dia_obs_init ! Initialize observational data
478	CALL dia_tmb_init ! TMB outputs
479	CALL dia_25h_init ! 25h mean outputs
480	IF( ln_diaobs ) CALL dia_obs( nit000-1 ) ! Observation operator for restart
481
482	! ! Assimilation increments
483	IF( lk_asminc ) CALL asm_inc_init ! Initialize assimilation increments
484	!
485	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
486	!
487	IF( ln_timing ) CALL timing_stop( 'nemo_init')
488	!
489	END SUBROUTINE nemo_init
490
491
492	SUBROUTINE nemo_ctl
493	!!----------------------------------------------------------------------
494	!! * ROUTINE nemo_ctl *
495	!!
496	!! ** Purpose : control print setting
497	!!
498	!! ** Method : - print namctl and namcfg information and check some consistencies
499	!!----------------------------------------------------------------------
500	!
501	IF(lwp) THEN ! control print
502	WRITE(numout,*)
503	WRITE(numout,*) 'nemo_ctl: Control prints'
504	WRITE(numout,*) '~~~~~~~~'
505	WRITE(numout,*) ' Namelist namctl'
506	WRITE(numout,*) ' run control (for debugging) ln_ctl = ', ln_ctl
507	WRITE(numout,*) ' finer control over o/p sn_cfctl%l_config = ', sn_cfctl%l_config
508	WRITE(numout,*) ' sn_cfctl%l_runstat = ', sn_cfctl%l_runstat
509	WRITE(numout,*) ' sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat
510	WRITE(numout,*) ' sn_cfctl%l_oceout = ', sn_cfctl%l_oceout
511	WRITE(numout,*) ' sn_cfctl%l_layout = ', sn_cfctl%l_layout
512	WRITE(numout,*) ' sn_cfctl%l_mppout = ', sn_cfctl%l_mppout
513	WRITE(numout,*) ' sn_cfctl%l_mpptop = ', sn_cfctl%l_mpptop
514	WRITE(numout,*) ' sn_cfctl%procmin = ', sn_cfctl%procmin
515	WRITE(numout,*) ' sn_cfctl%procmax = ', sn_cfctl%procmax
516	WRITE(numout,*) ' sn_cfctl%procincr = ', sn_cfctl%procincr
517	WRITE(numout,*) ' sn_cfctl%ptimincr = ', sn_cfctl%ptimincr
518	WRITE(numout,*) ' level of print nn_print = ', nn_print
519	WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls
520	WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle
521	WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls
522	WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle
523	WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt
524	WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt
525	WRITE(numout,*) ' timing by routine ln_timing = ', ln_timing
526	WRITE(numout,*) ' CFL diagnostics ln_diacfl = ', ln_diacfl
527	ENDIF
528	!
529	nprint = nn_print ! convert DOCTOR namelist names into OLD names
530	nictls = nn_ictls
531	nictle = nn_ictle
532	njctls = nn_jctls
533	njctle = nn_jctle
534	isplt = nn_isplt
535	jsplt = nn_jsplt
536
537	IF(lwp) THEN ! control print
538	WRITE(numout,*)
539	WRITE(numout,*) ' Namelist namcfg'
540	WRITE(numout,*) ' read domain configuration file ln_read_cfg = ', ln_read_cfg
541	WRITE(numout,*) ' filename to be read cn_domcfg = ', TRIM(cn_domcfg)
542	WRITE(numout,*) ' keep closed seas in the domain (if exist) ln_closea = ', ln_closea
543	WRITE(numout,*) ' create a configuration definition file ln_write_cfg = ', ln_write_cfg
544	WRITE(numout,*) ' filename to be written cn_domcfg_out = ', TRIM(cn_domcfg_out)
545	WRITE(numout,*) ' use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr
546	ENDIF
547	IF( .NOT.ln_read_cfg ) ln_closea = .false. ! dealing possible only with a domcfg file
548	!
549	! ! Parameter control
550	!
551	IF( ln_ctl ) THEN ! sub-domain area indices for the control prints
552	IF( lk_mpp .AND. jpnij > 1 ) THEN
553	isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real split domain
554	ELSE
555	IF( isplt == 1 .AND. jsplt == 1 ) THEN
556	CALL ctl_warn( ' - isplt & jsplt are equal to 1', &
557	& ' - the print control will be done over the whole domain' )
558	ENDIF
559	ijsplt = isplt * jsplt ! total number of processors ijsplt
560	ENDIF
561	IF(lwp) WRITE(numout,*)' - The total number of processors over which the'
562	IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt
563	!
564	! ! indices used for the SUM control
565	IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area
566	lsp_area = .FALSE.
567	ELSE ! print control done over a specific area
568	lsp_area = .TRUE.
569	IF( nictls < 1 .OR. nictls > jpiglo ) THEN
570	CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
571	nictls = 1
572	ENDIF
573	IF( nictle < 1 .OR. nictle > jpiglo ) THEN
574	CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
575	nictle = jpiglo
576	ENDIF
577	IF( njctls < 1 .OR. njctls > jpjglo ) THEN
578	CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
579	njctls = 1
580	ENDIF
581	IF( njctle < 1 .OR. njctle > jpjglo ) THEN
582	CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
583	njctle = jpjglo
584	ENDIF
585	ENDIF
586	ENDIF
587	!
588	IF( 1._wp /= SIGN(1._wp,-0._wp) ) CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.', &
589	& 'Compile with key_nosignedzero enabled:', &
590	& '--> add -Dkey_nosignedzero to the definition of %CPP in your arch file' )
591	!
592	#if defined key_agrif
593	IF( ln_timing ) CALL ctl_stop( 'AGRIF not implemented with ln_timing = true')
594	#endif
595	!
596	END SUBROUTINE nemo_ctl
597
598
599	SUBROUTINE nemo_closefile
600	!!----------------------------------------------------------------------
601	!! * ROUTINE nemo_closefile *
602	!!
603	!! ** Purpose : Close the files
604	!!----------------------------------------------------------------------
605	!
606	IF( lk_mpp ) CALL mppsync
607	!
608	CALL iom_close ! close all input/output files managed by iom_*
609	!
610	IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file
611	IF( numrun /= -1 ) CLOSE( numrun ) ! run statistics file
612	IF( numnam_ref /= -1 ) CLOSE( numnam_ref ) ! oce reference namelist
613	IF( numnam_cfg /= -1 ) CLOSE( numnam_cfg ) ! oce configuration namelist
614	IF( lwm.AND.numond /= -1 ) CLOSE( numond ) ! oce output namelist
615	IF( numnam_ice_ref /= -1 ) CLOSE( numnam_ice_ref ) ! ice reference namelist
616	IF( numnam_ice_cfg /= -1 ) CLOSE( numnam_ice_cfg ) ! ice configuration namelist
617	IF( lwm.AND.numoni /= -1 ) CLOSE( numoni ) ! ice output namelist
618	IF( numevo_ice /= -1 ) CLOSE( numevo_ice ) ! ice variables (temp. evolution)
619	IF( numout /= 6 ) CLOSE( numout ) ! standard model output file
620	IF( numdct_vol /= -1 ) CLOSE( numdct_vol ) ! volume transports
621	IF( numdct_heat /= -1 ) CLOSE( numdct_heat ) ! heat transports
622	IF( numdct_salt /= -1 ) CLOSE( numdct_salt ) ! salt transports
623	!
624	numout = 6 ! redefine numout in case it is used after this point...
625	!
626	END SUBROUTINE nemo_closefile
627
628
629	SUBROUTINE nemo_alloc
630	!!----------------------------------------------------------------------
631	!! * ROUTINE nemo_alloc *
632	!!
633	!! ** Purpose : Allocate all the dynamic arrays of the OPA modules
634	!!
635	!! ** Method :
636	!!----------------------------------------------------------------------
637	USE diawri , ONLY : dia_wri_alloc
638	USE dom_oce , ONLY : dom_oce_alloc
639	USE trc_oce , ONLY : trc_oce_alloc
640	USE bdy_oce , ONLY : bdy_oce_alloc
641	#if defined key_diadct
642	USE diadct , ONLY : diadct_alloc
643	#endif
644	!
645	INTEGER :: ierr
646	!!----------------------------------------------------------------------
647	!
648	ierr = oce_alloc () ! ocean
649	ierr = ierr + dia_wri_alloc()
650	ierr = ierr + dom_oce_alloc() ! ocean domain
651	ierr = ierr + zdf_oce_alloc() ! ocean vertical physics
652	ierr = ierr + trc_oce_alloc() ! shared TRC / TRA arrays
653	ierr = ierr + bdy_oce_alloc() ! bdy masks (incl. initialization)
654	!
655	#if defined key_diadct
656	ierr = ierr + diadct_alloc () !
657	#endif
658	!
659	CALL mpp_sum( 'nemogcm', ierr )
660	IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
661	!
662	END SUBROUTINE nemo_alloc
663
664
665	SUBROUTINE nemo_set_cfctl(sn_cfctl, setto, for_all )
666	!!----------------------------------------------------------------------
667	!! * ROUTINE nemo_set_cfctl *
668	!!
669	!! ** Purpose : Set elements of the output control structure to setto.
670	!! for_all should be .false. unless all areas are to be
671	!! treated identically.
672	!!
673	!! ** Method : Note this routine can be used to switch on/off some
674	!! types of output for selected areas but any output types
675	!! that involve global communications (e.g. mpp_max, glob_sum)
676	!! should be protected from selective switching by the
677	!! for_all argument
678	!!----------------------------------------------------------------------
679	LOGICAL :: setto, for_all
680	TYPE(sn_ctl) :: sn_cfctl
681	!!----------------------------------------------------------------------
682	IF( for_all ) THEN
683	sn_cfctl%l_runstat = setto
684	sn_cfctl%l_trcstat = setto
685	ENDIF
686	sn_cfctl%l_oceout = setto
687	sn_cfctl%l_layout = setto
688	sn_cfctl%l_mppout = setto
689	sn_cfctl%l_mpptop = setto
690	END SUBROUTINE nemo_set_cfctl
691
692	!!======================================================================
693	END MODULE nemogcm
694

Note: See TracBrowser for help on using the repository browser.

Download in other formats: