New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
diaharm.F90 in NEMO/branches/2019/dev_r11265_ASINTER-01_Guillaume_ABL1D/src/OCE/DIA – NEMO

source: NEMO/branches/2019/dev_r11265_ASINTER-01_Guillaume_ABL1D/src/OCE/DIA/diaharm.F90 @ 11348

Last change on this file since 11348 was 11348, checked in by gsamson, 5 years ago

dev_r11265_ABL :

  • merge HPC-13_IRRMANN_BDY_optimization branch @ rev11332 with dev_r11265_ABL branch @ rev11334
  • allow ln_dm2dc option with ABL
  • cosmetic change in sbcabl.F90

identical results with rev11334 for bulk and abl orca2

  • Property svn:keywords set to Id
File size: 18.8 KB
Line 
1MODULE diaharm 
2   !!======================================================================
3   !!                       ***  MODULE  diaharm  ***
4   !! Harmonic analysis of tidal constituents
5   !!======================================================================
6   !! History :  3.1  !  2007  (O. Le Galloudec, J. Chanut)  Original code
7   !!----------------------------------------------------------------------
8#if defined key_diaharm
9   !!----------------------------------------------------------------------
10   !!   'key_diaharm'
11   !!----------------------------------------------------------------------
12   USE oce             ! ocean dynamics and tracers variables
13   USE dom_oce         ! ocean space and time domain
14   USE phycst
15   USE daymod
16   USE tide_mod
17   USE sbctide         ! Tidal forcing or not
18   !
19   USE in_out_manager  ! I/O units
20   USE iom             ! I/0 library
21   USE ioipsl          ! NetCDF IPSL library
22   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
23   USE timing          ! preformance summary
24   USE lib_mpp           ! MPP library
25
26   IMPLICIT NONE
27   PRIVATE
28
29   LOGICAL, PUBLIC, PARAMETER :: lk_diaharm  = .TRUE.
30   
31   INTEGER, PARAMETER :: jpincomax    = 2.*jpmax_harmo
32   INTEGER, PARAMETER :: jpdimsparse  = jpincomax*300*24
33
34   !                         !!** namelist variables **
35   INTEGER ::   nit000_han    ! First time step used for harmonic analysis
36   INTEGER ::   nitend_han    ! Last time step used for harmonic analysis
37   INTEGER ::   nstep_han     ! Time step frequency for harmonic analysis
38   INTEGER ::   nb_ana        ! Number of harmonics to analyse
39
40   INTEGER , ALLOCATABLE, DIMENSION(:)       ::   name
41   REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:) ::   ana_temp
42   REAL(wp), ALLOCATABLE, DIMENSION(:)       ::   ana_freq, ut   , vt   , ft
43   REAL(wp), ALLOCATABLE, DIMENSION(:,:,:)   ::   out_eta , out_u, out_v
44
45   INTEGER ::   ninco, nsparse
46   INTEGER ,       DIMENSION(jpdimsparse)         ::   njsparse, nisparse
47   INTEGER , SAVE, DIMENSION(jpincomax)           ::   ipos1
48   REAL(wp),       DIMENSION(jpdimsparse)         ::   valuesparse
49   REAL(wp),       DIMENSION(jpincomax)           ::   ztmp4 , ztmp7
50   REAL(wp), SAVE, DIMENSION(jpincomax,jpincomax) ::   ztmp3 , zpilier
51   REAL(wp), SAVE, DIMENSION(jpincomax)           ::   zpivot
52
53   CHARACTER (LEN=4), DIMENSION(jpmax_harmo) ::   tname   ! Names of tidal constituents ('M2', 'K1',...)
54
55   PUBLIC   dia_harm   ! routine called by step.F90
56
57   !!----------------------------------------------------------------------
58   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
59   !! $Id$
60   !! Software governed by the CeCILL license (see ./LICENSE)
61   !!----------------------------------------------------------------------
62CONTAINS
63
64   SUBROUTINE dia_harm_init 
65      !!----------------------------------------------------------------------
66      !!                 ***  ROUTINE dia_harm_init  ***
67      !!         
68      !! ** Purpose :   Initialization of tidal harmonic analysis
69      !!
70      !! ** Method  :   Initialize frequency array and  nodal factor for nit000_han
71      !!
72      !!--------------------------------------------------------------------
73      INTEGER :: jh, nhan, jk, ji
74      INTEGER ::   ios                 ! Local integer output status for namelist read
75
76      NAMELIST/nam_diaharm/ nit000_han, nitend_han, nstep_han, tname
77      !!----------------------------------------------------------------------
78
79      IF(lwp) THEN
80         WRITE(numout,*)
81         WRITE(numout,*) 'dia_harm_init: Tidal harmonic analysis initialization'
82         WRITE(numout,*) '~~~~~~~ '
83      ENDIF
84      !
85      IF( .NOT. ln_tide )   CALL ctl_stop( 'dia_harm_init : ln_tide must be true for harmonic analysis')
86      !
87      CALL tide_init_Wave
88      !
89      REWIND( numnam_ref )              ! Namelist nam_diaharm in reference namelist : Tidal harmonic analysis
90      READ  ( numnam_ref, nam_diaharm, IOSTAT = ios, ERR = 901)
91901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nam_diaharm in reference namelist' )
92      REWIND( numnam_cfg )              ! Namelist nam_diaharm in configuration namelist : Tidal harmonic analysis
93      READ  ( numnam_cfg, nam_diaharm, IOSTAT = ios, ERR = 902 )
94902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nam_diaharm in configuration namelist' )
95      IF(lwm) WRITE ( numond, nam_diaharm )
96      !
97      IF(lwp) THEN
98         WRITE(numout,*) 'First time step used for analysis:  nit000_han= ', nit000_han
99         WRITE(numout,*) 'Last  time step used for analysis:  nitend_han= ', nitend_han
100         WRITE(numout,*) 'Time step frequency for harmonic analysis:  nstep_han= ', nstep_han
101      ENDIF
102
103      ! Basic checks on harmonic analysis time window:
104      ! ----------------------------------------------
105      IF( nit000 > nit000_han )   CALL ctl_stop( 'dia_harm_init : nit000_han must be greater than nit000',   &
106         &                                       ' restart capability not implemented' )
107      IF( nitend < nitend_han )   CALL ctl_stop( 'dia_harm_init : nitend_han must be lower than nitend',   &
108         &                                       'restart capability not implemented' )
109
110      IF( MOD( nitend_han-nit000_han+1 , nstep_han ) /= 0 )   &
111         &                        CALL ctl_stop( 'dia_harm_init : analysis time span must be a multiple of nstep_han' )
112
113      nb_ana = 0
114      DO jk=1,jpmax_harmo
115         DO ji=1,jpmax_harmo
116            IF(TRIM(tname(jk)) == Wave(ji)%cname_tide) THEN
117               nb_ana=nb_ana+1
118            ENDIF
119         END DO
120      END DO
121      !
122      IF(lwp) THEN
123         WRITE(numout,*) '        Namelist nam_diaharm'
124         WRITE(numout,*) '        nb_ana    = ', nb_ana
125         CALL flush(numout)
126      ENDIF
127      !
128      IF (nb_ana > jpmax_harmo) THEN
129         WRITE(ctmp1,*) ' nb_ana must be lower than jpmax_harmo'
130         WRITE(ctmp2,*) ' jpmax_harmo= ', jpmax_harmo
131         CALL ctl_stop( 'dia_harm_init', ctmp1, ctmp2 )
132      ENDIF
133
134      ALLOCATE(name    (nb_ana))
135      DO jk=1,nb_ana
136       DO ji=1,jpmax_harmo
137          IF (TRIM(tname(jk)) ==  Wave(ji)%cname_tide) THEN
138             name(jk) = ji
139             EXIT
140          END IF
141       END DO
142      END DO
143
144      ! Initialize frequency array:
145      ! ---------------------------
146      ALLOCATE( ana_freq(nb_ana), ut(nb_ana), vt(nb_ana), ft(nb_ana) )
147
148      CALL tide_harmo( ana_freq, vt, ut, ft, name, nb_ana )
149
150      IF(lwp) WRITE(numout,*) 'Analysed frequency  : ',nb_ana ,'Frequency '
151
152      DO jh = 1, nb_ana
153        IF(lwp) WRITE(numout,*) '                    : ',tname(jh),' ',ana_freq(jh)
154      END DO
155
156      ! Initialize temporary arrays:
157      ! ----------------------------
158      ALLOCATE( ana_temp(jpi,jpj,2*nb_ana,3) )
159      ana_temp(:,:,:,:) = 0._wp
160
161   END SUBROUTINE dia_harm_init
162
163
164   SUBROUTINE dia_harm ( kt )
165      !!----------------------------------------------------------------------
166      !!                 ***  ROUTINE dia_harm  ***
167      !!         
168      !! ** Purpose :   Tidal harmonic analysis main routine
169      !!
170      !! ** Action  :   Sums ssh/u/v over time analysis [nit000_han,nitend_han]
171      !!
172      !!--------------------------------------------------------------------
173      INTEGER, INTENT( IN ) :: kt
174      !
175      INTEGER  :: ji, jj, jh, jc, nhc
176      REAL(wp) :: ztime, ztemp
177      !!--------------------------------------------------------------------
178      IF( ln_timing )   CALL timing_start('dia_harm')
179      !
180      IF( kt == nit000 )   CALL dia_harm_init
181      !
182      IF( kt >= nit000_han .AND. kt <= nitend_han .AND. MOD(kt,nstep_han) == 0 ) THEN
183         !
184         ztime = (kt-nit000+1) * rdt 
185         !
186         nhc = 0
187         DO jh = 1, nb_ana
188            DO jc = 1, 2
189               nhc = nhc+1
190               ztemp =(     MOD(jc,2) * ft(jh) *COS(ana_freq(jh)*ztime + vt(jh) + ut(jh))  &
191                  &    +(1.-MOD(jc,2))* ft(jh) *SIN(ana_freq(jh)*ztime + vt(jh) + ut(jh)))
192                  !
193               DO jj = 1,jpj
194                  DO ji = 1,jpi
195                     ! Elevation
196                     ana_temp(ji,jj,nhc,1) = ana_temp(ji,jj,nhc,1) + ztemp*sshn(ji,jj)*ssmask (ji,jj)       
197                     ana_temp(ji,jj,nhc,2) = ana_temp(ji,jj,nhc,2) + ztemp*un_b(ji,jj)*ssumask(ji,jj)
198                     ana_temp(ji,jj,nhc,3) = ana_temp(ji,jj,nhc,3) + ztemp*vn_b(ji,jj)*ssvmask(ji,jj)
199                  END DO
200               END DO
201               !
202            END DO
203         END DO
204         !       
205      END IF
206      !
207      IF( kt == nitend_han )   CALL dia_harm_end
208      !
209      IF( ln_timing )   CALL timing_stop('dia_harm')
210      !
211   END SUBROUTINE dia_harm
212
213
214   SUBROUTINE dia_harm_end
215      !!----------------------------------------------------------------------
216      !!                 ***  ROUTINE diaharm_end  ***
217      !!         
218      !! ** Purpose :  Compute the Real and Imaginary part of tidal constituents
219      !!
220      !! ** Action  :  Decompose the signal on the harmonic constituents
221      !!
222      !!--------------------------------------------------------------------
223      INTEGER :: ji, jj, jh, jc, jn, nhan, jl
224      INTEGER :: ksp, kun, keq
225      REAL(wp) :: ztime, ztime_ini, ztime_end
226      REAL(wp) :: X1, X2
227      REAL(wp), DIMENSION(jpi,jpj,jpmax_harmo,2) ::   ana_amp   ! workspace
228      !!--------------------------------------------------------------------
229      !
230      IF(lwp) WRITE(numout,*)
231      IF(lwp) WRITE(numout,*) 'anharmo_end: kt=nitend_han: Perform harmonic analysis'
232      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~'
233
234      ztime_ini = nit000_han*rdt                 ! Initial time in seconds at the beginning of analysis
235      ztime_end = nitend_han*rdt                 ! Final time in seconds at the end of analysis
236      nhan = (nitend_han-nit000_han+1)/nstep_han ! Number of dumps used for analysis
237
238      ninco = 2*nb_ana
239
240      ksp = 0
241      keq = 0       
242      DO jn = 1, nhan
243         ztime=( (nhan-jn)*ztime_ini + (jn-1)*ztime_end )/FLOAT(nhan-1)
244         keq = keq + 1
245         kun = 0
246         DO jh = 1, nb_ana
247            DO jc = 1, 2
248               kun = kun + 1
249               ksp = ksp + 1
250               nisparse(ksp) = keq
251               njsparse(ksp) = kun
252               valuesparse(ksp) = (   MOD(jc,2) * ft(jh) * COS(ana_freq(jh)*ztime + vt(jh) + ut(jh))   &
253                  &             + (1.-MOD(jc,2))* ft(jh) * SIN(ana_freq(jh)*ztime + vt(jh) + ut(jh)) )
254            END DO
255         END DO
256      END DO
257
258      nsparse = ksp
259
260      ! Elevation:
261      DO jj = 1, jpj
262         DO ji = 1, jpi
263            ! Fill input array
264            kun = 0
265            DO jh = 1, nb_ana
266               DO jc = 1, 2
267                  kun = kun + 1
268                  ztmp4(kun)=ana_temp(ji,jj,kun,1)
269               END DO
270            END DO
271
272            CALL SUR_DETERMINE(jj)
273
274            ! Fill output array
275            DO jh = 1, nb_ana
276               ana_amp(ji,jj,jh,1)=ztmp7((jh-1)*2+1)
277               ana_amp(ji,jj,jh,2)=ztmp7((jh-1)*2+2)
278            END DO
279         END DO
280      END DO
281
282      ALLOCATE( out_eta(jpi,jpj,2*nb_ana),   & 
283         &      out_u  (jpi,jpj,2*nb_ana),   &
284         &      out_v  (jpi,jpj,2*nb_ana)  )
285
286      DO jj = 1, jpj
287         DO ji = 1, jpi
288            DO jh = 1, nb_ana 
289               X1 = ana_amp(ji,jj,jh,1)
290               X2 =-ana_amp(ji,jj,jh,2)
291               out_eta(ji,jj,jh       ) = X1 * tmask_i(ji,jj)
292               out_eta(ji,jj,jh+nb_ana) = X2 * tmask_i(ji,jj)
293            END DO
294         END DO
295      END DO
296
297      ! ubar:
298      DO jj = 1, jpj
299         DO ji = 1, jpi
300            ! Fill input array
301            kun=0
302            DO jh = 1,nb_ana
303               DO jc = 1,2
304                  kun = kun + 1
305                  ztmp4(kun)=ana_temp(ji,jj,kun,2)
306               END DO
307            END DO
308
309            CALL SUR_DETERMINE(jj+1)
310
311            ! Fill output array
312            DO jh = 1, nb_ana
313               ana_amp(ji,jj,jh,1) = ztmp7((jh-1)*2+1)
314               ana_amp(ji,jj,jh,2) = ztmp7((jh-1)*2+2)
315            END DO
316
317         END DO
318      END DO
319
320      DO jj = 1, jpj
321         DO ji = 1, jpi
322            DO jh = 1, nb_ana 
323               X1= ana_amp(ji,jj,jh,1)
324               X2=-ana_amp(ji,jj,jh,2)
325               out_u(ji,jj,       jh) = X1 * ssumask(ji,jj)
326               out_u(ji,jj,nb_ana+jh) = X2 * ssumask(ji,jj)
327            ENDDO
328         ENDDO
329      ENDDO
330
331      ! vbar:
332      DO jj = 1, jpj
333         DO ji = 1, jpi
334            ! Fill input array
335            kun=0
336            DO jh = 1,nb_ana
337               DO jc = 1,2
338                  kun = kun + 1
339                  ztmp4(kun)=ana_temp(ji,jj,kun,3)
340               END DO
341            END DO
342
343            CALL SUR_DETERMINE(jj+1)
344
345            ! Fill output array
346            DO jh = 1, nb_ana
347               ana_amp(ji,jj,jh,1)=ztmp7((jh-1)*2+1)
348               ana_amp(ji,jj,jh,2)=ztmp7((jh-1)*2+2)
349            END DO
350
351         END DO
352      END DO
353
354      DO jj = 1, jpj
355         DO ji = 1, jpi
356            DO jh = 1, nb_ana 
357               X1=ana_amp(ji,jj,jh,1)
358               X2=-ana_amp(ji,jj,jh,2)
359               out_v(ji,jj,       jh)=X1 * ssvmask(ji,jj)
360               out_v(ji,jj,nb_ana+jh)=X2 * ssvmask(ji,jj)
361            END DO
362         END DO
363      END DO
364      !
365      CALL dia_wri_harm ! Write results in files
366      !
367   END SUBROUTINE dia_harm_end
368
369
370   SUBROUTINE dia_wri_harm
371      !!--------------------------------------------------------------------
372      !!                 ***  ROUTINE dia_wri_harm  ***
373      !!         
374      !! ** Purpose : Write tidal harmonic analysis results in a netcdf file
375      !!--------------------------------------------------------------------
376      CHARACTER(LEN=lc) :: cltext
377      CHARACTER(LEN=lc) ::   &
378         cdfile_name_T   ,   & ! name of the file created (T-points)
379         cdfile_name_U   ,   & ! name of the file created (U-points)
380         cdfile_name_V         ! name of the file created (V-points)
381      INTEGER  ::   jh
382      !!----------------------------------------------------------------------
383
384      IF(lwp) WRITE(numout,*) '  '
385      IF(lwp) WRITE(numout,*) 'dia_wri_harm : Write harmonic analysis results'
386      IF(lwp) WRITE(numout,*) '  '
387
388      ! A) Elevation
389      !/////////////
390      !
391      DO jh = 1, nb_ana
392      CALL iom_put( TRIM(tname(jh))//'x', out_eta(:,:,jh) )
393      CALL iom_put( TRIM(tname(jh))//'y', out_eta(:,:,nb_ana+jh) )
394      END DO
395
396      ! B) ubar
397      !/////////
398      !
399      DO jh = 1, nb_ana
400      CALL iom_put( TRIM(tname(jh))//'x_u', out_u(:,:,jh) )
401      CALL iom_put( TRIM(tname(jh))//'y_u', out_u(:,:,nb_ana+jh) )
402      END DO
403
404      ! C) vbar
405      !/////////
406      !
407      DO jh = 1, nb_ana
408         CALL iom_put( TRIM(tname(jh))//'x_v', out_v(:,:,jh       ) )
409         CALL iom_put( TRIM(tname(jh))//'y_v', out_v(:,:,jh+nb_ana) )
410      END DO
411      !
412   END SUBROUTINE dia_wri_harm
413
414
415   SUBROUTINE SUR_DETERMINE(init)
416      !!---------------------------------------------------------------------------------
417      !!                      *** ROUTINE SUR_DETERMINE ***
418      !!   
419      !!   
420      !!       
421      !!---------------------------------------------------------------------------------
422      INTEGER, INTENT(in) ::   init 
423      !
424      INTEGER                         :: ji_sd, jj_sd, ji1_sd, ji2_sd, jk1_sd, jk2_sd
425      REAL(wp)                        :: zval1, zval2, zx1
426      REAL(wp), DIMENSION(jpincomax) :: ztmpx, zcol1, zcol2
427      INTEGER , DIMENSION(jpincomax) :: ipos2, ipivot
428      !---------------------------------------------------------------------------------
429      !           
430      IF( init == 1 ) THEN
431         IF( nsparse > jpdimsparse )   CALL ctl_stop( 'STOP', 'SUR_DETERMINE : nsparse .GT. jpdimsparse')
432         IF( ninco   > jpincomax   )   CALL ctl_stop( 'STOP', 'SUR_DETERMINE : ninco .GT. jpincomax')
433         !
434         ztmp3(:,:) = 0._wp
435         !
436         DO jk1_sd = 1, nsparse
437            DO jk2_sd = 1, nsparse
438               nisparse(jk2_sd) = nisparse(jk2_sd)
439               njsparse(jk2_sd) = njsparse(jk2_sd)
440               IF( nisparse(jk2_sd) == nisparse(jk1_sd) ) THEN
441                  ztmp3(njsparse(jk1_sd),njsparse(jk2_sd)) = ztmp3(njsparse(jk1_sd),njsparse(jk2_sd))  &
442                     &                                     + valuesparse(jk1_sd)*valuesparse(jk2_sd)
443               ENDIF
444            END DO
445         END DO
446         !
447         DO jj_sd = 1 ,ninco
448            ipos1(jj_sd) = jj_sd
449            ipos2(jj_sd) = jj_sd
450         END DO
451         !
452         DO ji_sd = 1 , ninco
453            !
454            !find greatest non-zero pivot:
455            zval1 = ABS(ztmp3(ji_sd,ji_sd))
456            !
457            ipivot(ji_sd) = ji_sd
458            DO jj_sd = ji_sd, ninco
459               zval2 = ABS(ztmp3(ji_sd,jj_sd))
460               IF( zval2 >= zval1 )THEN
461                  ipivot(ji_sd) = jj_sd
462                  zval1         = zval2
463               ENDIF
464            END DO
465            !
466            DO ji1_sd = 1, ninco
467               zcol1(ji1_sd)               = ztmp3(ji1_sd,ji_sd)
468               zcol2(ji1_sd)               = ztmp3(ji1_sd,ipivot(ji_sd))
469               ztmp3(ji1_sd,ji_sd)         = zcol2(ji1_sd)
470               ztmp3(ji1_sd,ipivot(ji_sd)) = zcol1(ji1_sd)
471            END DO
472            !
473            ipos2(ji_sd)         = ipos1(ipivot(ji_sd))
474            ipos2(ipivot(ji_sd)) = ipos1(ji_sd)
475            ipos1(ji_sd)         = ipos2(ji_sd)
476            ipos1(ipivot(ji_sd)) = ipos2(ipivot(ji_sd))
477            zpivot(ji_sd)        = ztmp3(ji_sd,ji_sd)
478            DO jj_sd = 1, ninco
479               ztmp3(ji_sd,jj_sd) = ztmp3(ji_sd,jj_sd) / zpivot(ji_sd)
480            END DO
481            !
482            DO ji2_sd = ji_sd+1, ninco
483               zpilier(ji2_sd,ji_sd)=ztmp3(ji2_sd,ji_sd)
484               DO jj_sd=1,ninco
485                  ztmp3(ji2_sd,jj_sd)=  ztmp3(ji2_sd,jj_sd) - ztmp3(ji_sd,jj_sd) * zpilier(ji2_sd,ji_sd)
486               END DO
487            END DO
488            !
489         END DO
490         !
491      ENDIF ! End init==1
492
493      DO ji_sd = 1, ninco
494         ztmp4(ji_sd) = ztmp4(ji_sd) / zpivot(ji_sd)
495         DO ji2_sd = ji_sd+1, ninco
496            ztmp4(ji2_sd) = ztmp4(ji2_sd) - ztmp4(ji_sd) * zpilier(ji2_sd,ji_sd)
497         END DO
498      END DO
499
500      !system solving:
501      ztmpx(ninco) = ztmp4(ninco) / ztmp3(ninco,ninco)
502      ji_sd = ninco
503      DO ji_sd = ninco-1, 1, -1
504         zx1 = 0._wp
505         DO jj_sd = ji_sd+1, ninco
506            zx1 = zx1 + ztmpx(jj_sd) * ztmp3(ji_sd,jj_sd)
507         END DO
508         ztmpx(ji_sd) = ztmp4(ji_sd)-zx1
509      END DO
510
511      DO jj_sd =1, ninco
512         ztmp7(ipos1(jj_sd))=ztmpx(jj_sd)
513      END DO
514      !
515   END SUBROUTINE SUR_DETERMINE
516
517#else
518   !!----------------------------------------------------------------------
519   !!   Default case :   Empty module
520   !!----------------------------------------------------------------------
521   LOGICAL, PUBLIC, PARAMETER ::   lk_diaharm = .FALSE.
522CONTAINS
523   SUBROUTINE dia_harm ( kt )     ! Empty routine
524      INTEGER, INTENT( IN ) :: kt 
525      WRITE(*,*) 'dia_harm: you should not have seen this print'
526   END SUBROUTINE dia_harm
527#endif
528
529   !!======================================================================
530END MODULE diaharm
Note: See TracBrowser for help on using the repository browser.