New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
domhgr.F90 in NEMO/branches/2019/dev_r11351_fldread_with_XIOS/src/OCE/DOM – NEMO

source: NEMO/branches/2019/dev_r11351_fldread_with_XIOS/src/OCE/DOM/domhgr.F90 @ 13463

Last change on this file since 13463 was 13463, checked in by andmirek, 4 years ago

Ticket #2195:update to trunk 13461

  • Property svn:keywords set to Id
File size: 13.3 KB
Line 
1MODULE domhgr
2   !!==============================================================================
3   !!                       ***  MODULE domhgr   ***
4   !! Ocean initialization : domain initialization
5   !!==============================================================================
6   !! History :  OPA  ! 1988-03  (G. Madec) Original code
7   !!            7.0  ! 1996-01  (G. Madec)  terrain following coordinates
8   !!            8.0  ! 1997-02  (G. Madec)  print mesh informations
9   !!            8.1  ! 1999-11  (M. Imbard) NetCDF format with IO-IPSL
10   !!            8.2  ! 2000-08  (D. Ludicone) Reduced section at Bab el Mandeb
11   !!             -   ! 2001-09  (M. Levy)  eel config: grid in km, beta-plane
12   !!  NEMO      1.0  ! 2002-08  (G. Madec)  F90: Free form and module, namelist
13   !!             -   ! 2004-01  (A.M. Treguier, J.M. Molines) Case 4 (Mercator mesh)
14   !!                            use of parameters in par_CONFIG-Rxx.h90, not in namelist
15   !!             -   ! 2004-05  (A. Koch-Larrouy) Add Gyre configuration
16   !!            3.7  ! 2015-09  (G. Madec, S. Flavoni) add cell surface and their inverse
17   !!                                       add optional read of e1e2u & e1e2v
18   !!             -   ! 2016-04  (S. Flavoni, G. Madec) new configuration interface: read or usrdef.F90
19   !!----------------------------------------------------------------------
20
21   !!----------------------------------------------------------------------
22   !!   dom_hgr       : initialize the horizontal mesh
23   !!   hgr_read      : read horizontal information in the domain configuration file
24   !!----------------------------------------------------------------------
25   USE dom_oce        ! ocean space and time domain
26   USE par_oce        ! ocean space and time domain
27   USE phycst         ! physical constants
28   USE usrdef_hgr     ! User defined routine
29   !
30   USE in_out_manager ! I/O manager
31   USE iom            ! I/O library
32   USE lib_mpp        ! MPP library
33   USE lbclnk         ! lateal boundary condition / mpp exchanges
34   USE timing         ! Timing
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   dom_hgr   ! called by domain.F90
40
41   !!----------------------------------------------------------------------
42   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
43   !! $Id$
44   !! Software governed by the CeCILL license (see ./LICENSE)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   SUBROUTINE dom_hgr
49      !!----------------------------------------------------------------------
50      !!                  ***  ROUTINE dom_hgr  ***
51      !!
52      !! ** Purpose :   Read or compute the geographical position (in degrees) 
53      !!      of the model grid-points, the horizontal scale factors (in meters),
54      !!      the associated horizontal metrics, and the Coriolis factor (in s-1).
55      !!
56      !! ** Method  :   Controlled by ln_read_cfg logical
57      !!              =T : all needed arrays are read in mesh_mask.nc file
58      !!              =F : user-defined configuration, all needed arrays
59      !!                   are computed in usr-def_hgr subroutine
60      !!
61      !!                If Coriolis factor is neither read nor computed (iff=0)
62      !!              it is computed from gphit assuming that the mesh is
63      !!              defined on the sphere :
64      !!                   ff = 2.*omega*sin(gphif)      (in s-1)
65      !!   
66      !!                If u- & v-surfaces are neither read nor computed (ie1e2u_v=0)
67      !!              (i.e. no use of reduced scale factors in some straits)
68      !!              they are computed from e1u, e2u, e1v and e2v as:
69      !!                   e1e2u = e1u*e2u   and   e1e2v = e1v*e2v 
70      !!   
71      !! ** Action  : - define longitude & latitude of t-, u-, v- and f-points (in degrees)
72      !!              - define Coriolis parameter at f-point                   (in 1/s)
73      !!              - define i- & j-scale factors at t-, u-, v- and f-points (in meters)
74      !!              - define associated horizontal metrics at t-, u-, v- and f-points
75      !!                (inverse of scale factors 1/e1 & 1/e2, surface e1*e2, ratios e1/e2 & e2/e1)
76      !!----------------------------------------------------------------------
77      INTEGER ::   ji, jj     ! dummy loop indices
78      INTEGER ::   ie1e2u_v   ! flag for u- & v-surfaces
79      INTEGER ::   iff        ! flag for Coriolis parameter
80      !!----------------------------------------------------------------------
81      !
82      IF( ln_timing )   CALL timing_start('dom_hgr')
83      !
84      IF(lwp) THEN
85         WRITE(numout,*)
86         WRITE(numout,*) 'dom_hgr : define the horizontal mesh from ithe following par_oce parameters '
87         WRITE(numout,*) '~~~~~~~   '
88         WRITE(numout,*) '   namcfg : read (=T) or user defined (=F) configuration    ln_read_cfg  = ', ln_read_cfg
89      ENDIF
90      !
91      IF( ln_read_cfg ) THEN        !==  read in mesh_mask.nc file  ==!
92         !
93         IF(lwp) WRITE(numout,*)
94         IF(lwp) WRITE(numout,*) '   ==>>>   read horizontal mesh in ', TRIM( cn_domcfg ), ' file'
95         !
96         CALL hgr_read   ( glamt , glamu , glamv , glamf ,   &    ! geographic position (required)
97            &              gphit , gphiu , gphiv , gphif ,   &    !     -        -
98            &              iff   , ff_f  , ff_t  ,           &    ! Coriolis parameter (if not on the sphere)
99            &              e1t   , e1u   , e1v   , e1f   ,   &    ! scale factors (required)
100            &              e2t   , e2u   , e2v   , e2f   ,   &    !    -     -        -
101            &              ie1e2u_v      , e1e2u , e1e2v     )    ! u- & v-surfaces (if gridsize reduction in some straits)
102         !
103      ELSE                          !==  User defined configuration  ==!
104         IF(lwp) WRITE(numout,*)
105         IF(lwp) WRITE(numout,*) '          User defined horizontal mesh (usr_def_hgr)'
106         !
107         CALL usr_def_hgr( glamt , glamu , glamv , glamf ,   &    ! geographic position (required)
108            &              gphit , gphiu , gphiv , gphif ,   &    !
109            &              iff   , ff_f  , ff_t  ,           &    ! Coriolis parameter  (if domain not on the sphere)
110            &              e1t   , e1u   , e1v   , e1f   ,   &    ! scale factors       (required)
111            &              e2t   , e2u   , e2v   , e2f   ,   &    !
112            &              ie1e2u_v      , e1e2u , e1e2v     )    ! u- & v-surfaces (if gridsize reduction is used in strait(s))
113         !
114      ENDIF
115      !                             !==  Coriolis parameter  ==!   (if necessary)
116      !
117      IF( iff == 0 ) THEN                 ! Coriolis parameter has not been defined
118         IF(lwp) WRITE(numout,*) '          Coriolis parameter calculated on the sphere from gphif & gphit'
119         ff_f(:,:) = 2. * omega * SIN( rad * gphif(:,:) )     ! compute it on the sphere at f-point
120         ff_t(:,:) = 2. * omega * SIN( rad * gphit(:,:) )     !    -        -       -    at t-point
121      ELSE
122         IF( ln_read_cfg ) THEN
123            IF(lwp) WRITE(numout,*) '          Coriolis parameter have been read in ', TRIM( cn_domcfg ), ' file'
124         ELSE
125            IF(lwp) WRITE(numout,*) '          Coriolis parameter have been set in usr_def_hgr routine'
126         ENDIF
127      ENDIF
128      !
129      !                             !==  associated horizontal metrics  ==!
130      !
131      r1_e1t(:,:) = 1._wp / e1t(:,:)   ;   r1_e2t (:,:) = 1._wp / e2t(:,:)
132      r1_e1u(:,:) = 1._wp / e1u(:,:)   ;   r1_e2u (:,:) = 1._wp / e2u(:,:)
133      r1_e1v(:,:) = 1._wp / e1v(:,:)   ;   r1_e2v (:,:) = 1._wp / e2v(:,:)
134      r1_e1f(:,:) = 1._wp / e1f(:,:)   ;   r1_e2f (:,:) = 1._wp / e2f(:,:)
135      !
136      e1e2t (:,:) = e1t(:,:) * e2t(:,:)   ;   r1_e1e2t(:,:) = 1._wp / e1e2t(:,:)
137      e1e2f (:,:) = e1f(:,:) * e2f(:,:)   ;   r1_e1e2f(:,:) = 1._wp / e1e2f(:,:)
138      IF( ie1e2u_v == 0 ) THEN               ! u- & v-surfaces have not been defined
139         IF(lwp) WRITE(numout,*) '          u- & v-surfaces calculated as e1 e2 product'
140         e1e2u (:,:) = e1u(:,:) * e2u(:,:)         ! compute them
141         e1e2v (:,:) = e1v(:,:) * e2v(:,:) 
142      ELSE
143         IF(lwp) WRITE(numout,*) '          u- & v-surfaces have been read in "mesh_mask" file:'
144         IF(lwp) WRITE(numout,*) '                     grid size reduction in strait(s) is used'
145      ENDIF
146      r1_e1e2u(:,:) = 1._wp / e1e2u(:,:)     ! compute their invert in any cases
147      r1_e1e2v(:,:) = 1._wp / e1e2v(:,:)
148      !   
149      e2_e1u(:,:) = e2u(:,:) / e1u(:,:)
150      e1_e2v(:,:) = e1v(:,:) / e2v(:,:)
151      !
152      IF( ln_timing )   CALL timing_stop('dom_hgr')
153      !
154   END SUBROUTINE dom_hgr
155
156
157   SUBROUTINE hgr_read( plamt , plamu , plamv  , plamf  ,   &    ! gridpoints position (required)
158      &                 pphit , pphiu , pphiv  , pphif  ,   &     
159      &                 kff   , pff_f , pff_t  ,            &    ! Coriolis parameter  (if not on the sphere)
160      &                 pe1t  , pe1u  , pe1v   , pe1f   ,   &    ! scale factors       (required)
161      &                 pe2t  , pe2u  , pe2v   , pe2f   ,   &
162      &                 ke1e2u_v      , pe1e2u , pe1e2v     )    ! u- & v-surfaces (if gridsize reduction in some straits)
163      !!---------------------------------------------------------------------
164      !!              ***  ROUTINE hgr_read  ***
165      !!
166      !! ** Purpose :   Read a mesh_mask file in NetCDF format using IOM
167      !!
168      !!----------------------------------------------------------------------
169      REAL(wp), DIMENSION(:,:), INTENT(out) ::   plamt, plamu, plamv, plamf   ! longitude outputs
170      REAL(wp), DIMENSION(:,:), INTENT(out) ::   pphit, pphiu, pphiv, pphif   ! latitude outputs
171      INTEGER                 , INTENT(out) ::   kff                          ! =1 Coriolis parameter read here, =0 otherwise
172      REAL(wp), DIMENSION(:,:), INTENT(out) ::   pff_f, pff_t                 ! Coriolis factor at f-point (if found in file)
173      REAL(wp), DIMENSION(:,:), INTENT(out) ::   pe1t, pe1u, pe1v, pe1f       ! i-scale factors
174      REAL(wp), DIMENSION(:,:), INTENT(out) ::   pe2t, pe2u, pe2v, pe2f       ! j-scale factors
175      INTEGER                 , INTENT(out) ::   ke1e2u_v                     ! =1 u- & v-surfaces read here, =0 otherwise
176      REAL(wp), DIMENSION(:,:), INTENT(out) ::   pe1e2u, pe1e2v              ! u- & v-surfaces (if found in file)
177      !
178      INTEGER  ::   inum                  ! logical unit
179      !!----------------------------------------------------------------------
180      !
181      IF(lwp) THEN
182         WRITE(numout,*)
183         WRITE(numout,*) '   hgr_read : read the horizontal coordinates in mesh_mask'
184         WRITE(numout,*) '   ~~~~~~~~      jpiglo = ', jpiglo, ' jpjglo = ', jpjglo, ' jpk = ', jpk
185      ENDIF
186      !
187      CALL iom_open( cn_domcfg, inum )
188      !
189      CALL iom_get( inum, jpdom_global, 'glamt', plamt, cd_type = 'T', psgn = 1._wp )
190      CALL iom_get( inum, jpdom_global, 'glamu', plamu, cd_type = 'U', psgn = 1._wp )
191      CALL iom_get( inum, jpdom_global, 'glamv', plamv, cd_type = 'V', psgn = 1._wp )
192      CALL iom_get( inum, jpdom_global, 'glamf', plamf, cd_type = 'F', psgn = 1._wp )
193      !
194      CALL iom_get( inum, jpdom_global, 'gphit', pphit, cd_type = 'T', psgn = 1._wp )
195      CALL iom_get( inum, jpdom_global, 'gphiu', pphiu, cd_type = 'U', psgn = 1._wp )
196      CALL iom_get( inum, jpdom_global, 'gphiv', pphiv, cd_type = 'V', psgn = 1._wp )
197      CALL iom_get( inum, jpdom_global, 'gphif', pphif, cd_type = 'F', psgn = 1._wp )
198      !
199      CALL iom_get( inum, jpdom_global, 'e1t'  , pe1t , cd_type = 'T', psgn = 1._wp, kfill = jpfillcopy )
200      CALL iom_get( inum, jpdom_global, 'e1u'  , pe1u , cd_type = 'U', psgn = 1._wp, kfill = jpfillcopy )
201      CALL iom_get( inum, jpdom_global, 'e1v'  , pe1v , cd_type = 'V', psgn = 1._wp, kfill = jpfillcopy )
202      CALL iom_get( inum, jpdom_global, 'e1f'  , pe1f , cd_type = 'F', psgn = 1._wp, kfill = jpfillcopy )
203      !
204      CALL iom_get( inum, jpdom_global, 'e2t'  , pe2t , cd_type = 'T', psgn = 1._wp, kfill = jpfillcopy )
205      CALL iom_get( inum, jpdom_global, 'e2u'  , pe2u , cd_type = 'U', psgn = 1._wp, kfill = jpfillcopy )
206      CALL iom_get( inum, jpdom_global, 'e2v'  , pe2v , cd_type = 'V', psgn = 1._wp, kfill = jpfillcopy )
207      CALL iom_get( inum, jpdom_global, 'e2f'  , pe2f , cd_type = 'F', psgn = 1._wp, kfill = jpfillcopy )
208      !
209      IF(  iom_varid( inum, 'ff_f', ldstop = .FALSE. ) > 0  .AND.  &
210         & iom_varid( inum, 'ff_t', ldstop = .FALSE. ) > 0    ) THEN
211         IF(lwp) WRITE(numout,*) '           Coriolis factor at f- and t-points read in ', TRIM( cn_domcfg ), ' file'
212         CALL iom_get( inum, jpdom_global, 'ff_f', pff_f, cd_type = 'F', psgn = 1._wp )
213         CALL iom_get( inum, jpdom_global, 'ff_t', pff_t, cd_type = 'T', psgn = 1._wp )
214         kff = 1
215      ELSE
216         kff = 0
217      ENDIF
218      !
219      IF( iom_varid( inum, 'e1e2u', ldstop = .FALSE. ) > 0 ) THEN
220         IF(lwp) WRITE(numout,*) '           e1e2u & e1e2v read in ', TRIM( cn_domcfg ), ' file'
221         CALL iom_get( inum, jpdom_global, 'e1e2u', pe1e2u, cd_type = 'U', psgn = 1._wp, kfill = jpfillcopy )
222         CALL iom_get( inum, jpdom_global, 'e1e2v', pe1e2v, cd_type = 'V', psgn = 1._wp, kfill = jpfillcopy )
223         ke1e2u_v = 1
224      ELSE
225         ke1e2u_v = 0
226      ENDIF
227      !
228      CALL iom_close( inum )
229      !
230   END SUBROUTINE hgr_read
231   
232   !!======================================================================
233END MODULE domhgr
Note: See TracBrowser for help on using the repository browser.