New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zdfiwm.F90 in NEMO/branches/2019/dev_r11351_fldread_with_XIOS/src/OCE/ZDF – NEMO

source: NEMO/branches/2019/dev_r11351_fldread_with_XIOS/src/OCE/ZDF/zdfiwm.F90 @ 13463

Last change on this file since 13463 was 13463, checked in by andmirek, 4 years ago

Ticket #2195:update to trunk 13461

  • Property svn:keywords set to Id
File size: 27.4 KB
Line 
1MODULE zdfiwm
2   !!========================================================================
3   !!                       ***  MODULE  zdfiwm  ***
4   !! Ocean physics: Internal gravity wave-driven vertical mixing
5   !!========================================================================
6   !! History :  1.0  !  2004-04  (L. Bessieres, G. Madec)  Original code
7   !!             -   !  2006-08  (A. Koch-Larrouy)  Indonesian strait
8   !!            3.3  !  2010-10  (C. Ethe, G. Madec)  reorganisation of initialisation phase
9   !!            3.6  !  2016-03  (C. de Lavergne)  New param: internal wave-driven mixing
10   !!            4.0  !  2017-04  (G. Madec)  renamed module, remove the old param. and the CPP keys
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   zdf_iwm       : global     momentum & tracer Kz with wave induced Kz
15   !!   zdf_iwm_init  : global     momentum & tracer Kz with wave induced Kz
16   !!----------------------------------------------------------------------
17   USE oce            ! ocean dynamics and tracers variables
18   USE dom_oce        ! ocean space and time domain variables
19   USE zdf_oce        ! ocean vertical physics variables
20   USE zdfddm         ! ocean vertical physics: double diffusive mixing
21   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
22   USE eosbn2         ! ocean equation of state
23   USE phycst         ! physical constants
24   !
25   USE fldread        ! field read
26   USE prtctl         ! Print control
27   USE in_out_manager ! I/O manager
28   USE iom            ! I/O Manager
29   USE lib_mpp        ! MPP library
30   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   zdf_iwm        ! called in step module
36   PUBLIC   zdf_iwm_init   ! called in nemogcm module
37
38   !                      !!* Namelist  namzdf_iwm : internal wave-driven mixing *
39   INTEGER ::  nn_zpyc     ! pycnocline-intensified mixing energy proportional to N (=1) or N^2 (=2)
40   LOGICAL ::  ln_mevar    ! variable (=T) or constant (=F) mixing efficiency
41   LOGICAL ::  ln_tsdiff   ! account for differential T/S wave-driven mixing (=T) or not (=F)
42
43   REAL(wp)::  r1_6 = 1._wp / 6._wp
44
45   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   ebot_iwm   ! power available from high-mode wave breaking (W/m2)
46   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   epyc_iwm   ! power available from low-mode, pycnocline-intensified wave breaking (W/m2)
47   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   ecri_iwm   ! power available from low-mode, critical slope wave breaking (W/m2)
48   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   hbot_iwm   ! WKB decay scale for high-mode energy dissipation (m)
49   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   hcri_iwm   ! decay scale for low-mode critical slope dissipation (m)
50
51   !! * Substitutions
52#  include "do_loop_substitute.h90"
53#  include "domzgr_substitute.h90"
54   !!----------------------------------------------------------------------
55   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
56   !! $Id$
57   !! Software governed by the CeCILL license (see ./LICENSE)
58   !!----------------------------------------------------------------------
59CONTAINS
60
61   INTEGER FUNCTION zdf_iwm_alloc()
62      !!----------------------------------------------------------------------
63      !!                ***  FUNCTION zdf_iwm_alloc  ***
64      !!----------------------------------------------------------------------
65      ALLOCATE( ebot_iwm(jpi,jpj),  epyc_iwm(jpi,jpj),  ecri_iwm(jpi,jpj) ,     &
66      &         hbot_iwm(jpi,jpj),  hcri_iwm(jpi,jpj)                     , STAT=zdf_iwm_alloc )
67      !
68      CALL mpp_sum ( 'zdfiwm', zdf_iwm_alloc )
69      IF( zdf_iwm_alloc /= 0 )   CALL ctl_stop( 'STOP', 'zdf_iwm_alloc: failed to allocate arrays' )
70   END FUNCTION zdf_iwm_alloc
71
72
73   SUBROUTINE zdf_iwm( kt, Kmm, p_avm, p_avt, p_avs )
74      !!----------------------------------------------------------------------
75      !!                  ***  ROUTINE zdf_iwm  ***
76      !!                   
77      !! ** Purpose :   add to the vertical mixing coefficients the effect of
78      !!              breaking internal waves.
79      !!
80      !! ** Method  : - internal wave-driven vertical mixing is given by:
81      !!                  Kz_wave = min(  100 cm2/s, f(  Reb = zemx_iwm /( Nu * N^2 )  )
82      !!              where zemx_iwm is the 3D space distribution of the wave-breaking
83      !!              energy and Nu the molecular kinematic viscosity.
84      !!              The function f(Reb) is linear (constant mixing efficiency)
85      !!              if the namelist parameter ln_mevar = F and nonlinear if ln_mevar = T.
86      !!
87      !!              - Compute zemx_iwm, the 3D power density that allows to compute
88      !!              Reb and therefrom the wave-induced vertical diffusivity.
89      !!              This is divided into three components:
90      !!                 1. Bottom-intensified low-mode dissipation at critical slopes
91      !!                     zemx_iwm(z) = ( ecri_iwm / rho0 ) * EXP( -(H-z)/hcri_iwm )
92      !!                                   / ( 1. - EXP( - H/hcri_iwm ) ) * hcri_iwm
93      !!              where hcri_iwm is the characteristic length scale of the bottom
94      !!              intensification, ecri_iwm a map of available power, and H the ocean depth.
95      !!                 2. Pycnocline-intensified low-mode dissipation
96      !!                     zemx_iwm(z) = ( epyc_iwm / rho0 ) * ( sqrt(rn2(z))^nn_zpyc )
97      !!                                   / SUM( sqrt(rn2(z))^nn_zpyc * e3w[z) )
98      !!              where epyc_iwm is a map of available power, and nn_zpyc
99      !!              is the chosen stratification-dependence of the internal wave
100      !!              energy dissipation.
101      !!                 3. WKB-height dependent high mode dissipation
102      !!                     zemx_iwm(z) = ( ebot_iwm / rho0 ) * rn2(z) * EXP(-z_wkb(z)/hbot_iwm)
103      !!                                   / SUM( rn2(z) * EXP(-z_wkb(z)/hbot_iwm) * e3w[z) )
104      !!              where hbot_iwm is the characteristic length scale of the WKB bottom
105      !!              intensification, ebot_iwm is a map of available power, and z_wkb is the
106      !!              WKB-stretched height above bottom defined as
107      !!                    z_wkb(z) = H * SUM( sqrt(rn2(z'>=z)) * e3w[z'>=z) )
108      !!                                 / SUM( sqrt(rn2(z'))    * e3w[z')    )
109      !!
110      !!              - update the model vertical eddy viscosity and diffusivity:
111      !!                     avt  = avt  +    av_wave
112      !!                     avm  = avm  +    av_wave
113      !!
114      !!              - if namelist parameter ln_tsdiff = T, account for differential mixing:
115      !!                     avs  = avt  +    av_wave * diffusivity_ratio(Reb)
116      !!
117      !! ** Action  : - avt, avs, avm, increased by tide internal wave-driven mixing   
118      !!
119      !! References :  de Lavergne et al. 2015, JPO; 2016, in prep.
120      !!----------------------------------------------------------------------
121      INTEGER                    , INTENT(in   ) ::   kt             ! ocean time step
122      INTEGER                    , INTENT(in   ) ::   Kmm            ! time level index
123      REAL(wp), DIMENSION(:,:,:) , INTENT(inout) ::   p_avm          ! momentum Kz (w-points)
124      REAL(wp), DIMENSION(:,:,:) , INTENT(inout) ::   p_avt, p_avs   ! tracer   Kz (w-points)
125      !
126      INTEGER  ::   ji, jj, jk   ! dummy loop indices
127      REAL(wp) ::   zztmp, ztmp1, ztmp2        ! scalar workspace
128      REAL(wp), DIMENSION(jpi,jpj)     ::   zfact       ! Used for vertical structure
129      REAL(wp), DIMENSION(jpi,jpj)     ::   zhdep       ! Ocean depth
130      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zwkb        ! WKB-stretched height above bottom
131      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zweight     ! Weight for high mode vertical distribution
132      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   znu_t       ! Molecular kinematic viscosity (T grid)
133      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   znu_w       ! Molecular kinematic viscosity (W grid)
134      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zReb        ! Turbulence intensity parameter
135      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zemx_iwm    ! local energy density available for mixing (W/kg)
136      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zav_ratio   ! S/T diffusivity ratio (only for ln_tsdiff=T)
137      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zav_wave    ! Internal wave-induced diffusivity
138      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   z3d  ! 3D workspace used for iom_put
139      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::   z2d  ! 2D     -      -    -     -
140      !!----------------------------------------------------------------------
141      !
142      !                       
143      ! Set to zero the 1st and last vertical levels of appropriate variables
144      IF( iom_use("emix_iwm") ) THEN
145         DO_2D( 0, 0, 0, 0 )
146            zemx_iwm (ji,jj,1) = 0._wp   ;   zemx_iwm (ji,jj,jpk) = 0._wp
147         END_2D
148      ENDIF
149      IF( iom_use("av_ratio") ) THEN
150         DO_2D( 0, 0, 0, 0 )
151            zav_ratio(ji,jj,1) = 0._wp   ;   zav_ratio(ji,jj,jpk) = 0._wp
152         END_2D
153      ENDIF
154      IF( iom_use("av_wave") .OR. sn_cfctl%l_prtctl ) THEN
155         DO_2D( 0, 0, 0, 0 )
156            zav_wave (ji,jj,1) = 0._wp   ;   zav_wave (ji,jj,jpk) = 0._wp
157         END_2D
158      ENDIF
159      !
160      !                       ! ----------------------------- !
161      !                       !  Internal wave-driven mixing  !  (compute zav_wave)
162      !                       ! ----------------------------- !
163      !                             
164      !                       !* Critical slope mixing: distribute energy over the time-varying ocean depth,
165      !                                                 using an exponential decay from the seafloor.
166      DO_2D( 0, 0, 0, 0 )
167         zhdep(ji,jj) = gdepw_0(ji,jj,mbkt(ji,jj)+1)       ! depth of the ocean
168         zfact(ji,jj) = rho0 * (  1._wp - EXP( -zhdep(ji,jj) / hcri_iwm(ji,jj) )  )
169         IF( zfact(ji,jj) /= 0._wp )   zfact(ji,jj) = ecri_iwm(ji,jj) / zfact(ji,jj)
170      END_2D
171!!gm gde3w ==>>>  check for ssh taken into account.... seem OK gde3w_n=gdept(:,:,:,Kmm) - ssh(:,:,Kmm)
172      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
173         IF ( zfact(ji,jj) == 0._wp .OR. wmask(ji,jj,jk) == 0._wp ) THEN   ! optimization
174            zemx_iwm(ji,jj,jk) = 0._wp
175         ELSE
176            zemx_iwm(ji,jj,jk) = zfact(ji,jj) * (  EXP( ( gde3w(ji,jj,jk  ) - zhdep(ji,jj) ) / hcri_iwm(ji,jj) )     &
177                 &                               - EXP( ( gde3w(ji,jj,jk-1) - zhdep(ji,jj) ) / hcri_iwm(ji,jj) ) )   &
178                 &                            / ( gde3w(ji,jj,jk) - gde3w(ji,jj,jk-1) )
179         ENDIF
180      END_3D
181!!gm delta(gde3w) = e3t(:,:,:,Kmm)  !!  Please verify the grid-point position w versus t-point
182!!gm it seems to me that only 1/hcri_iwm  is used ==>  compute it one for all
183
184
185      !                        !* Pycnocline-intensified mixing: distribute energy over the time-varying
186      !                        !* ocean depth as proportional to sqrt(rn2)^nn_zpyc
187      !                                          ! (NB: N2 is masked, so no use of wmask here)
188      SELECT CASE ( nn_zpyc )
189      !
190      CASE ( 1 )               ! Dissipation scales as N (recommended)
191         !
192         DO_2D( 0, 0, 0, 0 )
193            zfact(ji,jj) = 0._wp
194         END_2D
195         DO_3D( 0, 0, 0, 0, 2, jpkm1 )       ! part independent of the level
196            zfact(ji,jj) = zfact(ji,jj) + e3w(ji,jj,jk,Kmm) * SQRT(  MAX( 0._wp, rn2(ji,jj,jk) )  ) * wmask(ji,jj,jk)
197         END_3D
198         !
199         DO_2D( 0, 0, 0, 0 )
200            IF( zfact(ji,jj) /= 0 )   zfact(ji,jj) = epyc_iwm(ji,jj) / ( rho0 * zfact(ji,jj) )
201         END_2D
202         !
203         DO_3D( 0, 0, 0, 0, 2, jpkm1 )       ! complete with the level-dependent part
204            zemx_iwm(ji,jj,jk) = zemx_iwm(ji,jj,jk) + zfact(ji,jj) * SQRT(  MAX( 0._wp, rn2(ji,jj,jk) )  ) * wmask(ji,jj,jk)
205         END_3D
206         !
207      CASE ( 2 )               ! Dissipation scales as N^2
208         !
209         DO_2D( 0, 0, 0, 0 )
210            zfact(ji,jj) = 0._wp
211         END_2D
212         DO_3D( 0, 0, 0, 0, 2, jpkm1 )       ! part independent of the level
213            zfact(ji,jj) = zfact(ji,jj) + e3w(ji,jj,jk,Kmm) * MAX( 0._wp, rn2(ji,jj,jk) ) * wmask(ji,jj,jk)
214         END_3D
215         !
216         DO_2D( 0, 0, 0, 0 )
217            IF( zfact(ji,jj) /= 0 )   zfact(ji,jj) = epyc_iwm(ji,jj) / ( rho0 * zfact(ji,jj) )
218         END_2D
219         !
220         DO_3D( 0, 0, 0, 0, 2, jpkm1 )       ! complete with the level-dependent part
221            zemx_iwm(ji,jj,jk) = zemx_iwm(ji,jj,jk) + zfact(ji,jj) * MAX( 0._wp, rn2(ji,jj,jk) ) * wmask(ji,jj,jk)
222         END_3D
223         !
224      END SELECT
225
226      !                        !* WKB-height dependent mixing: distribute energy over the time-varying
227      !                        !* ocean depth as proportional to rn2 * exp(-z_wkb/rn_hbot)
228      !
229      DO_2D( 0, 0, 0, 0 )
230         zwkb(ji,jj,1) = 0._wp
231      END_2D
232      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
233         zwkb(ji,jj,jk) = zwkb(ji,jj,jk-1) + e3w(ji,jj,jk,Kmm) * SQRT(  MAX( 0._wp, rn2(ji,jj,jk) )  ) * wmask(ji,jj,jk)
234      END_3D
235      DO_2D( 0, 0, 0, 0 )
236         zfact(ji,jj) = zwkb(ji,jj,jpkm1)
237      END_2D
238      !
239      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
240         IF( zfact(ji,jj) /= 0 )   zwkb(ji,jj,jk) = zhdep(ji,jj) * ( zfact(ji,jj) - zwkb(ji,jj,jk) )   &
241            &                                     * wmask(ji,jj,jk) / zfact(ji,jj)
242      END_3D
243      DO_2D( 0, 0, 0, 0 )
244         zwkb (ji,jj,1) = zhdep(ji,jj) * wmask(ji,jj,1)
245      END_2D
246      !
247      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
248         IF ( rn2(ji,jj,jk) <= 0._wp .OR. wmask(ji,jj,jk) == 0._wp ) THEN   ! optimization: EXP coast a lot
249            zweight(ji,jj,jk) = 0._wp
250         ELSE
251            zweight(ji,jj,jk) = rn2(ji,jj,jk) * hbot_iwm(ji,jj)    &
252               &   * (  EXP( -zwkb(ji,jj,jk) / hbot_iwm(ji,jj) ) - EXP( -zwkb(ji,jj,jk-1) / hbot_iwm(ji,jj) )  )
253         ENDIF
254      END_3D
255      !
256      DO_2D( 0, 0, 0, 0 )
257         zfact(ji,jj) = 0._wp
258      END_2D
259      DO_3D( 0, 0, 0, 0, 2, jpkm1 )       ! part independent of the level
260         zfact(ji,jj) = zfact(ji,jj) + zweight(ji,jj,jk)
261      END_3D
262      !
263      DO_2D( 0, 0, 0, 0 )
264         IF( zfact(ji,jj) /= 0 )   zfact(ji,jj) = ebot_iwm(ji,jj) / ( rho0 * zfact(ji,jj) )
265      END_2D
266      !
267      DO_3D( 0, 0, 0, 0, 2, jpkm1 )       ! complete with the level-dependent part
268         zemx_iwm(ji,jj,jk) = zemx_iwm(ji,jj,jk) + zweight(ji,jj,jk) * zfact(ji,jj) * wmask(ji,jj,jk)   &
269            &                                                        / ( gde3w(ji,jj,jk) - gde3w(ji,jj,jk-1) )
270!!gm  use of e3t(ji,jj,:,Kmm) just above?
271      END_3D
272      !
273!!gm  this is to be replaced by just a constant value znu=1.e-6 m2/s
274      ! Calculate molecular kinematic viscosity
275      DO_3D( 0, 0, 0, 0, 1, jpkm1 )
276         znu_t(ji,jj,jk) = 1.e-4_wp * (  17.91_wp - 0.53810_wp * ts(ji,jj,jk,jp_tem,Kmm)   &
277            &                                     + 0.00694_wp * ts(ji,jj,jk,jp_tem,Kmm) * ts(ji,jj,jk,jp_tem,Kmm)  &
278            &                                     + 0.02305_wp * ts(ji,jj,jk,jp_sal,Kmm)  ) * tmask(ji,jj,jk) * r1_rho0
279      END_3D
280      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
281         znu_w(ji,jj,jk) = 0.5_wp * ( znu_t(ji,jj,jk-1) + znu_t(ji,jj,jk) ) * wmask(ji,jj,jk)
282      END_3D
283!!gm end
284      !
285      ! Calculate turbulence intensity parameter Reb
286      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
287         zReb(ji,jj,jk) = zemx_iwm(ji,jj,jk) / MAX( 1.e-20_wp, znu_w(ji,jj,jk) * rn2(ji,jj,jk) )
288      END_3D
289      !
290      ! Define internal wave-induced diffusivity
291      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
292         zav_wave(ji,jj,jk) = znu_w(ji,jj,jk) * zReb(ji,jj,jk) * r1_6   ! This corresponds to a constant mixing efficiency of 1/6
293      END_3D
294      !
295      IF( ln_mevar ) THEN              ! Variable mixing efficiency case : modify zav_wave in the
296         DO_3D( 0, 0, 0, 0, 2, jpkm1 )
297            IF( zReb(ji,jj,jk) > 480.00_wp ) THEN
298               zav_wave(ji,jj,jk) = 3.6515_wp * znu_w(ji,jj,jk) * SQRT( zReb(ji,jj,jk) )
299            ELSEIF( zReb(ji,jj,jk) < 10.224_wp ) THEN
300               zav_wave(ji,jj,jk) = 0.052125_wp * znu_w(ji,jj,jk) * zReb(ji,jj,jk) * SQRT( zReb(ji,jj,jk) )
301            ENDIF
302         END_3D
303      ENDIF
304      !
305      DO_3D( 0, 0, 0, 0, 2, jpkm1 )          ! Bound diffusivity by molecular value and 100 cm2/s
306         zav_wave(ji,jj,jk) = MIN(  MAX( 1.4e-7_wp, zav_wave(ji,jj,jk) ), 1.e-2_wp  ) * wmask(ji,jj,jk)
307      END_3D
308      !
309      IF( kt == nit000 ) THEN        !* Control print at first time-step: diagnose the energy consumed by zav_wave
310         zztmp = 0._wp
311!!gm used of glosum 3D....
312         DO_3D( 0, 0, 0, 0, 2, jpkm1 )
313            zztmp = zztmp + e3w(ji,jj,jk,Kmm) * e1e2t(ji,jj)   &
314               &          * MAX( 0._wp, rn2(ji,jj,jk) ) * zav_wave(ji,jj,jk) * wmask(ji,jj,jk) * tmask_i(ji,jj)
315         END_3D
316         CALL mpp_sum( 'zdfiwm', zztmp )
317         zztmp = rho0 * zztmp ! Global integral of rauo * Kz * N^2 = power contributing to mixing
318         !
319         IF(lwp) THEN
320            WRITE(numout,*)
321            WRITE(numout,*) 'zdf_iwm : Internal wave-driven mixing (iwm)'
322            WRITE(numout,*) '~~~~~~~ '
323            WRITE(numout,*)
324            WRITE(numout,*) '      Total power consumption by av_wave =  ', zztmp * 1.e-12_wp, 'TW'
325         ENDIF
326      ENDIF
327
328      !                          ! ----------------------- !
329      !                          !   Update  mixing coefs  !                         
330      !                          ! ----------------------- !
331      !     
332      IF( ln_tsdiff ) THEN          !* Option for differential mixing of salinity and temperature
333         ztmp1 = 0.505_wp + 0.495_wp * TANH( 0.92_wp * ( LOG10( 1.e-20_wp ) - 0.60_wp ) )
334         DO_3D( 0, 0, 0, 0, 2, jpkm1 )
335            ztmp2 = zReb(ji,jj,jk) * 5._wp * r1_6
336            IF ( ztmp2 > 1.e-20_wp .AND. wmask(ji,jj,jk) == 1._wp ) THEN
337               zav_ratio(ji,jj,jk) = 0.505_wp + 0.495_wp * TANH( 0.92_wp * ( LOG10(ztmp2) - 0.60_wp ) )
338            ELSE
339               zav_ratio(ji,jj,jk) = ztmp1 * wmask(ji,jj,jk)
340            ENDIF
341         END_3D
342         CALL iom_put( "av_ratio", zav_ratio )
343         DO_3D( 0, 0, 0, 0, 2, jpkm1 )    !* update momentum & tracer diffusivity with wave-driven mixing
344            p_avs(ji,jj,jk) = p_avs(ji,jj,jk) + zav_wave(ji,jj,jk) * zav_ratio(ji,jj,jk)
345            p_avt(ji,jj,jk) = p_avt(ji,jj,jk) + zav_wave(ji,jj,jk)
346            p_avm(ji,jj,jk) = p_avm(ji,jj,jk) + zav_wave(ji,jj,jk)
347         END_3D
348         !
349      ELSE                          !* update momentum & tracer diffusivity with wave-driven mixing
350         DO_3D( 0, 0, 0, 0, 2, jpkm1 )
351            p_avs(ji,jj,jk) = p_avs(ji,jj,jk) + zav_wave(ji,jj,jk)
352            p_avt(ji,jj,jk) = p_avt(ji,jj,jk) + zav_wave(ji,jj,jk)
353            p_avm(ji,jj,jk) = p_avm(ji,jj,jk) + zav_wave(ji,jj,jk)
354         END_3D
355      ENDIF
356
357      !                             !* output internal wave-driven mixing coefficient
358      CALL iom_put( "av_wave", zav_wave )
359                                    !* output useful diagnostics: Kz*N^2 ,
360!!gm Kz*N2 should take into account the ratio avs/avt if it is used.... (see diaar5)
361                                    !  vertical integral of rho0 * Kz * N^2 , energy density (zemx_iwm)
362      IF( iom_use("bflx_iwm") .OR. iom_use("pcmap_iwm") ) THEN
363         ALLOCATE( z2d(jpi,jpj) , z3d(jpi,jpj,jpk) )
364         ! Initialisation for iom_put
365         DO_2D( 0, 0, 0, 0 )
366            z3d(ji,jj,1) = 0._wp   ;   z3d(ji,jj,jpk) = 0._wp
367         END_2D
368         z3d(           1:nn_hls,:,:) = 0._wp   ;   z3d(:,           1:nn_hls,:) = 0._wp
369         z3d(jpi-nn_hls+1:jpi   ,:,:) = 0._wp   ;   z3d(:,jpj-nn_hls+1:   jpj,:) = 0._wp
370         z2d(           1:nn_hls,:  ) = 0._wp   ;   z2d(:,           1:nn_hls  ) = 0._wp
371         z2d(jpi-nn_hls+1:jpi   ,:  ) = 0._wp   ;   z2d(:,jpj-nn_hls+1:   jpj  ) = 0._wp
372
373         DO_3D( 0, 0, 0, 0, 2, jpkm1 )
374            z3d(ji,jj,jk) = MAX( 0._wp, rn2(ji,jj,jk) ) * zav_wave(ji,jj,jk)
375         END_3D
376         DO_2D( 0, 0, 0, 0 )
377            z2d(ji,jj) = 0._wp
378         END_2D
379         DO_3D( 0, 0, 0, 0, 2, jpkm1 ) 
380            z2d(ji,jj) = z2d(ji,jj) + e3w(ji,jj,jk,Kmm) * z3d(ji,jj,jk) * wmask(ji,jj,jk)
381         END_3D
382         DO_2D( 0, 0, 0, 0 )
383            z2d(ji,jj) = rho0 * z2d(ji,jj)
384         END_2D
385         CALL iom_put(  "bflx_iwm", z3d )
386         CALL iom_put( "pcmap_iwm", z2d )
387         DEALLOCATE( z2d , z3d )
388      ENDIF
389      CALL iom_put( "emix_iwm", zemx_iwm )
390     
391      IF(sn_cfctl%l_prtctl)   CALL prt_ctl(tab3d_1=zav_wave , clinfo1=' iwm - av_wave: ', tab3d_2=avt, clinfo2=' avt: ', kdim=jpk)
392      !
393   END SUBROUTINE zdf_iwm
394
395
396   SUBROUTINE zdf_iwm_init
397      !!----------------------------------------------------------------------
398      !!                  ***  ROUTINE zdf_iwm_init  ***
399      !!                     
400      !! ** Purpose :   Initialization of the wave-driven vertical mixing, reading
401      !!              of input power maps and decay length scales in netcdf files.
402      !!
403      !! ** Method  : - Read the namzdf_iwm namelist and check the parameters
404      !!
405      !!              - Read the input data in NetCDF files :
406      !!              power available from high-mode wave breaking (mixing_power_bot.nc)
407      !!              power available from pycnocline-intensified wave-breaking (mixing_power_pyc.nc)
408      !!              power available from critical slope wave-breaking (mixing_power_cri.nc)
409      !!              WKB decay scale for high-mode wave-breaking (decay_scale_bot.nc)
410      !!              decay scale for critical slope wave-breaking (decay_scale_cri.nc)
411      !!
412      !! ** input   : - Namlist namzdf_iwm
413      !!              - NetCDF files : mixing_power_bot.nc, mixing_power_pyc.nc, mixing_power_cri.nc,
414      !!              decay_scale_bot.nc decay_scale_cri.nc
415      !!
416      !! ** Action  : - Increase by 1 the nstop flag is setting problem encounter
417      !!              - Define ebot_iwm, epyc_iwm, ecri_iwm, hbot_iwm, hcri_iwm
418      !!
419      !! References : de Lavergne et al. JPO, 2015 ; de Lavergne PhD 2016
420      !!              de Lavergne et al. in prep., 2017
421      !!----------------------------------------------------------------------
422      INTEGER  ::   ifpr               ! dummy loop indices
423      INTEGER  ::   inum               ! local integer
424      INTEGER  ::   ios
425      REAL(wp) ::   zbot, zpyc, zcri   ! local scalars
426      !
427      CHARACTER(len=256)            ::   cn_dir                 ! Root directory for location of ssr files
428      INTEGER, PARAMETER            ::   jpiwm  = 5             ! maximum number of files to read
429      INTEGER, PARAMETER            ::   jp_mpb = 1
430      INTEGER, PARAMETER            ::   jp_mpp = 2
431      INTEGER, PARAMETER            ::   jp_mpc = 3
432      INTEGER, PARAMETER            ::   jp_dsb = 4
433      INTEGER, PARAMETER            ::   jp_dsc = 5
434      !
435      TYPE(FLD_N), DIMENSION(jpiwm) ::   slf_iwm                ! array of namelist informations
436      TYPE(FLD_N)                   ::   sn_mpb, sn_mpp, sn_mpc ! informations about Mixing Power field to be read
437      TYPE(FLD_N)                   ::   sn_dsb, sn_dsc         ! informations about Decay Scale field to be read
438      TYPE(FLD  ), DIMENSION(jpiwm) ::   sf_iwm                 ! structure of input fields (file informations, fields read)
439      !
440      NAMELIST/namzdf_iwm/ nn_zpyc, ln_mevar, ln_tsdiff, &
441         &                 cn_dir, sn_mpb, sn_mpp, sn_mpc, sn_dsb, sn_dsc
442      !!----------------------------------------------------------------------
443      !
444      READ  ( numnam_ref, namzdf_iwm, IOSTAT = ios, ERR = 901)
445901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namzdf_iwm in reference namelist' )
446      !
447      READ  ( numnam_cfg, namzdf_iwm, IOSTAT = ios, ERR = 902 )
448902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namzdf_iwm in configuration namelist' )
449      IF(lwm) WRITE ( numond, namzdf_iwm )
450      !
451      IF(lwp) THEN                  ! Control print
452         WRITE(numout,*)
453         WRITE(numout,*) 'zdf_iwm_init : internal wave-driven mixing'
454         WRITE(numout,*) '~~~~~~~~~~~~'
455         WRITE(numout,*) '   Namelist namzdf_iwm : set wave-driven mixing parameters'
456         WRITE(numout,*) '      Pycnocline-intensified diss. scales as N (=1) or N^2 (=2) = ', nn_zpyc
457         WRITE(numout,*) '      Variable (T) or constant (F) mixing efficiency            = ', ln_mevar
458         WRITE(numout,*) '      Differential internal wave-driven mixing (T) or not (F)   = ', ln_tsdiff
459      ENDIF
460     
461      ! The new wave-driven mixing parameterization elevates avt and avm in the interior, and
462      ! ensures that avt remains larger than its molecular value (=1.4e-7). Therefore, avtb should
463      ! be set here to a very small value, and avmb to its (uniform) molecular value (=1.4e-6).
464      avmb(:) = 1.4e-6_wp        ! viscous molecular value
465      avtb(:) = 1.e-10_wp        ! very small diffusive minimum (background avt is specified in zdf_iwm)   
466      avtb_2d(:,:) = 1.e0_wp     ! uniform
467      IF(lwp) THEN                  ! Control print
468         WRITE(numout,*)
469         WRITE(numout,*) '   Force the background value applied to avm & avt in TKE to be everywhere ',   &
470            &               'the viscous molecular value & a very small diffusive value, resp.'
471      ENDIF
472           
473      !                             ! allocate iwm arrays
474      IF( zdf_iwm_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'zdf_iwm_init : unable to allocate iwm arrays' )
475      !
476      ! store namelist information in an array
477      slf_iwm(jp_mpb) = sn_mpb ; slf_iwm(jp_mpp) = sn_mpp ; slf_iwm(jp_mpc) = sn_mpc
478      slf_iwm(jp_dsb) = sn_dsb ; slf_iwm(jp_dsc) = sn_dsc
479      !
480      DO ifpr= 1, jpiwm
481         ALLOCATE( sf_iwm(ifpr)%fnow(jpi,jpj,1)   )
482         IF( slf_iwm(ifpr)%ln_tint )ALLOCATE( sf_iwm(ifpr)%fdta(jpi,jpj,1,2) )
483      END DO
484
485      ! fill sf_iwm with sf_iwm and control print
486      CALL fld_fill( sf_iwm, slf_iwm , cn_dir, 'zdfiwm_init', 'iwm input file', 'namiwm' )
487
488      !                             ! hard-coded default definition (to be defined in namelist ?)
489      sf_iwm(jp_mpb)%fnow(:,:,1) = 1.e-6
490      sf_iwm(jp_mpp)%fnow(:,:,1) = 1.e-6
491      sf_iwm(jp_mpc)%fnow(:,:,1) = 1.e-10
492      sf_iwm(jp_dsb)%fnow(:,:,1) = 100.
493      sf_iwm(jp_dsc)%fnow(:,:,1) = 100.
494
495      !                             ! read necessary fields
496      CALL fld_read( nit000, 1, sf_iwm )
497
498      ebot_iwm(:,:) = sf_iwm(1)%fnow(:,:,1) * ssmask(:,:) ! energy flux for high-mode wave breaking [W/m2]
499      epyc_iwm(:,:) = sf_iwm(2)%fnow(:,:,1) * ssmask(:,:) ! energy flux for pynocline-intensified wave breaking [W/m2]
500      ecri_iwm(:,:) = sf_iwm(3)%fnow(:,:,1) * ssmask(:,:) ! energy flux for critical slope wave breaking [W/m2]
501      hbot_iwm(:,:) = sf_iwm(4)%fnow(:,:,1)               ! spatially variable decay scale for high-mode wave breaking [m]
502      hcri_iwm(:,:) = sf_iwm(5)%fnow(:,:,1)               ! spatially variable decay scale for critical slope wave breaking [m]
503
504      zbot = glob_sum( 'zdfiwm', e1e2t(:,:) * ebot_iwm(:,:) )
505      zpyc = glob_sum( 'zdfiwm', e1e2t(:,:) * epyc_iwm(:,:) )
506      zcri = glob_sum( 'zdfiwm', e1e2t(:,:) * ecri_iwm(:,:) )
507
508      IF(lwp) THEN
509         WRITE(numout,*) '      High-mode wave-breaking energy:             ', zbot * 1.e-12_wp, 'TW'
510         WRITE(numout,*) '      Pycnocline-intensifed wave-breaking energy: ', zpyc * 1.e-12_wp, 'TW'
511         WRITE(numout,*) '      Critical slope wave-breaking energy:        ', zcri * 1.e-12_wp, 'TW'
512      ENDIF
513      !
514   END SUBROUTINE zdf_iwm_init
515
516   !!======================================================================
517END MODULE zdfiwm
Note: See TracBrowser for help on using the repository browser.