New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
icesbc.F90 in NEMO/branches/2019/dev_r11265_ASINTER-01_Guillaume_ABL1D/src/ICE – NEMO

source: NEMO/branches/2019/dev_r11265_ASINTER-01_Guillaume_ABL1D/src/ICE/icesbc.F90 @ 11334

Last change on this file since 11334 was 11334, checked in by flemarie, 5 years ago

Follow-on to the ABL implementation (see ticket #2131)

  • Modification of diawri.F90 to output ABL variables with IOIPSL (i.e. without key_iomput)
  • Modification of ice_var_agg in icevar.F90 to allow the use of tm_su in ABL and bulk
  • Error handling in case ln_abl = .true. and ABL sources were not compiled
  • ABL now works with SI3 considering an average over ice categories
  • Update reference namelist to avoid runtime warnings due to nam_tide
  • Sanity checks with ORCA2 for the following configurations :

1 - ABL src + ln_blk = .true.
2 - ABL src + ln_abl = .true.
3 - no ABL src + ln_blk = .true.

All configurations are MPP reproducible and configurations 1 and 3 results are identical

  • Property svn:keywords set to Id
File size: 17.5 KB
Line 
1MODULE icesbc
2   !!======================================================================
3   !!                       ***  MODULE  icesbc  ***
4   !! Sea-Ice :   air-ice sbc fields
5   !!=====================================================================
6   !! History :  4.0  !  2017-08  (C. Rousset)       Original code
7   !!            4.0  !  2018     (many people)      SI3 [aka Sea Ice cube]
8   !!----------------------------------------------------------------------
9#if defined key_si3
10   !!----------------------------------------------------------------------
11   !!   'key_si3' :                                     SI3 sea-ice model
12   !!----------------------------------------------------------------------
13   USE oce            ! ocean dynamics and tracers
14   USE dom_oce        ! ocean space and time domain
15   USE ice            ! sea-ice: variables
16   USE sbc_oce        ! Surface boundary condition: ocean fields
17   USE sbc_ice        ! Surface boundary condition: ice   fields
18   USE usrdef_sbc     ! Surface boundary condition: user defined
19   USE sbcblk         ! Surface boundary condition: bulk
20   USE sbccpl         ! Surface boundary condition: coupled interface
21   USE icealb         ! sea-ice: albedo
22   !
23   USE in_out_manager ! I/O manager
24   USE iom            ! I/O manager library
25   USE lib_mpp        ! MPP library
26   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
27   USE lbclnk         ! lateral boundary conditions (or mpp links)
28   USE timing         ! Timing
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC ice_sbc_tau   ! called by icestp.F90
34   PUBLIC ice_sbc_flx   ! called by icestp.F90
35   PUBLIC ice_sbc_init  ! called by icestp.F90
36
37   !! * Substitutions
38#  include "vectopt_loop_substitute.h90"
39   !!----------------------------------------------------------------------
40   !! NEMO/ICE 4.0 , NEMO Consortium (2018)
41   !! $Id$
42   !! Software governed by the CeCILL license (see ./LICENSE)
43   !!----------------------------------------------------------------------
44CONTAINS
45
46   SUBROUTINE ice_sbc_tau( kt, ksbc, utau_ice, vtau_ice )
47      !!-------------------------------------------------------------------
48      !!                  ***  ROUTINE ice_sbc_tau  ***
49      !!
50      !! ** Purpose : provide surface boundary condition for sea ice (momentum)
51      !!
52      !! ** Action  : It provides the following fields:
53      !!              utau_ice, vtau_ice : surface ice stress (U- & V-points) [N/m2]
54      !!-------------------------------------------------------------------
55      INTEGER                     , INTENT(in   ) ::   kt                   ! ocean time step
56      INTEGER                     , INTENT(in   ) ::   ksbc                 ! type of sbc flux
57      REAL(wp), DIMENSION(jpi,jpj), INTENT(  out) ::   utau_ice, vtau_ice   ! air-ice stress   [N/m2]
58      !!
59      INTEGER  ::   ji, jj                 ! dummy loop index
60      REAL(wp), DIMENSION(jpi,jpj) ::   zutau_ice, zvtau_ice 
61      !!-------------------------------------------------------------------
62      !
63      IF( ln_timing )   CALL timing_start('ice_sbc')
64      !
65      IF( kt == nit000 .AND. lwp ) THEN
66         WRITE(numout,*)
67         WRITE(numout,*)'ice_sbc_tau: Surface boundary condition for sea ice (momentum)'
68         WRITE(numout,*)'~~~~~~~~~~~~~~~'
69      ENDIF
70      !
71      SELECT CASE( ksbc )
72         CASE( jp_usr     )   ;    CALL usrdef_sbc_ice_tau( kt )                 ! user defined formulation
73         CASE( jp_blk     )   ;    CALL blk_ice_1( sf(jp_wndi)%fnow(:,:,1), sf(jp_wndj)%fnow(:,:,1),   &
74            &                                      sf(jp_tair)%fnow(:,:,1), sf(jp_humi)%fnow(:,:,1), sf(jp_slp)%fnow(:,:,1),   &
75            &                                      u_ice, v_ice,   &    ! inputs
76            &                                      putaui = utau_ice, pvtaui = vtau_ice )    ! outputs                             
77 !        CASE( jp_abl     )    utau_ice & vtau_ice are computed in ablmod
78         CASE( jp_purecpl )   ;    CALL sbc_cpl_ice_tau( utau_ice , vtau_ice )   ! Coupled      formulation
79      END SELECT
80      !
81      IF( ln_mixcpl) THEN                                                        ! Case of a mixed Bulk/Coupled formulation
82                                   CALL sbc_cpl_ice_tau( zutau_ice , zvtau_ice )
83         DO jj = 2, jpjm1
84            DO ji = 2, jpim1
85               utau_ice(ji,jj) = utau_ice(ji,jj) * xcplmask(ji,jj,0) + zutau_ice(ji,jj) * ( 1. - xcplmask(ji,jj,0) )
86               vtau_ice(ji,jj) = vtau_ice(ji,jj) * xcplmask(ji,jj,0) + zvtau_ice(ji,jj) * ( 1. - xcplmask(ji,jj,0) )
87            END DO
88         END DO
89         CALL lbc_lnk_multi( 'icesbc', utau_ice, 'U', -1., vtau_ice, 'V', -1. )
90      ENDIF
91      !
92      IF( ln_timing )   CALL timing_stop('ice_sbc')
93      !
94   END SUBROUTINE ice_sbc_tau
95
96   
97   SUBROUTINE ice_sbc_flx( kt, ksbc )
98      !!-------------------------------------------------------------------
99      !!                  ***  ROUTINE ice_sbc_flx  ***
100      !!
101      !! ** Purpose : provide surface boundary condition for sea ice (flux)
102      !!
103      !! ** Action  : It provides the following fields used in sea ice model:
104      !!                emp_oce , emp_ice                        = E-P over ocean and sea ice                    [Kg/m2/s]
105      !!                sprecip                                  = solid precipitation                           [Kg/m2/s]
106      !!                evap_ice                                 = sublimation                                   [Kg/m2/s]
107      !!                qsr_tot , qns_tot                        = solar & non solar heat flux (total)           [W/m2]
108      !!                qsr_ice , qns_ice                        = solar & non solar heat flux over ice          [W/m2]
109      !!                dqns_ice                                 = non solar  heat sensistivity                  [W/m2]
110      !!                qemp_oce, qemp_ice, qprec_ice, qevap_ice = sensible heat (associated with evap & precip) [W/m2]
111      !!            + some fields that are not used outside this module:
112      !!                qla_ice                                  = latent heat flux over ice                     [W/m2]
113      !!                dqla_ice                                 = latent heat sensistivity                      [W/m2]
114      !!                tprecip                                  = total  precipitation                          [Kg/m2/s]
115      !!                alb_ice                                  = albedo above sea ice
116      !!-------------------------------------------------------------------
117      INTEGER, INTENT(in) ::   kt     ! ocean time step
118      INTEGER, INTENT(in) ::   ksbc   ! flux formulation (user defined, bulk or Pure Coupled)
119      !
120      INTEGER  ::   ji, jj, jl                                ! dummy loop index
121      REAL(wp), DIMENSION(jpi,jpj,jpl) ::   zalb_os, zalb_cs  ! ice albedo under overcast/clear sky
122      REAL(wp), DIMENSION(jpi,jpj)     ::   zalb              ! 2D workspace
123      !!--------------------------------------------------------------------
124      !
125      IF( ln_timing )   CALL timing_start('ice_sbc_flx')
126
127      IF( kt == nit000 .AND. lwp ) THEN
128         WRITE(numout,*)
129         WRITE(numout,*)'ice_sbc_flx: Surface boundary condition for sea ice (flux)'
130         WRITE(numout,*)'~~~~~~~~~~~~~~~'
131      ENDIF
132
133      ! --- cloud-sky and overcast-sky ice albedos --- !
134      CALL ice_alb( t_su, h_i, h_s, ln_pnd_alb, a_ip_frac, h_ip, zalb_cs, zalb_os )
135
136      ! albedo depends on cloud fraction because of non-linear spectral effects
137!!gm cldf_ice is a real, DOCTOR naming rule: start with cd means CHARACTER passed in argument !
138      alb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
139      !
140      !
141      SELECT CASE( ksbc )   !== fluxes over sea ice ==!
142      !
143      CASE( jp_usr )              !--- user defined formulation
144                                  CALL usrdef_sbc_ice_flx( kt, h_s, h_i )
145      CASE( jp_blk, jp_abl )  !--- bulk formulation & ABL formulation
146                                  CALL blk_ice_2    ( t_su, h_s, h_i, alb_ice, sf(jp_tair)%fnow(:,:,1), sf(jp_humi)%fnow(:,:,1),    &
147            &                                           sf(jp_slp)%fnow(:,:,1), sf(jp_qlw)%fnow(:,:,1), sf(jp_prec)%fnow(:,:,1), sf(jp_snow)%fnow(:,:,1) )    !
148         IF( ln_mixcpl        )   CALL sbc_cpl_ice_flx( picefr=at_i_b, palbi=alb_ice, psst=sst_m, pist=t_su, phs=h_s, phi=h_i )
149         IF( nn_flxdist /= -1 )   CALL ice_flx_dist   ( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_flxdist )
150         !                        !    compute conduction flux and surface temperature (as in Jules surface module)
151         IF( ln_cndflx .AND. .NOT.ln_cndemulate ) &
152            &                     CALL blk_ice_qcn    ( ln_virtual_itd, t_su, t_bo, h_s, h_i )
153      CASE ( jp_purecpl )         !--- coupled formulation
154                                  CALL sbc_cpl_ice_flx( picefr=at_i_b, palbi=alb_ice, psst=sst_m, pist=t_su, phs=h_s, phi=h_i )
155         IF( nn_flxdist /= -1 )   CALL ice_flx_dist   ( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_flxdist )
156      END SELECT
157
158      !--- output ice albedo and surface albedo ---!
159      IF( iom_use('icealb') ) THEN
160         WHERE( at_i_b <= epsi06 )   ;   zalb(:,:) = rn_alb_oce
161         ELSEWHERE                   ;   zalb(:,:) = SUM( alb_ice * a_i_b, dim=3 ) / at_i_b
162         END WHERE
163         CALL iom_put( "icealb" , zalb(:,:) )
164      ENDIF
165      IF( iom_use('albedo') ) THEN
166         zalb(:,:) = SUM( alb_ice * a_i_b, dim=3 ) + rn_alb_oce * ( 1._wp - at_i_b )
167         CALL iom_put( "albedo" , zalb(:,:) )
168      ENDIF
169      !
170      IF( ln_timing )   CALL timing_stop('ice_sbc_flx')
171      !
172   END SUBROUTINE ice_sbc_flx
173
174
175   SUBROUTINE ice_flx_dist( ptn_ice, palb_ice, pqns_ice, pqsr_ice, pdqn_ice, pevap_ice, pdevap_ice, k_flxdist )
176      !!-------------------------------------------------------------------
177      !!                  ***  ROUTINE ice_flx_dist  ***
178      !!
179      !! ** Purpose :   update the ice surface boundary condition by averaging
180      !!              and/or redistributing fluxes on ice categories
181      !!
182      !! ** Method  :   average then redistribute
183      !!
184      !! ** Action  :   depends on k_flxdist
185      !!                = -1  Do nothing (needs N(cat) fluxes)
186      !!                =  0  Average N(cat) fluxes then apply the average over the N(cat) ice
187      !!                =  1  Average N(cat) fluxes then redistribute over the N(cat) ice
188      !!                                                 using T-ice and albedo sensitivity
189      !!                =  2  Redistribute a single flux over categories
190      !!-------------------------------------------------------------------
191      INTEGER                   , INTENT(in   ) ::   k_flxdist  ! redistributor
192      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   ptn_ice    ! ice surface temperature
193      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   palb_ice   ! ice albedo
194      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pqns_ice   ! non solar flux
195      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pqsr_ice   ! net solar flux
196      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pdqn_ice   ! non solar flux sensitivity
197      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pevap_ice  ! sublimation
198      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pdevap_ice ! sublimation sensitivity
199      !
200      INTEGER  ::   jl      ! dummy loop index
201      !
202      REAL(wp), DIMENSION(jpi,jpj) ::   z1_at_i   ! inverse of concentration
203      !
204      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   z_qsr_m   ! Mean solar heat flux over all categories
205      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   z_qns_m   ! Mean non solar heat flux over all categories
206      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   z_evap_m  ! Mean sublimation over all categories
207      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   z_dqn_m   ! Mean d(qns)/dT over all categories
208      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   z_devap_m ! Mean d(evap)/dT over all categories
209      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   zalb_m    ! Mean albedo over all categories
210      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   ztem_m    ! Mean temperature over all categories
211      !!----------------------------------------------------------------------
212      !
213      WHERE ( at_i (:,:) > 0._wp )   ; z1_at_i(:,:) = 1._wp / at_i (:,:)
214      ELSEWHERE                      ; z1_at_i(:,:) = 0._wp
215      END WHERE
216     
217      SELECT CASE( k_flxdist )       !==  averaged on all ice categories  ==!
218      !
219      CASE( 0 , 1 )
220         !
221         ALLOCATE( z_qns_m(jpi,jpj), z_qsr_m(jpi,jpj), z_dqn_m(jpi,jpj), z_evap_m(jpi,jpj), z_devap_m(jpi,jpj) ) 
222         !
223         z_qns_m  (:,:) = SUM( a_i(:,:,:) * pqns_ice  (:,:,:) , dim=3 ) * z1_at_i(:,:)
224         z_qsr_m  (:,:) = SUM( a_i(:,:,:) * pqsr_ice  (:,:,:) , dim=3 ) * z1_at_i(:,:)
225         z_dqn_m  (:,:) = SUM( a_i(:,:,:) * pdqn_ice  (:,:,:) , dim=3 ) * z1_at_i(:,:)
226         z_evap_m (:,:) = SUM( a_i(:,:,:) * pevap_ice (:,:,:) , dim=3 ) * z1_at_i(:,:)
227         z_devap_m(:,:) = SUM( a_i(:,:,:) * pdevap_ice(:,:,:) , dim=3 ) * z1_at_i(:,:)
228         DO jl = 1, jpl
229            pqns_ice  (:,:,jl) = z_qns_m (:,:)
230            pqsr_ice  (:,:,jl) = z_qsr_m (:,:)
231            pdqn_ice  (:,:,jl) = z_dqn_m  (:,:)
232            pevap_ice (:,:,jl) = z_evap_m(:,:)
233            pdevap_ice(:,:,jl) = z_devap_m(:,:)
234         END DO
235         !
236         DEALLOCATE( z_qns_m, z_qsr_m, z_dqn_m, z_evap_m, z_devap_m ) 
237         !
238      END SELECT
239      !
240      SELECT CASE( k_flxdist )       !==  redistribution on all ice categories  ==!
241      !
242      CASE( 1 , 2 )
243         !
244         ALLOCATE( zalb_m(jpi,jpj), ztem_m(jpi,jpj) ) 
245         !
246         zalb_m(:,:) = SUM( a_i(:,:,:) * palb_ice(:,:,:) , dim=3 ) * z1_at_i(:,:)
247         ztem_m(:,:) = SUM( a_i(:,:,:) * ptn_ice (:,:,:) , dim=3 ) * z1_at_i(:,:)
248         DO jl = 1, jpl
249            pqns_ice (:,:,jl) = pqns_ice (:,:,jl) + pdqn_ice  (:,:,jl) * ( ptn_ice(:,:,jl) - ztem_m(:,:) )
250            pevap_ice(:,:,jl) = pevap_ice(:,:,jl) + pdevap_ice(:,:,jl) * ( ptn_ice(:,:,jl) - ztem_m(:,:) )
251            pqsr_ice (:,:,jl) = pqsr_ice (:,:,jl) * ( 1._wp - palb_ice(:,:,jl) ) / ( 1._wp - zalb_m(:,:) )
252         END DO
253         !
254         DEALLOCATE( zalb_m, ztem_m ) 
255         !
256      END SELECT
257      !
258   END SUBROUTINE ice_flx_dist
259
260
261   SUBROUTINE ice_sbc_init
262      !!-------------------------------------------------------------------
263      !!                  ***  ROUTINE ice_sbc_init  ***
264      !!
265      !! ** Purpose :   Physical constants and parameters linked to the ice dynamics
266      !!     
267      !! ** Method  :   Read the namsbc namelist and check the ice-dynamic
268      !!              parameter values called at the first timestep (nit000)
269      !!
270      !! ** input   :   Namelist namsbc
271      !!-------------------------------------------------------------------
272      INTEGER ::   ios, ioptio   ! Local integer
273      !!
274      NAMELIST/namsbc/ rn_cio, rn_blow_s, nn_flxdist, ln_cndflx, ln_cndemulate
275      !!-------------------------------------------------------------------
276      !
277      REWIND( numnam_ice_ref )         ! Namelist namsbc in reference namelist : Ice dynamics
278      READ  ( numnam_ice_ref, namsbc, IOSTAT = ios, ERR = 901)
279901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namsbc in reference namelist', lwp )
280      REWIND( numnam_ice_cfg )         ! Namelist namsbc in configuration namelist : Ice dynamics
281      READ  ( numnam_ice_cfg, namsbc, IOSTAT = ios, ERR = 902 )
282902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namsbc in configuration namelist', lwp )
283      IF(lwm) WRITE( numoni, namsbc )
284      !
285      IF(lwp) THEN                     ! control print
286         WRITE(numout,*)
287         WRITE(numout,*) 'ice_sbc_init: ice parameters for ice dynamics '
288         WRITE(numout,*) '~~~~~~~~~~~~~~~~'
289         WRITE(numout,*) '   Namelist namsbc:'
290         WRITE(numout,*) '      drag coefficient for oceanic stress              rn_cio        = ', rn_cio
291         WRITE(numout,*) '      coefficient for ice-lead partition of snowfall   rn_blow_s     = ', rn_blow_s
292         WRITE(numout,*) '      Multicategory heat flux formulation              nn_flxdist    = ', nn_flxdist
293         WRITE(numout,*) '      Use conduction flux as surface condition         ln_cndflx     = ', ln_cndflx
294         WRITE(numout,*) '         emulate conduction flux                       ln_cndemulate = ', ln_cndemulate
295      ENDIF
296      !
297      IF(lwp) WRITE(numout,*)
298      SELECT CASE( nn_flxdist )         ! SI3 Multi-category heat flux formulation
299      CASE( -1  )
300         IF(lwp) WRITE(numout,*) '   SI3: use per-category fluxes (nn_flxdist = -1) '
301      CASE(  0  )
302         IF(lwp) WRITE(numout,*) '   SI3: use average per-category fluxes (nn_flxdist = 0) '
303      CASE(  1  )
304         IF(lwp) WRITE(numout,*) '   SI3: use average then redistribute per-category fluxes (nn_flxdist = 1) '
305         IF( ln_cpl )         CALL ctl_stop( 'ice_thd_init: the chosen nn_flxdist for SI3 in coupled mode must be /=1' )
306      CASE(  2  )
307         IF(lwp) WRITE(numout,*) '   SI3: Redistribute a single flux over categories (nn_flxdist = 2) '
308         IF( .NOT. ln_cpl )   CALL ctl_stop( 'ice_thd_init: the chosen nn_flxdist for SI3 in forced mode must be /=2' )
309      CASE DEFAULT
310         CALL ctl_stop( 'ice_thd_init: SI3 option, nn_flxdist, should be between -1 and 2' )
311      END SELECT
312      !
313   END SUBROUTINE ice_sbc_init
314
315#else
316   !!----------------------------------------------------------------------
317   !!   Default option :         Empty module         NO SI3 sea-ice model
318   !!----------------------------------------------------------------------
319#endif
320
321   !!======================================================================
322END MODULE icesbc
Note: See TracBrowser for help on using the repository browser.