New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcrnf.F90 in NEMO/branches/2019/dev_r11351_fldread_with_XIOS/src/OCE/SBC – NEMO

source: NEMO/branches/2019/dev_r11351_fldread_with_XIOS/src/OCE/SBC/sbcrnf.F90 @ 13463

Last change on this file since 13463 was 13463, checked in by andmirek, 4 years ago

Ticket #2195:update to trunk 13461
  • Property svn:keywords set to Id
File size: 30.2 KB
Line 
1MODULE sbcrnf
2   !!======================================================================
3   !!                       ***  MODULE  sbcrnf  ***
4   !! Ocean forcing:  river runoff
5   !!=====================================================================
6   !! History :  OPA  ! 2000-11  (R. Hordoir, E. Durand)  NetCDF FORMAT
7   !!   NEMO     1.0  ! 2002-09  (G. Madec)  F90: Free form and module
8   !!            3.0  ! 2006-07  (G. Madec)  Surface module
9   !!            3.2  ! 2009-04  (B. Lemaire)  Introduce iom_put
10   !!            3.3  ! 2010-10  (R. Furner, G. Madec) runoff distributed over ocean levels
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   sbc_rnf       : monthly runoffs read in a NetCDF file
15   !!   sbc_rnf_init  : runoffs initialisation
16   !!   rnf_mouth     : set river mouth mask
17   !!----------------------------------------------------------------------
18   USE dom_oce        ! ocean space and time domain
19   USE phycst         ! physical constants
20   USE sbc_oce        ! surface boundary condition variables
21   USE eosbn2         ! Equation Of State
22   USE closea, ONLY: l_clo_rnf, clo_rnf ! closed seas
23   !
24   USE in_out_manager ! I/O manager
25   USE fldread        ! read input field at current time step
26   USE iom            ! I/O module
27   USE lib_mpp        ! MPP library
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   sbc_rnf       ! called in sbcmod module
33   PUBLIC   sbc_rnf_div   ! called in divhor module
34   PUBLIC   sbc_rnf_alloc ! called in sbcmod module
35   PUBLIC   sbc_rnf_init  ! called in sbcmod module
36   
37   !                                                !!* namsbc_rnf namelist *
38   CHARACTER(len=100)         ::   cn_dir            !: Root directory for location of rnf files
39   LOGICAL           , PUBLIC ::   ln_rnf_depth      !: depth       river runoffs attribute specified in a file
40   LOGICAL                    ::      ln_rnf_depth_ini  !: depth       river runoffs  computed at the initialisation
41   REAL(wp)                   ::      rn_rnf_max        !: maximum value of the runoff climatologie (ln_rnf_depth_ini =T)
42   REAL(wp)                   ::      rn_dep_max        !: depth over which runoffs is spread       (ln_rnf_depth_ini =T)
43   INTEGER                    ::      nn_rnf_depth_file !: create (=1) a runoff depth file or not (=0)
44   LOGICAL                    ::   ln_rnf_icb        !: iceberg flux is specified in a file
45   LOGICAL                    ::   ln_rnf_tem        !: temperature river runoffs attribute specified in a file
46   LOGICAL           , PUBLIC ::   ln_rnf_sal        !: salinity    river runoffs attribute specified in a file
47   TYPE(FLD_N)       , PUBLIC ::   sn_rnf            !: information about the runoff file to be read
48   TYPE(FLD_N)                ::   sn_cnf            !: information about the runoff mouth file to be read
49   TYPE(FLD_N)                ::   sn_i_rnf        !: information about the iceberg flux file to be read
50   TYPE(FLD_N)                ::   sn_s_rnf          !: information about the salinities of runoff file to be read
51   TYPE(FLD_N)                ::   sn_t_rnf          !: information about the temperatures of runoff file to be read
52   TYPE(FLD_N)                ::   sn_dep_rnf        !: information about the depth which river inflow affects
53   LOGICAL           , PUBLIC ::   ln_rnf_mouth      !: specific treatment in mouths vicinity
54   REAL(wp)                   ::   rn_hrnf           !: runoffs, depth over which enhanced vertical mixing is used
55   REAL(wp)          , PUBLIC ::   rn_avt_rnf        !: runoffs, value of the additional vertical mixing coef. [m2/s]
56   REAL(wp)          , PUBLIC ::   rn_rfact          !: multiplicative factor for runoff
57
58   LOGICAL , PUBLIC ::   l_rnfcpl = .false.   !: runoffs recieved from oasis
59   INTEGER , PUBLIC ::   nkrnf = 0            !: nb of levels over which Kz is increased at river mouths
60   
61   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   rnfmsk              !: river mouth mask (hori.)
62   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:)     ::   rnfmsk_z            !: river mouth mask (vert.)
63   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   h_rnf               !: depth of runoff in m
64   INTEGER,  PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   nk_rnf              !: depth of runoff in model levels
65   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   rnf_tsc_b, rnf_tsc  !: before and now T & S runoff contents   [K.m/s & PSU.m/s]   
66
67   TYPE(FLD),        ALLOCATABLE, DIMENSION(:) ::   sf_rnf       ! structure: river runoff (file information, fields read)
68   TYPE(FLD),        ALLOCATABLE, DIMENSION(:) ::   sf_i_rnf     ! structure: iceberg flux (file information, fields read)
69   TYPE(FLD),        ALLOCATABLE, DIMENSION(:) ::   sf_s_rnf     ! structure: river runoff salinity (file information, fields read) 
70   TYPE(FLD),        ALLOCATABLE, DIMENSION(:) ::   sf_t_rnf     ! structure: river runoff temperature (file information, fields read) 
71 
72   !! * Substitutions
73#  include "do_loop_substitute.h90"
74#  include "domzgr_substitute.h90"
75   !!----------------------------------------------------------------------
76   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
77   !! $Id$
78   !! Software governed by the CeCILL license (see ./LICENSE)
79   !!----------------------------------------------------------------------
80CONTAINS
81
82   INTEGER FUNCTION sbc_rnf_alloc()
83      !!----------------------------------------------------------------------
84      !!                ***  ROUTINE sbc_rnf_alloc  ***
85      !!----------------------------------------------------------------------
86      ALLOCATE( rnfmsk(jpi,jpj)         , rnfmsk_z(jpk)          ,     &
87         &      h_rnf (jpi,jpj)         , nk_rnf  (jpi,jpj)      ,     &
88         &      rnf_tsc_b(jpi,jpj,jpts) , rnf_tsc (jpi,jpj,jpts) , STAT=sbc_rnf_alloc )
89         !
90      CALL mpp_sum ( 'sbcrnf', sbc_rnf_alloc )
91      IF( sbc_rnf_alloc > 0 )   CALL ctl_warn('sbc_rnf_alloc: allocation of arrays failed')
92   END FUNCTION sbc_rnf_alloc
93
94
95   SUBROUTINE sbc_rnf( kt )
96      !!----------------------------------------------------------------------
97      !!                  ***  ROUTINE sbc_rnf  ***
98      !!
99      !! ** Purpose :   Introduce a climatological run off forcing
100      !!
101      !! ** Method  :   Set each river mouth with a monthly climatology
102      !!                provided from different data.
103      !!                CAUTION : upward water flux, runoff forced to be < 0
104      !!
105      !! ** Action  :   runoff updated runoff field at time-step kt
106      !!----------------------------------------------------------------------
107      INTEGER, INTENT(in) ::   kt          ! ocean time step
108      !
109      INTEGER  ::   ji, jj    ! dummy loop indices
110      INTEGER  ::   z_err = 0 ! dummy integer for error handling
111      !!----------------------------------------------------------------------
112      REAL(wp), DIMENSION(jpi,jpj) ::   ztfrz   ! freezing point used for temperature correction
113      !
114      !
115      !                                            !-------------------!
116      !                                            !   Update runoff   !
117      !                                            !-------------------!
118      !
119      !
120      IF( .NOT. l_rnfcpl )  THEN
121                            CALL fld_read ( kt, nn_fsbc, sf_rnf   )    ! Read Runoffs data and provide it at kt ( runoffs + iceberg )
122         IF( ln_rnf_icb )   CALL fld_read ( kt, nn_fsbc, sf_i_rnf )    ! idem for iceberg flux if required
123      ENDIF
124      IF(   ln_rnf_tem   )   CALL fld_read ( kt, nn_fsbc, sf_t_rnf )    ! idem for runoffs temperature if required
125      IF(   ln_rnf_sal   )   CALL fld_read ( kt, nn_fsbc, sf_s_rnf )    ! idem for runoffs salinity    if required
126      !
127      IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN
128         !
129         IF( .NOT. l_rnfcpl ) THEN
130             rnf(:,:) = rn_rfact * ( sf_rnf(1)%fnow(:,:,1) ) * tmask(:,:,1)  ! updated runoff value at time step kt
131             IF( ln_rnf_icb ) THEN
132                fwficb(:,:) = rn_rfact * ( sf_i_rnf(1)%fnow(:,:,1) ) * tmask(:,:,1)  ! updated runoff value at time step kt
133                CALL iom_put( 'iceberg_cea'  , fwficb(:,:)  )         ! output iceberg flux
134                CALL iom_put( 'hflx_icb_cea' , fwficb(:,:) * rLfus )   ! output Heat Flux into Sea Water due to Iceberg Thermodynamics -->
135             ENDIF
136         ENDIF
137         !
138         !                                                           ! set temperature & salinity content of runoffs
139         IF( ln_rnf_tem ) THEN                                       ! use runoffs temperature data
140            rnf_tsc(:,:,jp_tem) = ( sf_t_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rho0
141            CALL eos_fzp( sss_m(:,:), ztfrz(:,:) )
142            WHERE( sf_t_rnf(1)%fnow(:,:,1) == -999._wp )             ! if missing data value use SST as runoffs temperature
143               rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rho0
144            END WHERE
145         ELSE                                                        ! use SST as runoffs temperature
146            !CEOD River is fresh water so must at least be 0 unless we consider ice
147            rnf_tsc(:,:,jp_tem) = MAX( sst_m(:,:), 0.0_wp ) * rnf(:,:) * r1_rho0
148         ENDIF
149         !                                                           ! use runoffs salinity data
150         IF( ln_rnf_sal )   rnf_tsc(:,:,jp_sal) = ( sf_s_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rho0
151         !                                                           ! else use S=0 for runoffs (done one for all in the init)
152                                         CALL iom_put( 'runoffs'     , rnf(:,:)                         )   ! output runoff mass flux
153         IF( iom_use('hflx_rnf_cea') )   CALL iom_put( 'hflx_rnf_cea', rnf_tsc(:,:,jp_tem) * rho0 * rcp )   ! output runoff sensible heat (W/m2)
154      ENDIF
155      !
156      !                                                ! ---------------------------------------- !
157      IF( kt == nit000 ) THEN                          !   set the forcing field at nit000 - 1    !
158         !                                             ! ---------------------------------------- !
159         IF( ln_rstart .AND.    &                               !* Restart: read in restart file
160            & iom_varid( numror, 'rnf_b', ldstop = .FALSE. ) > 0 ) THEN
161            IF(lrxios) CALL iom_swap( TRIM(crxios_context) )
162            IF(lwp) WRITE(numout,*) '          nit000-1 runoff forcing fields red in the restart file', lrxios
163            CALL iom_get( numror, jpdom_auto, 'rnf_b', rnf_b, ldxios = lrxios )     ! before runoff
164            CALL iom_get( numror, jpdom_auto, 'rnf_hc_b', rnf_tsc_b(:,:,jp_tem), ldxios = lrxios )   ! before heat content of runoff
165            CALL iom_get( numror, jpdom_auto, 'rnf_sc_b', rnf_tsc_b(:,:,jp_sal), ldxios = lrxios )   ! before salinity content of runoff
166            IF(lrxios) CALL iom_swap( TRIM(cxios_context) )
167         ELSE                                                   !* no restart: set from nit000 values
168            IF(lwp) WRITE(numout,*) '          nit000-1 runoff forcing fields set to nit000'
169            rnf_b    (:,:  ) = rnf    (:,:  )
170            rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
171         ENDIF
172      ENDIF
173      !                                                ! ---------------------------------------- !
174      IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
175         !                                             ! ---------------------------------------- !
176         IF(lwp) WRITE(numout,*)
177         IF(lwp) WRITE(numout,*) 'sbcrnf : runoff forcing fields written in ocean restart file ',   &
178            &                    'at it= ', kt,' date= ', ndastp
179         IF(lwp) WRITE(numout,*) '~~~~'
180         IF( lwxios ) CALL iom_swap(      cwxios_context          )
181         CALL iom_rstput( kt, nitrst, numrow, 'rnf_b' , rnf, ldxios = lwxios )
182         CALL iom_rstput( kt, nitrst, numrow, 'rnf_hc_b', rnf_tsc(:,:,jp_tem), ldxios = lwxios )
183         CALL iom_rstput( kt, nitrst, numrow, 'rnf_sc_b', rnf_tsc(:,:,jp_sal), ldxios = lwxios )
184         IF( lwxios ) CALL iom_swap(      cxios_context          )
185      ENDIF
186      !
187   END SUBROUTINE sbc_rnf
188
189
190   SUBROUTINE sbc_rnf_div( phdivn, Kmm )
191      !!----------------------------------------------------------------------
192      !!                  ***  ROUTINE sbc_rnf  ***
193      !!
194      !! ** Purpose :   update the horizontal divergence with the runoff inflow
195      !!
196      !! ** Method  :
197      !!                CAUTION : rnf is positive (inflow) decreasing the
198      !!                          divergence and expressed in m/s
199      !!
200      !! ** Action  :   phdivn   decreased by the runoff inflow
201      !!----------------------------------------------------------------------
202      INTEGER                   , INTENT(in   ) ::   Kmm      ! ocean time level index
203      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   phdivn   ! horizontal divergence
204      !!
205      INTEGER  ::   ji, jj, jk   ! dummy loop indices
206      REAL(wp) ::   zfact     ! local scalar
207      !!----------------------------------------------------------------------
208      !
209      zfact = 0.5_wp
210      !
211      IF( ln_rnf_depth .OR. ln_rnf_depth_ini ) THEN      !==   runoff distributed over several levels   ==!
212         IF( ln_linssh ) THEN    !* constant volume case : just apply the runoff input flow
213            DO_2D( 1, 1, 1, 1 )
214               DO jk = 1, nk_rnf(ji,jj)
215                  phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rho0 / h_rnf(ji,jj)
216               END DO
217            END_2D
218         ELSE                    !* variable volume case
219            DO_2D( 1, 1, 1, 1 )
220               h_rnf(ji,jj) = 0._wp
221               DO jk = 1, nk_rnf(ji,jj)                           ! recalculates h_rnf to be the depth in metres
222                  h_rnf(ji,jj) = h_rnf(ji,jj) + e3t(ji,jj,jk,Kmm)   ! to the bottom of the relevant grid box
223               END DO
224               !                          ! apply the runoff input flow
225               DO jk = 1, nk_rnf(ji,jj)
226                  phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rho0 / h_rnf(ji,jj)
227               END DO
228            END_2D
229         ENDIF
230      ELSE                       !==   runoff put only at the surface   ==!
231         h_rnf (:,:)   = e3t (:,:,1,Kmm)        ! update h_rnf to be depth of top box
232         phdivn(:,:,1) = phdivn(:,:,1) - ( rnf(:,:) + rnf_b(:,:) ) * zfact * r1_rho0 / e3t(:,:,1,Kmm)
233      ENDIF
234      !
235   END SUBROUTINE sbc_rnf_div
236
237
238   SUBROUTINE sbc_rnf_init( Kmm )
239      !!----------------------------------------------------------------------
240      !!                  ***  ROUTINE sbc_rnf_init  ***
241      !!
242      !! ** Purpose :   Initialisation of the runoffs if (ln_rnf=T)
243      !!
244      !! ** Method  : - read the runoff namsbc_rnf namelist
245      !!
246      !! ** Action  : - read parameters
247      !!----------------------------------------------------------------------
248      INTEGER, INTENT(in) :: Kmm           ! ocean time level index
249      CHARACTER(len=32) ::   rn_dep_file   ! runoff file name
250      INTEGER           ::   ji, jj, jk, jm    ! dummy loop indices
251      INTEGER           ::   ierror, inum  ! temporary integer
252      INTEGER           ::   ios           ! Local integer output status for namelist read
253      INTEGER           ::   nbrec         ! temporary integer
254      REAL(wp)          ::   zacoef 
255      REAL(wp), DIMENSION(jpi,jpj,2) :: zrnfcl   
256      !!
257      NAMELIST/namsbc_rnf/ cn_dir            , ln_rnf_depth, ln_rnf_tem, ln_rnf_sal, ln_rnf_icb,   &
258         &                 sn_rnf, sn_cnf    , sn_i_rnf, sn_s_rnf    , sn_t_rnf  , sn_dep_rnf,   &
259         &                 ln_rnf_mouth      , rn_hrnf     , rn_avt_rnf, rn_rfact,     &
260         &                 ln_rnf_depth_ini  , rn_dep_max  , rn_rnf_max, nn_rnf_depth_file
261      !!----------------------------------------------------------------------
262      !
263      !                                         !==  allocate runoff arrays
264      IF( sbc_rnf_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_rnf_alloc : unable to allocate arrays' )
265      !
266      IF( .NOT. ln_rnf ) THEN                      ! no specific treatment in vicinity of river mouths
267         ln_rnf_mouth  = .FALSE.                   ! default definition needed for example by sbc_ssr or by tra_adv_muscl
268         nkrnf         = 0
269         rnf     (:,:) = 0.0_wp
270         rnf_b   (:,:) = 0.0_wp
271         rnfmsk  (:,:) = 0.0_wp
272         rnfmsk_z(:)   = 0.0_wp
273         RETURN
274      ENDIF
275      !
276      !                                   ! ============
277      !                                   !   Namelist
278      !                                   ! ============
279      !
280      READ  ( numnam_ref, namsbc_rnf, IOSTAT = ios, ERR = 901)
281901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namsbc_rnf in reference namelist' )
282
283      READ  ( numnam_cfg, namsbc_rnf, IOSTAT = ios, ERR = 902 )
284902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namsbc_rnf in configuration namelist' )
285      IF(lwm) WRITE ( numond, namsbc_rnf )
286      !
287      !                                         ! Control print
288      IF(lwp) THEN
289         WRITE(numout,*)
290         WRITE(numout,*) 'sbc_rnf_init : runoff '
291         WRITE(numout,*) '~~~~~~~~~~~~ '
292         WRITE(numout,*) '   Namelist namsbc_rnf'
293         WRITE(numout,*) '      specific river mouths treatment            ln_rnf_mouth = ', ln_rnf_mouth
294         WRITE(numout,*) '      river mouth additional Kz                  rn_avt_rnf   = ', rn_avt_rnf
295         WRITE(numout,*) '      depth of river mouth additional mixing     rn_hrnf      = ', rn_hrnf
296         WRITE(numout,*) '      multiplicative factor for runoff           rn_rfact     = ', rn_rfact
297      ENDIF
298      !                                   ! ==================
299      !                                   !   Type of runoff
300      !                                   ! ==================
301      !
302      IF( .NOT. l_rnfcpl ) THEN                   
303         ALLOCATE( sf_rnf(1), STAT=ierror )         ! Create sf_rnf structure (runoff inflow)
304         IF(lwp) WRITE(numout,*)
305         IF(lwp) WRITE(numout,*) '   ==>>>   runoffs inflow read in a file'
306         IF( ierror > 0 ) THEN
307            CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_rnf structure' )   ;   RETURN
308         ENDIF
309         ALLOCATE( sf_rnf(1)%fnow(jpi,jpj,1)   )
310         IF( sn_rnf%ln_tint ) ALLOCATE( sf_rnf(1)%fdta(jpi,jpj,1,2) )
311         CALL fld_fill( sf_rnf, (/ sn_rnf /), cn_dir, 'sbc_rnf_init', 'read runoffs data', 'namsbc_rnf', no_print )
312         !
313         IF( ln_rnf_icb ) THEN                      ! Create (if required) sf_i_rnf structure
314            IF(lwp) WRITE(numout,*)
315            IF(lwp) WRITE(numout,*) '          iceberg flux read in a file'
316            ALLOCATE( sf_i_rnf(1), STAT=ierror  )
317            IF( ierror > 0 ) THEN
318               CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_i_rnf structure' )   ;   RETURN
319            ENDIF
320            ALLOCATE( sf_i_rnf(1)%fnow(jpi,jpj,1)   )
321            IF( sn_i_rnf%ln_tint ) ALLOCATE( sf_i_rnf(1)%fdta(jpi,jpj,1,2) )
322            CALL fld_fill (sf_i_rnf, (/ sn_i_rnf /), cn_dir, 'sbc_rnf_init', 'read iceberg flux data', 'namsbc_rnf' )
323         ELSE
324            fwficb(:,:) = 0._wp
325         ENDIF
326
327      ENDIF
328      !
329      IF( ln_rnf_tem ) THEN                      ! Create (if required) sf_t_rnf structure
330         IF(lwp) WRITE(numout,*)
331         IF(lwp) WRITE(numout,*) '   ==>>>   runoffs temperatures read in a file'
332         ALLOCATE( sf_t_rnf(1), STAT=ierror  )
333         IF( ierror > 0 ) THEN
334            CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_t_rnf structure' )   ;   RETURN
335         ENDIF
336         ALLOCATE( sf_t_rnf(1)%fnow(jpi,jpj,1)   )
337         IF( sn_t_rnf%ln_tint ) ALLOCATE( sf_t_rnf(1)%fdta(jpi,jpj,1,2) )
338         CALL fld_fill (sf_t_rnf, (/ sn_t_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff temperature data', 'namsbc_rnf', no_print )
339      ENDIF
340      !
341      IF( ln_rnf_sal  ) THEN                     ! Create (if required) sf_s_rnf and sf_t_rnf structures
342         IF(lwp) WRITE(numout,*)
343         IF(lwp) WRITE(numout,*) '   ==>>>   runoffs salinities read in a file'
344         ALLOCATE( sf_s_rnf(1), STAT=ierror  )
345         IF( ierror > 0 ) THEN
346            CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_s_rnf structure' )   ;   RETURN
347         ENDIF
348         ALLOCATE( sf_s_rnf(1)%fnow(jpi,jpj,1)   )
349         IF( sn_s_rnf%ln_tint ) ALLOCATE( sf_s_rnf(1)%fdta(jpi,jpj,1,2) )
350         CALL fld_fill (sf_s_rnf, (/ sn_s_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff salinity data', 'namsbc_rnf', no_print )
351      ENDIF
352      !
353      IF( ln_rnf_depth ) THEN                    ! depth of runoffs set from a file
354         IF(lwp) WRITE(numout,*)
355         IF(lwp) WRITE(numout,*) '   ==>>>   runoffs depth read in a file'
356         rn_dep_file = TRIM( cn_dir )//TRIM( sn_dep_rnf%clname )
357         IF( .NOT. sn_dep_rnf%ln_clim ) THEN   ;   WRITE(rn_dep_file, '(a,"_y",i4)' ) TRIM( rn_dep_file ), nyear    ! add year
358            IF( sn_dep_rnf%clftyp == 'monthly' )   WRITE(rn_dep_file, '(a,"m",i2)'  ) TRIM( rn_dep_file ), nmonth   ! add month
359         ENDIF
360         CALL iom_open ( rn_dep_file, inum )                             ! open file
361         CALL iom_get  ( inum, jpdom_global, sn_dep_rnf%clvar, h_rnf )   ! read the river mouth array
362         CALL iom_close( inum )                                          ! close file
363         !
364         nk_rnf(:,:) = 0                               ! set the number of level over which river runoffs are applied
365         DO_2D( 1, 1, 1, 1 )
366            IF( h_rnf(ji,jj) > 0._wp ) THEN
367               jk = 2
368               DO WHILE ( jk < mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ;  jk = jk + 1
369               END DO
370               nk_rnf(ji,jj) = jk
371            ELSEIF( h_rnf(ji,jj) == -1._wp   ) THEN   ;  nk_rnf(ji,jj) = 1
372            ELSEIF( h_rnf(ji,jj) == -999._wp ) THEN   ;  nk_rnf(ji,jj) = mbkt(ji,jj)
373            ELSE
374               CALL ctl_stop( 'sbc_rnf_init: runoff depth not positive, and not -999 or -1, rnf value in file fort.999'  )
375               WRITE(999,*) 'ji, jj, h_rnf(ji,jj) :', ji, jj, h_rnf(ji,jj)
376            ENDIF
377         END_2D
378         DO_2D( 1, 1, 1, 1 )
379            h_rnf(ji,jj) = 0._wp
380            DO jk = 1, nk_rnf(ji,jj)
381               h_rnf(ji,jj) = h_rnf(ji,jj) + e3t(ji,jj,jk,Kmm)
382            END DO
383         END_2D
384         !
385      ELSE IF( ln_rnf_depth_ini ) THEN           ! runoffs applied at the surface
386         !
387         IF(lwp) WRITE(numout,*)
388         IF(lwp) WRITE(numout,*) '   ==>>>   depth of runoff computed once from max value of runoff'
389         IF(lwp) WRITE(numout,*) '        max value of the runoff climatologie (over global domain) rn_rnf_max = ', rn_rnf_max
390         IF(lwp) WRITE(numout,*) '        depth over which runoffs is spread                        rn_dep_max = ', rn_dep_max
391         IF(lwp) WRITE(numout,*) '        create (=1) a runoff depth file or not (=0)      nn_rnf_depth_file  = ', nn_rnf_depth_file
392
393         CALL iom_open( TRIM( sn_rnf%clname ), inum )    !  open runoff file
394         nbrec = iom_getszuld( inum )
395         zrnfcl(:,:,1) = 0._wp                                                            ! init the max to 0. in 1
396         DO jm = 1, nbrec
397            CALL iom_get( inum, jpdom_global, TRIM( sn_rnf%clvar ), zrnfcl(:,:,2), jm )   ! read the value in 2
398            zrnfcl(:,:,1) = MAXVAL( zrnfcl(:,:,:), DIM=3 )                                ! store the maximum value in time in 1
399         END DO
400         CALL iom_close( inum )
401         !
402         h_rnf(:,:) = 1.
403         !
404         zacoef = rn_dep_max / rn_rnf_max            ! coef of linear relation between runoff and its depth (150m for max of runoff)
405         !
406         WHERE( zrnfcl(:,:,1) > 0._wp )  h_rnf(:,:) = zacoef * zrnfcl(:,:,1)   ! compute depth for all runoffs
407         !
408         DO_2D( 1, 1, 1, 1 )
409            IF( zrnfcl(ji,jj,1) > 0._wp ) THEN
410               jk = mbkt(ji,jj)
411               h_rnf(ji,jj) = MIN( h_rnf(ji,jj), gdept_0(ji,jj,jk ) )
412            ENDIF
413         END_2D
414         !
415         nk_rnf(:,:) = 0                       ! number of levels on which runoffs are distributed
416         DO_2D( 1, 1, 1, 1 )
417            IF( zrnfcl(ji,jj,1) > 0._wp ) THEN
418               jk = 2
419               DO WHILE ( jk < mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ;  jk = jk + 1
420               END DO
421               nk_rnf(ji,jj) = jk
422            ELSE
423               nk_rnf(ji,jj) = 1
424            ENDIF
425         END_2D
426         !
427         DO_2D( 1, 1, 1, 1 )
428            h_rnf(ji,jj) = 0._wp
429            DO jk = 1, nk_rnf(ji,jj)
430               h_rnf(ji,jj) = h_rnf(ji,jj) + e3t(ji,jj,jk,Kmm)
431            END DO
432         END_2D
433         !
434         IF( nn_rnf_depth_file == 1 ) THEN      !  save  output nb levels for runoff
435            IF(lwp) WRITE(numout,*) '   ==>>>   create runoff depht file'
436            CALL iom_open  ( TRIM( sn_dep_rnf%clname ), inum, ldwrt = .TRUE. )
437            CALL iom_rstput( 0, 0, inum, 'rodepth', h_rnf )
438            CALL iom_close ( inum )
439         ENDIF
440      ELSE                                       ! runoffs applied at the surface
441         nk_rnf(:,:) = 1
442         h_rnf (:,:) = e3t(:,:,1,Kmm)
443      ENDIF
444      !
445      rnf(:,:) =  0._wp                         ! runoff initialisation
446      rnf_tsc(:,:,:) = 0._wp                    ! runoffs temperature & salinty contents initilisation
447      !
448      !                                   ! ========================
449      !                                   !   River mouth vicinity
450      !                                   ! ========================
451      !
452      IF( ln_rnf_mouth ) THEN                   ! Specific treatment in vicinity of river mouths :
453         !                                      !    - Increase Kz in surface layers ( rn_hrnf > 0 )
454         !                                      !    - set to zero SSS damping (ln_ssr=T)
455         !                                      !    - mixed upstream-centered (ln_traadv_cen2=T)
456         !
457         IF( ln_rnf_depth )   CALL ctl_warn( 'sbc_rnf_init: increased mixing turned on but effects may already',   &
458            &                                              'be spread through depth by ln_rnf_depth'               )
459         !
460         nkrnf = 0                                  ! Number of level over which Kz increase
461         IF( rn_hrnf > 0._wp ) THEN
462            nkrnf = 2
463            DO WHILE( nkrnf /= jpkm1 .AND. gdepw_1d(nkrnf+1) < rn_hrnf )   ;   nkrnf = nkrnf + 1
464            END DO
465            IF( ln_sco )   CALL ctl_warn( 'sbc_rnf_init: number of levels over which Kz is increased is computed for zco...' )
466         ENDIF
467         IF(lwp) WRITE(numout,*)
468         IF(lwp) WRITE(numout,*) '   ==>>>   Specific treatment used in vicinity of river mouths :'
469         IF(lwp) WRITE(numout,*) '             - Increase Kz in surface layers (if rn_hrnf > 0 )'
470         IF(lwp) WRITE(numout,*) '               by ', rn_avt_rnf,' m2/s  over ', nkrnf, ' w-levels'
471         IF(lwp) WRITE(numout,*) '             - set to zero SSS damping       (if ln_ssr=T)'
472         IF(lwp) WRITE(numout,*) '             - mixed upstream-centered       (if ln_traadv_cen2=T)'
473         !
474         CALL rnf_mouth                             ! set river mouth mask
475         !
476      ELSE                                      ! No treatment at river mouths
477         IF(lwp) WRITE(numout,*)
478         IF(lwp) WRITE(numout,*) '   ==>>>   No specific treatment at river mouths'
479         rnfmsk  (:,:) = 0._wp
480         rnfmsk_z(:)   = 0._wp
481         nkrnf = 0
482      ENDIF
483      !
484      IF( lwxios ) THEN
485         CALL iom_set_rstw_var_active('rnf_b')
486         CALL iom_set_rstw_var_active('rnf_hc_b')
487         CALL iom_set_rstw_var_active('rnf_sc_b')
488      ENDIF
489
490   END SUBROUTINE sbc_rnf_init
491
492
493   SUBROUTINE rnf_mouth
494      !!----------------------------------------------------------------------
495      !!                  ***  ROUTINE rnf_mouth  ***
496      !!
497      !! ** Purpose :   define the river mouths mask
498      !!
499      !! ** Method  :   read the river mouth mask (=0/1) in the river runoff
500      !!                climatological file. Defined a given vertical structure.
501      !!                CAUTION, the vertical structure is hard coded on the
502      !!                first 5 levels.
503      !!                This fields can be used to:
504      !!                 - set an upstream advection scheme
505      !!                   (ln_rnf_mouth=T and ln_traadv_cen2=T)
506      !!                 - increase vertical on the top nn_krnf vertical levels
507      !!                   at river runoff input grid point (nn_krnf>=2, see step.F90)
508      !!                 - set to zero SSS restoring flux at river mouth grid points
509      !!
510      !! ** Action  :   rnfmsk   set to 1 at river runoff input, 0 elsewhere
511      !!                rnfmsk_z vertical structure
512      !!----------------------------------------------------------------------
513      INTEGER            ::   inum        ! temporary integers
514      CHARACTER(len=140) ::   cl_rnfile   ! runoff file name
515      !!----------------------------------------------------------------------
516      !
517      IF(lwp) WRITE(numout,*)
518      IF(lwp) WRITE(numout,*) '   rnf_mouth : river mouth mask'
519      IF(lwp) WRITE(numout,*) '   ~~~~~~~~~ '
520      !
521      cl_rnfile = TRIM( cn_dir )//TRIM( sn_cnf%clname )
522      IF( .NOT. sn_cnf%ln_clim ) THEN   ;   WRITE(cl_rnfile, '(a,"_y",i4)' ) TRIM( cl_rnfile ), nyear    ! add year
523         IF( sn_cnf%clftyp == 'monthly' )   WRITE(cl_rnfile, '(a,"m",i2)'  ) TRIM( cl_rnfile ), nmonth   ! add month
524      ENDIF
525      !
526      ! horizontal mask (read in NetCDF file)
527      CALL iom_open ( cl_rnfile, inum )                             ! open file
528      CALL iom_get  ( inum, jpdom_global, sn_cnf%clvar, rnfmsk )    ! read the river mouth array
529      CALL iom_close( inum )                                        ! close file
530      !
531      IF( l_clo_rnf )   CALL clo_rnf( rnfmsk )   ! closed sea inflow set as river mouth
532      !
533      rnfmsk_z(:)   = 0._wp                                       ! vertical structure
534      rnfmsk_z(1)   = 1.0
535      rnfmsk_z(2)   = 1.0                                         ! **********
536      rnfmsk_z(3)   = 0.5                                         ! HARD CODED on the 5 first levels
537      rnfmsk_z(4)   = 0.25                                        ! **********
538      rnfmsk_z(5)   = 0.125
539      !
540   END SUBROUTINE rnf_mouth
541
542   !!======================================================================
543END MODULE sbcrnf
Note: See TracBrowser for help on using the repository browser.