New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
usrdef_istate.F90 in NEMO/branches/2019/dev_r11470_HPC_12_mpi3/tests/BENCH/MY_SRC – NEMO

source: NEMO/branches/2019/dev_r11470_HPC_12_mpi3/tests/BENCH/MY_SRC/usrdef_istate.F90 @ 11799

Last change on this file since 11799 was 11799, checked in by mocavero, 4 years ago

Update the branch to v4.0.1 of the trunk

File size: 4.4 KB
Line 
1MODULE usrdef_istate
2   !!======================================================================
3   !!                     ***  MODULE usrdef_istate   ***
4   !!
5   !!                      ===  BENCH configuration  ===
6   !!
7   !! User defined : set the initial state of a user configuration
8   !!======================================================================
9   !! History :  NEMO !
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!  usr_def_istate : initial state in Temperature and salinity
14   !!----------------------------------------------------------------------
15   USE par_oce        ! ocean space and time domain
16   USE dom_oce       
17   USE phycst         ! physical constants
18   !
19   USE in_out_manager ! I/O manager
20   USE lib_mpp        ! MPP library
21   USE lbclnk          ! lateral boundary conditions - mpp exchanges
22   !   
23   USE usrdef_nam
24   
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   usr_def_istate   ! called by istate.F90
29
30   !!----------------------------------------------------------------------
31   !! NEMO/OPA 4.0 , NEMO Consortium (2016)
32   !! $Id$
33   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
34   !!----------------------------------------------------------------------
35CONTAINS
36 
37   SUBROUTINE usr_def_istate( pdept, ptmask, pts, pu, pv, pssh )
38      !!----------------------------------------------------------------------
39      !!                   ***  ROUTINE usr_def_istate  ***
40      !!
41      !! ** Purpose :   Initialization of the dynamics and tracers
42      !!                Here BENCH configuration
43      !!
44      !! ** Method  :   Set a gaussian anomaly of pressure and associated
45      !!                geostrophic velocities
46      !!----------------------------------------------------------------------
47      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(in   ) ::   pdept   ! depth of t-point               [m]
48      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(in   ) ::   ptmask  ! t-point ocean mask             [m]
49      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(  out) ::   pts     ! T & S fields      [Celsius ; g/kg]
50      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(  out) ::   pu      ! i-component of the velocity  [m/s]
51      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(  out) ::   pv      ! j-component of the velocity  [m/s]
52      REAL(wp), DIMENSION(jpi,jpj)         , INTENT(  out) ::   pssh    ! sea-surface height
53      !
54      REAL(wp), DIMENSION(jpi,jpj) ::   z2d   ! 2D workspace
55      REAL(wp) ::   zfact
56      INTEGER  ::   ji, jj, jk
57      !!----------------------------------------------------------------------
58      !
59      IF(lwp) WRITE(numout,*)
60      IF(lwp) WRITE(numout,*) 'usr_def_istate : BENCH configuration, analytical definition of initial state'
61      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~   '
62      !
63      ! define unique value on each point. z2d ranging from 0.05 to -0.05
64      DO jj = 1, jpj
65         DO ji = 1, jpi
66            z2d(ji,jj) = 0.1 * ( 0.5 - REAL( mig(ji) + mjg(jj) * jpiglo, wp ) / REAL( jpiglo * jpjglo, wp ) )
67         ENDDO
68      ENDDO
69      !
70      ! sea level:
71      pssh(:,:) = z2d(:,:)                                                ! +/- 0.05 m
72      !
73      DO jk = 1, jpk
74         zfact = REAL(jk-1,wp) / REAL(jpk-1,wp)   ! 0 to 1 to add a basic stratification
75         ! temperature choosen to lead to ~50% ice at the beginning if rn_thres_sst = 0.5
76         pts(:,:,jk,jp_tem) = 20._wp*z2d(:,:) - 1._wp - 0.5_wp * zfact    ! -1 to -1.5 +/-1.0 degG
77         ! salinity: 
78         pts(:,:,jk,jp_sal) = 30._wp + 1._wp * zfact + z2d(:,:)           ! 30 to 31 +/- 0.05 psu
79         ! velocities:
80         pu(:,:,jk) = z2d(:,:) * 0.1_wp                                   ! +/- 0.005  m/s
81         pv(:,:,jk) = z2d(:,:) * 0.01_wp                                  ! +/- 0.0005 m/s
82      ENDDO
83      !
84      CALL lbc_lnk('usrdef_istate', pssh, 'T',  1. )            ! apply boundary conditions
85      CALL lbc_lnk('usrdef_istate',  pts, 'T',  1. )            ! apply boundary conditions
86      CALL lbc_lnk('usrdef_istate',   pu, 'U', -1. )            ! apply boundary conditions
87      CALL lbc_lnk('usrdef_istate',   pv, 'V', -1. )            ! apply boundary conditions
88     
89   END SUBROUTINE usr_def_istate
90
91   !!======================================================================
92END MODULE usrdef_istate
Note: See TracBrowser for help on using the repository browser.