New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynhpg.F90 in NEMO/branches/2019/dev_r11265_ASINTER-01_Guillaume_ABL1D/src/OCE/DYN – NEMO

source: NEMO/branches/2019/dev_r11265_ASINTER-01_Guillaume_ABL1D/src/OCE/DYN/dynhpg.F90 @ 11348

Last change on this file since 11348 was 11348, checked in by gsamson, 5 years ago

dev_r11265_ABL :

  • merge HPC-13_IRRMANN_BDY_optimization branch @ rev11332 with dev_r11265_ABL branch @ rev11334
  • allow ln_dm2dc option with ABL
  • cosmetic change in sbcabl.F90

identical results with rev11334 for bulk and abl orca2

  • Property svn:keywords set to Id
File size: 72.4 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!            3.6  !  2014-11  (P. Mathiot) hpg_isf: original code for ice shelf cavity
19   !!----------------------------------------------------------------------
20
21   !!----------------------------------------------------------------------
22   !!   dyn_hpg      : update the momentum trend with the now horizontal
23   !!                  gradient of the hydrostatic pressure
24   !!   dyn_hpg_init : initialisation and control of options
25   !!       hpg_zco  : z-coordinate scheme
26   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
27   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
28   !!       hpg_isf  : s-coordinate (sco formulation) adapted to ice shelf
29   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
30   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
31   !!----------------------------------------------------------------------
32   USE oce             ! ocean dynamics and tracers
33   USE sbc_oce         ! surface variable (only for the flag with ice shelf)
34   USE dom_oce         ! ocean space and time domain
35   USE wet_dry         ! wetting and drying
36   USE phycst          ! physical constants
37   USE trd_oce         ! trends: ocean variables
38   USE trddyn          ! trend manager: dynamics
39!jc   USE zpshde          ! partial step: hor. derivative     (zps_hde routine)
40   !
41   USE in_out_manager  ! I/O manager
42   USE prtctl          ! Print control
43   USE lbclnk          ! lateral boundary condition
44   USE lib_mpp         ! MPP library
45   USE eosbn2          ! compute density
46   USE timing          ! Timing
47   USE iom
48
49   IMPLICIT NONE
50   PRIVATE
51
52   PUBLIC   dyn_hpg        ! routine called by step module
53   PUBLIC   dyn_hpg_init   ! routine called by opa module
54
55   !                                !!* Namelist namdyn_hpg : hydrostatic pressure gradient
56   LOGICAL, PUBLIC ::   ln_hpg_zco   !: z-coordinate - full steps
57   LOGICAL, PUBLIC ::   ln_hpg_zps   !: z-coordinate - partial steps (interpolation)
58   LOGICAL, PUBLIC ::   ln_hpg_sco   !: s-coordinate (standard jacobian formulation)
59   LOGICAL, PUBLIC ::   ln_hpg_djc   !: s-coordinate (Density Jacobian with Cubic polynomial)
60   LOGICAL, PUBLIC ::   ln_hpg_prj   !: s-coordinate (Pressure Jacobian scheme)
61   LOGICAL, PUBLIC ::   ln_hpg_isf   !: s-coordinate similar to sco modify for isf
62
63   !                                !! Flag to control the type of hydrostatic pressure gradient
64   INTEGER, PARAMETER ::   np_ERROR  =-10   ! error in specification of lateral diffusion
65   INTEGER, PARAMETER ::   np_zco    =  0   ! z-coordinate - full steps
66   INTEGER, PARAMETER ::   np_zps    =  1   ! z-coordinate - partial steps (interpolation)
67   INTEGER, PARAMETER ::   np_sco    =  2   ! s-coordinate (standard jacobian formulation)
68   INTEGER, PARAMETER ::   np_djc    =  3   ! s-coordinate (Density Jacobian with Cubic polynomial)
69   INTEGER, PARAMETER ::   np_prj    =  4   ! s-coordinate (Pressure Jacobian scheme)
70   INTEGER, PARAMETER ::   np_isf    =  5   ! s-coordinate similar to sco modify for isf
71   !
72   INTEGER, PUBLIC ::   nhpg         !: type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
73
74   !! * Substitutions
75#  include "vectopt_loop_substitute.h90"
76   !!----------------------------------------------------------------------
77   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
78   !! $Id$
79   !! Software governed by the CeCILL license (see ./LICENSE)
80   !!----------------------------------------------------------------------
81CONTAINS
82
83   SUBROUTINE dyn_hpg( kt )
84      !!---------------------------------------------------------------------
85      !!                  ***  ROUTINE dyn_hpg  ***
86      !!
87      !! ** Method  :   Call the hydrostatic pressure gradient routine
88      !!              using the scheme defined in the namelist
89      !!
90      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
91      !!             - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
92      !!----------------------------------------------------------------------
93      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
94      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   ztrdu, ztrdv
95      !!----------------------------------------------------------------------
96      !
97      IF( ln_timing )   CALL timing_start('dyn_hpg')
98      !
99      IF( l_trddyn ) THEN                    ! Temporary saving of ua and va trends (l_trddyn)
100         ALLOCATE( ztrdu(jpi,jpj,jpk) , ztrdv(jpi,jpj,jpk) )
101         ztrdu(:,:,:) = ua(:,:,:)
102         ztrdv(:,:,:) = va(:,:,:)
103      ENDIF
104      !
105      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
106      CASE ( np_zco )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
107      CASE ( np_zps )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
108      CASE ( np_sco )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
109      CASE ( np_djc )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
110      CASE ( np_prj )   ;   CALL hpg_prj    ( kt )      ! s-coordinate (Pressure Jacobian scheme)
111      CASE ( np_isf )   ;   CALL hpg_isf    ( kt )      ! s-coordinate similar to sco modify for ice shelf
112      END SELECT
113      !
114      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
115         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
116         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
117         CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt )
118         DEALLOCATE( ztrdu , ztrdv )
119      ENDIF
120      !
121      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
122         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
123      !
124      IF( ln_timing )   CALL timing_stop('dyn_hpg')
125      !
126   END SUBROUTINE dyn_hpg
127
128
129   SUBROUTINE dyn_hpg_init
130      !!----------------------------------------------------------------------
131      !!                 ***  ROUTINE dyn_hpg_init  ***
132      !!
133      !! ** Purpose :   initializations for the hydrostatic pressure gradient
134      !!              computation and consistency control
135      !!
136      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
137      !!      with the type of vertical coordinate used (zco, zps, sco)
138      !!----------------------------------------------------------------------
139      INTEGER ::   ioptio = 0      ! temporary integer
140      INTEGER ::   ios             ! Local integer output status for namelist read
141      !!
142      INTEGER  ::   ji, jj, jk, ikt    ! dummy loop indices      ISF
143      REAL(wp) ::   znad
144      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::  zts_top, zrhd   ! hypothesys on isf density
145      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::  zrhdtop_isf    ! density at bottom of ISF
146      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::  ziceload       ! density at bottom of ISF
147      !!
148      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,     &
149         &                 ln_hpg_djc, ln_hpg_prj, ln_hpg_isf
150      !!----------------------------------------------------------------------
151      !
152      REWIND( numnam_ref )              ! Namelist namdyn_hpg in reference namelist : Hydrostatic pressure gradient
153      READ  ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
154901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist' )
155      !
156      REWIND( numnam_cfg )              ! Namelist namdyn_hpg in configuration namelist : Hydrostatic pressure gradient
157      READ  ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
158902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist' )
159      IF(lwm) WRITE ( numond, namdyn_hpg )
160      !
161      IF(lwp) THEN                   ! Control print
162         WRITE(numout,*)
163         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
164         WRITE(numout,*) '~~~~~~~~~~~~'
165         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
166         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
167         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
168         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
169         WRITE(numout,*) '      s-coord. (standard jacobian formulation) for isf  ln_hpg_isf    = ', ln_hpg_isf
170         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
171         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
172      ENDIF
173      !
174      IF( ln_hpg_djc )   &
175         &   CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method',   &
176         &                 '   currently disabled (bugs under investigation).'        ,   &
177         &                 '   Please select either  ln_hpg_sco or  ln_hpg_prj instead' )
178         !
179      IF( .NOT.ln_linssh .AND. .NOT.(ln_hpg_sco.OR.ln_hpg_prj.OR.ln_hpg_isf) )          &
180         &   CALL ctl_stop('dyn_hpg_init : non-linear free surface requires either ',   &
181         &                 '   the standard jacobian formulation hpg_sco    or '    ,   &
182         &                 '   the pressure jacobian formulation hpg_prj'             )
183         !
184      IF( ln_hpg_isf ) THEN
185         IF( .NOT. ln_isfcav )   CALL ctl_stop( ' hpg_isf not available if ln_isfcav = false ' )
186       ELSE
187         IF(       ln_isfcav )   CALL ctl_stop( 'Only hpg_isf has been corrected to work with ice shelf cavity.' )
188      ENDIF
189      !
190      !                               ! Set nhpg from ln_hpg_... flags & consistency check
191      nhpg   = np_ERROR
192      ioptio = 0
193      IF( ln_hpg_zco ) THEN   ;   nhpg = np_zco   ;   ioptio = ioptio +1   ;   ENDIF
194      IF( ln_hpg_zps ) THEN   ;   nhpg = np_zps   ;   ioptio = ioptio +1   ;   ENDIF
195      IF( ln_hpg_sco ) THEN   ;   nhpg = np_sco   ;   ioptio = ioptio +1   ;   ENDIF
196      IF( ln_hpg_djc ) THEN   ;   nhpg = np_djc   ;   ioptio = ioptio +1   ;   ENDIF
197      IF( ln_hpg_prj ) THEN   ;   nhpg = np_prj   ;   ioptio = ioptio +1   ;   ENDIF
198      IF( ln_hpg_isf ) THEN   ;   nhpg = np_isf   ;   ioptio = ioptio +1   ;   ENDIF
199      !
200      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
201      !
202      IF(lwp) THEN
203         WRITE(numout,*)
204         SELECT CASE( nhpg )
205         CASE( np_zco )   ;   WRITE(numout,*) '   ==>>>   z-coord. - full steps '
206         CASE( np_zps )   ;   WRITE(numout,*) '   ==>>>   z-coord. - partial steps (interpolation)'
207         CASE( np_sco )   ;   WRITE(numout,*) '   ==>>>   s-coord. (standard jacobian formulation)'
208         CASE( np_djc )   ;   WRITE(numout,*) '   ==>>>   s-coord. (Density Jacobian: Cubic polynomial)'
209         CASE( np_prj )   ;   WRITE(numout,*) '   ==>>>   s-coord. (Pressure Jacobian: Cubic polynomial)'
210         CASE( np_isf )   ;   WRITE(numout,*) '   ==>>>   s-coord. (standard jacobian formulation) for isf'
211         END SELECT
212         WRITE(numout,*)
213      ENDIF
214      !                         
215      IF ( .NOT. ln_isfcav ) THEN     !--- no ice shelf load
216         riceload(:,:) = 0._wp
217         !
218      ELSE                            !--- set an ice shelf load
219         !
220         IF(lwp) WRITE(numout,*)
221         IF(lwp) WRITE(numout,*) '   ice shelf case: set the ice-shelf load'
222         ALLOCATE( zts_top(jpi,jpj,jpts) , zrhd(jpi,jpj,jpk) , zrhdtop_isf(jpi,jpj) , ziceload(jpi,jpj) ) 
223         !
224         znad = 1._wp                     !- To use density and not density anomaly
225         !
226         !                                !- assume water displaced by the ice shelf is at T=-1.9 and S=34.4 (rude)
227         zts_top(:,:,jp_tem) = -1.9_wp   ;   zts_top(:,:,jp_sal) = 34.4_wp
228         !
229         DO jk = 1, jpk                   !- compute density of the water displaced by the ice shelf
230            CALL eos( zts_top(:,:,:), gdept_n(:,:,jk), zrhd(:,:,jk) )
231         END DO
232         !
233         !                                !- compute rhd at the ice/oce interface (ice shelf side)
234         CALL eos( zts_top , risfdep, zrhdtop_isf )
235         !
236         !                                !- Surface value + ice shelf gradient
237         ziceload = 0._wp                       ! compute pressure due to ice shelf load
238         DO jj = 1, jpj                         ! (used to compute hpgi/j for all the level from 1 to miku/v)
239            DO ji = 1, jpi                      ! divided by 2 later
240               ikt = mikt(ji,jj)
241               ziceload(ji,jj) = ziceload(ji,jj) + (znad + zrhd(ji,jj,1) ) * e3w_n(ji,jj,1) * (1._wp - tmask(ji,jj,1))
242               DO jk = 2, ikt-1
243                  ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhd(ji,jj,jk-1) + zrhd(ji,jj,jk)) * e3w_n(ji,jj,jk) &
244                     &                              * (1._wp - tmask(ji,jj,jk))
245               END DO
246               IF (ikt  >=  2) ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhdtop_isf(ji,jj) + zrhd(ji,jj,ikt-1)) &
247                  &                                              * ( risfdep(ji,jj) - gdept_n(ji,jj,ikt-1) )
248            END DO
249         END DO
250         riceload(:,:) = ziceload(:,:)  ! need to be saved for diaar5
251         !
252         DEALLOCATE( zts_top , zrhd , zrhdtop_isf , ziceload ) 
253      ENDIF
254      !
255   END SUBROUTINE dyn_hpg_init
256
257
258   SUBROUTINE hpg_zco( kt )
259      !!---------------------------------------------------------------------
260      !!                  ***  ROUTINE hpg_zco  ***
261      !!
262      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
263      !!      The now hydrostatic pressure gradient at a given level, jk,
264      !!      is computed by taking the vertical integral of the in-situ
265      !!      density gradient along the model level from the suface to that
266      !!      level:    zhpi = grav .....
267      !!                zhpj = grav .....
268      !!      add it to the general momentum trend (ua,va).
269      !!            ua = ua - 1/e1u * zhpi
270      !!            va = va - 1/e2v * zhpj
271      !!
272      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
273      !!----------------------------------------------------------------------
274      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
275      !
276      INTEGER  ::   ji, jj, jk       ! dummy loop indices
277      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
278      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  zhpi, zhpj
279      !!----------------------------------------------------------------------
280      !
281      IF( kt == nit000 ) THEN
282         IF(lwp) WRITE(numout,*)
283         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
284         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
285      ENDIF
286
287      zcoef0 = - grav * 0.5_wp      ! Local constant initialization
288
289      ! Surface value
290      DO jj = 2, jpjm1
291         DO ji = fs_2, fs_jpim1   ! vector opt.
292            zcoef1 = zcoef0 * e3w_n(ji,jj,1)
293            ! hydrostatic pressure gradient
294            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
295            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
296            ! add to the general momentum trend
297            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
298            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
299         END DO
300      END DO
301
302      !
303      ! interior value (2=<jk=<jpkm1)
304      DO jk = 2, jpkm1
305         DO jj = 2, jpjm1
306            DO ji = fs_2, fs_jpim1   ! vector opt.
307               zcoef1 = zcoef0 * e3w_n(ji,jj,jk)
308               ! hydrostatic pressure gradient
309               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
310                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )    &
311                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
312
313               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
314                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )    &
315                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
316               ! add to the general momentum trend
317               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
318               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
319            END DO
320         END DO
321      END DO
322      !
323   END SUBROUTINE hpg_zco
324
325
326   SUBROUTINE hpg_zps( kt )
327      !!---------------------------------------------------------------------
328      !!                 ***  ROUTINE hpg_zps  ***
329      !!
330      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
331      !!
332      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
333      !!----------------------------------------------------------------------
334      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
335      !!
336      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
337      INTEGER  ::   iku, ikv                         ! temporary integers
338      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
339      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  zhpi, zhpj
340      !!----------------------------------------------------------------------
341      !
342      IF( kt == nit000 ) THEN
343         IF(lwp) WRITE(numout,*)
344         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
345         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
346      ENDIF
347
348      ! Partial steps: bottom before horizontal gradient of t, s, rd at the last ocean level
349!jc      CALL zps_hde    ( kt, jpts, tsn, gtsu, gtsv, rhd, gru , grv )
350
351      ! Local constant initialization
352      zcoef0 = - grav * 0.5_wp
353
354      !  Surface value (also valid in partial step case)
355      DO jj = 2, jpjm1
356         DO ji = fs_2, fs_jpim1   ! vector opt.
357            zcoef1 = zcoef0 * e3w_n(ji,jj,1)
358            ! hydrostatic pressure gradient
359            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
360            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
361            ! add to the general momentum trend
362            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
363            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
364         END DO
365      END DO
366
367      ! interior value (2=<jk=<jpkm1)
368      DO jk = 2, jpkm1
369         DO jj = 2, jpjm1
370            DO ji = fs_2, fs_jpim1   ! vector opt.
371               zcoef1 = zcoef0 * e3w_n(ji,jj,jk)
372               ! hydrostatic pressure gradient
373               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
374                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
375                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
376
377               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
378                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
379                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
380               ! add to the general momentum trend
381               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
382               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
383            END DO
384         END DO
385      END DO
386
387      ! partial steps correction at the last level  (use gru & grv computed in zpshde.F90)
388      DO jj = 2, jpjm1
389         DO ji = 2, jpim1
390            iku = mbku(ji,jj)
391            ikv = mbkv(ji,jj)
392            zcoef2 = zcoef0 * MIN( e3w_n(ji,jj,iku), e3w_n(ji+1,jj  ,iku) )
393            zcoef3 = zcoef0 * MIN( e3w_n(ji,jj,ikv), e3w_n(ji  ,jj+1,ikv) )
394            IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
395               ua  (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)         ! subtract old value
396               zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
397                  &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) * r1_e1u(ji,jj)
398               ua  (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
399            ENDIF
400            IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
401               va  (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)         ! subtract old value
402               zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
403                  &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) * r1_e2v(ji,jj)
404               va  (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
405            ENDIF
406         END DO
407      END DO
408      !
409   END SUBROUTINE hpg_zps
410
411
412   SUBROUTINE hpg_sco( kt )
413      !!---------------------------------------------------------------------
414      !!                  ***  ROUTINE hpg_sco  ***
415      !!
416      !! ** Method  :   s-coordinate case. Jacobian scheme.
417      !!      The now hydrostatic pressure gradient at a given level, jk,
418      !!      is computed by taking the vertical integral of the in-situ
419      !!      density gradient along the model level from the suface to that
420      !!      level. s-coordinates (ln_sco): a corrective term is added
421      !!      to the horizontal pressure gradient :
422      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
423      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
424      !!      add it to the general momentum trend (ua,va).
425      !!         ua = ua - 1/e1u * zhpi
426      !!         va = va - 1/e2v * zhpj
427      !!
428      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
429      !!----------------------------------------------------------------------
430      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
431      !!
432      INTEGER  ::   ji, jj, jk, jii, jjj                 ! dummy loop indices
433      REAL(wp) ::   zcoef0, zuap, zvap, znad, ztmp       ! temporary scalars
434      LOGICAL  ::   ll_tmp1, ll_tmp2                     ! local logical variables
435      REAL(wp), DIMENSION(jpi,jpj,jpk)      ::   zhpi, zhpj
436      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zcpx, zcpy   !W/D pressure filter
437      !!----------------------------------------------------------------------
438      !
439      IF( ln_wd_il ) ALLOCATE(zcpx(jpi,jpj), zcpy(jpi,jpj))
440      !
441      IF( kt == nit000 ) THEN
442         IF(lwp) WRITE(numout,*)
443         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
444         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
445      ENDIF
446      !
447      zcoef0 = - grav * 0.5_wp
448      IF ( ln_linssh ) THEN   ;   znad = 0._wp         ! Fixed    volume: density anomaly
449      ELSE                    ;   znad = 1._wp         ! Variable volume: density
450      ENDIF
451      !
452      IF( ln_wd_il ) THEN
453        DO jj = 2, jpjm1
454           DO ji = 2, jpim1 
455             ll_tmp1 = MIN(  sshn(ji,jj)               ,  sshn(ji+1,jj) ) >                &
456                  &    MAX( -ht_0(ji,jj)               , -ht_0(ji+1,jj) ) .AND.            &
457                  &    MAX(  sshn(ji,jj) +  ht_0(ji,jj),  sshn(ji+1,jj) + ht_0(ji+1,jj) )  &
458                  &                                                       > rn_wdmin1 + rn_wdmin2
459             ll_tmp2 = ( ABS( sshn(ji,jj)              -  sshn(ji+1,jj) ) > 1.E-12 ) .AND. (       &
460                  &    MAX(   sshn(ji,jj)              ,  sshn(ji+1,jj) ) >                &
461                  &    MAX(  -ht_0(ji,jj)              , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
462
463             IF(ll_tmp1) THEN
464               zcpx(ji,jj) = 1.0_wp
465             ELSE IF(ll_tmp2) THEN
466               ! no worries about  sshn(ji+1,jj) -  sshn(ji  ,jj) = 0, it won't happen ! here
467               zcpx(ji,jj) = ABS( (sshn(ji+1,jj) + ht_0(ji+1,jj) - sshn(ji,jj) - ht_0(ji,jj)) &
468                           &    / (sshn(ji+1,jj) - sshn(ji  ,jj)) )
469             ELSE
470               zcpx(ji,jj) = 0._wp
471             END IF
472     
473             ll_tmp1 = MIN(  sshn(ji,jj)              ,  sshn(ji,jj+1) ) >                &
474                  &    MAX( -ht_0(ji,jj)              , -ht_0(ji,jj+1) ) .AND.            &
475                  &    MAX(  sshn(ji,jj) + ht_0(ji,jj),  sshn(ji,jj+1) + ht_0(ji,jj+1) )  &
476                  &                                                      > rn_wdmin1 + rn_wdmin2
477             ll_tmp2 = ( ABS( sshn(ji,jj)             -  sshn(ji,jj+1) ) > 1.E-12 ) .AND. (        &
478                  &    MAX(   sshn(ji,jj)             ,  sshn(ji,jj+1) ) >                &
479                  &    MAX(  -ht_0(ji,jj)             , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
480
481             IF(ll_tmp1) THEN
482               zcpy(ji,jj) = 1.0_wp
483             ELSE IF(ll_tmp2) THEN
484               ! no worries about  sshn(ji,jj+1) -  sshn(ji,jj  ) = 0, it won't happen ! here
485               zcpy(ji,jj) = ABS( (sshn(ji,jj+1) + ht_0(ji,jj+1) - sshn(ji,jj) - ht_0(ji,jj)) &
486                           &    / (sshn(ji,jj+1) - sshn(ji,jj  )) )
487             ELSE
488               zcpy(ji,jj) = 0._wp
489             END IF
490           END DO
491        END DO
492        CALL lbc_lnk_multi( 'dynhpg', zcpx, 'U', 1., zcpy, 'V', 1. )
493      END IF
494
495      ! Surface value
496      DO jj = 2, jpjm1
497         DO ji = fs_2, fs_jpim1   ! vector opt.
498            ! hydrostatic pressure gradient along s-surfaces
499            zhpi(ji,jj,1) = zcoef0 * (  e3w_n(ji+1,jj  ,1) * ( znad + rhd(ji+1,jj  ,1) )    &
500               &                      - e3w_n(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) )  ) * r1_e1u(ji,jj)
501            zhpj(ji,jj,1) = zcoef0 * (  e3w_n(ji  ,jj+1,1) * ( znad + rhd(ji  ,jj+1,1) )    &
502               &                      - e3w_n(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) )  ) * r1_e2v(ji,jj)
503            ! s-coordinate pressure gradient correction
504            zuap = -zcoef0 * ( rhd    (ji+1,jj,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
505               &           * ( gde3w_n(ji+1,jj,1) - gde3w_n(ji,jj,1) ) * r1_e1u(ji,jj)
506            zvap = -zcoef0 * ( rhd    (ji,jj+1,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
507               &           * ( gde3w_n(ji,jj+1,1) - gde3w_n(ji,jj,1) ) * r1_e2v(ji,jj)
508            !
509            IF( ln_wd_il ) THEN
510               zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
511               zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj) 
512               zuap = zuap * zcpx(ji,jj)
513               zvap = zvap * zcpy(ji,jj)
514            ENDIF
515            !
516            ! add to the general momentum trend
517            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
518            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
519         END DO
520      END DO
521
522      ! interior value (2=<jk=<jpkm1)
523      DO jk = 2, jpkm1
524         DO jj = 2, jpjm1
525            DO ji = fs_2, fs_jpim1   ! vector opt.
526               ! hydrostatic pressure gradient along s-surfaces
527               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 * r1_e1u(ji,jj)   &
528                  &           * (  e3w_n(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad )   &
529                  &              - e3w_n(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad )  )
530               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 * r1_e2v(ji,jj)   &
531                  &           * (  e3w_n(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad )   &
532                  &              - e3w_n(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad )  )
533               ! s-coordinate pressure gradient correction
534               zuap = -zcoef0 * ( rhd    (ji+1,jj  ,jk) + rhd    (ji,jj,jk) + 2._wp * znad )   &
535                  &           * ( gde3w_n(ji+1,jj  ,jk) - gde3w_n(ji,jj,jk) ) * r1_e1u(ji,jj)
536               zvap = -zcoef0 * ( rhd    (ji  ,jj+1,jk) + rhd    (ji,jj,jk) + 2._wp * znad )   &
537                  &           * ( gde3w_n(ji  ,jj+1,jk) - gde3w_n(ji,jj,jk) ) * r1_e2v(ji,jj)
538               !
539               IF( ln_wd_il ) THEN
540                  zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
541                  zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj) 
542                  zuap = zuap * zcpx(ji,jj)
543                  zvap = zvap * zcpy(ji,jj)
544               ENDIF
545               !
546               ! add to the general momentum trend
547               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
548               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
549            END DO
550         END DO
551      END DO
552      !
553      IF( ln_wd_il )  DEALLOCATE( zcpx , zcpy )
554      !
555   END SUBROUTINE hpg_sco
556
557
558   SUBROUTINE hpg_isf( kt )
559      !!---------------------------------------------------------------------
560      !!                  ***  ROUTINE hpg_isf  ***
561      !!
562      !! ** Method  :   s-coordinate case. Jacobian scheme.
563      !!      The now hydrostatic pressure gradient at a given level, jk,
564      !!      is computed by taking the vertical integral of the in-situ
565      !!      density gradient along the model level from the suface to that
566      !!      level. s-coordinates (ln_sco): a corrective term is added
567      !!      to the horizontal pressure gradient :
568      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
569      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
570      !!      add it to the general momentum trend (ua,va).
571      !!         ua = ua - 1/e1u * zhpi
572      !!         va = va - 1/e2v * zhpj
573      !!      iceload is added and partial cell case are added to the top and bottom
574      !!     
575      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
576      !!----------------------------------------------------------------------
577      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
578      !!
579      INTEGER  ::   ji, jj, jk, ikt, iktp1i, iktp1j   ! dummy loop indices
580      REAL(wp) ::   zcoef0, zuap, zvap, znad          ! temporary scalars
581      REAL(wp), DIMENSION(jpi,jpj,jpk ) ::  zhpi, zhpj
582      REAL(wp), DIMENSION(jpi,jpj,jpts) ::  zts_top
583      REAL(wp), DIMENSION(jpi,jpj)      ::  zrhdtop_oce
584      !!----------------------------------------------------------------------
585      !
586      zcoef0 = - grav * 0.5_wp   ! Local constant initialization
587      !
588      znad=1._wp                 ! To use density and not density anomaly
589      !
590      !                          ! iniitialised to 0. zhpi zhpi
591      zhpi(:,:,:) = 0._wp   ;   zhpj(:,:,:) = 0._wp
592
593      ! compute rhd at the ice/oce interface (ocean side)
594      ! usefull to reduce residual current in the test case ISOMIP with no melting
595      DO ji = 1, jpi
596        DO jj = 1, jpj
597          ikt = mikt(ji,jj)
598          zts_top(ji,jj,1) = tsn(ji,jj,ikt,1)
599          zts_top(ji,jj,2) = tsn(ji,jj,ikt,2)
600        END DO
601      END DO
602      CALL eos( zts_top, risfdep, zrhdtop_oce )
603
604!==================================================================================     
605!===== Compute surface value =====================================================
606!==================================================================================
607      DO jj = 2, jpjm1
608         DO ji = fs_2, fs_jpim1   ! vector opt.
609            ikt    = mikt(ji,jj)
610            iktp1i = mikt(ji+1,jj)
611            iktp1j = mikt(ji,jj+1)
612            ! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
613            ! we assume ISF is in isostatic equilibrium
614            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( 0.5_wp * e3w_n(ji+1,jj,iktp1i)                                    &
615               &                                    * ( 2._wp * znad + rhd(ji+1,jj,iktp1i) + zrhdtop_oce(ji+1,jj) )   &
616               &                                  - 0.5_wp * e3w_n(ji,jj,ikt)                                         &
617               &                                    * ( 2._wp * znad + rhd(ji,jj,ikt) + zrhdtop_oce(ji,jj) )          &
618               &                                  + ( riceload(ji+1,jj) - riceload(ji,jj))                            ) 
619            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( 0.5_wp * e3w_n(ji,jj+1,iktp1j)                                    &
620               &                                    * ( 2._wp * znad + rhd(ji,jj+1,iktp1j) + zrhdtop_oce(ji,jj+1) )   &
621               &                                  - 0.5_wp * e3w_n(ji,jj,ikt)                                         & 
622               &                                    * ( 2._wp * znad + rhd(ji,jj,ikt) + zrhdtop_oce(ji,jj) )          &
623               &                                  + ( riceload(ji,jj+1) - riceload(ji,jj))                            ) 
624            ! s-coordinate pressure gradient correction (=0 if z coordinate)
625            zuap = -zcoef0 * ( rhd    (ji+1,jj,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
626               &           * ( gde3w_n(ji+1,jj,1) - gde3w_n(ji,jj,1) ) * r1_e1u(ji,jj)
627            zvap = -zcoef0 * ( rhd    (ji,jj+1,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
628               &           * ( gde3w_n(ji,jj+1,1) - gde3w_n(ji,jj,1) ) * r1_e2v(ji,jj)
629            ! add to the general momentum trend
630            ua(ji,jj,1) = ua(ji,jj,1) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
631            va(ji,jj,1) = va(ji,jj,1) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
632         END DO
633      END DO
634!==================================================================================     
635!===== Compute interior value =====================================================
636!==================================================================================
637      ! interior value (2=<jk=<jpkm1)
638      DO jk = 2, jpkm1
639         DO jj = 2, jpjm1
640            DO ji = fs_2, fs_jpim1   ! vector opt.
641               ! hydrostatic pressure gradient along s-surfaces
642               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   &
643                  &           * (  e3w_n(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad ) * wmask(ji+1,jj,jk)   &
644                  &              - e3w_n(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad ) * wmask(ji  ,jj,jk)   )
645               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
646                  &           * (  e3w_n(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad ) * wmask(ji,jj+1,jk)   &
647                  &              - e3w_n(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad ) * wmask(ji,jj  ,jk)   )
648               ! s-coordinate pressure gradient correction
649               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
650                  &           * ( gde3w_n(ji+1,jj  ,jk) - gde3w_n(ji,jj,jk) ) / e1u(ji,jj)
651               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
652                  &           * ( gde3w_n(ji  ,jj+1,jk) - gde3w_n(ji,jj,jk) ) / e2v(ji,jj)
653               ! add to the general momentum trend
654               ua(ji,jj,jk) = ua(ji,jj,jk) + (zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
655               va(ji,jj,jk) = va(ji,jj,jk) + (zhpj(ji,jj,jk) + zvap) * vmask(ji,jj,jk)
656            END DO
657         END DO
658      END DO
659      !
660   END SUBROUTINE hpg_isf
661
662
663   SUBROUTINE hpg_djc( kt )
664      !!---------------------------------------------------------------------
665      !!                  ***  ROUTINE hpg_djc  ***
666      !!
667      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
668      !!
669      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
670      !!----------------------------------------------------------------------
671      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
672      !!
673      INTEGER  ::   ji, jj, jk          ! dummy loop indices
674      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
675      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
676      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
677      LOGICAL  ::   ll_tmp1, ll_tmp2    ! local logical variables
678      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zhpi, zhpj
679      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   dzx, dzy, dzz, dzu, dzv, dzw
680      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   drhox, drhoy, drhoz, drhou, drhov, drhow
681      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   rho_i, rho_j, rho_k
682      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zcpx, zcpy   !W/D pressure filter
683      !!----------------------------------------------------------------------
684      !
685      IF( ln_wd_il ) THEN
686         ALLOCATE( zcpx(jpi,jpj) , zcpy(jpi,jpj) )
687        DO jj = 2, jpjm1
688           DO ji = 2, jpim1 
689             ll_tmp1 = MIN(  sshn(ji,jj)              ,  sshn(ji+1,jj) ) >                &
690                  &    MAX( -ht_0(ji,jj)              , -ht_0(ji+1,jj) ) .AND.            &
691                  &    MAX(  sshn(ji,jj) + ht_0(ji,jj),  sshn(ji+1,jj) + ht_0(ji+1,jj) )  &
692                  &                                                      > rn_wdmin1 + rn_wdmin2
693             ll_tmp2 = ( ABS( sshn(ji,jj)             -  sshn(ji+1,jj) ) > 1.E-12 ) .AND. (        &
694                  &    MAX(   sshn(ji,jj)             ,  sshn(ji+1,jj) ) >                &
695                  &    MAX(  -ht_0(ji,jj)             , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
696             IF(ll_tmp1) THEN
697               zcpx(ji,jj) = 1.0_wp
698             ELSE IF(ll_tmp2) THEN
699               ! no worries about  sshn(ji+1,jj) -  sshn(ji  ,jj) = 0, it won't happen ! here
700               zcpx(ji,jj) = ABS( (sshn(ji+1,jj) + ht_0(ji+1,jj) - sshn(ji,jj) - ht_0(ji,jj)) &
701                           &    / (sshn(ji+1,jj) - sshn(ji  ,jj)) )
702             ELSE
703               zcpx(ji,jj) = 0._wp
704             END IF
705     
706             ll_tmp1 = MIN(  sshn(ji,jj)              ,  sshn(ji,jj+1) ) >                &
707                  &    MAX( -ht_0(ji,jj)              , -ht_0(ji,jj+1) ) .AND.            &
708                  &    MAX(  sshn(ji,jj) + ht_0(ji,jj),  sshn(ji,jj+1) + ht_0(ji,jj+1) )  &
709                  &                                                      > rn_wdmin1 + rn_wdmin2
710             ll_tmp2 = ( ABS( sshn(ji,jj)             -  sshn(ji,jj+1) ) > 1.E-12 ) .AND. (        &
711                  &    MAX(   sshn(ji,jj)             ,  sshn(ji,jj+1) ) >                &
712                  &    MAX(  -ht_0(ji,jj)             , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
713
714             IF(ll_tmp1) THEN
715               zcpy(ji,jj) = 1.0_wp
716             ELSE IF(ll_tmp2) THEN
717               ! no worries about  sshn(ji,jj+1) -  sshn(ji,jj  ) = 0, it won't happen ! here
718               zcpy(ji,jj) = ABS( (sshn(ji,jj+1) + ht_0(ji,jj+1) - sshn(ji,jj) - ht_0(ji,jj)) &
719                           &    / (sshn(ji,jj+1) - sshn(ji,jj  )) )
720             ELSE
721               zcpy(ji,jj) = 0._wp
722             END IF
723           END DO
724        END DO
725        CALL lbc_lnk_multi( 'dynhpg', zcpx, 'U', 1., zcpy, 'V', 1. )
726      END IF
727
728      IF( kt == nit000 ) THEN
729         IF(lwp) WRITE(numout,*)
730         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
731         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
732      ENDIF
733
734      ! Local constant initialization
735      zcoef0 = - grav * 0.5_wp
736      z1_10  = 1._wp / 10._wp
737      z1_12  = 1._wp / 12._wp
738
739      !----------------------------------------------------------------------------------------
740      !  compute and store in provisional arrays elementary vertical and horizontal differences
741      !----------------------------------------------------------------------------------------
742
743!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
744
745      DO jk = 2, jpkm1
746         DO jj = 2, jpjm1
747            DO ji = fs_2, fs_jpim1   ! vector opt.
748               drhoz(ji,jj,jk) = rhd    (ji  ,jj  ,jk) - rhd    (ji,jj,jk-1)
749               dzz  (ji,jj,jk) = gde3w_n(ji  ,jj  ,jk) - gde3w_n(ji,jj,jk-1)
750               drhox(ji,jj,jk) = rhd    (ji+1,jj  ,jk) - rhd    (ji,jj,jk  )
751               dzx  (ji,jj,jk) = gde3w_n(ji+1,jj  ,jk) - gde3w_n(ji,jj,jk  )
752               drhoy(ji,jj,jk) = rhd    (ji  ,jj+1,jk) - rhd    (ji,jj,jk  )
753               dzy  (ji,jj,jk) = gde3w_n(ji  ,jj+1,jk) - gde3w_n(ji,jj,jk  )
754            END DO
755         END DO
756      END DO
757
758      !-------------------------------------------------------------------------
759      ! compute harmonic averages using eq. 5.18
760      !-------------------------------------------------------------------------
761      zep = 1.e-15
762
763!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
764!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
765
766      DO jk = 2, jpkm1
767         DO jj = 2, jpjm1
768            DO ji = fs_2, fs_jpim1   ! vector opt.
769               cffw = 2._wp * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
770
771               cffu = 2._wp * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
772               cffx = 2._wp * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
773
774               cffv = 2._wp * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
775               cffy = 2._wp * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
776
777               IF( cffw > zep) THEN
778                  drhow(ji,jj,jk) = 2._wp *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
779                     &                    / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
780               ELSE
781                  drhow(ji,jj,jk) = 0._wp
782               ENDIF
783
784               dzw(ji,jj,jk) = 2._wp *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
785                  &                  / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
786
787               IF( cffu > zep ) THEN
788                  drhou(ji,jj,jk) = 2._wp *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
789                     &                    / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
790               ELSE
791                  drhou(ji,jj,jk ) = 0._wp
792               ENDIF
793
794               IF( cffx > zep ) THEN
795                  dzu(ji,jj,jk) = 2._wp *   dzx(ji+1,jj,jk) * dzx(ji,jj,jk)   &
796                     &                  / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
797               ELSE
798                  dzu(ji,jj,jk) = 0._wp
799               ENDIF
800
801               IF( cffv > zep ) THEN
802                  drhov(ji,jj,jk) = 2._wp *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
803                     &                    / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
804               ELSE
805                  drhov(ji,jj,jk) = 0._wp
806               ENDIF
807
808               IF( cffy > zep ) THEN
809                  dzv(ji,jj,jk) = 2._wp *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
810                     &                  / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
811               ELSE
812                  dzv(ji,jj,jk) = 0._wp
813               ENDIF
814
815            END DO
816         END DO
817      END DO
818
819      !----------------------------------------------------------------------------------
820      ! apply boundary conditions at top and bottom using 5.36-5.37
821      !----------------------------------------------------------------------------------
822      drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5_wp * drhow(:,:,  2  )
823      drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5_wp * drhou(:,:,  2  )
824      drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5_wp * drhov(:,:,  2  )
825
826      drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
827      drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
828      drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
829
830
831      !--------------------------------------------------------------
832      ! Upper half of top-most grid box, compute and store
833      !-------------------------------------------------------------
834
835!!bug gm   :  e3w-gde3w = 0.5*e3w  ....  and gde3w(2)-gde3w(1)=e3w(2) ....   to be verified
836!          true if gde3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
837
838      DO jj = 2, jpjm1
839         DO ji = fs_2, fs_jpim1   ! vector opt.
840            rho_k(ji,jj,1) = -grav * ( e3w_n(ji,jj,1) - gde3w_n(ji,jj,1) )               &
841               &                   * (  rhd(ji,jj,1)                                     &
842               &                     + 0.5_wp * ( rhd    (ji,jj,2) - rhd    (ji,jj,1) )  &
843               &                              * ( e3w_n  (ji,jj,1) - gde3w_n(ji,jj,1) )  &
844               &                              / ( gde3w_n(ji,jj,2) - gde3w_n(ji,jj,1) )  )
845         END DO
846      END DO
847
848!!bug gm    : here also, simplification is possible
849!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
850
851      DO jk = 2, jpkm1
852         DO jj = 2, jpjm1
853            DO ji = fs_2, fs_jpim1   ! vector opt.
854
855               rho_k(ji,jj,jk) = zcoef0 * ( rhd    (ji,jj,jk) + rhd    (ji,jj,jk-1) )                                   &
856                  &                     * ( gde3w_n(ji,jj,jk) - gde3w_n(ji,jj,jk-1) )                                   &
857                  &            - grav * z1_10 * (                                                                   &
858                  &     ( drhow  (ji,jj,jk) - drhow  (ji,jj,jk-1) )                                                     &
859                  &   * ( gde3w_n(ji,jj,jk) - gde3w_n(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
860                  &   - ( dzw    (ji,jj,jk) - dzw    (ji,jj,jk-1) )                                                     &
861                  &   * ( rhd    (ji,jj,jk) - rhd    (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
862                  &                             )
863
864               rho_i(ji,jj,jk) = zcoef0 * ( rhd    (ji+1,jj,jk) + rhd    (ji,jj,jk) )                                   &
865                  &                     * ( gde3w_n(ji+1,jj,jk) - gde3w_n(ji,jj,jk) )                                   &
866                  &            - grav* z1_10 * (                                                                    &
867                  &     ( drhou  (ji+1,jj,jk) - drhou  (ji,jj,jk) )                                                     &
868                  &   * ( gde3w_n(ji+1,jj,jk) - gde3w_n(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
869                  &   - ( dzu    (ji+1,jj,jk) - dzu    (ji,jj,jk) )                                                     &
870                  &   * ( rhd    (ji+1,jj,jk) - rhd    (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
871                  &                            )
872
873               rho_j(ji,jj,jk) = zcoef0 * ( rhd    (ji,jj+1,jk) + rhd    (ji,jj,jk) )                                 &
874                  &                     * ( gde3w_n(ji,jj+1,jk) - gde3w_n(ji,jj,jk) )                                   &
875                  &            - grav* z1_10 * (                                                                    &
876                  &     ( drhov  (ji,jj+1,jk) - drhov  (ji,jj,jk) )                                                     &
877                  &   * ( gde3w_n(ji,jj+1,jk) - gde3w_n(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
878                  &   - ( dzv    (ji,jj+1,jk) - dzv    (ji,jj,jk) )                                                     &
879                  &   * ( rhd    (ji,jj+1,jk) - rhd    (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
880                  &                            )
881
882            END DO
883         END DO
884      END DO
885      CALL lbc_lnk_multi( 'dynhpg', rho_k, 'W', 1., rho_i, 'U', 1., rho_j, 'V', 1. )
886
887      ! ---------------
888      !  Surface value
889      ! ---------------
890      DO jj = 2, jpjm1
891         DO ji = fs_2, fs_jpim1   ! vector opt.
892            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) * r1_e1u(ji,jj)
893            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) * r1_e2v(ji,jj)
894            IF( ln_wd_il ) THEN
895              zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
896              zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj) 
897            ENDIF
898            ! add to the general momentum trend
899            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
900            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
901         END DO
902      END DO
903
904      ! ----------------
905      !  interior value   (2=<jk=<jpkm1)
906      ! ----------------
907      DO jk = 2, jpkm1
908         DO jj = 2, jpjm1
909            DO ji = fs_2, fs_jpim1   ! vector opt.
910               ! hydrostatic pressure gradient along s-surfaces
911               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
912                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
913                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) * r1_e1u(ji,jj)
914               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
915                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
916                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) * r1_e2v(ji,jj)
917               IF( ln_wd_il ) THEN
918                 zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
919                 zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj) 
920               ENDIF
921               ! add to the general momentum trend
922               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
923               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
924            END DO
925         END DO
926      END DO
927      !
928      IF( ln_wd_il )   DEALLOCATE( zcpx, zcpy )
929      !
930   END SUBROUTINE hpg_djc
931
932
933   SUBROUTINE hpg_prj( kt )
934      !!---------------------------------------------------------------------
935      !!                  ***  ROUTINE hpg_prj  ***
936      !!
937      !! ** Method  :   s-coordinate case.
938      !!      A Pressure-Jacobian horizontal pressure gradient method
939      !!      based on the constrained cubic-spline interpolation for
940      !!      all vertical coordinate systems
941      !!
942      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
943      !!----------------------------------------------------------------------
944      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
945      INTEGER, INTENT(in) ::   kt                   ! ocean time-step index
946      !!
947      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
948      REAL(wp) ::   zcoef0, znad                    ! local scalars
949      !
950      !! The local variables for the correction term
951      INTEGER  :: jk1, jis, jid, jjs, jjd
952      LOGICAL  :: ll_tmp1, ll_tmp2                  ! local logical variables
953      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
954      REAL(wp) :: zrhdt1
955      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
956      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zdept, zrhh
957      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
958      REAL(wp), DIMENSION(jpi,jpj)   ::   zsshu_n, zsshv_n
959      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zcpx, zcpy   !W/D pressure filter
960      !!----------------------------------------------------------------------
961      !
962      IF( kt == nit000 ) THEN
963         IF(lwp) WRITE(numout,*)
964         IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
965         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
966      ENDIF
967
968      ! Local constant initialization
969      zcoef0 = - grav
970      znad = 1._wp
971      IF( ln_linssh )   znad = 0._wp
972
973      IF( ln_wd_il ) THEN
974         ALLOCATE( zcpx(jpi,jpj) , zcpy(jpi,jpj) )
975         DO jj = 2, jpjm1
976           DO ji = 2, jpim1 
977             ll_tmp1 = MIN(  sshn(ji,jj)              ,  sshn(ji+1,jj) ) >                &
978                  &    MAX( -ht_0(ji,jj)              , -ht_0(ji+1,jj) ) .AND.            &
979                  &    MAX(  sshn(ji,jj) + ht_0(ji,jj),  sshn(ji+1,jj) + ht_0(ji+1,jj) )  &
980                  &                                                      > rn_wdmin1 + rn_wdmin2
981             ll_tmp2 = ( ABS( sshn(ji,jj)             -  sshn(ji+1,jj) ) > 1.E-12 ) .AND. (         &
982                  &    MAX(   sshn(ji,jj)             ,  sshn(ji+1,jj) ) >                &
983                  &    MAX(  -ht_0(ji,jj)             , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
984
985             IF(ll_tmp1) THEN
986               zcpx(ji,jj) = 1.0_wp
987             ELSE IF(ll_tmp2) THEN
988               ! no worries about  sshn(ji+1,jj) -  sshn(ji  ,jj) = 0, it won't happen ! here
989               zcpx(ji,jj) = ABS( (sshn(ji+1,jj) + ht_0(ji+1,jj) - sshn(ji,jj) - ht_0(ji,jj)) &
990                           &    / (sshn(ji+1,jj) -  sshn(ji  ,jj)) )
991             
992                zcpx(ji,jj) = max(min( zcpx(ji,jj) , 1.0_wp),0.0_wp)
993             ELSE
994               zcpx(ji,jj) = 0._wp
995             END IF
996     
997             ll_tmp1 = MIN(  sshn(ji,jj)              ,  sshn(ji,jj+1) ) >                &
998                  &    MAX( -ht_0(ji,jj)              , -ht_0(ji,jj+1) ) .AND.            &
999                  &    MAX(  sshn(ji,jj) + ht_0(ji,jj),  sshn(ji,jj+1) + ht_0(ji,jj+1) )  &
1000                  &                                                      > rn_wdmin1 + rn_wdmin2
1001             ll_tmp2 = ( ABS( sshn(ji,jj)             -  sshn(ji,jj+1) ) > 1.E-12 ) .AND. (      &
1002                  &    MAX(   sshn(ji,jj)             ,  sshn(ji,jj+1) ) >                &
1003                  &    MAX(  -ht_0(ji,jj)             , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
1004
1005             IF(ll_tmp1) THEN
1006               zcpy(ji,jj) = 1.0_wp
1007             ELSE IF(ll_tmp2) THEN
1008               ! no worries about  sshn(ji,jj+1) -  sshn(ji,jj  ) = 0, it won't happen ! here
1009               zcpy(ji,jj) = ABS( (sshn(ji,jj+1) + ht_0(ji,jj+1) - sshn(ji,jj) - ht_0(ji,jj)) &
1010                           &    / (sshn(ji,jj+1) - sshn(ji,jj  )) )
1011                zcpy(ji,jj) = max(min( zcpy(ji,jj) , 1.0_wp),0.0_wp)
1012
1013               ELSE
1014                  zcpy(ji,jj) = 0._wp
1015               ENDIF
1016            END DO
1017         END DO
1018         CALL lbc_lnk_multi( 'dynhpg', zcpx, 'U', 1., zcpy, 'V', 1. )
1019      ENDIF
1020
1021      ! Clean 3-D work arrays
1022      zhpi(:,:,:) = 0._wp
1023      zrhh(:,:,:) = rhd(:,:,:)
1024
1025      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
1026      DO jj = 1, jpj
1027        DO ji = 1, jpi
1028          jk = mbkt(ji,jj)+1
1029          IF(     jk <=  0   ) THEN   ;   zrhh(ji,jj,    :   ) = 0._wp
1030          ELSEIF( jk ==  1   ) THEN   ;   zrhh(ji,jj,jk+1:jpk) = rhd(ji,jj,jk)
1031          ELSEIF( jk < jpkm1 ) THEN
1032             DO jkk = jk+1, jpk
1033                zrhh(ji,jj,jkk) = interp1(gde3w_n(ji,jj,jkk  ), gde3w_n(ji,jj,jkk-1),   &
1034                   &                      gde3w_n(ji,jj,jkk-2), rhd    (ji,jj,jkk-1), rhd(ji,jj,jkk-2))
1035             END DO
1036          ENDIF
1037        END DO
1038      END DO
1039
1040      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
1041      DO jj = 1, jpj
1042         DO ji = 1, jpi
1043            zdept(ji,jj,1) = 0.5_wp * e3w_n(ji,jj,1) - sshn(ji,jj) * znad
1044         END DO
1045      END DO
1046
1047      DO jk = 2, jpk
1048         DO jj = 1, jpj
1049            DO ji = 1, jpi
1050               zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + e3w_n(ji,jj,jk)
1051            END DO
1052         END DO
1053      END DO
1054
1055      fsp(:,:,:) = zrhh (:,:,:)
1056      xsp(:,:,:) = zdept(:,:,:)
1057
1058      ! Construct the vertical density profile with the
1059      ! constrained cubic spline interpolation
1060      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
1061      CALL cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1062
1063      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
1064      DO jj = 2, jpj
1065        DO ji = 2, jpi
1066          zrhdt1 = zrhh(ji,jj,1) - interp3( zdept(ji,jj,1), asp(ji,jj,1), bsp(ji,jj,1),  &
1067             &                                              csp(ji,jj,1), dsp(ji,jj,1) ) * 0.25_wp * e3w_n(ji,jj,1)
1068
1069          ! assuming linear profile across the top half surface layer
1070          zhpi(ji,jj,1) =  0.5_wp * e3w_n(ji,jj,1) * zrhdt1
1071        END DO
1072      END DO
1073
1074      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1075      DO jk = 2, jpkm1
1076        DO jj = 2, jpj
1077          DO ji = 2, jpi
1078            zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                                  &
1079               &             integ_spline( zdept(ji,jj,jk-1), zdept(ji,jj,jk),   &
1080               &                           asp  (ji,jj,jk-1), bsp  (ji,jj,jk-1), &
1081               &                           csp  (ji,jj,jk-1), dsp  (ji,jj,jk-1)  )
1082          END DO
1083        END DO
1084      END DO
1085
1086      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1087
1088      ! Prepare zsshu_n and zsshv_n
1089      DO jj = 2, jpjm1
1090        DO ji = 2, jpim1
1091!!gm BUG ?    if it is ssh at u- & v-point then it should be:
1092!          zsshu_n(ji,jj) = (e1e2t(ji,jj) * sshn(ji,jj) + e1e2t(ji+1,jj) * sshn(ji+1,jj)) * &
1093!                         & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp
1094!          zsshv_n(ji,jj) = (e1e2t(ji,jj) * sshn(ji,jj) + e1e2t(ji,jj+1) * sshn(ji,jj+1)) * &
1095!                         & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp
1096!!gm not this:
1097          zsshu_n(ji,jj) = (e1e2u(ji,jj) * sshn(ji,jj) + e1e2u(ji+1, jj) * sshn(ji+1,jj)) * &
1098                         & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp 
1099          zsshv_n(ji,jj) = (e1e2v(ji,jj) * sshn(ji,jj) + e1e2v(ji+1, jj) * sshn(ji,jj+1)) * &
1100                         & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp 
1101        END DO
1102      END DO
1103
1104      CALL lbc_lnk_multi ('dynhpg', zsshu_n, 'U', 1., zsshv_n, 'V', 1. )
1105
1106      DO jj = 2, jpjm1
1107        DO ji = 2, jpim1
1108          zu(ji,jj,1) = - ( e3u_n(ji,jj,1) - zsshu_n(ji,jj) * znad) 
1109          zv(ji,jj,1) = - ( e3v_n(ji,jj,1) - zsshv_n(ji,jj) * znad)
1110        END DO
1111      END DO
1112
1113      DO jk = 2, jpkm1
1114        DO jj = 2, jpjm1
1115          DO ji = 2, jpim1
1116            zu(ji,jj,jk) = zu(ji,jj,jk-1) - e3u_n(ji,jj,jk)
1117            zv(ji,jj,jk) = zv(ji,jj,jk-1) - e3v_n(ji,jj,jk)
1118          END DO
1119        END DO
1120      END DO
1121
1122      DO jk = 1, jpkm1
1123        DO jj = 2, jpjm1
1124          DO ji = 2, jpim1
1125            zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * e3u_n(ji,jj,jk)
1126            zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * e3v_n(ji,jj,jk)
1127          END DO
1128        END DO
1129      END DO
1130
1131      DO jk = 1, jpkm1
1132        DO jj = 2, jpjm1
1133          DO ji = 2, jpim1
1134            zu(ji,jj,jk) = MIN(  zu(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) )  )
1135            zu(ji,jj,jk) = MAX(  zu(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) )  )
1136            zv(ji,jj,jk) = MIN(  zv(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) )  )
1137            zv(ji,jj,jk) = MAX(  zv(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) )  )
1138          END DO
1139        END DO
1140      END DO
1141
1142
1143      DO jk = 1, jpkm1
1144        DO jj = 2, jpjm1
1145          DO ji = 2, jpim1
1146            zpwes = 0._wp; zpwed = 0._wp
1147            zpnss = 0._wp; zpnsd = 0._wp
1148            zuijk = zu(ji,jj,jk)
1149            zvijk = zv(ji,jj,jk)
1150
1151            !!!!!     for u equation
1152            IF( jk <= mbku(ji,jj) ) THEN
1153               IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1154                 jis = ji + 1; jid = ji
1155               ELSE
1156                 jis = ji;     jid = ji +1
1157               ENDIF
1158
1159               ! integrate the pressure on the shallow side
1160               jk1 = jk
1161               DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1162                 IF( jk1 == mbku(ji,jj) ) THEN
1163                   zuijk = -zdept(jis,jj,jk1)
1164                   EXIT
1165                 ENDIF
1166                 zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1167                 zpwes = zpwes +                                    &
1168                      integ_spline(zdept(jis,jj,jk1), zdeps,            &
1169                             asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
1170                             csp(jis,jj,jk1),    dsp(jis,jj,jk1))
1171                 jk1 = jk1 + 1
1172               END DO
1173
1174               ! integrate the pressure on the deep side
1175               jk1 = jk
1176               DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1177                 IF( jk1 == 1 ) THEN
1178                   zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
1179                   zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1180                                                     bsp(jid,jj,1),   csp(jid,jj,1), &
1181                                                     dsp(jid,jj,1)) * zdeps
1182                   zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1183                   EXIT
1184                 ENDIF
1185                 zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1186                 zpwed = zpwed +                                        &
1187                        integ_spline(zdeps,              zdept(jid,jj,jk1), &
1188                               asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
1189                               csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1190                 jk1 = jk1 - 1
1191               END DO
1192
1193               ! update the momentum trends in u direction
1194
1195               zdpdx1 = zcoef0 * r1_e1u(ji,jj) * ( zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk) )
1196               IF( .NOT.ln_linssh ) THEN
1197                 zdpdx2 = zcoef0 * r1_e1u(ji,jj) * &
1198                    &    ( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
1199                ELSE
1200                 zdpdx2 = zcoef0 * r1_e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1201               ENDIF
1202               IF( ln_wd_il ) THEN
1203                  zdpdx1 = zdpdx1 * zcpx(ji,jj) * wdrampu(ji,jj)
1204                  zdpdx2 = zdpdx2 * zcpx(ji,jj) * wdrampu(ji,jj)
1205               ENDIF
1206               ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * umask(ji,jj,jk) 
1207            ENDIF
1208
1209            !!!!!     for v equation
1210            IF( jk <= mbkv(ji,jj) ) THEN
1211               IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1212                 jjs = jj + 1; jjd = jj
1213               ELSE
1214                 jjs = jj    ; jjd = jj + 1
1215               ENDIF
1216
1217               ! integrate the pressure on the shallow side
1218               jk1 = jk
1219               DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1220                 IF( jk1 == mbkv(ji,jj) ) THEN
1221                   zvijk = -zdept(ji,jjs,jk1)
1222                   EXIT
1223                 ENDIF
1224                 zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1225                 zpnss = zpnss +                                      &
1226                        integ_spline(zdept(ji,jjs,jk1), zdeps,            &
1227                               asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
1228                               csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
1229                 jk1 = jk1 + 1
1230               END DO
1231
1232               ! integrate the pressure on the deep side
1233               jk1 = jk
1234               DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1235                 IF( jk1 == 1 ) THEN
1236                   zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
1237                   zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1238                                                     bsp(ji,jjd,1),   csp(ji,jjd,1), &
1239                                                     dsp(ji,jjd,1) ) * zdeps
1240                   zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1241                   EXIT
1242                 ENDIF
1243                 zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1244                 zpnsd = zpnsd +                                        &
1245                        integ_spline(zdeps,              zdept(ji,jjd,jk1), &
1246                               asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1247                               csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1248                 jk1 = jk1 - 1
1249               END DO
1250
1251
1252               ! update the momentum trends in v direction
1253
1254               zdpdy1 = zcoef0 * r1_e2v(ji,jj) * ( zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk) )
1255               IF( .NOT.ln_linssh ) THEN
1256                  zdpdy2 = zcoef0 * r1_e2v(ji,jj) * &
1257                          ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
1258               ELSE
1259                  zdpdy2 = zcoef0 * r1_e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1260               ENDIF
1261               IF( ln_wd_il ) THEN
1262                  zdpdy1 = zdpdy1 * zcpy(ji,jj) * wdrampv(ji,jj) 
1263                  zdpdy2 = zdpdy2 * zcpy(ji,jj) * wdrampv(ji,jj) 
1264               ENDIF
1265
1266               va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2) * vmask(ji,jj,jk)
1267            ENDIF
1268               !
1269            END DO
1270         END DO
1271      END DO
1272      !
1273      IF( ln_wd_il )   DEALLOCATE( zcpx, zcpy )
1274      !
1275   END SUBROUTINE hpg_prj
1276
1277
1278   SUBROUTINE cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1279      !!----------------------------------------------------------------------
1280      !!                 ***  ROUTINE cspline  ***
1281      !!
1282      !! ** Purpose :   constrained cubic spline interpolation
1283      !!
1284      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
1285      !!
1286      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1287      !!----------------------------------------------------------------------
1288      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   fsp, xsp           ! value and coordinate
1289      REAL(wp), DIMENSION(:,:,:), INTENT(  out) ::   asp, bsp, csp, dsp ! coefficients of the interpoated function
1290      INTEGER                   , INTENT(in   ) ::   polynomial_type    ! 1: cubic spline   ;   2: Linear
1291      !
1292      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
1293      INTEGER  ::   jpi, jpj, jpkm1
1294      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1295      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
1296      REAL(wp) ::   zdf(size(fsp,3))
1297      !!----------------------------------------------------------------------
1298      !
1299!!gm  WHAT !!!!!   THIS IS VERY DANGEROUS !!!!! 
1300      jpi   = size(fsp,1)
1301      jpj   = size(fsp,2)
1302      jpkm1 = MAX( 1, size(fsp,3) - 1 )
1303      !
1304      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
1305         DO ji = 1, jpi
1306            DO jj = 1, jpj
1307           !!Fritsch&Butland's method, 1984 (preferred, but more computation)
1308           !    DO jk = 2, jpkm1-1
1309           !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1)
1310           !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1311           !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
1312           !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
1313           !
1314           !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1315           !
1316           !       IF(zdf1 * zdf2 <= 0._wp) THEN
1317           !           zdf(jk) = 0._wp
1318           !       ELSE
1319           !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1320           !       ENDIF
1321           !    END DO
1322
1323           !!Simply geometric average
1324               DO jk = 2, jpkm1-1
1325                  zdf1 = (fsp(ji,jj,jk  ) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk  ) - xsp(ji,jj,jk-1))
1326                  zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk  )) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk  ))
1327
1328                  IF(zdf1 * zdf2 <= 0._wp) THEN
1329                     zdf(jk) = 0._wp
1330                  ELSE
1331                     zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1332                  ENDIF
1333               END DO
1334
1335               zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1336                          &          ( xsp(ji,jj,2) - xsp(ji,jj,1) )           -  0.5_wp * zdf(2)
1337               zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1338                          &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - 0.5_wp * zdf(jpkm1 - 1)
1339
1340               DO jk = 1, jpkm1 - 1
1341                 zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1342                 ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1343                 ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1344                 zddf1  = -2._wp * ztmp1 + ztmp2
1345                 ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1346                 zddf2  =  2._wp * ztmp1 - ztmp2
1347
1348                 dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1349                 csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1350                 bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1351                               & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1352                               & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1353                               &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1354                 asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1355                               &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1356                               &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1357               END DO
1358            END DO
1359         END DO
1360
1361      ELSEIF ( polynomial_type == 2 ) THEN     ! Linear
1362         DO ji = 1, jpi
1363            DO jj = 1, jpj
1364               DO jk = 1, jpkm1-1
1365                  zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1366                  ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1367
1368                  dsp(ji,jj,jk) = 0._wp
1369                  csp(ji,jj,jk) = 0._wp
1370                  bsp(ji,jj,jk) = ztmp1 / zdxtmp
1371                  asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1372               END DO
1373            END DO
1374         END DO
1375         !
1376      ELSE
1377         CALL ctl_stop( 'invalid polynomial type in cspline' )
1378      ENDIF
1379      !
1380   END SUBROUTINE cspline
1381
1382
1383   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f)
1384      !!----------------------------------------------------------------------
1385      !!                 ***  ROUTINE interp1  ***
1386      !!
1387      !! ** Purpose :   1-d linear interpolation
1388      !!
1389      !! ** Method  :   interpolation is straight forward
1390      !!                extrapolation is also permitted (no value limit)
1391      !!----------------------------------------------------------------------
1392      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr
1393      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1394      REAL(wp)             ::  zdeltx
1395      !!----------------------------------------------------------------------
1396      !
1397      zdeltx = xr - xl
1398      IF( abs(zdeltx) <= 10._wp * EPSILON(x) ) THEN
1399         f = 0.5_wp * (fl + fr)
1400      ELSE
1401         f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1402      ENDIF
1403      !
1404   END FUNCTION interp1
1405
1406
1407   FUNCTION interp2( x, a, b, c, d )  RESULT(f)
1408      !!----------------------------------------------------------------------
1409      !!                 ***  ROUTINE interp1  ***
1410      !!
1411      !! ** Purpose :   1-d constrained cubic spline interpolation
1412      !!
1413      !! ** Method  :  cubic spline interpolation
1414      !!
1415      !!----------------------------------------------------------------------
1416      REAL(wp), INTENT(in) ::  x, a, b, c, d
1417      REAL(wp)             ::  f ! value from the interpolation
1418      !!----------------------------------------------------------------------
1419      !
1420      f = a + x* ( b + x * ( c + d * x ) )
1421      !
1422   END FUNCTION interp2
1423
1424
1425   FUNCTION interp3( x, a, b, c, d )  RESULT(f)
1426      !!----------------------------------------------------------------------
1427      !!                 ***  ROUTINE interp1  ***
1428      !!
1429      !! ** Purpose :   Calculate the first order of derivative of
1430      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1431      !!
1432      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1433      !!
1434      !!----------------------------------------------------------------------
1435      REAL(wp), INTENT(in) ::  x, a, b, c, d
1436      REAL(wp)             ::  f ! value from the interpolation
1437      !!----------------------------------------------------------------------
1438      !
1439      f = b + x * ( 2._wp * c + 3._wp * d * x)
1440      !
1441   END FUNCTION interp3
1442
1443
1444   FUNCTION integ_spline( xl, xr, a, b, c, d )  RESULT(f)
1445      !!----------------------------------------------------------------------
1446      !!                 ***  ROUTINE interp1  ***
1447      !!
1448      !! ** Purpose :   1-d constrained cubic spline integration
1449      !!
1450      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1451      !!
1452      !!----------------------------------------------------------------------
1453      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d
1454      REAL(wp)             ::  za1, za2, za3
1455      REAL(wp)             ::  f                   ! integration result
1456      !!----------------------------------------------------------------------
1457      !
1458      za1 = 0.5_wp * b
1459      za2 = c / 3.0_wp
1460      za3 = 0.25_wp * d
1461      !
1462      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1463         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1464      !
1465   END FUNCTION integ_spline
1466
1467   !!======================================================================
1468END MODULE dynhpg
1469
Note: See TracBrowser for help on using the repository browser.