New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
agrif_oce_sponge.F90 in NEMO/branches/2019/dev_r11233_AGRIF-05_jchanut_vert_coord_interp/src/NST – NEMO

source: NEMO/branches/2019/dev_r11233_AGRIF-05_jchanut_vert_coord_interp/src/NST/agrif_oce_sponge.F90 @ 11769

Last change on this file since 11769 was 11769, checked in by jchanut, 5 years ago

#2222 1) change sponge definition to add time relaxation in addition to Laplacian diffusion (WRF like): Add new parameters in namelist.
2) Reduce sponge width by 1 child grid point to match coarse grid cells.
  • Property svn:keywords set to Id
File size: 30.7 KB
Line 
1#define SPONGE && define SPONGE_TOP
2
3MODULE agrif_oce_sponge
4   !!======================================================================
5   !!                   ***  MODULE  agrif_oce_interp  ***
6   !! AGRIF: sponge package for the ocean dynamics (OPA)
7   !!======================================================================
8   !! History :  2.0  !  2002-06  (XXX)  Original cade
9   !!             -   !  2005-11  (XXX)
10   !!            3.2  !  2009-04  (R. Benshila)
11   !!            3.6  !  2014-09  (R. Benshila)
12   !!----------------------------------------------------------------------
13#if defined key_agrif
14   !!----------------------------------------------------------------------
15   !!   'key_agrif'                                              AGRIF zoom
16   !!----------------------------------------------------------------------
17   USE par_oce
18   USE oce
19   USE dom_oce
20   !
21   USE in_out_manager
22   USE agrif_oce
23   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
24   USE iom
25   USE vremap
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC Agrif_Sponge, Agrif_Sponge_Tra, Agrif_Sponge_Dyn
31   PUBLIC interptsn_sponge, interpun_sponge, interpvn_sponge
32
33   !!----------------------------------------------------------------------
34   !! NEMO/NST 4.0 , NEMO Consortium (2018)
35   !! $Id$
36   !! Software governed by the CeCILL license (see ./LICENSE)
37   !!----------------------------------------------------------------------
38CONTAINS
39
40   SUBROUTINE Agrif_Sponge_Tra
41      !!----------------------------------------------------------------------
42      !!                 *** ROUTINE Agrif_Sponge_Tra ***
43      !!----------------------------------------------------------------------
44      REAL(wp) ::   zcoef   ! local scalar
45     
46      !!----------------------------------------------------------------------
47      !
48#if defined SPONGE
49      !! Assume persistence:
50      zcoef = REAL(Agrif_rhot()-1,wp)/REAL(Agrif_rhot())
51
52      CALL Agrif_Sponge
53      Agrif_SpecialValue    = 0._wp
54      Agrif_UseSpecialValue = .TRUE.
55      tabspongedone_tsn     = .FALSE.
56      !
57      CALL Agrif_Bc_Variable( tsn_sponge_id, calledweight=zcoef, procname=interptsn_sponge )
58      !
59      Agrif_UseSpecialValue = .FALSE.
60#endif
61      !
62      CALL iom_put("agrif_spu", fspu(:,:))
63      CALL iom_put("agrif_spv", fspv(:,:))
64      !
65   END SUBROUTINE Agrif_Sponge_Tra
66
67
68   SUBROUTINE Agrif_Sponge_dyn
69      !!----------------------------------------------------------------------
70      !!                 *** ROUTINE Agrif_Sponge_dyn ***
71      !!----------------------------------------------------------------------
72      REAL(wp) ::   zcoef   ! local scalar
73      !!----------------------------------------------------------------------
74      !
75#if defined SPONGE
76      zcoef = REAL(Agrif_rhot()-1,wp)/REAL(Agrif_rhot())
77
78      Agrif_SpecialValue=0.
79      Agrif_UseSpecialValue = ln_spc_dyn
80      !
81      tabspongedone_u = .FALSE.
82      tabspongedone_v = .FALSE.         
83      CALL Agrif_Bc_Variable( un_sponge_id, calledweight=zcoef, procname=interpun_sponge )
84      !
85      tabspongedone_u = .FALSE.
86      tabspongedone_v = .FALSE.
87      CALL Agrif_Bc_Variable( vn_sponge_id, calledweight=zcoef, procname=interpvn_sponge )
88      !
89      Agrif_UseSpecialValue = .FALSE.
90#endif
91      !
92      CALL iom_put("agrif_spt", fspt(:,:))
93      CALL iom_put("agrif_spf", fspf(:,:))
94      !
95   END SUBROUTINE Agrif_Sponge_dyn
96
97
98   SUBROUTINE Agrif_Sponge
99      !!----------------------------------------------------------------------
100      !!                 *** ROUTINE  Agrif_Sponge ***
101      !!----------------------------------------------------------------------
102      INTEGER  ::   ji, jj, ind1, ind2
103      INTEGER  ::   ispongearea, jspongearea
104      REAL(wp) ::   z1_ispongearea, z1_jspongearea
105      REAL(wp), DIMENSION(jpi,jpj) :: ztabramp
106      REAL(wp), DIMENSION(jpjmax)  :: zmskwest,  zmskeast
107      REAL(wp), DIMENSION(jpimax)  :: zmsknorth, zmsksouth
108      !!----------------------------------------------------------------------
109      !
110      ! Sponge 1d example with:
111      !      iraf = 3 ; nbghost = 3 ; nn_sponge_len = 2
112      !                       
113      !coarse :     U     T     U     T     U     T     U
114      !|            |           |           |           |
115      !fine :     t u t u t u t u t u t u t u t u t u t u t
116      !sponge val:0   0   0   1  5/6 4/6 3/6 2/6 1/6  0   0
117      !           |   ghost     | <-- sponge area  -- > |
118      !           |   points    |                       |
119      !                         |--> dynamical interface
120
121#if defined SPONGE || defined SPONGE_TOP
122      IF (( .NOT. spongedoneT ).OR.( .NOT. spongedoneU )) THEN
123         !
124         ! Retrieve masks at open boundaries:
125
126         ! --- West --- !
127         ztabramp(:,:) = 0._wp
128         ind1 = 1+nbghostcells
129         DO ji = mi0(ind1), mi1(ind1)               
130            ztabramp(ji,:) = umask(ji,:,1)
131         END DO
132         !
133         zmskwest(:) = 0._wp
134         zmskwest(1:jpj) = MAXVAL(ztabramp(:,:), dim=1)
135
136         ! --- East --- !
137         ztabramp(:,:) = 0._wp
138         ind1 = jpiglo - nbghostcells - 1
139         DO ji = mi0(ind1), mi1(ind1)                 
140            ztabramp(ji,:) = umask(ji,:,1)
141         END DO
142         !
143         zmskeast(:) = 0._wp
144         zmskeast(1:jpj) = MAXVAL(ztabramp(:,:), dim=1)
145
146         ! --- South --- !
147         ztabramp(:,:) = 0._wp
148         ind1 = 1+nbghostcells
149         DO jj = mj0(ind1), mj1(ind1)                 
150            ztabramp(:,jj) = vmask(:,jj,1)
151         END DO
152         !
153         zmsksouth(:) = 0._wp
154         zmsksouth(1:jpi) = MAXVAL(ztabramp(:,:), dim=2)
155
156         ! --- North --- !
157         ztabramp(:,:) = 0._wp
158         ind1 = jpjglo - nbghostcells - 1
159         DO jj = mj0(ind1), mj1(ind1)                 
160            ztabramp(:,jj) = vmask(:,jj,1)
161         END DO
162         !
163         zmsknorth(:) = 0._wp
164         zmsknorth(1:jpi) = MAXVAL(ztabramp(:,:), dim=2)
165
166#if defined key_mpp_mpi
167         CALL mpp_max( 'AGRIF_sponge', zmskwest(:) , jpjmax )
168         CALL mpp_max( 'AGRIF_Sponge', zmskeast(:) , jpjmax )
169         CALL mpp_max( 'AGRIF_Sponge', zmsksouth(:), jpimax )
170         CALL mpp_max( 'AGRIF_Sponge', zmsknorth(:), jpimax )
171#endif
172
173         ! Define ramp from boundaries towards domain interior at T-points
174         ! Store it in ztabramp
175
176         ispongearea  = nn_sponge_len * Agrif_irhox()
177         z1_ispongearea = 1._wp / REAL( ispongearea )
178         jspongearea  = nn_sponge_len * Agrif_irhoy()
179         z1_jspongearea = 1._wp / REAL( jspongearea )
180         
181         ztabramp(:,:) = 0._wp
182         IF ( Agrif_irhox()==1 ) ispongearea =-1
183         IF ( Agrif_irhoy()==1 ) jspongearea =-1
184
185         ! --- West --- !
186         ind1 = 1+nbghostcells
187         ind2 = 1+nbghostcells + ispongearea 
188         DO ji = mi0(ind1), mi1(ind2)   
189            DO jj = 1, jpj               
190               ztabramp(ji,jj) = REAL( ind2 - mig(ji) ) * z1_ispongearea * zmskwest(jj)
191            END DO
192         END DO
193
194         ! ghost cells (cosmetic):
195         ind1 = 1
196         ind2 = nbghostcells
197         DO ji = mi0(ind1), mi1(ind2)   
198            DO jj = 1, jpj               
199               ztabramp(ji,jj) = zmskwest(jj)
200            END DO
201         END DO
202
203         ! --- East --- !
204         ind1 = jpiglo - nbghostcells - ispongearea
205         ind2 = jpiglo - nbghostcells
206         DO ji = mi0(ind1), mi1(ind2)
207            DO jj = 1, jpj
208               ztabramp(ji,jj) = MAX( ztabramp(ji,jj), REAL( mig(ji) - ind1 ) * z1_ispongearea) * zmskeast(jj)
209            ENDDO
210         END DO
211
212         ! ghost cells (cosmetic):
213         ind1 = jpiglo - nbghostcells + 1
214         ind2 = jpiglo
215         DO ji = mi0(ind1), mi1(ind2)
216            DO jj = 1, jpj
217               ztabramp(ji,jj) = zmskeast(jj)
218            ENDDO
219         END DO
220
221         ! --- South --- !
222         ind1 = 1+nbghostcells
223         ind2 = 1+nbghostcells + jspongearea
224         DO jj = mj0(ind1), mj1(ind2) 
225            DO ji = 1, jpi
226               ztabramp(ji,jj) = MAX( ztabramp(ji,jj), REAL( ind2 - mjg(jj) ) * z1_jspongearea) * zmsksouth(ji)
227            END DO
228         END DO
229
230         ! ghost cells (cosmetic):
231         ind1 = 1
232         ind2 = nbghostcells
233         DO jj = mj0(ind1), mj1(ind2) 
234            DO ji = 1, jpi
235               ztabramp(ji,jj) = zmsksouth(ji)
236            END DO
237         END DO
238
239         ! --- North --- !
240         ind1 = jpjglo - nbghostcells - jspongearea
241         ind2 = jpjglo - nbghostcells
242         DO jj = mj0(ind1), mj1(ind2)
243            DO ji = 1, jpi
244               ztabramp(ji,jj) = MAX( ztabramp(ji,jj), REAL( mjg(jj) - ind1 ) * z1_jspongearea) * zmsknorth(ji)
245            END DO
246         END DO
247
248         ! ghost cells (cosmetic):
249         ind1 = jpjglo - nbghostcells + 1
250         ind2 = jpjglo
251         DO jj = mj0(ind1), mj1(ind2)
252            DO ji = 1, jpi
253               ztabramp(ji,jj) = zmsknorth(ji)
254            END DO
255         END DO
256
257      ENDIF
258
259      ! Tracers
260      IF( .NOT. spongedoneT ) THEN
261         fspu(:,:) = 0._wp
262         fspv(:,:) = 0._wp
263         DO jj = 2, jpjm1
264            DO ji = 2, jpim1   ! vector opt.
265               fspu(ji,jj) = 0.5_wp * ( ztabramp(ji,jj) + ztabramp(ji+1,jj  ) )
266               fspv(ji,jj) = 0.5_wp * ( ztabramp(ji,jj) + ztabramp(ji  ,jj+1) )
267            END DO
268         END DO
269         CALL lbc_lnk( 'agrif_Sponge', fspu, 'U', 1. )   ! Lateral boundary conditions
270         CALL lbc_lnk( 'agrif_Sponge', fspv, 'V', 1. )
271
272         spongedoneT = .TRUE.
273      ENDIF
274
275      ! Dynamics
276      IF( .NOT. spongedoneU ) THEN
277         fspt(:,:) = 0._wp
278         fspf(:,:) = 0._wp
279         DO jj = 2, jpjm1
280            DO ji = 2, jpim1   ! vector opt.
281               fspt(ji,jj) = ztabramp(ji,jj)
282               fspf(ji,jj) = 0.25_wp * ( ztabramp(ji  ,jj  ) + ztabramp(ji  ,jj+1) &
283                                     &  +ztabramp(ji+1,jj+1) + ztabramp(ji+1,jj  ) )
284            END DO
285         END DO
286         CALL lbc_lnk( 'agrif_Sponge', fspt, 'T', 1. )   ! Lateral boundary conditions
287         CALL lbc_lnk( 'agrif_Sponge', fspf, 'F', 1. )
288         
289         spongedoneU = .TRUE.
290      ENDIF
291      !
292#endif
293      !
294   END SUBROUTINE Agrif_Sponge
295
296   SUBROUTINE interptsn_sponge( tabres, i1, i2, j1, j2, k1, k2, n1, n2, before )
297      !!----------------------------------------------------------------------
298      !!                 *** ROUTINE interptsn_sponge ***
299      !!----------------------------------------------------------------------
300      INTEGER                                     , INTENT(in   ) ::   i1, i2, j1, j2, k1, k2, n1, n2
301      REAL(wp), DIMENSION(i1:i2,j1:j2,k1:k2,n1:n2), INTENT(inout) ::   tabres
302      LOGICAL                                     , INTENT(in   ) ::   before
303      !
304      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
305      INTEGER  ::   iku, ikv
306      REAL(wp) :: ztsa, zabe1, zabe2, zbtr, zhtot, ztrelax
307      REAL(wp), DIMENSION(i1:i2,j1:j2,jpk) :: ztu, ztv
308      REAL(wp), DIMENSION(i1:i2,j1:j2,jpk,n1:n2) ::tsbdiff
309      ! vertical interpolation:
310      REAL(wp), DIMENSION(i1:i2,j1:j2,jpk,n1:n2) ::tabres_child
311      REAL(wp), DIMENSION(k1:k2,n1:n2-1) :: tabin
312      REAL(wp), DIMENSION(k1:k2) :: h_in
313      REAL(wp), DIMENSION(1:jpk) :: h_out
314      INTEGER :: N_in, N_out
315      !!----------------------------------------------------------------------
316      !
317      IF( before ) THEN
318         DO jn = 1, jpts
319            DO jk=k1,k2
320               DO jj=j1,j2
321                  DO ji=i1,i2
322                     tabres(ji,jj,jk,jn) = tsb(ji,jj,jk,jn)
323                  END DO
324               END DO
325            END DO
326         END DO
327
328# if defined key_vertical
329        ! Interpolate thicknesses
330        ! Warning: these are masked, hence extrapolated prior interpolation.
331        DO jk=k1,k2
332           DO jj=j1,j2
333              DO ji=i1,i2
334                  tabres(ji,jj,jk,jpts+1) = tmask(ji,jj,jk) * e3t_b(ji,jj,jk)
335              END DO
336           END DO
337        END DO
338
339        ! Extrapolate thicknesses in partial bottom cells:
340        ! Set them to Agrif_SpecialValue (0.). Correct bottom thicknesses are retrieved later on
341        IF (ln_zps) THEN
342           DO jj=j1,j2
343              DO ji=i1,i2
344                  jk = mbkt(ji,jj)
345                  tabres(ji,jj,jk,jpts+1) = 0._wp
346              END DO
347           END DO           
348        END IF
349     
350        ! Save ssh at last level:
351        IF (.NOT.ln_linssh) THEN
352           tabres(i1:i2,j1:j2,k2,jpts+1) = sshb(i1:i2,j1:j2)*tmask(i1:i2,j1:j2,1) 
353        ELSE
354           tabres(i1:i2,j1:j2,k2,jpts+1) = 0._wp
355        END IF     
356# endif
357
358      ELSE   
359         !
360# if defined key_vertical
361
362         IF (ln_linssh) tabres(i1:i2,j1:j2,k2,n2) = 0._wp
363
364         DO jj=j1,j2
365            DO ji=i1,i2
366               tabres_child(ji,jj,:,:) = 0._wp 
367               N_in = mbkt_parent(ji,jj)
368               zhtot = 0._wp
369               DO jk=1,N_in !k2 = jpk of parent grid
370                  IF (jk==N_in) THEN
371                     h_in(jk) = ht0_parent(ji,jj) + tabres(ji,jj,k2,n2) - zhtot
372                  ELSE
373                     h_in(jk) = tabres(ji,jj,jk,n2)
374                  ENDIF
375                  zhtot = zhtot + h_in(jk)
376                  tabin(jk,:) = tabres(ji,jj,jk,n1:n2-1)
377               END DO
378               N_out = 0
379               DO jk=1,jpk ! jpk of child grid
380                  IF (tmask(ji,jj,jk) == 0) EXIT
381                  N_out = N_out + 1
382                  h_out(jk) = e3t_b(ji,jj,jk) !Child grid scale factors. Could multiply by e1e2t here instead of division above
383               ENDDO
384
385               ! Account for small differences in free-surface
386               IF ( sum(h_out(1:N_out)) > sum(h_in(1:N_in) )) THEN
387                  h_out(1) = h_out(1) - ( sum(h_out(1:N_out))-sum(h_in(1:N_in)) )
388               ELSE
389                  h_in(1)   = h_in(1)   - (sum(h_in(1:N_in))-sum(h_out(1:N_out)) )
390               ENDIF
391               IF (N_in*N_out > 0) THEN
392                  CALL reconstructandremap(tabin(1:N_in,1:jpts),h_in(1:N_in),tabres_child(ji,jj,1:N_out,1:jpts),h_out(1:N_out),N_in,N_out,jpts)
393               ENDIF
394            ENDDO
395         ENDDO
396# endif
397
398         DO jj=j1,j2
399            DO ji=i1,i2
400               DO jk=1,jpkm1
401# if defined key_vertical
402                  tsbdiff(ji,jj,jk,1:jpts) = (tsb(ji,jj,jk,1:jpts) - tabres_child(ji,jj,jk,1:jpts)) * tmask(ji,jj,jk)
403# else
404                  tsbdiff(ji,jj,jk,1:jpts) = (tsb(ji,jj,jk,1:jpts) - tabres(ji,jj,jk,1:jpts))*tmask(ji,jj,jk)
405# endif
406               ENDDO
407            ENDDO
408         ENDDO
409
410         !* set relaxation time scale
411         IF( neuler == 0 .AND. lk_agrif_fstep ) THEN   ;   ztrelax =   rn_trelax_tra  / (        rdt )
412         ELSE                                          ;   ztrelax =   rn_trelax_tra  / (2._wp * rdt )
413         ENDIF
414
415         DO jn = 1, jpts           
416            DO jk = 1, jpkm1
417               ztu(i1:i2,j1:j2,jk) = 0._wp
418               DO jj = j1,j2
419                  DO ji = i1,i2-1
420                     zabe1 = rn_sponge_tra * fspu(ji,jj) * umask(ji,jj,jk) * e2_e1u(ji,jj) * e3u_n(ji,jj,jk)
421                     ztu(ji,jj,jk) = zabe1 * ( tsbdiff(ji+1,jj  ,jk,jn) - tsbdiff(ji,jj,jk,jn) ) 
422                  END DO
423               END DO
424               ztv(i1:i2,j1:j2,jk) = 0._wp
425               DO ji = i1,i2
426                  DO jj = j1,j2-1
427                     zabe2 = rn_sponge_tra * fspv(ji,jj) * vmask(ji,jj,jk) * e1_e2v(ji,jj) * e3v_n(ji,jj,jk)
428                     ztv(ji,jj,jk) = zabe2 * ( tsbdiff(ji  ,jj+1,jk,jn) - tsbdiff(ji,jj,jk,jn) )
429                  END DO
430               END DO
431               !
432               IF( ln_zps ) THEN      ! set gradient at partial step level
433                  DO jj = j1,j2
434                     DO ji = i1,i2
435                        ! last level
436                        iku = mbku(ji,jj)
437                        ikv = mbkv(ji,jj)
438                        IF( iku == jk )   ztu(ji,jj,jk) = 0._wp
439                        IF( ikv == jk )   ztv(ji,jj,jk) = 0._wp
440                     END DO
441                  END DO
442               ENDIF
443            END DO
444            !
445            DO jk = 1, jpkm1
446               DO jj = j1+1,j2-1
447                  DO ji = i1+1,i2-1
448                     IF (.NOT. tabspongedone_tsn(ji,jj)) THEN
449                        zbtr = r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
450                        ! horizontal diffusive trends
451                        ztsa = zbtr * (  ztu(ji,jj,jk) - ztu(ji-1,jj,jk) + ztv(ji,jj,jk) - ztv(ji,jj-1,jk)  ) &
452                             &  - ztrelax * fspt(ji,jj) * tsbdiff(ji,jj,jk,jn) 
453                        ! add it to the general tracer trends
454                        tsa(ji,jj,jk,jn) = tsa(ji,jj,jk,jn) + ztsa
455                     ENDIF
456                  END DO
457               END DO
458            END DO
459            !
460         END DO
461         !
462         tabspongedone_tsn(i1+1:i2-1,j1+1:j2-1) = .TRUE.
463         !
464      ENDIF
465      !
466   END SUBROUTINE interptsn_sponge
467
468   SUBROUTINE interpun_sponge(tabres,i1,i2,j1,j2,k1,k2,m1,m2, before)
469      !!---------------------------------------------
470      !!   *** ROUTINE interpun_sponge ***
471      !!---------------------------------------------   
472      INTEGER, INTENT(in) :: i1,i2,j1,j2,k1,k2,m1,m2
473      REAL(wp), DIMENSION(i1:i2,j1:j2,k1:k2,m1:m2), INTENT(inout) :: tabres
474      LOGICAL, INTENT(in) :: before
475
476      INTEGER :: ji,jj,jk,jmax
477
478      ! sponge parameters
479      REAL(wp) :: ze2u, ze1v, zua, zva, zbtr, zhtot, ztrelax
480      REAL(wp), DIMENSION(i1:i2,j1:j2,1:jpk) :: ubdiff
481      REAL(wp), DIMENSION(i1:i2,j1:j2,1:jpk) :: rotdiff, hdivdiff
482      ! vertical interpolation:
483      REAL(wp), DIMENSION(i1:i2,j1:j2,1:jpk) :: tabres_child
484      REAL(wp), DIMENSION(k1:k2) :: tabin, h_in
485      REAL(wp), DIMENSION(1:jpk) :: h_out
486      INTEGER ::N_in, N_out
487      !!---------------------------------------------   
488      !
489      IF( before ) THEN
490         DO jk=k1,k2
491            DO jj=j1,j2
492               DO ji=i1,i2
493                  tabres(ji,jj,jk,m1) = ub(ji,jj,jk)
494# if defined key_vertical
495                  tabres(ji,jj,jk,m2) = e3u_b(ji,jj,jk)*umask(ji,jj,jk)
496# endif
497               END DO
498            END DO
499         END DO
500
501# if defined key_vertical
502         ! Extrapolate thicknesses in partial bottom cells:
503         ! Set them to Agrif_SpecialValue (0.). Correct bottom thicknesses are retrieved later on
504         IF (ln_zps) THEN
505            DO jj=j1,j2
506               DO ji=i1,i2
507                  jk = mbku(ji,jj)
508                  tabres(ji,jj,jk,m2) = 0._wp
509               END DO
510            END DO           
511         END IF
512        ! Save ssh at last level:
513        tabres(i1:i2,j1:j2,k2,m2) = 0._wp
514        IF (.NOT.ln_linssh) THEN
515           ! This vertical sum below should be replaced by the sea-level at U-points (optimization):
516           DO jk=1,jpk
517              tabres(i1:i2,j1:j2,k2,m2) = tabres(i1:i2,j1:j2,k2,m2) + e3u_b(i1:i2,j1:j2,jk) * umask(i1:i2,j1:j2,jk)
518           END DO
519           tabres(i1:i2,j1:j2,k2,m2) = tabres(i1:i2,j1:j2,k2,m2) - hu_0(i1:i2,j1:j2)
520        END IF 
521# endif
522
523      ELSE
524
525# if defined key_vertical
526         IF (ln_linssh) tabres(i1:i2,j1:j2,k2,m2) = 0._wp
527
528         DO jj=j1,j2
529            DO ji=i1,i2
530               tabres_child(ji,jj,:) = 0._wp
531               N_in = mbku_parent(ji,jj)
532               zhtot = 0._wp
533               DO jk=1,N_in
534                  IF (jk==N_in) THEN
535                     h_in(jk) = hu0_parent(ji,jj) + tabres(ji,jj,k2,m2) - zhtot
536                  ELSE
537                     h_in(jk) = tabres(ji,jj,jk,m2)
538                  ENDIF
539                  zhtot = zhtot + h_in(jk)
540                  tabin(jk) = tabres(ji,jj,jk,m1)
541               ENDDO
542               !         
543               N_out = 0
544               DO jk=1,jpk
545                  IF (umask(ji,jj,jk) == 0) EXIT
546                  N_out = N_out + 1
547                  h_out(N_out) = e3u_b(ji,jj,jk)
548               ENDDO
549
550               ! Account for small differences in free-surface
551               IF ( sum(h_out(1:N_out)) > sum(h_in(1:N_in) )) THEN
552                  h_out(1) = h_out(1) - ( sum(h_out(1:N_out))-sum(h_in(1:N_in)) )
553               ELSE
554                  h_in(1)   = h_in(1)   - (sum(h_in(1:N_in))-sum(h_out(1:N_out)) )
555               ENDIF
556                 
557               IF (N_in * N_out > 0) THEN
558                  CALL reconstructandremap(tabin(1:N_in),h_in(1:N_in),tabres_child(ji,jj,1:N_out),h_out(1:N_out),N_in,N_out,1)
559               ENDIF
560            ENDDO
561         ENDDO
562
563         ubdiff(i1:i2,j1:j2,:) = (ub(i1:i2,j1:j2,:) - tabres_child(i1:i2,j1:j2,:))*umask(i1:i2,j1:j2,:)
564#else
565         ubdiff(i1:i2,j1:j2,:) = (ub(i1:i2,j1:j2,:) - tabres(i1:i2,j1:j2,:,1))*umask(i1:i2,j1:j2,:)
566#endif
567         !* set relaxation time scale
568         IF( neuler == 0 .AND. lk_agrif_fstep ) THEN   ;   ztrelax =   rn_trelax_dyn  / (        rdt )
569         ELSE                                          ;   ztrelax =   rn_trelax_dyn  / (2._wp * rdt )
570         ENDIF
571         !
572         DO jk = 1, jpkm1                                 ! Horizontal slab
573            !                                             ! ===============
574
575            !                                             ! --------
576            ! Horizontal divergence                       !   div
577            !                                             ! --------
578            DO jj = j1,j2
579               DO ji = i1+1,i2   ! vector opt.
580                  zbtr = r1_e1e2t(ji,jj) / e3t_b(ji,jj,jk) * rn_sponge_dyn * fspt(ji,jj)
581                  hdivdiff(ji,jj,jk) = (  e2u(ji  ,jj)*e3u_b(ji  ,jj,jk) * ubdiff(ji  ,jj,jk) &
582                                     &   -e2u(ji-1,jj)*e3u_b(ji-1,jj,jk) * ubdiff(ji-1,jj,jk) ) * zbtr
583               END DO
584            END DO
585
586            DO jj = j1,j2-1
587               DO ji = i1,i2   ! vector opt.
588                  zbtr = r1_e1e2f(ji,jj) * e3f_n(ji,jj,jk) * rn_sponge_dyn * fspf(ji,jj)
589                  rotdiff(ji,jj,jk) = ( -e1u(ji,jj+1) * ubdiff(ji,jj+1,jk)   &
590                                    &   +e1u(ji,jj  ) * ubdiff(ji,jj  ,jk) ) * fmask(ji,jj,jk) * zbtr 
591               END DO
592            END DO
593         END DO
594         !
595         DO jj = j1+1, j2-1
596            DO ji = i1+1, i2-1   ! vector opt.
597
598               IF (.NOT. tabspongedone_u(ji,jj)) THEN
599                  DO jk = 1, jpkm1                                 ! Horizontal slab
600                     ze2u = rotdiff (ji,jj,jk)
601                     ze1v = hdivdiff(ji,jj,jk)
602                     ! horizontal diffusive trends
603                     zua = - ( ze2u - rotdiff (ji,jj-1,jk) ) / ( e2u(ji,jj) * e3u_n(ji,jj,jk) )   &
604                         & + ( hdivdiff(ji+1,jj,jk) - ze1v ) * r1_e1u(ji,jj) & 
605                         & - ztrelax  * fspu(ji,jj) * ubdiff(ji,jj,jk)
606
607                     ! add it to the general momentum trends
608                     ua(ji,jj,jk) = ua(ji,jj,jk) + zua                                 
609                  END DO
610               ENDIF
611
612            END DO
613         END DO
614
615         tabspongedone_u(i1+1:i2-1,j1+1:j2-1) = .TRUE.
616
617         jmax = j2-1
618         IF ((nbondj == 1).OR.(nbondj == 2)) jmax = MIN(jmax,nlcj-nbghostcells-2)   ! North
619
620         DO jj = j1+1, jmax
621            DO ji = i1+1, i2   ! vector opt.
622
623               IF (.NOT. tabspongedone_v(ji,jj)) THEN
624                  DO jk = 1, jpkm1                                 ! Horizontal slab
625                     ze2u = rotdiff (ji,jj,jk)
626                     ze1v = hdivdiff(ji,jj,jk)
627
628                     ! horizontal diffusive trends
629                     zva = + ( ze2u - rotdiff (ji-1,jj,jk) ) / ( e1v(ji,jj) * e3v_n(ji,jj,jk) )   &
630                           + ( hdivdiff(ji,jj+1,jk) - ze1v ) * r1_e2v(ji,jj)
631
632                     ! add it to the general momentum trends
633                     va(ji,jj,jk) = va(ji,jj,jk) + zva
634                  END DO
635               ENDIF
636               !
637            END DO
638         END DO
639         !
640         tabspongedone_v(i1+1:i2,j1+1:jmax) = .TRUE.
641         !
642      ENDIF
643      !
644   END SUBROUTINE interpun_sponge
645
646   SUBROUTINE interpvn_sponge(tabres,i1,i2,j1,j2,k1,k2,m1,m2, before,nb,ndir)
647      !!---------------------------------------------
648      !!   *** ROUTINE interpvn_sponge ***
649      !!---------------------------------------------
650      INTEGER, INTENT(in) :: i1,i2,j1,j2,k1,k2,m1,m2
651      REAL(wp), DIMENSION(i1:i2,j1:j2,k1:k2,m1:m2), INTENT(inout) :: tabres
652      LOGICAL, INTENT(in) :: before
653      INTEGER, INTENT(in) :: nb , ndir
654      !
655      INTEGER  ::   ji, jj, jk, imax
656      REAL(wp) ::   ze2u, ze1v, zua, zva, zbtr, zhtot, ztrelax
657      REAL(wp), DIMENSION(i1:i2,j1:j2,1:jpk) :: vbdiff
658      REAL(wp), DIMENSION(i1:i2,j1:j2,1:jpk) :: rotdiff, hdivdiff
659      ! vertical interpolation:
660      REAL(wp), DIMENSION(i1:i2,j1:j2,1:jpk) :: tabres_child
661      REAL(wp), DIMENSION(k1:k2) :: tabin, h_in
662      REAL(wp), DIMENSION(1:jpk) :: h_out
663      INTEGER :: N_in, N_out
664      !!---------------------------------------------
665     
666      IF( before ) THEN
667         DO jk=k1,k2
668            DO jj=j1,j2
669               DO ji=i1,i2
670                  tabres(ji,jj,jk,m1) = vb(ji,jj,jk)
671# if defined key_vertical
672                  tabres(ji,jj,jk,m2) = vmask(ji,jj,jk) * e3v_b(ji,jj,jk)
673# endif
674               END DO
675            END DO
676         END DO
677
678# if defined key_vertical
679         ! Extrapolate thicknesses in partial bottom cells:
680         ! Set them to Agrif_SpecialValue (0.). Correct bottom thicknesses are retrieved later on
681         IF (ln_zps) THEN
682            DO jj=j1,j2
683               DO ji=i1,i2
684                  jk = mbkv(ji,jj)
685                  tabres(ji,jj,jk,m2) = 0._wp
686               END DO
687            END DO           
688         END IF
689        ! Save ssh at last level:
690        tabres(i1:i2,j1:j2,k2,m2) = 0._wp
691        IF (.NOT.ln_linssh) THEN
692           ! This vertical sum below should be replaced by the sea-level at V-points (optimization):
693           DO jk=1,jpk
694              tabres(i1:i2,j1:j2,k2,m2) = tabres(i1:i2,j1:j2,k2,m2) + e3v_b(i1:i2,j1:j2,jk) * vmask(i1:i2,j1:j2,jk)
695           END DO
696           tabres(i1:i2,j1:j2,k2,m2) = tabres(i1:i2,j1:j2,k2,m2) - hv_0(i1:i2,j1:j2)
697        END IF 
698# endif
699
700      ELSE
701
702# if defined key_vertical
703         IF (ln_linssh) tabres(i1:i2,j1:j2,k2,m2) = 0._wp
704         DO jj=j1,j2
705            DO ji=i1,i2
706               tabres_child(ji,jj,:) = 0._wp
707               N_in = mbkv_parent(ji,jj)
708               zhtot = 0._wp
709               DO jk=1,N_in
710                  IF (jk==N_in) THEN
711                     h_in(jk) = hv0_parent(ji,jj) + tabres(ji,jj,k2,m2) - zhtot
712                  ELSE
713                     h_in(jk) = tabres(ji,jj,jk,m2)
714                  ENDIF
715                  zhtot = zhtot + h_in(jk)
716                  tabin(jk) = tabres(ji,jj,jk,m1)
717               ENDDO
718               !         
719               N_out = 0
720               DO jk=1,jpk
721                  IF (vmask(ji,jj,jk) == 0) EXIT
722                  N_out = N_out + 1
723                  h_out(N_out) = e3v_b(ji,jj,jk)
724               ENDDO
725
726               ! Account for small differences in free-surface
727               IF ( sum(h_out(1:N_out)) > sum(h_in(1:N_in) )) THEN
728                  h_out(1) = h_out(1) - ( sum(h_out(1:N_out))-sum(h_in(1:N_in)) )
729               ELSE
730                  h_in(1)   = h_in(1) - (  sum(h_in(1:N_in))-sum(h_out(1:N_out)) )
731               ENDIF
732         
733               IF (N_in * N_out > 0) THEN
734                  CALL reconstructandremap(tabin(1:N_in),h_in(1:N_in),tabres_child(ji,jj,1:N_out),h_out(1:N_out),N_in,N_out,1)
735               ENDIF
736            ENDDO
737         ENDDO
738
739         vbdiff(i1:i2,j1:j2,:) = (vb(i1:i2,j1:j2,:) - tabres_child(i1:i2,j1:j2,:))*vmask(i1:i2,j1:j2,:) 
740# else
741         vbdiff(i1:i2,j1:j2,:) = (vb(i1:i2,j1:j2,:) - tabres(i1:i2,j1:j2,:,1))*vmask(i1:i2,j1:j2,:)
742# endif
743         !* set relaxation time scale
744         IF( neuler == 0 .AND. lk_agrif_fstep ) THEN   ;   ztrelax =   rn_trelax_dyn  / (        rdt )
745         ELSE                                          ;   ztrelax =   rn_trelax_dyn  / (2._wp * rdt )
746         ENDIF
747         !
748         DO jk = 1, jpkm1                                 ! Horizontal slab
749            !                                             ! ===============
750
751            !                                             ! --------
752            ! Horizontal divergence                       !   div
753            !                                             ! --------
754            DO jj = j1+1,j2
755               DO ji = i1,i2   ! vector opt.
756                  zbtr = r1_e1e2t(ji,jj) / e3t_b(ji,jj,jk) * rn_sponge_dyn * fspt(ji,jj)
757                  hdivdiff(ji,jj,jk) = ( e1v(ji,jj  ) * e3v_b(ji,jj  ,jk) * vbdiff(ji,jj  ,jk)  &
758                                     &  -e1v(ji,jj-1) * e3v_b(ji,jj-1,jk) * vbdiff(ji,jj-1,jk)  ) * zbtr
759               END DO
760            END DO
761            DO jj = j1,j2
762               DO ji = i1,i2-1   ! vector opt.
763                  zbtr = r1_e1e2f(ji,jj) * e3f_n(ji,jj,jk) * rn_sponge_dyn * fspf(ji,jj)
764                  rotdiff(ji,jj,jk) = ( e2v(ji+1,jj) * vbdiff(ji+1,jj,jk) & 
765                                    &  -e2v(ji  ,jj) * vbdiff(ji  ,jj,jk)  ) * fmask(ji,jj,jk) * zbtr
766               END DO
767            END DO
768         END DO
769
770         !                                                ! ===============
771         !                                               
772
773         imax = i2 - 1
774         IF ((nbondi == 1).OR.(nbondi == 2))   imax = MIN(imax,nlci-nbghostcells-2)   ! East
775
776         DO jj = j1+1, j2
777            DO ji = i1+1, imax   ! vector opt.
778               IF( .NOT. tabspongedone_u(ji,jj) ) THEN
779                  DO jk = 1, jpkm1
780                     ua(ji,jj,jk) = ua(ji,jj,jk)                                                               &
781                        & - ( rotdiff (ji  ,jj,jk) - rotdiff (ji,jj-1,jk)) / ( e2u(ji,jj) * e3u_n(ji,jj,jk) )  &
782                        & + ( hdivdiff(ji+1,jj,jk) - hdivdiff(ji,jj  ,jk)) * r1_e1u(ji,jj)
783                  END DO
784               ENDIF
785            END DO
786         END DO
787         !
788         tabspongedone_u(i1+1:imax,j1+1:j2) = .TRUE.
789         !
790         DO jj = j1+1, j2-1
791            DO ji = i1+1, i2-1   ! vector opt.
792               IF( .NOT. tabspongedone_v(ji,jj) ) THEN
793                  DO jk = 1, jpkm1
794                     va(ji,jj,jk) = va(ji,jj,jk)                                                                  &
795                        &  + ( rotdiff (ji,jj  ,jk) - rotdiff (ji-1,jj,jk) ) / ( e1v(ji,jj) * e3v_n(ji,jj,jk) )   &
796                        &  + ( hdivdiff(ji,jj+1,jk) - hdivdiff(ji  ,jj,jk) ) * r1_e2v(ji,jj)                      &
797                        &  - ztrelax * fspv(ji,jj) * vbdiff(ji,jj,jk)
798                  END DO
799               ENDIF
800            END DO
801         END DO
802         tabspongedone_v(i1+1:i2-1,j1+1:j2-1) = .TRUE.
803      ENDIF
804      !
805   END SUBROUTINE interpvn_sponge
806
807#else
808   !!----------------------------------------------------------------------
809   !!   Empty module                                          no AGRIF zoom
810   !!----------------------------------------------------------------------
811CONTAINS
812   SUBROUTINE agrif_oce_sponge_empty
813      WRITE(*,*)  'agrif_oce_sponge : You should not have seen this print! error?'
814   END SUBROUTINE agrif_oce_sponge_empty
815#endif
816
817   !!======================================================================
818END MODULE agrif_oce_sponge
Note: See TracBrowser for help on using the repository browser.