New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p2zexp.F90 in NEMO/branches/2019/dev_r11351_fldread_with_XIOS/src/TOP/PISCES/P2Z – NEMO

source: NEMO/branches/2019/dev_r11351_fldread_with_XIOS/src/TOP/PISCES/P2Z/p2zexp.F90 @ 13463

Last change on this file since 13463 was 13463, checked in by andmirek, 4 years ago

Ticket #2195:update to trunk 13461

  • Property svn:keywords set to Id
File size: 9.9 KB
Line 
1MODULE p2zexp
2   !!======================================================================
3   !!                         ***  MODULE p2zsed  ***
4   !! TOP :   LOBSTER Compute loss of organic matter in the sediments
5   !!======================================================================
6   !! History :    -   !  1999    (O. Aumont, C. Le Quere)  original code
7   !!              -   !  2001-05 (O. Aumont, E. Kestenare) add sediment computations
8   !!             1.0  !  2005-06 (A.-S. Kremeur) new temporal integration for sedpoc
9   !!             2.0  !  2007-12  (C. Deltel, G. Madec)  F90
10   !!             3.5  !  2012-03  (C. Ethe)  Merge PISCES-LOBSTER
11   !!----------------------------------------------------------------------
12   !!   p2z_exp        :  Compute loss of organic matter in the sediments
13   !!----------------------------------------------------------------------
14   USE oce_trc         !
15   USE trc
16   USE sms_pisces
17   USE p2zsed
18   USE lbclnk
19   USE prtctl          ! Print control for debbuging
20   USE trd_oce
21   USE trdtrc
22   USE iom
23
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC   p2z_exp   
28   PUBLIC   p2z_exp_init 
29   PUBLIC   p2z_exp_alloc
30
31   !
32   REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::   dminl     !: fraction of sinking POC released in sediments
33   REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   dmin3     !: fraction of sinking POC released at each level
34   REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::   sedpocb   !: mass of POC in sediments
35   REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::   sedpocn   !: mass of POC in sediments
36   REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::   cmask     !: Coastal mask area
37   REAL(wp)                                ::   areacot   !: surface coastal area
38
39   !! * Substitutions
40#  include "do_loop_substitute.h90"
41#  include "domzgr_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
44   !! $Id$
45   !! Software governed by the CeCILL license (see ./LICENSE)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   SUBROUTINE p2z_exp( kt, Kmm, Krhs )
50      !!---------------------------------------------------------------------
51      !!                     ***  ROUTINE p2z_exp  ***
52      !!
53      !! ** Purpose :   MODELS EXPORT OF BIOGENIC MATTER (POC ''SOFT
54      !!              TISSUE'') AND ITS DISTRIBUTION IN WATER COLUMN
55      !!
56      !! ** Method  : - IN THE SURFACE LAYER POC IS PRODUCED ACCORDING TO
57      !!              NURTRIENTS AVAILABLE AND GROWTH CONDITIONS. NUTRIENT UPTAKE
58      !!              KINETICS FOLLOW MICHAELIS-MENTON FORMULATION.
59      !!              THE TOTAL PARTICLE AMOUNT PRODUCED, IS DISTRIBUTED IN THE WATER
60      !!              COLUMN BELOW THE SURFACE LAYER.
61      !!---------------------------------------------------------------------
62      !!
63      INTEGER, INTENT( in ) ::   kt             ! ocean time-step index     
64      INTEGER, INTENT( in ) ::   Kmm, Krhs      ! time level indices
65      !!
66      INTEGER  ::   ji, jj, jk, jl, ikt
67      REAL(wp) ::   zgeolpoc, zfact, zwork, ze3t, zsedpocd, zmaskt
68      REAL(wp), DIMENSION(jpi,jpj)   ::  zsedpoca
69      CHARACTER (len=25) :: charout
70      !!---------------------------------------------------------------------
71      !
72      IF( ln_timing )   CALL timing_start('p2z_exp')
73      !
74      IF( kt == nittrc000 )   CALL p2z_exp_init( Kmm )
75
76      zsedpoca(:,:) = 0.
77
78
79      ! VERTICAL DISTRIBUTION OF NEWLY PRODUCED BIOGENIC
80      ! POC IN THE WATER COLUMN
81      ! (PARTS OF NEWLY FORMED MATTER REMAINING IN THE DIFFERENT
82      ! LAYERS IS DETERMINED BY DMIN3 DEFINED IN sms_p2z.F90
83      ! ----------------------------------------------------------------------
84      DO_3D( 0, 0, 0, 0, 1, jpkm1 )
85         ze3t = 1. / e3t(ji,jj,jk,Kmm)
86         tr(ji,jj,jk,jpno3,Krhs) = tr(ji,jj,jk,jpno3,Krhs) + ze3t * dmin3(ji,jj,jk) * xksi(ji,jj)
87      END_3D
88
89      ! Find the last level of the water column
90      ! Compute fluxes due to sinking particles (slow)
91   
92
93      zgeolpoc = 0.e0         !     Initialization
94      ! Release of nutrients from the "simple" sediment
95      DO_2D( 0, 0, 0, 0 )
96         ikt = mbkt(ji,jj) 
97         tr(ji,jj,ikt,jpno3,Krhs) = tr(ji,jj,ikt,jpno3,Krhs) + sedlam * sedpocn(ji,jj) / e3t(ji,jj,ikt,Kmm) 
98         ! Deposition of organic matter in the sediment
99         zwork = vsed * tr(ji,jj,ikt,jpdet,Kmm)
100         zsedpoca(ji,jj) = ( zwork + dminl(ji,jj) * xksi(ji,jj)   &
101            &           - sedlam * sedpocn(ji,jj) - sedlostpoc * sedpocn(ji,jj) ) * rn_Dt
102         zgeolpoc = zgeolpoc + sedlostpoc * sedpocn(ji,jj) * e1e2t(ji,jj)
103      END_2D
104
105      DO_2D( 0, 0, 0, 0 )
106         tr(ji,jj,1,jpno3,Krhs) = tr(ji,jj,1,jpno3,Krhs) + zgeolpoc * cmask(ji,jj) / areacot / e3t(ji,jj,1,Kmm)
107      END_2D
108
109      CALL lbc_lnk( 'p2zexp', sedpocn, 'T', 1.0_wp )
110 
111      ! Oa & Ek: diagnostics depending on jpdia2d !          left as example
112      IF( lk_iomput )  CALL iom_put( "SEDPOC" , sedpocn )
113
114     
115      ! Time filter and swap of arrays
116      ! ------------------------------
117      IF( l_1st_euler ) THEN        ! Euler time-stepping at first time-step
118        !                           ! (only swap)
119        sedpocn(:,:) = zsedpoca(:,:)
120        !                                             
121      ELSE
122        !
123        DO_2D( 1, 1, 1, 1 )
124           zsedpocd = zsedpoca(ji,jj) - 2. * sedpocn(ji,jj) + sedpocb(ji,jj)      ! time laplacian on tracers
125           sedpocb(ji,jj) = sedpocn(ji,jj) + rn_atfp * zsedpocd                     ! sedpocb <-- filtered sedpocn
126           sedpocn(ji,jj) = zsedpoca(ji,jj)                                       ! sedpocn <-- sedpoca
127        END_2D
128        !
129      ENDIF
130      !
131      IF( lrst_trc ) THEN
132         IF(lwp) WRITE(numout,*)
133         IF(lwp) WRITE(numout,*) 'p2z_exp : POC in sediment fields written in ocean restart file ',   &
134            &                    'at it= ', kt,' date= ', ndastp
135         IF(lwp) WRITE(numout,*) '~~~~'
136         CALL iom_rstput( kt, nitrst, numrtw, 'SEDB'//ctrcnm(jpdet), sedpocb(:,:) )
137         CALL iom_rstput( kt, nitrst, numrtw, 'SEDN'//ctrcnm(jpdet), sedpocn(:,:) )
138      ENDIF
139      !
140      IF(sn_cfctl%l_prttrc)   THEN  ! print mean trends (used for debugging)
141         WRITE(charout, FMT="('exp')")
142         CALL prt_ctl_info( charout, cdcomp = 'top' )
143         CALL prt_ctl(tab4d_1=tr(:,:,:,:,Krhs), mask1=tmask, clinfo=ctrcnm)
144      ENDIF
145      !
146      IF( ln_timing )  CALL timing_stop('p2z_exp')
147      !
148   END SUBROUTINE p2z_exp
149
150
151   SUBROUTINE p2z_exp_init( Kmm )
152      !!----------------------------------------------------------------------
153      !!                    ***  ROUTINE p4z_exp_init  ***
154      !! ** purpose :   specific initialisation for export
155      !!----------------------------------------------------------------------
156      INTEGER, INTENT(in)  ::  Kmm      ! time level index
157      INTEGER  ::   ji, jj, jk
158      REAL(wp) ::   zmaskt, zfluo, zfluu
159      REAL(wp), DIMENSION(jpi,jpj    ) :: zrro
160      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zdm0
161      !!---------------------------------------------------------------------
162      !
163      IF(lwp) THEN
164         WRITE(numout,*)
165         WRITE(numout,*) ' p2z_exp: LOBSTER export'
166         WRITE(numout,*) ' ~~~~~~~'
167         WRITE(numout,*) '  compute remineralisation-damping arrays for tracers'
168      ENDIF
169      !
170
171      ! Calculate vertical distribution of newly formed biogenic poc
172      ! in the water column in the case of max. possible bottom depth
173      ! ------------------------------------------------------------
174      zdm0 = 0._wp
175      zrro = 1._wp
176      DO_3D( 1, 1, 1, 1, jpkb, jpkm1 )
177         zfluo = ( gdepw(ji,jj,jk  ,Kmm) / gdepw(ji,jj,jpkb,Kmm) )**xhr
178         zfluu = ( gdepw(ji,jj,jk+1,Kmm) / gdepw(ji,jj,jpkb,Kmm) )**xhr
179         IF( zfluo.GT.1. )   zfluo = 1._wp
180         zdm0(ji,jj,jk) = zfluo - zfluu
181         IF( jk <= jpkb-1 )   zdm0(ji,jj,jk) = 0._wp
182         zrro(ji,jj) = zrro(ji,jj) - zdm0(ji,jj,jk)
183      END_3D
184      !
185      zdm0(:,:,jpk) = zrro(:,:)
186
187      ! Calculate vertical distribution of newly formed biogenic poc
188      ! in the water column with realistic topography (first "dry" layer
189      ! contains total fraction, which has passed to the upper layers)
190      ! ----------------------------------------------------------------------
191      dminl(:,:)   = 0._wp
192      dmin3(:,:,:) = zdm0
193      DO_3D( 1, 1, 1, 1, 1, jpk )
194         IF( tmask(ji,jj,jk) == 0._wp ) THEN
195            dminl(ji,jj) = dminl(ji,jj) + dmin3(ji,jj,jk)
196            dmin3(ji,jj,jk) = 0._wp
197         ENDIF
198      END_3D
199
200      DO_2D( 1, 1, 1, 1 )
201         IF( tmask(ji,jj,1) == 0 )   dmin3(ji,jj,1) = 0._wp
202      END_2D
203
204      ! Coastal mask
205      cmask(:,:) = 0._wp
206      DO_2D( 0, 0, 0, 0 )
207         IF( tmask(ji,jj,1) /= 0. ) THEN
208            zmaskt = tmask(ji+1,jj,1) * tmask(ji-1,jj,1) * tmask(ji,jj+1,1) * tmask(ji,jj-1,1) 
209            IF( zmaskt == 0. )   cmask(ji,jj) = 1._wp
210         END IF
211      END_2D
212      CALL lbc_lnk( 'p2zexp', cmask , 'T', 1.0_wp )      ! lateral boundary conditions on cmask   (sign unchanged)
213      areacot = glob_sum( 'p2zexp', e1e2t(:,:) * cmask(:,:) )
214      !
215      IF( ln_rsttr ) THEN
216         CALL iom_get( numrtr, jpdom_auto, 'SEDB'//ctrcnm(jpdet), sedpocb(:,:) )
217         CALL iom_get( numrtr, jpdom_auto, 'SEDN'//ctrcnm(jpdet), sedpocn(:,:) )
218      ELSE
219         sedpocb(:,:) = 0._wp
220         sedpocn(:,:) = 0._wp
221      ENDIF
222      !
223   END SUBROUTINE p2z_exp_init
224
225   INTEGER FUNCTION p2z_exp_alloc()
226      !!----------------------------------------------------------------------
227      !!                     ***  ROUTINE p2z_exp_alloc  ***
228      !!----------------------------------------------------------------------
229      ALLOCATE( cmask(jpi,jpj) , dminl(jpi,jpj) , dmin3(jpi,jpj,jpk), &
230         &      sedpocb(jpi,jpj) , sedpocn(jpi,jpj),   STAT=p2z_exp_alloc )
231      IF( p2z_exp_alloc /= 0 ) CALL ctl_stop( 'STOP', 'p2z_exp_alloc : failed to allocate arrays.' )
232      !
233   END FUNCTION p2z_exp_alloc
234
235   !!======================================================================
236END MODULE p2zexp
Note: See TracBrowser for help on using the repository browser.