New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
agrif_top_sponge.F90 in NEMO/branches/2019/dev_r11233_AGRIF-05_jchanut_vert_coord_interp/src/NST – NEMO

source: NEMO/branches/2019/dev_r11233_AGRIF-05_jchanut_vert_coord_interp/src/NST/agrif_top_sponge.F90 @ 11625

Last change on this file since 11625 was 11625, checked in by jchanut, 4 years ago

#2222, add initialization to 0 of tracer open boundary data with vertical interpolation + various neutral optimizations

  • Property svn:keywords set to Id
File size: 6.6 KB
Line 
1#define SPONGE_TOP
2
3MODULE agrif_top_sponge
4   !!======================================================================
5   !!                ***  MODULE agrif_top_sponge  ***
6   !! AGRIF :   sponge layer pakage for passive tracers (TOP)
7   !!======================================================================
8   !! History :  2.0  ! 2006-08  (R. Benshila, L. Debreu)  Original code
9   !!----------------------------------------------------------------------
10#if defined key_agrif && defined key_top
11   !!----------------------------------------------------------------------
12   !!   Agrif_Sponge_trc :
13   !!   interptrn_sponge : 
14   !!----------------------------------------------------------------------
15   USE par_oce
16   USE par_trc
17   USE oce
18   USE trc
19   USE dom_oce
20   USE agrif_oce
21   USE agrif_oce_sponge
22   USE vremap
23   !
24   USE in_out_manager
25   USE lib_mpp
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC Agrif_Sponge_trc, interptrn_sponge
31
32   !!----------------------------------------------------------------------
33   !! NEMO/NST 4.0 , NEMO Consortium (2018)
34   !! $Id$
35   !! Software governed by the CeCILL license (see ./LICENSE)
36   !!----------------------------------------------------------------------
37CONTAINS
38
39   SUBROUTINE Agrif_Sponge_trc
40      !!----------------------------------------------------------------------
41      !!                   *** ROUTINE Agrif_Sponge_Trc ***
42      !!----------------------------------------------------------------------
43      REAL(wp) ::   zcoef   ! local scalar
44      !!----------------------------------------------------------------------
45      !
46#if defined SPONGE_TOP
47!! Assume persistence
48      zcoef = REAL(Agrif_rhot()-1,wp)/REAL(Agrif_rhot())
49      CALL Agrif_sponge
50      Agrif_SpecialValue    = 0._wp
51      Agrif_UseSpecialValue = .TRUE.
52      tabspongedone_trn     = .FALSE.
53      CALL Agrif_Bc_Variable( trn_sponge_id, calledweight=zcoef, procname=interptrn_sponge )
54      Agrif_UseSpecialValue = .FALSE.
55#endif
56      !
57   END SUBROUTINE Agrif_Sponge_Trc
58
59
60   SUBROUTINE interptrn_sponge( tabres, i1, i2, j1, j2, k1, k2, n1, n2, before )
61      !!----------------------------------------------------------------------
62      !!                   *** ROUTINE interptrn_sponge ***
63      !!----------------------------------------------------------------------
64      INTEGER                                     , INTENT(in   ) ::   i1, i2, j1, j2, k1, k2, n1, n2
65      REAL(wp), DIMENSION(i1:i2,j1:j2,k1:k2,n1:n2), INTENT(inout) ::   tabres
66      LOGICAL                                     , INTENT(in   ) ::   before
67      !
68      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
69      REAL(wp) ::   zabe1, zabe2
70      REAL(wp), DIMENSION(i1:i2,j1:j2)               ::   ztu, ztv
71      REAL(wp), DIMENSION(i1:i2,j1:j2,k1:k2,1:jptra) ::   trbdiff
72      ! vertical interpolation:
73      REAL(wp), DIMENSION(i1:i2,j1:j2,jpk,1:jptra) ::tabres_child
74      REAL(wp), DIMENSION(k1:k2,1:jptra) :: tabin
75      REAL(wp), DIMENSION(k1:k2) :: h_in
76      REAL(wp), DIMENSION(1:jpk) :: h_out
77      INTEGER :: N_in, N_out
78      REAL(wp) :: h_diff
79      !!----------------------------------------------------------------------
80      !
81      IF( before ) THEN
82         DO jn = 1, jptra
83            DO jk=k1,k2
84               DO jj=j1,j2
85                  DO ji=i1,i2
86                     tabres(ji,jj,jk,jn) = trb(ji,jj,jk,jn)
87                  END DO
88               END DO
89            END DO
90         END DO
91
92# if defined key_vertical
93         DO jk=k1,k2
94            DO jj=j1,j2
95               DO ji=i1,i2
96                  tabres(ji,jj,jk,jpts+1) = tmask(ji,jj,jk) * e3t_b(ji,jj,jk) 
97               END DO
98            END DO
99         END DO
100# endif
101      ELSE     
102# if defined key_vertical
103         tabres_child(:,:,:,:) = 0.
104         DO jj=j1,j2
105            DO ji=i1,i2
106               N_in = 0
107               DO jk=k1,k2 !k2 = jpk of parent grid
108                  IF (tabres(ji,jj,jk,n2) == 0) EXIT
109                  N_in = N_in + 1
110                  tabin(jk,:) = tabres(ji,jj,jk,n1:n2-1)
111                  h_in(N_in) = tabres(ji,jj,jk,n2)
112               END DO
113               N_out = 0
114               DO jk=1,jpk ! jpk of child grid
115                  IF (tmask(ji,jj,jk) == 0) EXIT
116                  N_out = N_out + 1
117                  h_out(jk) = e3t_b(ji,jj,jk) !Child grid scale factors. Could multiply by e1e2t here instead of division above
118               ENDDO
119               IF (N_in > 0) THEN
120                  CALL reconstructandremap(tabin(1:N_in,1:jptra),h_in,tabres_child(ji,jj,1:N_out,1:jptra),h_out,N_in,N_out,jptra)
121               ENDIF
122            ENDDO
123         ENDDO
124# endif
125
126         DO jj=j1,j2
127            DO ji=i1,i2
128               DO jk=1,jpkm1
129# if defined key_vertical
130                  trbdiff(ji,jj,jk,1:jptra) = trb(ji,jj,jk,1:jptra) - tabres_child(ji,jj,jk,1:jptra)
131# else
132                  trbdiff(ji,jj,jk,1:jptra) = trb(ji,jj,jk,1:jptra) - tabres(ji,jj,jk,1:jptra)
133# endif
134               ENDDO
135            ENDDO
136         ENDDO
137
138         DO jn = 1, jptra
139            DO jk = 1, jpkm1
140               DO jj = j1,j2-1
141                  DO ji = i1,i2-1
142                     zabe1 = fsaht_spu(ji,jj) * e2_e1u(ji,jj) * e3u_n(ji,jj,jk) * umask(ji,jj,jk)
143                     zabe2 = fsaht_spv(ji,jj) * e1_e2v(ji,jj) * e3v_n(ji,jj,jk) * vmask(ji,jj,jk)
144                     ztu(ji,jj) = zabe1 * ( trbdiff(ji+1,jj  ,jk,jn) - trbdiff(ji,jj,jk,jn) )
145                     ztv(ji,jj) = zabe2 * ( trbdiff(ji  ,jj+1,jk,jn) - trbdiff(ji,jj,jk,jn) )
146                  END DO
147               END DO
148               !
149               DO jj = j1+1,j2-1
150                  DO ji = i1+1,i2-1
151                     IF( .NOT. tabspongedone_trn(ji,jj) ) THEN
152                        tra(ji,jj,jk,jn) = tra(ji,jj,jk,jn) + (  ztu(ji,jj) - ztu(ji-1,jj  )     &
153                           &                                   + ztv(ji,jj) - ztv(ji  ,jj-1)  )  &
154                           &                                * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
155                     ENDIF
156                  END DO
157               END DO
158            END DO
159            !
160         END DO
161         !
162         tabspongedone_trn(i1+1:i2-1,j1+1:j2-1) = .TRUE.
163      ENDIF
164      !                 
165   END SUBROUTINE interptrn_sponge
166
167#else
168   !!----------------------------------------------------------------------
169   !!   Empty module                                           no TOP AGRIF
170   !!----------------------------------------------------------------------
171CONTAINS
172   SUBROUTINE agrif_top_sponge_empty
173      WRITE(*,*)  'agrif_top_sponge : You should not have seen this print! error?'
174   END SUBROUTINE agrif_top_sponge_empty
175#endif
176
177   !!======================================================================
178END MODULE agrif_top_sponge
Note: See TracBrowser for help on using the repository browser.