New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
agrif_oce_sponge.F90 in NEMO/branches/2019/dev_r11351_fldread_with_XIOS/src/NST – NEMO

source: NEMO/branches/2019/dev_r11351_fldread_with_XIOS/src/NST/agrif_oce_sponge.F90 @ 13463

Last change on this file since 13463 was 13463, checked in by andmirek, 4 years ago

Ticket #2195:update to trunk 13461

  • Property svn:keywords set to Id
File size: 33.7 KB
Line 
1#define SPONGE && define SPONGE_TOP
2
3MODULE agrif_oce_sponge
4   !!======================================================================
5   !!                   ***  MODULE  agrif_oce_interp  ***
6   !! AGRIF: sponge package for the ocean dynamics (OPA)
7   !!======================================================================
8   !! History :  2.0  !  2002-06  (XXX)  Original cade
9   !!             -   !  2005-11  (XXX)
10   !!            3.2  !  2009-04  (R. Benshila)
11   !!            3.6  !  2014-09  (R. Benshila)
12   !!----------------------------------------------------------------------
13#if defined key_agrif
14   !!----------------------------------------------------------------------
15   !!   'key_agrif'                                              AGRIF zoom
16   !!----------------------------------------------------------------------
17   USE par_oce
18   USE oce
19   USE dom_oce
20   !
21   USE in_out_manager
22   USE agrif_oce
23   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
24   USE iom
25   USE vremap
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC Agrif_Sponge, Agrif_Sponge_Tra, Agrif_Sponge_Dyn
31   PUBLIC interptsn_sponge, interpun_sponge, interpvn_sponge
32
33   !! * Substitutions
34#  include "do_loop_substitute.h90"
35   !!----------------------------------------------------------------------
36   !! NEMO/NST 4.0 , NEMO Consortium (2018)
37   !! $Id$
38   !! Software governed by the CeCILL license (see ./LICENSE)
39   !!----------------------------------------------------------------------
40CONTAINS
41
42   SUBROUTINE Agrif_Sponge_Tra
43      !!----------------------------------------------------------------------
44      !!                 *** ROUTINE Agrif_Sponge_Tra ***
45      !!----------------------------------------------------------------------
46      REAL(wp) ::   zcoef   ! local scalar
47     
48      !!----------------------------------------------------------------------
49      !
50#if defined SPONGE
51      !! Assume persistence:
52      zcoef = REAL(Agrif_rhot()-1,wp)/REAL(Agrif_rhot())
53
54      CALL Agrif_Sponge
55      Agrif_SpecialValue    = 0._wp
56      Agrif_UseSpecialValue = .TRUE.
57      tabspongedone_tsn     = .FALSE.
58      !
59      CALL Agrif_Bc_Variable( tsn_sponge_id, calledweight=zcoef, procname=interptsn_sponge )
60      !
61      Agrif_UseSpecialValue = .FALSE.
62#endif
63      !
64      CALL iom_put( 'agrif_spu', fspu(:,:))
65      CALL iom_put( 'agrif_spv', fspv(:,:))
66      !
67   END SUBROUTINE Agrif_Sponge_Tra
68
69
70   SUBROUTINE Agrif_Sponge_dyn
71      !!----------------------------------------------------------------------
72      !!                 *** ROUTINE Agrif_Sponge_dyn ***
73      !!----------------------------------------------------------------------
74      REAL(wp) ::   zcoef   ! local scalar
75      !!----------------------------------------------------------------------
76      !
77#if defined SPONGE
78      zcoef = REAL(Agrif_rhot()-1,wp)/REAL(Agrif_rhot())
79
80      Agrif_SpecialValue    = 0._wp
81      Agrif_UseSpecialValue = ln_spc_dyn
82      use_sign_north        = .TRUE.
83      sign_north            = -1._wp
84      !
85      tabspongedone_u = .FALSE.
86      tabspongedone_v = .FALSE.         
87      CALL Agrif_Bc_Variable( un_sponge_id, calledweight=zcoef, procname=interpun_sponge )
88      !
89      tabspongedone_u = .FALSE.
90      tabspongedone_v = .FALSE.
91      CALL Agrif_Bc_Variable( vn_sponge_id, calledweight=zcoef, procname=interpvn_sponge )
92      !
93      Agrif_UseSpecialValue = .FALSE.
94      use_sign_north        = .FALSE.
95#endif
96      !
97      CALL iom_put( 'agrif_spt', fspt(:,:))
98      CALL iom_put( 'agrif_spf', fspf(:,:))
99      !
100   END SUBROUTINE Agrif_Sponge_dyn
101
102
103   SUBROUTINE Agrif_Sponge
104      !!----------------------------------------------------------------------
105      !!                 *** ROUTINE  Agrif_Sponge ***
106      !!----------------------------------------------------------------------
107      INTEGER  ::   ji, jj, ind1, ind2
108      INTEGER  ::   ispongearea, jspongearea
109      REAL(wp) ::   z1_ispongearea, z1_jspongearea
110      REAL(wp), DIMENSION(jpi,jpj) :: ztabramp
111#if defined key_vertical
112      REAL(wp), DIMENSION(jpi,jpj) :: ztabrampu
113      REAL(wp), DIMENSION(jpi,jpj) :: ztabrampv
114#endif
115      REAL(wp), DIMENSION(jpjmax)  :: zmskwest,  zmskeast
116      REAL(wp), DIMENSION(jpimax)  :: zmsknorth, zmsksouth
117      !!----------------------------------------------------------------------
118      !
119      ! Sponge 1d example with:
120      !      iraf = 3 ; nbghost = 3 ; nn_sponge_len = 2
121      !                       
122      !coarse :     U     T     U     T     U     T     U
123      !|            |           |           |           |
124      !fine :     t u t u t u t u t u t u t u t u t u t u t
125      !sponge val:0   0   0   1  5/6 4/6 3/6 2/6 1/6  0   0
126      !           |   ghost     | <-- sponge area  -- > |
127      !           |   points    |                       |
128      !                         |--> dynamical interface
129
130#if defined SPONGE || defined SPONGE_TOP
131      IF (( .NOT. spongedoneT ).OR.( .NOT. spongedoneU )) THEN
132         !
133         ! Retrieve masks at open boundaries:
134
135         IF( lk_west ) THEN                             ! --- West --- !
136            ztabramp(:,:) = 0._wp
137            ind1 = nn_hls + 1 + nbghostcells               ! halo + land + nbghostcells
138            DO ji = mi0(ind1), mi1(ind1)               
139               ztabramp(ji,:) = ssumask(ji,:)
140            END DO
141            zmskwest(    1:jpj   ) = MAXVAL(ztabramp(:,:), dim=1)
142            zmskwest(jpj+1:jpjmax) = 0._wp
143         ENDIF
144         IF( lk_east ) THEN                             ! --- East --- !
145            ztabramp(:,:) = 0._wp
146            ind1 = jpiglo - ( nn_hls + nbghostcells + 1)   ! halo + land + nbghostcells
147            DO ji = mi0(ind1), mi1(ind1)                 
148               ztabramp(ji,:) = ssumask(ji,:)
149            END DO
150            zmskeast(    1:jpj   ) = MAXVAL(ztabramp(:,:), dim=1)
151            zmskeast(jpj+1:jpjmax) = 0._wp
152         ENDIF
153         IF( lk_south ) THEN                            ! --- South --- !
154            ztabramp(:,:) = 0._wp
155            ind1 = nn_hls + 1 + nbghostcells               ! halo + land + nbghostcells
156            DO jj = mj0(ind1), mj1(ind1)                 
157               ztabramp(:,jj) = ssvmask(:,jj)
158            END DO
159            zmsksouth(    1:jpi   ) = MAXVAL(ztabramp(:,:), dim=2)
160            zmsksouth(jpi+1:jpimax) = 0._wp
161         ENDIF
162         IF( lk_north ) THEN                            ! --- North --- !
163            ztabramp(:,:) = 0._wp
164            ind1 = jpjglo - ( nn_hls + nbghostcells + 1)   ! halo + land + nbghostcells
165            DO jj = mj0(ind1), mj1(ind1)                 
166               ztabramp(:,jj) = ssvmask(:,jj)
167            END DO
168            zmsknorth(    1:jpi   ) = MAXVAL(ztabramp(:,:), dim=2)
169            zmsknorth(jpi+1:jpimax) = 0._wp
170         ENDIF
171
172         ! JC: SPONGE MASKING TO BE SORTED OUT:
173         zmskwest(:)  = 1._wp
174         zmskeast(:)  = 1._wp
175         zmsksouth(:) = 1._wp
176         zmsknorth(:) = 1._wp
177#if defined key_mpp_mpi
178!         CALL mpp_max( 'AGRIF_sponge', zmskwest(:) , jpjmax )
179!         CALL mpp_max( 'AGRIF_Sponge', zmskeast(:) , jpjmax )
180!         CALL mpp_max( 'AGRIF_Sponge', zmsksouth(:), jpimax )
181!         CALL mpp_max( 'AGRIF_Sponge', zmsknorth(:), jpimax )
182#endif
183
184         ! Define ramp from boundaries towards domain interior at T-points
185         ! Store it in ztabramp
186
187         ispongearea    = nn_sponge_len * Agrif_irhox()
188         z1_ispongearea = 1._wp / REAL( ispongearea, wp )
189         jspongearea    = nn_sponge_len * Agrif_irhoy()
190         z1_jspongearea = 1._wp / REAL( jspongearea, wp )
191         
192         ztabramp(:,:) = 0._wp
193
194         ! Trick to remove sponge in 2DV domains:
195         IF ( nbcellsx <= 3 ) ispongearea = -1
196         IF ( nbcellsy <= 3 ) jspongearea = -1
197
198         IF( lk_west ) THEN                             ! --- West --- !
199            ind1 = nn_hls + 1 + nbghostcells               ! halo + land + nbghostcells
200            ind2 = nn_hls + 1 + nbghostcells + ispongearea 
201            DO ji = mi0(ind1), mi1(ind2)   
202               DO jj = 1, jpj               
203                  ztabramp(ji,jj) =                       REAL(ind2 - mig(ji), wp) * z1_ispongearea   * zmskwest(jj)
204               END DO
205            END DO
206            ! ghost cells:
207            ind1 = 1
208            ind2 = nn_hls + 1 + nbghostcells               ! halo + land + nbghostcells
209            DO ji = mi0(ind1), mi1(ind2)   
210               DO jj = 1, jpj               
211                  ztabramp(ji,jj) = zmskwest(jj)
212               END DO
213            END DO
214         ENDIF
215         IF( lk_east ) THEN                             ! --- East --- !
216            ind1 = jpiglo - ( nn_hls + nbghostcells ) - ispongearea
217            ind2 = jpiglo - ( nn_hls + nbghostcells )      ! halo + land + nbghostcells - 1
218            DO ji = mi0(ind1), mi1(ind2)
219               DO jj = 1, jpj
220                  ztabramp(ji,jj) = MAX( ztabramp(ji,jj), REAL(mig(ji) - ind1, wp) * z1_ispongearea ) * zmskeast(jj)
221               END DO
222            END DO
223            ! ghost cells:
224            ind1 = jpiglo - ( nn_hls + nbghostcells )      ! halo + land + nbghostcells - 1
225            ind2 = jpiglo
226            DO ji = mi0(ind1), mi1(ind2)
227               DO jj = 1, jpj
228                  ztabramp(ji,jj) = zmskeast(jj)
229               END DO
230            END DO
231         ENDIF     
232         IF( lk_south ) THEN                            ! --- South --- !
233            ind1 = nn_hls + 1 + nbghostcells               ! halo + land + nbghostcells
234            ind2 = nn_hls + 1 + nbghostcells + jspongearea 
235            DO jj = mj0(ind1), mj1(ind2) 
236               DO ji = 1, jpi
237                  ztabramp(ji,jj) = MAX( ztabramp(ji,jj), REAL(ind2 - mjg(jj), wp) * z1_jspongearea ) * zmsksouth(ji)
238               END DO
239            END DO
240            ! ghost cells:
241            ind1 = 1
242            ind2 = nn_hls + 1 + nbghostcells               ! halo + land + nbghostcells
243            DO jj = mj0(ind1), mj1(ind2) 
244               DO ji = 1, jpi
245                  ztabramp(ji,jj) = zmsksouth(ji)
246               END DO
247            END DO
248         ENDIF
249         IF( lk_north ) THEN                            ! --- North --- !
250            ind1 = jpjglo - ( nn_hls + nbghostcells ) - jspongearea
251            ind2 = jpjglo - ( nn_hls + nbghostcells )      ! halo + land + nbghostcells - 1
252            DO jj = mj0(ind1), mj1(ind2)
253               DO ji = 1, jpi
254                  ztabramp(ji,jj) = MAX( ztabramp(ji,jj), REAL(mjg(jj) - ind1, wp) * z1_jspongearea ) * zmsknorth(ji)
255               END DO
256            END DO
257            ! ghost cells:
258            ind1 = jpjglo - ( nn_hls + nbghostcells )      ! halo + land + nbghostcells - 1
259            ind2 = jpjglo
260            DO jj = mj0(ind1), mj1(ind2)
261               DO ji = 1, jpi
262                  ztabramp(ji,jj) = zmsknorth(ji)
263               END DO
264            END DO
265         ENDIF
266         !
267      ENDIF
268
269      ! Tracers
270      IF( .NOT. spongedoneT ) THEN
271         fspu(:,:) = 0._wp
272         fspv(:,:) = 0._wp
273         DO_2D( 0, 0, 0, 0 )
274            fspu(ji,jj) = 0.5_wp * ( ztabramp(ji,jj) + ztabramp(ji+1,jj  ) ) * ssumask(ji,jj)
275            fspv(ji,jj) = 0.5_wp * ( ztabramp(ji,jj) + ztabramp(ji  ,jj+1) ) * ssvmask(ji,jj)
276         END_2D
277      ENDIF
278
279      ! Dynamics
280      IF( .NOT. spongedoneU ) THEN
281         fspt(:,:) = 0._wp
282         fspf(:,:) = 0._wp
283         DO_2D( 0, 0, 0, 0 )
284            fspt(ji,jj) = ztabramp(ji,jj) * ssmask(ji,jj)
285            fspf(ji,jj) = 0.25_wp * ( ztabramp(ji  ,jj  ) + ztabramp(ji  ,jj+1)   &
286                                  &  +ztabramp(ji+1,jj+1) + ztabramp(ji+1,jj  ) ) &
287                                  &  * ssvmask(ji,jj) * ssvmask(ji,jj+1)
288         END_2D
289      ENDIF
290     
291      IF( .NOT. spongedoneT .AND. .NOT. spongedoneU ) THEN
292         CALL lbc_lnk_multi( 'agrif_Sponge', fspu, 'U', 1._wp, fspv, 'V', 1._wp, fspt, 'T', 1._wp, fspf, 'F', 1._wp )
293         spongedoneT = .TRUE.
294         spongedoneU = .TRUE.
295      ENDIF
296      IF( .NOT. spongedoneT ) THEN
297         CALL lbc_lnk_multi( 'agrif_Sponge', fspu, 'U', 1._wp, fspv, 'V', 1._wp )
298         spongedoneT = .TRUE.
299      ENDIF
300      IF( .NOT. spongedoneT .AND. .NOT. spongedoneU ) THEN
301         CALL lbc_lnk_multi( 'agrif_Sponge', fspt, 'T', 1._wp, fspf, 'F', 1._wp )
302         spongedoneU = .TRUE.
303      ENDIF
304
305#if defined key_vertical
306      ! Remove vertical interpolation where not needed:
307      DO_2D( 0, 0, 0, 0 )
308         IF ((fspu(ji-1,jj)==0._wp).AND.(fspu(ji,jj)==0._wp).AND. &
309         &   (fspv(ji,jj-1)==0._wp).AND.(fspv(ji,jj)==0._wp)) mbkt_parent(ji,jj) = 0
310!
311         IF ((fspt(ji+1,jj)==0._wp).AND.(fspt(ji,jj)==0._wp).AND. &
312         &   (fspf(ji,jj-1)==0._wp).AND.(fspf(ji,jj)==0._wp)) mbku_parent(ji,jj) = 0
313!
314         IF ((fspt(ji,jj+1)==0._wp).AND.(fspt(ji,jj)==0._wp).AND. &
315         &   (fspf(ji-1,jj)==0._wp).AND.(fspf(ji,jj)==0._wp)) mbkv_parent(ji,jj) = 0
316!
317         IF ( ssmask(ji,jj) == 0._wp) mbkt_parent(ji,jj) = 0
318         IF (ssumask(ji,jj) == 0._wp) mbku_parent(ji,jj) = 0
319         IF (ssvmask(ji,jj) == 0._wp) mbkv_parent(ji,jj) = 0
320      END_2D
321      !
322      ztabramp (:,:) = REAL( mbkt_parent(:,:), wp )
323      ztabrampu(:,:) = REAL( mbku_parent(:,:), wp )
324      ztabrampv(:,:) = REAL( mbkv_parent(:,:), wp )
325      CALL lbc_lnk_multi( 'Agrif_Sponge', ztabramp, 'T', 1._wp, ztabrampu, 'U', 1._wp, ztabrampv, 'V', 1._wp )
326      mbkt_parent(:,:) = NINT( ztabramp (:,:) )
327      mbku_parent(:,:) = NINT( ztabrampu(:,:) )
328      mbkv_parent(:,:) = NINT( ztabrampv(:,:) )
329#endif
330      !
331#endif
332      !
333   END SUBROUTINE Agrif_Sponge
334
335   
336   SUBROUTINE interptsn_sponge( tabres, i1, i2, j1, j2, k1, k2, n1, n2, before )
337      !!----------------------------------------------------------------------
338      !!                 *** ROUTINE interptsn_sponge ***
339      !!----------------------------------------------------------------------
340      INTEGER                                     , INTENT(in   ) ::   i1, i2, j1, j2, k1, k2, n1, n2
341      REAL(wp), DIMENSION(i1:i2,j1:j2,k1:k2,n1:n2), INTENT(inout) ::   tabres
342      LOGICAL                                     , INTENT(in   ) ::   before
343      !
344      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
345      INTEGER  ::   iku, ikv
346      REAL(wp) :: ztsa, zabe1, zabe2, zbtr, zhtot
347      REAL(wp), DIMENSION(i1:i2,j1:j2,jpk) :: ztu, ztv
348      REAL(wp), DIMENSION(i1:i2,j1:j2,jpk,n1:n2) ::tsbdiff
349      ! vertical interpolation:
350      REAL(wp), DIMENSION(i1:i2,j1:j2,jpk,n1:n2) ::tabres_child
351      REAL(wp), DIMENSION(k1:k2,n1:n2-1) :: tabin
352      REAL(wp), DIMENSION(k1:k2) :: h_in
353      REAL(wp), DIMENSION(1:jpk) :: h_out
354      INTEGER :: N_in, N_out
355      !!----------------------------------------------------------------------
356      !
357      IF( before ) THEN
358         DO jn = 1, jpts
359            DO jk=k1,k2
360               DO jj=j1,j2
361                  DO ji=i1,i2
362                     tabres(ji,jj,jk,jn) = ts(ji,jj,jk,jn,Kbb_a)
363                  END DO
364               END DO
365            END DO
366         END DO
367
368# if defined key_vertical
369        ! Interpolate thicknesses
370        ! Warning: these are masked, hence extrapolated prior interpolation.
371        DO jk=k1,k2
372           DO jj=j1,j2
373              DO ji=i1,i2
374                  tabres(ji,jj,jk,jpts+1) = tmask(ji,jj,jk) * e3t(ji,jj,jk,Kbb_a)
375              END DO
376           END DO
377        END DO
378
379        ! Extrapolate thicknesses in partial bottom cells:
380        ! Set them to Agrif_SpecialValue (0.). Correct bottom thicknesses are retrieved later on
381        IF (ln_zps) THEN
382           DO jj=j1,j2
383              DO ji=i1,i2
384                  jk = mbkt(ji,jj)
385                  tabres(ji,jj,jk,jpts+1) = 0._wp
386              END DO
387           END DO           
388        END IF
389     
390        ! Save ssh at last level:
391        IF (.NOT.ln_linssh) THEN
392           tabres(i1:i2,j1:j2,k2,jpts+1) = ssh(i1:i2,j1:j2,Kbb_a)*tmask(i1:i2,j1:j2,1) 
393        ELSE
394           tabres(i1:i2,j1:j2,k2,jpts+1) = 0._wp
395        END IF     
396# endif
397
398      ELSE   
399         !
400# if defined key_vertical
401
402         IF (ln_linssh) tabres(i1:i2,j1:j2,k2,n2) = 0._wp
403
404         DO jj=j1,j2
405            DO ji=i1,i2
406               tabres_child(ji,jj,:,:) = 0._wp 
407               N_in = mbkt_parent(ji,jj)
408               zhtot = 0._wp
409               DO jk=1,N_in !k2 = jpk of parent grid
410                  IF (jk==N_in) THEN
411                     h_in(jk) = ht0_parent(ji,jj) + tabres(ji,jj,k2,n2) - zhtot
412                  ELSE
413                     h_in(jk) = tabres(ji,jj,jk,n2)
414                  ENDIF
415                  zhtot = zhtot + h_in(jk)
416                  tabin(jk,:) = tabres(ji,jj,jk,n1:n2-1)
417               END DO
418               N_out = 0
419               DO jk=1,jpk ! jpk of child grid
420                  IF (tmask(ji,jj,jk) == 0) EXIT
421                  N_out = N_out + 1
422                  h_out(jk) = e3t(ji,jj,jk,Kbb_a) !Child grid scale factors. Could multiply by e1e2t here instead of division above
423               END DO
424
425               ! Account for small differences in free-surface
426               IF ( sum(h_out(1:N_out)) > sum(h_in(1:N_in) )) THEN
427                  h_out(1) = h_out(1) - ( sum(h_out(1:N_out))-sum(h_in(1:N_in)) )
428               ELSE
429                  h_in(1)   = h_in(1)   - (sum(h_in(1:N_in))-sum(h_out(1:N_out)) )
430               ENDIF
431               IF (N_in*N_out > 0) THEN
432                  CALL reconstructandremap(tabin(1:N_in,1:jpts),h_in(1:N_in),tabres_child(ji,jj,1:N_out,1:jpts),h_out(1:N_out),N_in,N_out,jpts)
433               ENDIF
434            END DO
435         END DO
436# endif
437
438         DO jj=j1,j2
439            DO ji=i1,i2
440               DO jk=1,jpkm1
441# if defined key_vertical
442                  tsbdiff(ji,jj,jk,1:jpts) = (ts(ji,jj,jk,1:jpts,Kbb_a) - tabres_child(ji,jj,jk,1:jpts)) * tmask(ji,jj,jk)
443# else
444                  tsbdiff(ji,jj,jk,1:jpts) = (ts(ji,jj,jk,1:jpts,Kbb_a) - tabres(ji,jj,jk,1:jpts))*tmask(ji,jj,jk)
445# endif
446               END DO
447            END DO
448         END DO
449
450         DO jn = 1, jpts           
451            DO jk = 1, jpkm1
452               ztu(i1:i2,j1:j2,jk) = 0._wp
453               DO jj = j1,j2
454                  DO ji = i1,i2-1
455                     zabe1 = rn_sponge_tra * r1_Dt * fspu(ji,jj) * umask(ji,jj,jk) * e1e2u(ji,jj) * e3u(ji,jj,jk,Kmm_a)
456                     ztu(ji,jj,jk) = zabe1 * ( tsbdiff(ji+1,jj  ,jk,jn) - tsbdiff(ji,jj,jk,jn) ) 
457                  END DO
458               END DO
459               ztv(i1:i2,j1:j2,jk) = 0._wp
460               DO ji = i1,i2
461                  DO jj = j1,j2-1
462                     zabe2 = rn_sponge_tra * r1_Dt * fspv(ji,jj) * vmask(ji,jj,jk) * e1e2v(ji,jj) * e3v(ji,jj,jk,Kmm_a)
463                     ztv(ji,jj,jk) = zabe2 * ( tsbdiff(ji  ,jj+1,jk,jn) - tsbdiff(ji,jj,jk,jn) )
464                  END DO
465               END DO
466               !
467               IF( ln_zps ) THEN      ! set gradient at partial step level
468                  DO jj = j1,j2
469                     DO ji = i1,i2
470                        ! last level
471                        iku = mbku(ji,jj)
472                        ikv = mbkv(ji,jj)
473                        IF( iku == jk )   ztu(ji,jj,jk) = 0._wp
474                        IF( ikv == jk )   ztv(ji,jj,jk) = 0._wp
475                     END DO
476                  END DO
477               ENDIF
478            END DO
479            !
480            DO jk = 1, jpkm1
481               DO jj = j1+1,j2-1
482                  DO ji = i1+1,i2-1
483                     IF (.NOT. tabspongedone_tsn(ji,jj)) THEN
484                        zbtr = r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm_a)
485                        ! horizontal diffusive trends
486                        ztsa = zbtr * (  ztu(ji,jj,jk) - ztu(ji-1,jj,jk) + ztv(ji,jj,jk) - ztv(ji,jj-1,jk)  ) &
487                             &  - rn_trelax_tra * r1_Dt * fspt(ji,jj) * tsbdiff(ji,jj,jk,jn) 
488                        ! add it to the general tracer trends
489                        ts(ji,jj,jk,jn,Krhs_a) = ts(ji,jj,jk,jn,Krhs_a) + ztsa
490                     ENDIF
491                  END DO
492               END DO
493            END DO
494            !
495         END DO
496         !
497         tabspongedone_tsn(i1+1:i2-1,j1+1:j2-1) = .TRUE.
498         !
499      ENDIF
500      !
501   END SUBROUTINE interptsn_sponge
502
503   
504   SUBROUTINE interpun_sponge(tabres,i1,i2,j1,j2,k1,k2,m1,m2, before)
505      !!---------------------------------------------
506      !!   *** ROUTINE interpun_sponge ***
507      !!---------------------------------------------   
508      INTEGER, INTENT(in) :: i1,i2,j1,j2,k1,k2,m1,m2
509      REAL(wp), DIMENSION(i1:i2,j1:j2,k1:k2,m1:m2), INTENT(inout) :: tabres
510      LOGICAL, INTENT(in) :: before
511
512      INTEGER  :: ji,jj,jk,jmax
513      INTEGER  :: ind1
514      ! sponge parameters
515      REAL(wp) :: ze2u, ze1v, zua, zva, zbtr, zhtot
516      REAL(wp), DIMENSION(i1:i2,j1:j2,1:jpk) :: ubdiff
517      REAL(wp), DIMENSION(i1:i2,j1:j2,1:jpk) :: rotdiff, hdivdiff
518      ! vertical interpolation:
519      REAL(wp), DIMENSION(i1:i2,j1:j2,1:jpk) :: tabres_child
520      REAL(wp), DIMENSION(k1:k2) :: tabin, h_in
521      REAL(wp), DIMENSION(1:jpk) :: h_out
522      INTEGER ::N_in, N_out
523      !!---------------------------------------------   
524      !
525      IF( before ) THEN
526         DO jk=k1,k2
527            DO jj=j1,j2
528               DO ji=i1,i2
529                  tabres(ji,jj,jk,m1) = uu(ji,jj,jk,Kbb_a)
530# if defined key_vertical
531                  tabres(ji,jj,jk,m2) = e3u(ji,jj,jk,Kbb_a)*umask(ji,jj,jk)
532# endif
533               END DO
534            END DO
535         END DO
536
537# if defined key_vertical
538         ! Extrapolate thicknesses in partial bottom cells:
539         ! Set them to Agrif_SpecialValue (0.). Correct bottom thicknesses are retrieved later on
540         IF (ln_zps) THEN
541            DO jj=j1,j2
542               DO ji=i1,i2
543                  jk = mbku(ji,jj)
544                  tabres(ji,jj,jk,m2) = 0._wp
545               END DO
546            END DO           
547         END IF
548        ! Save ssh at last level:
549        tabres(i1:i2,j1:j2,k2,m2) = 0._wp
550        IF (.NOT.ln_linssh) THEN
551           ! This vertical sum below should be replaced by the sea-level at U-points (optimization):
552           DO jk=1,jpk
553              tabres(i1:i2,j1:j2,k2,m2) = tabres(i1:i2,j1:j2,k2,m2) + e3u(i1:i2,j1:j2,jk,Kbb_a) * umask(i1:i2,j1:j2,jk)
554           END DO
555           tabres(i1:i2,j1:j2,k2,m2) = tabres(i1:i2,j1:j2,k2,m2) - hu_0(i1:i2,j1:j2)
556        END IF 
557# endif
558
559      ELSE
560
561# if defined key_vertical
562         IF (ln_linssh) tabres(i1:i2,j1:j2,k2,m2) = 0._wp
563
564         DO jj=j1,j2
565            DO ji=i1,i2
566               tabres_child(ji,jj,:) = 0._wp
567               N_in = mbku_parent(ji,jj)
568               zhtot = 0._wp
569               DO jk=1,N_in
570                  IF (jk==N_in) THEN
571                     h_in(jk) = hu0_parent(ji,jj) + tabres(ji,jj,k2,m2) - zhtot
572                  ELSE
573                     h_in(jk) = tabres(ji,jj,jk,m2)
574                  ENDIF
575                  zhtot = zhtot + h_in(jk)
576                  tabin(jk) = tabres(ji,jj,jk,m1)
577               END DO
578               !         
579               N_out = 0
580               DO jk=1,jpk
581                  IF (umask(ji,jj,jk) == 0) EXIT
582                  N_out = N_out + 1
583                  h_out(N_out) = e3u(ji,jj,jk,Kbb_a)
584               END DO
585
586               ! Account for small differences in free-surface
587               IF ( sum(h_out(1:N_out)) > sum(h_in(1:N_in) )) THEN
588                  h_out(1) = h_out(1) - ( sum(h_out(1:N_out))-sum(h_in(1:N_in)) )
589               ELSE
590                  h_in(1)   = h_in(1)   - (sum(h_in(1:N_in))-sum(h_out(1:N_out)) )
591               ENDIF
592                 
593               IF (N_in * N_out > 0) THEN
594                  CALL reconstructandremap(tabin(1:N_in),h_in(1:N_in),tabres_child(ji,jj,1:N_out),h_out(1:N_out),N_in,N_out,1)
595               ENDIF
596            END DO
597         END DO
598
599         ubdiff(i1:i2,j1:j2,:) = (uu(i1:i2,j1:j2,:,Kbb_a) - tabres_child(i1:i2,j1:j2,:))*umask(i1:i2,j1:j2,:)
600#else
601         ubdiff(i1:i2,j1:j2,:) = (uu(i1:i2,j1:j2,:,Kbb_a) - tabres(i1:i2,j1:j2,:,1))*umask(i1:i2,j1:j2,:)
602#endif
603         !
604         DO jk = 1, jpkm1                                 ! Horizontal slab
605            !                                             ! ===============
606
607            !                                             ! --------
608            ! Horizontal divergence                       !   div
609            !                                             ! --------
610            DO jj = j1,j2
611               DO ji = i1+1,i2   ! vector opt.
612                  zbtr = rn_sponge_dyn * r1_Dt * fspt(ji,jj) / e3t(ji,jj,jk,Kbb_a)
613                  hdivdiff(ji,jj,jk) = (  e2u(ji  ,jj)*e3u(ji  ,jj,jk,Kbb_a) * ubdiff(ji  ,jj,jk) &
614                                     &   -e2u(ji-1,jj)*e3u(ji-1,jj,jk,Kbb_a) * ubdiff(ji-1,jj,jk) ) * zbtr
615               END DO
616            END DO
617
618            DO jj = j1,j2-1
619               DO ji = i1,i2   ! vector opt.
620                  zbtr = rn_sponge_dyn * r1_Dt * fspf(ji,jj) * e3f(ji,jj,jk) 
621                  rotdiff(ji,jj,jk) = ( -e1u(ji,jj+1) * ubdiff(ji,jj+1,jk)   &
622                                    &   +e1u(ji,jj  ) * ubdiff(ji,jj  ,jk) ) * fmask(ji,jj,jk) * zbtr 
623               END DO
624            END DO
625         END DO
626         !
627         DO jj = j1+1, j2-1
628            DO ji = i1+1, i2-1   ! vector opt.
629
630               IF (.NOT. tabspongedone_u(ji,jj)) THEN
631                  DO jk = 1, jpkm1                                 ! Horizontal slab
632                     ze2u = rotdiff (ji,jj,jk)
633                     ze1v = hdivdiff(ji,jj,jk)
634                     ! horizontal diffusive trends
635                     zua = - ( ze2u - rotdiff (ji,jj-1,jk) ) / ( e2u(ji,jj) * e3u(ji,jj,jk,Kmm_a) )   &
636                         & + ( hdivdiff(ji+1,jj,jk) - ze1v ) * r1_e1u(ji,jj) & 
637                         & - rn_trelax_dyn * r1_Dt * fspu(ji,jj) * ubdiff(ji,jj,jk)
638
639                     ! add it to the general momentum trends
640                     uu(ji,jj,jk,Krhs_a) = uu(ji,jj,jk,Krhs_a) + zua                                 
641                  END DO
642               ENDIF
643
644            END DO
645         END DO
646
647         tabspongedone_u(i1+1:i2-1,j1+1:j2-1) = .TRUE.
648
649         jmax = j2-1
650         ind1 = jpjglo - ( nn_hls + nbghostcells + 2 )   ! North
651         DO jj = mj0(ind1), mj1(ind1)                 
652            jmax = MIN(jmax,jj)
653         END DO
654
655         DO jj = j1+1, jmax
656            DO ji = i1+1, i2   ! vector opt.
657
658               IF (.NOT. tabspongedone_v(ji,jj)) THEN
659                  DO jk = 1, jpkm1                                 ! Horizontal slab
660                     ze2u = rotdiff (ji,jj,jk)
661                     ze1v = hdivdiff(ji,jj,jk)
662
663                     ! horizontal diffusive trends
664                     zva = + ( ze2u - rotdiff (ji-1,jj,jk) ) / ( e1v(ji,jj) * e3v(ji,jj,jk,Kmm_a) )   &
665                           + ( hdivdiff(ji,jj+1,jk) - ze1v ) * r1_e2v(ji,jj)
666
667                     ! add it to the general momentum trends
668                     vv(ji,jj,jk,Krhs_a) = vv(ji,jj,jk,Krhs_a) + zva
669                  END DO
670               ENDIF
671               !
672            END DO
673         END DO
674         !
675         tabspongedone_v(i1+1:i2,j1+1:jmax) = .TRUE.
676         !
677      ENDIF
678      !
679   END SUBROUTINE interpun_sponge
680
681   
682   SUBROUTINE interpvn_sponge(tabres,i1,i2,j1,j2,k1,k2,m1,m2, before)
683      !!---------------------------------------------
684      !!   *** ROUTINE interpvn_sponge ***
685      !!---------------------------------------------
686      INTEGER, INTENT(in) :: i1,i2,j1,j2,k1,k2,m1,m2
687      REAL(wp), DIMENSION(i1:i2,j1:j2,k1:k2,m1:m2), INTENT(inout) :: tabres
688      LOGICAL, INTENT(in) :: before
689      !
690      INTEGER  ::   ji, jj, jk, imax
691      INTEGER  :: ind1
692      REAL(wp) ::   ze2u, ze1v, zua, zva, zbtr, zhtot
693      REAL(wp), DIMENSION(i1:i2,j1:j2,1:jpk) :: vbdiff
694      REAL(wp), DIMENSION(i1:i2,j1:j2,1:jpk) :: rotdiff, hdivdiff
695      ! vertical interpolation:
696      REAL(wp), DIMENSION(i1:i2,j1:j2,1:jpk) :: tabres_child
697      REAL(wp), DIMENSION(k1:k2) :: tabin, h_in
698      REAL(wp), DIMENSION(1:jpk) :: h_out
699      INTEGER :: N_in, N_out
700      !!---------------------------------------------
701     
702      IF( before ) THEN
703         DO jk=k1,k2
704            DO jj=j1,j2
705               DO ji=i1,i2
706                  tabres(ji,jj,jk,m1) = vv(ji,jj,jk,Kbb_a)
707# if defined key_vertical
708                  tabres(ji,jj,jk,m2) = vmask(ji,jj,jk) * e3v(ji,jj,jk,Kbb_a)
709# endif
710               END DO
711            END DO
712         END DO
713
714# if defined key_vertical
715         ! Extrapolate thicknesses in partial bottom cells:
716         ! Set them to Agrif_SpecialValue (0.). Correct bottom thicknesses are retrieved later on
717         IF (ln_zps) THEN
718            DO jj=j1,j2
719               DO ji=i1,i2
720                  jk = mbkv(ji,jj)
721                  tabres(ji,jj,jk,m2) = 0._wp
722               END DO
723            END DO           
724         END IF
725        ! Save ssh at last level:
726        tabres(i1:i2,j1:j2,k2,m2) = 0._wp
727        IF (.NOT.ln_linssh) THEN
728           ! This vertical sum below should be replaced by the sea-level at V-points (optimization):
729           DO jk=1,jpk
730              tabres(i1:i2,j1:j2,k2,m2) = tabres(i1:i2,j1:j2,k2,m2) + e3v(i1:i2,j1:j2,jk,Kbb_a) * vmask(i1:i2,j1:j2,jk)
731           END DO
732           tabres(i1:i2,j1:j2,k2,m2) = tabres(i1:i2,j1:j2,k2,m2) - hv_0(i1:i2,j1:j2)
733        END IF 
734# endif
735
736      ELSE
737
738# if defined key_vertical
739         IF (ln_linssh) tabres(i1:i2,j1:j2,k2,m2) = 0._wp
740         DO jj=j1,j2
741            DO ji=i1,i2
742               tabres_child(ji,jj,:) = 0._wp
743               N_in = mbkv_parent(ji,jj)
744               zhtot = 0._wp
745               DO jk=1,N_in
746                  IF (jk==N_in) THEN
747                     h_in(jk) = hv0_parent(ji,jj) + tabres(ji,jj,k2,m2) - zhtot
748                  ELSE
749                     h_in(jk) = tabres(ji,jj,jk,m2)
750                  ENDIF
751                  zhtot = zhtot + h_in(jk)
752                  tabin(jk) = tabres(ji,jj,jk,m1)
753               END DO
754               !         
755               N_out = 0
756               DO jk=1,jpk
757                  IF (vmask(ji,jj,jk) == 0) EXIT
758                  N_out = N_out + 1
759                  h_out(N_out) = e3v(ji,jj,jk,Kbb_a)
760               END DO
761
762               ! Account for small differences in free-surface
763               IF ( sum(h_out(1:N_out)) > sum(h_in(1:N_in) )) THEN
764                  h_out(1) = h_out(1) - ( sum(h_out(1:N_out))-sum(h_in(1:N_in)) )
765               ELSE
766                  h_in(1)   = h_in(1) - (  sum(h_in(1:N_in))-sum(h_out(1:N_out)) )
767               ENDIF
768         
769               IF (N_in * N_out > 0) THEN
770                  CALL reconstructandremap(tabin(1:N_in),h_in(1:N_in),tabres_child(ji,jj,1:N_out),h_out(1:N_out),N_in,N_out,1)
771               ENDIF
772            END DO
773         END DO
774
775         vbdiff(i1:i2,j1:j2,:) = (vv(i1:i2,j1:j2,:,Kbb_a) - tabres_child(i1:i2,j1:j2,:))*vmask(i1:i2,j1:j2,:) 
776# else
777         vbdiff(i1:i2,j1:j2,:) = (vv(i1:i2,j1:j2,:,Kbb_a) - tabres(i1:i2,j1:j2,:,1))*vmask(i1:i2,j1:j2,:)
778# endif
779         !
780         DO jk = 1, jpkm1                                 ! Horizontal slab
781            !                                             ! ===============
782
783            !                                             ! --------
784            ! Horizontal divergence                       !   div
785            !                                             ! --------
786            DO jj = j1+1,j2
787               DO ji = i1,i2   ! vector opt.
788                  zbtr = rn_sponge_dyn * r1_Dt * fspt(ji,jj) / e3t(ji,jj,jk,Kbb_a)
789                  hdivdiff(ji,jj,jk) = ( e1v(ji,jj  ) * e3v(ji,jj  ,jk,Kbb_a) * vbdiff(ji,jj  ,jk)  &
790                                     &  -e1v(ji,jj-1) * e3v(ji,jj-1,jk,Kbb_a) * vbdiff(ji,jj-1,jk)  ) * zbtr
791               END DO
792            END DO
793            DO jj = j1,j2
794               DO ji = i1,i2-1   ! vector opt.
795                  zbtr = rn_sponge_dyn * r1_Dt * fspf(ji,jj) * e3f(ji,jj,jk) 
796                  rotdiff(ji,jj,jk) = ( e2v(ji+1,jj) * vbdiff(ji+1,jj,jk) & 
797                                    &  -e2v(ji  ,jj) * vbdiff(ji  ,jj,jk)  ) * fmask(ji,jj,jk) * zbtr
798               END DO
799            END DO
800         END DO
801
802         !                                                ! ===============
803         !                                               
804
805         imax = i2 - 1
806         ind1 = jpiglo - ( nn_hls + nbghostcells + 2 )   ! East
807         DO ji = mi0(ind1), mi1(ind1)               
808            imax = MIN(imax,ji)
809         END DO
810         
811         DO jj = j1+1, j2
812            DO ji = i1+1, imax   ! vector opt.
813               IF( .NOT. tabspongedone_u(ji,jj) ) THEN
814                  DO jk = 1, jpkm1
815                     uu(ji,jj,jk,Krhs_a) = uu(ji,jj,jk,Krhs_a)                                                     &
816                        & - ( rotdiff (ji  ,jj,jk) - rotdiff (ji,jj-1,jk)) / ( e2u(ji,jj) * e3u(ji,jj,jk,Kmm_a) )  &
817                        & + ( hdivdiff(ji+1,jj,jk) - hdivdiff(ji,jj  ,jk)) * r1_e1u(ji,jj)
818                  END DO
819               ENDIF
820            END DO
821         END DO
822         !
823         tabspongedone_u(i1+1:imax,j1+1:j2) = .TRUE.
824         !
825         DO jj = j1+1, j2-1
826            DO ji = i1+1, i2-1   ! vector opt.
827               IF( .NOT. tabspongedone_v(ji,jj) ) THEN
828                  DO jk = 1, jpkm1
829                     vv(ji,jj,jk,Krhs_a) = vv(ji,jj,jk,Krhs_a)                                                        &
830                        &  + ( rotdiff (ji,jj  ,jk) - rotdiff (ji-1,jj,jk) ) / ( e1v(ji,jj) * e3v(ji,jj,jk,Kmm_a) )   &
831                        &  + ( hdivdiff(ji,jj+1,jk) - hdivdiff(ji  ,jj,jk) ) * r1_e2v(ji,jj)                          &
832                        &  - rn_trelax_dyn * r1_Dt * fspv(ji,jj) * vbdiff(ji,jj,jk)
833                  END DO
834               ENDIF
835            END DO
836         END DO
837         tabspongedone_v(i1+1:i2-1,j1+1:j2-1) = .TRUE.
838      ENDIF
839      !
840   END SUBROUTINE interpvn_sponge
841
842#else
843   !!----------------------------------------------------------------------
844   !!   Empty module                                          no AGRIF zoom
845   !!----------------------------------------------------------------------
846CONTAINS
847   SUBROUTINE agrif_oce_sponge_empty
848      WRITE(*,*)  'agrif_oce_sponge : You should not have seen this print! error?'
849   END SUBROUTINE agrif_oce_sponge_empty
850#endif
851
852   !!======================================================================
853END MODULE agrif_oce_sponge
Note: See TracBrowser for help on using the repository browser.