New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zprod.F90 in NEMO/branches/2019/dev_r11351_fldread_with_XIOS/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2019/dev_r11351_fldread_with_XIOS/src/TOP/PISCES/P4Z/p4zprod.F90 @ 13463

Last change on this file since 13463 was 13463, checked in by andmirek, 4 years ago

Ticket #2195:update to trunk 13461
  • Property svn:keywords set to Id
File size: 21.8 KB
Line 
1MODULE p4zprod
2   !!======================================================================
3   !!                         ***  MODULE p4zprod  ***
4   !! TOP :  Growth Rate of the two phytoplanktons groups
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-05  (O. Aumont, C. Ethe) New parameterization of light limitation
9   !!----------------------------------------------------------------------
10   !!   p4z_prod       : Compute the growth Rate of the two phytoplanktons groups
11   !!   p4z_prod_init  : Initialization of the parameters for growth
12   !!   p4z_prod_alloc : Allocate variables for growth
13   !!----------------------------------------------------------------------
14   USE oce_trc         ! shared variables between ocean and passive tracers
15   USE trc             ! passive tracers common variables
16   USE sms_pisces      ! PISCES Source Minus Sink variables
17   USE p4zlim          ! Co-limitations of differents nutrients
18   USE prtctl          ! print control for debugging
19   USE iom             ! I/O manager
20
21   IMPLICIT NONE
22   PRIVATE
23
24   PUBLIC   p4z_prod         ! called in p4zbio.F90
25   PUBLIC   p4z_prod_init    ! called in trcsms_pisces.F90
26   PUBLIC   p4z_prod_alloc
27
28   REAL(wp), PUBLIC ::   pislopen     !:
29   REAL(wp), PUBLIC ::   pisloped     !:
30   REAL(wp), PUBLIC ::   xadap        !:
31   REAL(wp), PUBLIC ::   excretn      !:
32   REAL(wp), PUBLIC ::   excretd      !:
33   REAL(wp), PUBLIC ::   bresp        !:
34   REAL(wp), PUBLIC ::   chlcnm       !:
35   REAL(wp), PUBLIC ::   chlcdm       !:
36   REAL(wp), PUBLIC ::   chlcmin      !:
37   REAL(wp), PUBLIC ::   fecnm        !:
38   REAL(wp), PUBLIC ::   fecdm        !:
39   REAL(wp), PUBLIC ::   grosip       !:
40
41   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   quotan   !: proxy of N quota in Nanophyto
42   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   quotad   !: proxy of N quota in diatomee
43   
44   REAL(wp) ::   r1_rday    ! 1 / rday
45   REAL(wp) ::   texcretn   ! 1 - excretn
46   REAL(wp) ::   texcretd   ! 1 - excretd       
47
48   !! * Substitutions
49#  include "do_loop_substitute.h90"
50#  include "domzgr_substitute.h90"
51   !!----------------------------------------------------------------------
52   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
53   !! $Id$
54   !! Software governed by the CeCILL license (see ./LICENSE)
55   !!----------------------------------------------------------------------
56CONTAINS
57
58   SUBROUTINE p4z_prod( kt , knt, Kbb, Kmm, Krhs )
59      !!---------------------------------------------------------------------
60      !!                     ***  ROUTINE p4z_prod  ***
61      !!
62      !! ** Purpose :   Compute the phytoplankton production depending on
63      !!              light, temperature and nutrient availability
64      !!
65      !! ** Method  : - ???
66      !!---------------------------------------------------------------------
67      INTEGER, INTENT(in) ::   kt, knt   !
68      INTEGER, INTENT(in) ::   Kbb, Kmm, Krhs  ! time level indices
69      !
70      INTEGER  ::   ji, jj, jk
71      REAL(wp) ::   zsilfac, znanotot, zdiattot, zconctemp, zconctemp2
72      REAL(wp) ::   zratio, zmax, zsilim, ztn, zadap, zlim, zsilfac2, zsiborn
73      REAL(wp) ::   zprod, zproreg, zproreg2, zprochln, zprochld
74      REAL(wp) ::   zmaxday, zdocprod, zpislopen, zpisloped
75      REAL(wp) ::   zmxltst, zmxlday
76      REAL(wp) ::   zrum, zcodel, zargu, zval, zfeup, chlcnm_n, chlcdm_n
77      REAL(wp) ::   zfact
78      CHARACTER (len=25) :: charout
79      REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: zw2d
80      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: zw3d
81      REAL(wp), DIMENSION(jpi,jpj    ) :: zstrn, zmixnano, zmixdiat
82      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprmaxn,zprmaxd
83      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zpislopeadn, zpislopeadd, zysopt 
84      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprdia, zprbio, zprdch, zprnch   
85      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprorcan, zprorcad, zprofed, zprofen
86      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zpronewn, zpronewd
87      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zmxl_fac, zmxl_chl
88      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zpligprod1, zpligprod2
89      !!---------------------------------------------------------------------
90      !
91      IF( ln_timing )   CALL timing_start('p4z_prod')
92      !
93      !  Allocate temporary workspace
94      !
95      zprorcan  (:,:,:) = 0._wp ; zprorcad  (:,:,:) = 0._wp ; zprofed (:,:,:) = 0._wp
96      zprofen   (:,:,:) = 0._wp ; zysopt    (:,:,:) = 0._wp
97      zpronewn  (:,:,:) = 0._wp ; zpronewd  (:,:,:) = 0._wp ; zprdia  (:,:,:) = 0._wp
98      zprbio    (:,:,:) = 0._wp ; zprdch    (:,:,:) = 0._wp ; zprnch  (:,:,:) = 0._wp 
99      zmxl_fac  (:,:,:) = 0._wp ; zmxl_chl  (:,:,:) = 0._wp 
100      zpligprod1(:,:,:) = 0._wp ; zpligprod2(:,:,:) = 0._wp 
101
102      ! Computation of the optimal production
103      zprmaxn(:,:,:) = 0.8_wp * r1_rday * tgfunc(:,:,:)
104      zprmaxd(:,:,:) = zprmaxn(:,:,:)
105
106      ! compute the day length depending on latitude and the day
107      zrum = REAL( nday_year - 80, wp ) / REAL( nyear_len(1), wp )
108      zcodel = ASIN(  SIN( zrum * rpi * 2._wp ) * SIN( rad * 23.5_wp )  )
109
110      ! day length in hours
111      zstrn(:,:) = 0.
112      DO_2D( 1, 1, 1, 1 )
113         zargu = TAN( zcodel ) * TAN( gphit(ji,jj) * rad )
114         zargu = MAX( -1., MIN(  1., zargu ) )
115         zstrn(ji,jj) = MAX( 0.0, 24. - 2. * ACOS( zargu ) / rad / 15. )
116      END_2D
117
118      ! Impact of the day duration and light intermittency on phytoplankton growth
119      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
120         IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
121            zval = MAX( 1., zstrn(ji,jj) )
122            IF( gdept(ji,jj,jk,Kmm) <= hmld(ji,jj) ) THEN
123               zval = zval * MIN(1., heup_01(ji,jj) / ( hmld(ji,jj) + rtrn ))
124            ENDIF
125            zmxl_chl(ji,jj,jk) = zval / 24.
126            zmxl_fac(ji,jj,jk) = 1.5 * zval / ( 12. + zval )
127         ENDIF
128      END_3D
129
130      zprbio(:,:,:) = zprmaxn(:,:,:) * zmxl_fac(:,:,:)
131      zprdia(:,:,:) = zprmaxd(:,:,:) * zmxl_fac(:,:,:)
132
133      ! Maximum light intensity
134      WHERE( zstrn(:,:) < 1.e0 ) zstrn(:,:) = 24.
135
136      ! Computation of the P-I slope for nanos and diatoms
137      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
138         IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
139            ztn         = MAX( 0., ts(ji,jj,jk,jp_tem,Kmm) - 15. )
140            zadap       = xadap * ztn / ( 2.+ ztn )
141            zconctemp   = MAX( 0.e0 , tr(ji,jj,jk,jpdia,Kbb) - xsizedia )
142            zconctemp2  = tr(ji,jj,jk,jpdia,Kbb) - zconctemp
143            !
144            zpislopeadn(ji,jj,jk) = pislopen * ( 1.+ zadap  * EXP( -0.25 * enano(ji,jj,jk) ) )  &
145            &                   * tr(ji,jj,jk,jpnch,Kbb) /( tr(ji,jj,jk,jpphy,Kbb) * 12. + rtrn)
146            !
147            zpislopeadd(ji,jj,jk) = (pislopen * zconctemp2 + pisloped * zconctemp) / ( tr(ji,jj,jk,jpdia,Kbb) + rtrn )   &
148            &                   * tr(ji,jj,jk,jpdch,Kbb) /( tr(ji,jj,jk,jpdia,Kbb) * 12. + rtrn)
149         ENDIF
150      END_3D
151
152      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
153         IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
154             ! Computation of production function for Carbon
155             !  ---------------------------------------------
156             zpislopen = zpislopeadn(ji,jj,jk) / ( ( r1_rday + bresp * r1_rday ) &
157             &            * zmxl_fac(ji,jj,jk) * rday + rtrn)
158             zpisloped = zpislopeadd(ji,jj,jk) / ( ( r1_rday + bresp * r1_rday ) &
159             &            * zmxl_fac(ji,jj,jk) * rday + rtrn)
160             zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) )  )
161             zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) )  )
162             !  Computation of production function for Chlorophyll
163             !--------------------------------------------------
164             zpislopen = zpislopeadn(ji,jj,jk) / ( zprmaxn(ji,jj,jk) * zmxl_chl(ji,jj,jk) * rday + rtrn )
165             zpisloped = zpislopeadd(ji,jj,jk) / ( zprmaxd(ji,jj,jk) * zmxl_chl(ji,jj,jk) * rday + rtrn )
166             zprnch(ji,jj,jk) = zprmaxn(ji,jj,jk) * ( 1.- EXP( -zpislopen * enanom(ji,jj,jk) ) )
167             zprdch(ji,jj,jk) = zprmaxd(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediatm(ji,jj,jk) ) )
168         ENDIF
169      END_3D
170
171      !  Computation of a proxy of the N/C ratio
172      !  ---------------------------------------
173      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
174          zval = MIN( xnanopo4(ji,jj,jk), ( xnanonh4(ji,jj,jk) + xnanono3(ji,jj,jk) ) )   &
175          &      * zprmaxn(ji,jj,jk) / ( zprbio(ji,jj,jk) + rtrn )
176          quotan(ji,jj,jk) = MIN( 1., 0.2 + 0.8 * zval )
177          zval = MIN( xdiatpo4(ji,jj,jk), ( xdiatnh4(ji,jj,jk) + xdiatno3(ji,jj,jk) ) )   &
178          &      * zprmaxd(ji,jj,jk) / ( zprdia(ji,jj,jk) + rtrn )
179          quotad(ji,jj,jk) = MIN( 1., 0.2 + 0.8 * zval )
180      END_3D
181
182
183      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
184
185          IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
186             !    Si/C of diatoms
187             !    ------------------------
188             !    Si/C increases with iron stress and silicate availability
189             !    Si/C is arbitrariliy increased for very high Si concentrations
190             !    to mimic the very high ratios observed in the Southern Ocean (silpot2)
191            zlim  = tr(ji,jj,jk,jpsil,Kbb) / ( tr(ji,jj,jk,jpsil,Kbb) + xksi1 )
192            zsilim = MIN( zprdia(ji,jj,jk) / ( zprmaxd(ji,jj,jk) + rtrn ), xlimsi(ji,jj,jk) )
193            zsilfac = 4.4 * EXP( -4.23 * zsilim ) * MAX( 0.e0, MIN( 1., 2.2 * ( zlim - 0.5 ) )  ) + 1.e0
194            zsiborn = tr(ji,jj,jk,jpsil,Kbb) * tr(ji,jj,jk,jpsil,Kbb) * tr(ji,jj,jk,jpsil,Kbb)
195            IF (gphit(ji,jj) < -30 ) THEN
196              zsilfac2 = 1. + 2. * zsiborn / ( zsiborn + xksi2**3 )
197            ELSE
198              zsilfac2 = 1. +      zsiborn / ( zsiborn + xksi2**3 )
199            ENDIF
200            zysopt(ji,jj,jk) = grosip * zlim * zsilfac * zsilfac2
201        ENDIF
202      END_3D
203
204      !  Mixed-layer effect on production
205      !  Sea-ice effect on production
206
207      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
208         zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
209         zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
210      END_3D
211
212      ! Computation of the various production terms
213      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
214         IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
215            !  production terms for nanophyto. (C)
216            zprorcan(ji,jj,jk) = zprbio(ji,jj,jk)  * xlimphy(ji,jj,jk) * tr(ji,jj,jk,jpphy,Kbb) * rfact2
217            zpronewn(ji,jj,jk)  = zprorcan(ji,jj,jk)* xnanono3(ji,jj,jk) / ( xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk) + rtrn )
218            !
219            zratio = tr(ji,jj,jk,jpnfe,Kbb) / ( tr(ji,jj,jk,jpphy,Kbb) * fecnm + rtrn )
220            zmax   = MAX( 0., ( 1. - zratio ) / ABS( 1.05 - zratio ) ) 
221            zprofen(ji,jj,jk) = fecnm * zprmaxn(ji,jj,jk) * ( 1.0 - fr_i(ji,jj) )  &
222            &             * ( 4. - 4.5 * xlimnfe(ji,jj,jk) / ( xlimnfe(ji,jj,jk) + 0.5 ) )    &
223            &             * biron(ji,jj,jk) / ( biron(ji,jj,jk) + concnfe(ji,jj,jk) )  &
224            &             * zmax * tr(ji,jj,jk,jpphy,Kbb) * rfact2
225            !  production terms for diatoms (C)
226            zprorcad(ji,jj,jk) = zprdia(ji,jj,jk) * xlimdia(ji,jj,jk) * tr(ji,jj,jk,jpdia,Kbb) * rfact2
227            zpronewd(ji,jj,jk) = zprorcad(ji,jj,jk) * xdiatno3(ji,jj,jk) / ( xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk) + rtrn )
228            !
229            zratio = tr(ji,jj,jk,jpdfe,Kbb) / ( tr(ji,jj,jk,jpdia,Kbb) * fecdm + rtrn )
230            zmax   = MAX( 0., ( 1. - zratio ) / ABS( 1.05 - zratio ) ) 
231            zprofed(ji,jj,jk) = fecdm * zprmaxd(ji,jj,jk) * ( 1.0 - fr_i(ji,jj) )  &
232            &             * ( 4. - 4.5 * xlimdfe(ji,jj,jk) / ( xlimdfe(ji,jj,jk) + 0.5 ) )    &
233            &             * biron(ji,jj,jk) / ( biron(ji,jj,jk) + concdfe(ji,jj,jk) )  &
234            &             * zmax * tr(ji,jj,jk,jpdia,Kbb) * rfact2
235         ENDIF
236      END_3D
237
238      ! Computation of the chlorophyll production terms
239      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
240         IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
241            !  production terms for nanophyto. ( chlorophyll )
242            znanotot = enanom(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
243            zprod    = rday * zprorcan(ji,jj,jk) * zprnch(ji,jj,jk) * xlimphy(ji,jj,jk)
244            zprochln = chlcmin * 12. * zprorcan (ji,jj,jk)
245            chlcnm_n   = MIN ( chlcnm, ( chlcnm / (1. - 1.14 / 43.4 *ts(ji,jj,jk,jp_tem,Kmm))) * (1. - 1.14 / 43.4 * 20.))
246            zprochln = zprochln + (chlcnm_n-chlcmin) * 12. * zprod / &
247                                  & (  zpislopeadn(ji,jj,jk) * znanotot +rtrn)
248            !  production terms for diatoms ( chlorophyll )
249            zdiattot = ediatm(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
250            zprod    = rday * zprorcad(ji,jj,jk) * zprdch(ji,jj,jk) * xlimdia(ji,jj,jk)
251            zprochld = chlcmin * 12. * zprorcad(ji,jj,jk)
252            chlcdm_n   = MIN ( chlcdm, ( chlcdm / (1. - 1.14 / 43.4 * ts(ji,jj,jk,jp_tem,Kmm))) * (1. - 1.14 / 43.4 * 20.))
253            zprochld = zprochld + (chlcdm_n-chlcmin) * 12. * zprod / &
254                                  & ( zpislopeadd(ji,jj,jk) * zdiattot +rtrn )
255            !   Update the arrays TRA which contain the Chla sources and sinks
256            tr(ji,jj,jk,jpnch,Krhs) = tr(ji,jj,jk,jpnch,Krhs) + zprochln * texcretn
257            tr(ji,jj,jk,jpdch,Krhs) = tr(ji,jj,jk,jpdch,Krhs) + zprochld * texcretd
258         ENDIF
259      END_3D
260
261      !   Update the arrays TRA which contain the biological sources and sinks
262      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
263        IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
264           zproreg  = zprorcan(ji,jj,jk) - zpronewn(ji,jj,jk)
265           zproreg2 = zprorcad(ji,jj,jk) - zpronewd(ji,jj,jk)
266           zdocprod = excretd * zprorcad(ji,jj,jk) + excretn * zprorcan(ji,jj,jk)
267           tr(ji,jj,jk,jppo4,Krhs) = tr(ji,jj,jk,jppo4,Krhs) - zprorcan(ji,jj,jk) - zprorcad(ji,jj,jk)
268           tr(ji,jj,jk,jpno3,Krhs) = tr(ji,jj,jk,jpno3,Krhs) - zpronewn(ji,jj,jk) - zpronewd(ji,jj,jk)
269           tr(ji,jj,jk,jpnh4,Krhs) = tr(ji,jj,jk,jpnh4,Krhs) - zproreg - zproreg2
270           tr(ji,jj,jk,jpphy,Krhs) = tr(ji,jj,jk,jpphy,Krhs) + zprorcan(ji,jj,jk) * texcretn
271           tr(ji,jj,jk,jpnfe,Krhs) = tr(ji,jj,jk,jpnfe,Krhs) + zprofen(ji,jj,jk) * texcretn
272           tr(ji,jj,jk,jpdia,Krhs) = tr(ji,jj,jk,jpdia,Krhs) + zprorcad(ji,jj,jk) * texcretd
273           tr(ji,jj,jk,jpdfe,Krhs) = tr(ji,jj,jk,jpdfe,Krhs) + zprofed(ji,jj,jk) * texcretd
274           tr(ji,jj,jk,jpdsi,Krhs) = tr(ji,jj,jk,jpdsi,Krhs) + zprorcad(ji,jj,jk) * zysopt(ji,jj,jk) * texcretd
275           tr(ji,jj,jk,jpdoc,Krhs) = tr(ji,jj,jk,jpdoc,Krhs) + zdocprod
276           tr(ji,jj,jk,jpoxy,Krhs) = tr(ji,jj,jk,jpoxy,Krhs) + o2ut * ( zproreg + zproreg2) &
277           &                   + ( o2ut + o2nit ) * ( zpronewn(ji,jj,jk) + zpronewd(ji,jj,jk) )
278           !
279           zfeup = texcretn * zprofen(ji,jj,jk) + texcretd * zprofed(ji,jj,jk)
280           tr(ji,jj,jk,jpfer,Krhs) = tr(ji,jj,jk,jpfer,Krhs) - zfeup
281           tr(ji,jj,jk,jpsil,Krhs) = tr(ji,jj,jk,jpsil,Krhs) - texcretd * zprorcad(ji,jj,jk) * zysopt(ji,jj,jk)
282           tr(ji,jj,jk,jpdic,Krhs) = tr(ji,jj,jk,jpdic,Krhs) - zprorcan(ji,jj,jk) - zprorcad(ji,jj,jk)
283           tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) + rno3 * ( zpronewn(ji,jj,jk) + zpronewd(ji,jj,jk) ) &
284           &                                         - rno3 * ( zproreg + zproreg2 )
285        ENDIF
286      END_3D
287     !
288     IF( ln_ligand ) THEN
289         zpligprod1(:,:,:) = 0._wp    ;    zpligprod2(:,:,:) = 0._wp
290         DO_3D( 1, 1, 1, 1, 1, jpkm1 )
291           IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
292              zdocprod = excretd * zprorcad(ji,jj,jk) + excretn * zprorcan(ji,jj,jk)
293              zfeup    = texcretn * zprofen(ji,jj,jk) + texcretd * zprofed(ji,jj,jk)
294              tr(ji,jj,jk,jplgw,Krhs) = tr(ji,jj,jk,jplgw,Krhs) + zdocprod * ldocp - zfeup * plig(ji,jj,jk) * lthet
295              zpligprod1(ji,jj,jk) = zdocprod * ldocp
296              zpligprod2(ji,jj,jk) = zfeup * plig(ji,jj,jk) * lthet
297           ENDIF
298         END_3D
299     ENDIF
300
301
302    ! Total primary production per year
303    IF( iom_use( "tintpp" ) .OR. ( ln_check_mass .AND. kt == nitend .AND. knt == nrdttrc )  )  &
304         & tpp = glob_sum( 'p4zprod', ( zprorcan(:,:,:) + zprorcad(:,:,:) ) * cvol(:,:,:) )
305
306    IF( lk_iomput .AND.  knt == nrdttrc ) THEN
307       zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
308       !
309       CALL iom_put( "PPPHYN"  , zprorcan(:,:,:) * zfact * tmask(:,:,:) )  ! primary production by nanophyto
310       CALL iom_put( "PPPHYD"  , zprorcad(:,:,:) * zfact * tmask(:,:,:)   ) ! primary production by diatomes
311       CALL iom_put( "PPNEWN"  , zpronewn(:,:,:) * zfact * tmask(:,:,:)    ) ! new primary production by nanophyto
312       CALL iom_put( "PPNEWD"  , zpronewd(:,:,:) * zfact * tmask(:,:,:)   ) ! new primary production by diatomes
313       CALL iom_put( "PBSi"    , zprorcad(:,:,:) * zfact * tmask(:,:,:) * zysopt(:,:,:)  ) ! biogenic silica production
314       CALL iom_put( "PFeN"    , zprofen(:,:,:) * zfact * tmask(:,:,:)  ) ! biogenic iron production by nanophyto
315       CALL iom_put( "PFeD"    , zprofed(:,:,:) * zfact * tmask(:,:,:)  ) ! biogenic iron production by  diatomes
316       IF( ln_ligand ) THEN
317         CALL iom_put( "LPRODP"  , zpligprod1(:,:,:) * 1e9 * zfact * tmask(:,:,:) )
318         CALL iom_put( "LDETP"   , zpligprod2(:,:,:) * 1e9 * zfact * tmask(:,:,:) )
319       ENDIF
320       CALL iom_put( "Mumax"   , zprmaxn(:,:,:) * tmask(:,:,:)  ) ! Maximum growth rate
321       CALL iom_put( "MuN"     , zprbio(:,:,:) * xlimphy(:,:,:) * tmask(:,:,:) ) ! Realized growth rate for nanophyto
322       CALL iom_put( "MuD"     , zprdia(:,:,:) * xlimdia(:,:,:) * tmask(:,:,:) ) ! Realized growth rate for diatoms
323       CALL iom_put( "LNlight" , zprbio (:,:,:) / (zprmaxn(:,:,:) + rtrn) * tmask(:,:,:)  )  ! light limitation term
324       CALL iom_put( "LDlight" , zprdia (:,:,:) / (zprmaxd(:,:,:) + rtrn) * tmask(:,:,:)   )
325       CALL iom_put( "TPP"     , ( zprorcan(:,:,:) + zprorcad(:,:,:) ) * zfact * tmask(:,:,:)  )  ! total primary production
326       CALL iom_put( "TPNEW"   , ( zpronewn(:,:,:) + zpronewd(:,:,:) ) * zfact * tmask(:,:,:)  ) ! total new production
327       CALL iom_put( "TPBFE"   , ( zprofen(:,:,:) + zprofed(:,:,:) ) * zfact * tmask(:,:,:)  )  ! total biogenic iron production
328       CALL iom_put( "tintpp"  , tpp * zfact )  !  global total integrated primary production molC/s
329     ENDIF
330
331     IF(sn_cfctl%l_prttrc)   THEN  ! print mean trends (used for debugging)
332         WRITE(charout, FMT="('prod')")
333         CALL prt_ctl_info( charout, cdcomp = 'top' )
334         CALL prt_ctl(tab4d_1=tr(:,:,:,:,Krhs), mask1=tmask, clinfo=ctrcnm)
335     ENDIF
336      !
337      IF( ln_timing )  CALL timing_stop('p4z_prod')
338      !
339   END SUBROUTINE p4z_prod
340
341
342   SUBROUTINE p4z_prod_init
343      !!----------------------------------------------------------------------
344      !!                  ***  ROUTINE p4z_prod_init  ***
345      !!
346      !! ** Purpose :   Initialization of phytoplankton production parameters
347      !!
348      !! ** Method  :   Read the nampisprod namelist and check the parameters
349      !!      called at the first timestep (nittrc000)
350      !!
351      !! ** input   :   Namelist nampisprod
352      !!----------------------------------------------------------------------
353      INTEGER ::   ios   ! Local integer
354      !
355      NAMELIST/namp4zprod/ pislopen, pisloped, xadap, bresp, excretn, excretd,  &
356         &                 chlcnm, chlcdm, chlcmin, fecnm, fecdm, grosip
357      !!----------------------------------------------------------------------
358      !
359      IF(lwp) THEN                         ! control print
360         WRITE(numout,*)
361         WRITE(numout,*) 'p4z_prod_init : phytoplankton growth'
362         WRITE(numout,*) '~~~~~~~~~~~~~'
363      ENDIF
364      !
365      READ  ( numnatp_ref, namp4zprod, IOSTAT = ios, ERR = 901)
366901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namp4zprod in reference namelist' )
367      READ  ( numnatp_cfg, namp4zprod, IOSTAT = ios, ERR = 902 )
368902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namp4zprod in configuration namelist' )
369      IF(lwm) WRITE( numonp, namp4zprod )
370
371      IF(lwp) THEN                         ! control print
372         WRITE(numout,*) '   Namelist : namp4zprod'
373         WRITE(numout,*) '      mean Si/C ratio                           grosip       =', grosip
374         WRITE(numout,*) '      P-I slope                                 pislopen     =', pislopen
375         WRITE(numout,*) '      Acclimation factor to low light           xadap        =', xadap
376         WRITE(numout,*) '      excretion ratio of nanophytoplankton      excretn      =', excretn
377         WRITE(numout,*) '      excretion ratio of diatoms                excretd      =', excretd
378         WRITE(numout,*) '      basal respiration in phytoplankton        bresp        =', bresp
379         WRITE(numout,*) '      Maximum Chl/C in phytoplankton            chlcmin      =', chlcmin
380         WRITE(numout,*) '      P-I slope  for diatoms                    pisloped     =', pisloped
381         WRITE(numout,*) '      Minimum Chl/C in nanophytoplankton        chlcnm       =', chlcnm
382         WRITE(numout,*) '      Minimum Chl/C in diatoms                  chlcdm       =', chlcdm
383         WRITE(numout,*) '      Maximum Fe/C in nanophytoplankton         fecnm        =', fecnm
384         WRITE(numout,*) '      Minimum Fe/C in diatoms                   fecdm        =', fecdm
385      ENDIF
386      !
387      r1_rday   = 1._wp / rday 
388      texcretn  = 1._wp - excretn
389      texcretd  = 1._wp - excretd
390      tpp       = 0._wp
391      !
392   END SUBROUTINE p4z_prod_init
393
394
395   INTEGER FUNCTION p4z_prod_alloc()
396      !!----------------------------------------------------------------------
397      !!                     ***  ROUTINE p4z_prod_alloc  ***
398      !!----------------------------------------------------------------------
399      ALLOCATE( quotan(jpi,jpj,jpk), quotad(jpi,jpj,jpk), STAT = p4z_prod_alloc )
400      !
401      IF( p4z_prod_alloc /= 0 ) CALL ctl_stop( 'STOP', 'p4z_prod_alloc : failed to allocate arrays.' )
402      !
403   END FUNCTION p4z_prod_alloc
404
405   !!======================================================================
406END MODULE p4zprod
Note: See TracBrowser for help on using the repository browser.