New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zmeso.F90 in NEMO/branches/2019/dev_r11514_HPC-02_single-core-extrahalo/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2019/dev_r11514_HPC-02_single-core-extrahalo/src/TOP/PISCES/P4Z/p4zmeso.F90 @ 11692

Last change on this file since 11692 was 11692, checked in by francesca, 4 years ago

Update branch to integrate the development starting from the current v4.01 ready trunk

  • Property svn:keywords set to Id
File size: 18.5 KB
Line 
1MODULE p4zmeso
2   !!======================================================================
3   !!                         ***  MODULE p4zmeso  ***
4   !! TOP :   PISCES Compute the sources/sinks for mesozooplankton
5   !!======================================================================
6   !! History :   1.0  !  2002     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!----------------------------------------------------------------------
10   !!   p4z_meso       : Compute the sources/sinks for mesozooplankton
11   !!   p4z_meso_init  : Initialization of the parameters for mesozooplankton
12   !!----------------------------------------------------------------------
13   USE oce_trc         ! shared variables between ocean and passive tracers
14   USE trc             ! passive tracers common variables
15   USE sms_pisces      ! PISCES Source Minus Sink variables
16   USE p4zprod         ! production
17   USE prtctl_trc      ! print control for debugging
18   USE iom             ! I/O manager
19
20   IMPLICIT NONE
21   PRIVATE
22
23   PUBLIC   p4z_meso              ! called in p4zbio.F90
24   PUBLIC   p4z_meso_init         ! called in trcsms_pisces.F90
25
26   REAL(wp), PUBLIC ::  part2        !: part of calcite not dissolved in mesozoo guts
27   REAL(wp), PUBLIC ::  xpref2d      !: mesozoo preference for diatoms
28   REAL(wp), PUBLIC ::  xpref2n      !: mesozoo preference for nanophyto
29   REAL(wp), PUBLIC ::  xpref2z      !: mesozoo preference for microzooplankton
30   REAL(wp), PUBLIC ::  xpref2c      !: mesozoo preference for POC
31   REAL(wp), PUBLIC ::  xthresh2zoo  !: zoo feeding threshold for mesozooplankton
32   REAL(wp), PUBLIC ::  xthresh2dia  !: diatoms feeding threshold for mesozooplankton
33   REAL(wp), PUBLIC ::  xthresh2phy  !: nanophyto feeding threshold for mesozooplankton
34   REAL(wp), PUBLIC ::  xthresh2poc  !: poc feeding threshold for mesozooplankton
35   REAL(wp), PUBLIC ::  xthresh2     !: feeding threshold for mesozooplankton
36   REAL(wp), PUBLIC ::  resrat2      !: exsudation rate of mesozooplankton
37   REAL(wp), PUBLIC ::  mzrat2       !: microzooplankton mortality rate
38   REAL(wp), PUBLIC ::  grazrat2     !: maximal mesozoo grazing rate
39   REAL(wp), PUBLIC ::  xkgraz2      !: non assimilated fraction of P by mesozoo
40   REAL(wp), PUBLIC ::  unass2       !: Efficicency of mesozoo growth
41   REAL(wp), PUBLIC ::  sigma2       !: Fraction of mesozoo excretion as DOM
42   REAL(wp), PUBLIC ::  epsher2      !: growth efficiency
43   REAL(wp), PUBLIC ::  epsher2min   !: minimum growth efficiency at high food for grazing 2
44   REAL(wp), PUBLIC ::  grazflux     !: mesozoo flux feeding rate
45
46   !!----------------------------------------------------------------------
47   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
48   !! $Id$
49   !! Software governed by the CeCILL license (see ./LICENSE)
50   !!----------------------------------------------------------------------
51CONTAINS
52
53   SUBROUTINE p4z_meso( kt, knt )
54      !!---------------------------------------------------------------------
55      !!                     ***  ROUTINE p4z_meso  ***
56      !!
57      !! ** Purpose :   Compute the sources/sinks for mesozooplankton
58      !!
59      !! ** Method  : - ???
60      !!---------------------------------------------------------------------
61      INTEGER, INTENT(in) ::   kt, knt   ! ocean time step and ???
62      !
63      INTEGER  :: ji, jj, jk
64      REAL(wp) :: zcompadi, zcompaph, zcompapoc, zcompaz, zcompam
65      REAL(wp) :: zgraze2 , zdenom, zdenom2
66      REAL(wp) :: zfact   , zfood, zfoodlim, zproport, zbeta
67      REAL(wp) :: zmortzgoc, zfrac, zfracfe, zratio, zratio2, zfracal, zgrazcal
68      REAL(wp) :: zepsherf, zepshert, zepsherv, zgrarsig, zgraztotc, zgraztotn, zgraztotf
69      REAL(wp) :: zgrarem2, zgrafer2, zgrapoc2, zprcaca, zmortz, zgrasrat, zgrasratn
70      REAL(wp) :: zrespz, ztortz, zgrazd, zgrazz, zgrazpof
71      REAL(wp) :: zgrazn, zgrazpoc, zgraznf, zgrazf
72      REAL(wp) :: zgrazfffp, zgrazfffg, zgrazffep, zgrazffeg
73      CHARACTER (len=25) :: charout
74      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zgrazing, zfezoo2
75      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   zw3d, zz2ligprod
76      !!---------------------------------------------------------------------
77      !
78      IF( ln_timing )   CALL timing_start('p4z_meso')
79      !
80      zgrazing(:,:,:) = 0._wp
81      zfezoo2 (:,:,:) = 0._wp
82      !
83      IF (ln_ligand) THEN
84         ALLOCATE( zz2ligprod(jpi,jpj,jpk) )
85         zz2ligprod(:,:,:) = 0._wp
86      ENDIF
87      !
88      DO jk = 1, jpkm1
89         DO jj = 1, jpj
90            DO ji = 1, jpi
91               zcompam   = MAX( ( trb(ji,jj,jk,jpmes) - 1.e-9 ), 0.e0 )
92               zfact     = xstep * tgfunc2(ji,jj,jk) * zcompam
93
94               !  Respiration rates of both zooplankton
95               !  -------------------------------------
96               zrespz    = resrat2 * zfact * ( trb(ji,jj,jk,jpmes) / ( xkmort + trb(ji,jj,jk,jpmes) )  &
97               &           + 3. * nitrfac(ji,jj,jk) )
98
99               !  Zooplankton mortality. A square function has been selected with
100               !  no real reason except that it seems to be more stable and may mimic predation
101               !  ---------------------------------------------------------------
102               ztortz    = mzrat2 * 1.e6 * zfact * trb(ji,jj,jk,jpmes)  * (1. - nitrfac(ji,jj,jk) )
103               !
104               zcompadi  = MAX( ( trb(ji,jj,jk,jpdia) - xthresh2dia ), 0.e0 )
105               zcompaz   = MAX( ( trb(ji,jj,jk,jpzoo) - xthresh2zoo ), 0.e0 )
106               zcompapoc = MAX( ( trb(ji,jj,jk,jppoc) - xthresh2poc ), 0.e0 )
107               ! Size effect of nanophytoplankton on grazing : the smaller it is, the less prone
108               ! it is to predation by mesozooplankton
109               ! -------------------------------------------------------------------------------
110               zcompaph  = MAX( ( trb(ji,jj,jk,jpphy) - xthresh2phy ), 0.e0 ) &
111                  &      * MIN(1., MAX( 0., ( quotan(ji,jj,jk) - 0.2) / 0.3 ) )
112
113               !   Mesozooplankton grazing
114               !   ------------------------
115               zfood     = xpref2d * zcompadi + xpref2z * zcompaz + xpref2n * zcompaph + xpref2c * zcompapoc 
116               zfoodlim  = MAX( 0., zfood - MIN( 0.5 * zfood, xthresh2 ) )
117               zdenom    = zfoodlim / ( xkgraz2 + zfoodlim )
118               zdenom2   = zdenom / ( zfood + rtrn )
119               zgraze2   = grazrat2 * xstep * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jpmes) * (1. - nitrfac(ji,jj,jk)) 
120
121               zgrazd    = zgraze2  * xpref2d  * zcompadi  * zdenom2 
122               zgrazz    = zgraze2  * xpref2z  * zcompaz   * zdenom2 
123               zgrazn    = zgraze2  * xpref2n  * zcompaph  * zdenom2 
124               zgrazpoc  = zgraze2  * xpref2c  * zcompapoc * zdenom2 
125
126               zgraznf   = zgrazn   * trb(ji,jj,jk,jpnfe) / ( trb(ji,jj,jk,jpphy) + rtrn)
127               zgrazf    = zgrazd   * trb(ji,jj,jk,jpdfe) / ( trb(ji,jj,jk,jpdia) + rtrn)
128               zgrazpof  = zgrazpoc * trb(ji,jj,jk,jpsfe) / ( trb(ji,jj,jk,jppoc) + rtrn)
129
130               !  Mesozooplankton flux feeding on GOC
131               !  ----------------------------------
132               zgrazffeg = grazflux  * xstep * wsbio4(ji,jj,jk)      &
133               &           * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jpgoc) * trb(ji,jj,jk,jpmes) &
134               &           * (1. - nitrfac(ji,jj,jk))
135               zgrazfffg = zgrazffeg * trb(ji,jj,jk,jpbfe) / (trb(ji,jj,jk,jpgoc) + rtrn)
136               zgrazffep = grazflux  * xstep *  wsbio3(ji,jj,jk)     &
137               &           * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jppoc) * trb(ji,jj,jk,jpmes) &
138               &           * (1. - nitrfac(ji,jj,jk))
139               zgrazfffp = zgrazffep * trb(ji,jj,jk,jpsfe) / (trb(ji,jj,jk,jppoc) + rtrn)
140               !
141               zgraztotc = zgrazd + zgrazz + zgrazn + zgrazpoc + zgrazffep + zgrazffeg
142               ! Compute the proportion of filter feeders
143               zproport  = (zgrazffep + zgrazffeg)/(rtrn + zgraztotc)
144               ! Compute fractionation of aggregates. It is assumed that
145               ! diatoms based aggregates are more prone to fractionation
146               ! since they are more porous (marine snow instead of fecal pellets)
147               zratio    = trb(ji,jj,jk,jpgsi) / ( trb(ji,jj,jk,jpgoc) + rtrn )
148               zratio2   = zratio * zratio
149               zfrac     = zproport * grazflux  * xstep * wsbio4(ji,jj,jk)      &
150               &          * trb(ji,jj,jk,jpgoc) * trb(ji,jj,jk,jpmes)          &
151               &          * ( 0.2 + 3.8 * zratio2 / ( 1.**2 + zratio2 ) )
152               zfracfe   = zfrac * trb(ji,jj,jk,jpbfe) / (trb(ji,jj,jk,jpgoc) + rtrn)
153
154               zgrazffep = zproport * zgrazffep
155               zgrazffeg = zproport * zgrazffeg
156               zgrazfffp = zproport * zgrazfffp
157               zgrazfffg = zproport * zgrazfffg
158               zgraztotc = zgrazd + zgrazz + zgrazn + zgrazpoc + zgrazffep + zgrazffeg
159               zgraztotn = zgrazd * quotad(ji,jj,jk) + zgrazz + zgrazn * quotan(ji,jj,jk)   &
160               &   + zgrazpoc + zgrazffep + zgrazffeg
161               zgraztotf = zgrazf + zgraznf + zgrazz * ferat3 + zgrazpof + zgrazfffp + zgrazfffg
162
163               ! Total grazing ( grazing by microzoo is already computed in p4zmicro )
164               zgrazing(ji,jj,jk) = zgraztotc
165
166               !    Mesozooplankton efficiency
167               !    --------------------------
168               zgrasrat  =  ( zgraztotf + rtrn )/ ( zgraztotc + rtrn )
169               zgrasratn =  ( zgraztotn + rtrn )/ ( zgraztotc + rtrn )
170               zepshert  = MIN( 1., zgrasratn, zgrasrat / ferat3)
171               zbeta     = MAX(0., (epsher2 - epsher2min) )
172               zepsherf  = epsher2min + zbeta / ( 1.0 + 0.04E6 * 12. * zfood * zbeta ) 
173               zepsherv  = zepsherf * zepshert 
174
175               zgrarem2  = zgraztotc * ( 1. - zepsherv - unass2 ) &
176               &         + ( 1. - epsher2 - unass2 ) / ( 1. - epsher2 ) * ztortz
177               zgrafer2  = zgraztotc * MAX( 0. , ( 1. - unass2 ) * zgrasrat - ferat3 * zepsherv )    &
178               &         + ferat3 * ( ( 1. - epsher2 - unass2 ) /( 1. - epsher2 ) * ztortz )
179               zgrapoc2  = zgraztotc * unass2
180
181               !   Update the arrays TRA which contain the biological sources and sinks
182               zgrarsig  = zgrarem2 * sigma2
183               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zgrarsig
184               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zgrarsig
185               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zgrarem2 - zgrarsig
186               !
187               IF( ln_ligand ) THEN
188                  tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) + (zgrarem2 - zgrarsig) * ldocz
189                  zz2ligprod(ji,jj,jk) = (zgrarem2 - zgrarsig) * ldocz
190               ENDIF
191               !
192               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2ut * zgrarsig
193               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zgrafer2
194               zfezoo2(ji,jj,jk)   = zgrafer2
195               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrarsig
196               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * zgrarsig             
197
198               zmortz = ztortz + zrespz
199               zmortzgoc = unass2 / ( 1. - epsher2 ) * ztortz + zrespz
200               tra(ji,jj,jk,jpmes) = tra(ji,jj,jk,jpmes) - zmortz + zepsherv * zgraztotc 
201               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zgrazd
202               tra(ji,jj,jk,jpzoo) = tra(ji,jj,jk,jpzoo) - zgrazz
203               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zgrazn
204               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zgrazn * trb(ji,jj,jk,jpnch) / ( trb(ji,jj,jk,jpphy) + rtrn )
205               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zgrazd * trb(ji,jj,jk,jpdch) / ( trb(ji,jj,jk,jpdia) + rtrn )
206               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) - zgrazd * trb(ji,jj,jk,jpdsi) / ( trb(ji,jj,jk,jpdia) + rtrn )
207               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) + zgrazd * trb(ji,jj,jk,jpdsi) / ( trb(ji,jj,jk,jpdia) + rtrn )
208               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zgraznf
209               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zgrazf
210
211               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) - zgrazpoc - zgrazffep + zfrac
212               prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + zfrac
213               conspoc(ji,jj,jk) = conspoc(ji,jj,jk) - zgrazpoc - zgrazffep
214               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zmortzgoc - zgrazffeg + zgrapoc2 - zfrac
215               prodgoc(ji,jj,jk) = prodgoc(ji,jj,jk) + zmortzgoc + zgrapoc2
216               consgoc(ji,jj,jk) = consgoc(ji,jj,jk) - zgrazffeg - zfrac
217               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) - zgrazpof - zgrazfffp + zfracfe
218               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + ferat3 * zmortzgoc - zgrazfffg     &
219                 &                + zgraztotf * unass2 - zfracfe
220               zfracal = trb(ji,jj,jk,jpcal) / (trb(ji,jj,jk,jppoc) + trb(ji,jj,jk,jpgoc) + rtrn )
221               zgrazcal = (zgrazffeg + zgrazpoc) * (1. - part2) * zfracal
222               ! calcite production
223               zprcaca = xfracal(ji,jj,jk) * zgrazn
224               prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
225               !
226               zprcaca = part2 * zprcaca
227               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrazcal - zprcaca
228               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * ( zgrazcal + zprcaca )
229               tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) - zgrazcal + zprcaca
230            END DO
231         END DO
232      END DO
233      !
234      IF( lk_iomput .AND. knt == nrdttrc ) THEN
235         ALLOCATE( zw3d(jpi,jpj,jpk) )
236         IF( iom_use( "GRAZ2" ) ) THEN
237            zw3d(:,:,:) = zgrazing(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:)  !   Total grazing of phyto by zooplankton
238            CALL iom_put( "GRAZ2", zw3d )
239         ENDIF
240         IF( iom_use( "PCAL" ) ) THEN
241            zw3d(:,:,:) = prodcal(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:)   !  Calcite production
242            CALL iom_put( "PCAL", zw3d ) 
243         ENDIF
244         IF( iom_use( "FEZOO2" ) ) THEN
245            zw3d(:,:,:) = zfezoo2(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:)   !
246            CALL iom_put( "FEZOO2", zw3d )
247         ENDIF
248         IF( iom_use( "LPRODZ2" ) .AND. ln_ligand )  THEN
249            zw3d(:,:,:) = zz2ligprod(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:)
250            CALL iom_put( "LPRODZ2"  , zw3d )
251         ENDIF
252         DEALLOCATE( zw3d )
253      ENDIF
254      !
255      IF (ln_ligand)  DEALLOCATE( zz2ligprod )
256      !
257      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
258        WRITE(charout, FMT="('meso')")
259        CALL prt_ctl_trc_info(charout)
260        CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
261      ENDIF
262      !
263      IF( ln_timing )   CALL timing_stop('p4z_meso')
264      !
265   END SUBROUTINE p4z_meso
266
267
268   SUBROUTINE p4z_meso_init
269      !!----------------------------------------------------------------------
270      !!                  ***  ROUTINE p4z_meso_init  ***
271      !!
272      !! ** Purpose :   Initialization of mesozooplankton parameters
273      !!
274      !! ** Method  :   Read the nampismes namelist and check the parameters
275      !!      called at the first timestep (nittrc000)
276      !!
277      !! ** input   :   Namelist nampismes
278      !!----------------------------------------------------------------------
279      INTEGER ::   ios   ! Local integer
280      !
281      NAMELIST/namp4zmes/ part2, grazrat2, resrat2, mzrat2, xpref2n, xpref2d, xpref2z,   &
282         &                xpref2c, xthresh2dia, xthresh2phy, xthresh2zoo, xthresh2poc, &
283         &                xthresh2, xkgraz2, epsher2, epsher2min, sigma2, unass2, grazflux
284      !!----------------------------------------------------------------------
285      !
286      IF(lwp) THEN
287         WRITE(numout,*) 
288         WRITE(numout,*) 'p4z_meso_init : Initialization of mesozooplankton parameters'
289         WRITE(numout,*) '~~~~~~~~~~~~~'
290      ENDIF
291      !
292      REWIND( numnatp_ref )              ! Namelist nampismes in reference namelist : Pisces mesozooplankton
293      READ  ( numnatp_ref, namp4zmes, IOSTAT = ios, ERR = 901)
294901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namp4zmes in reference namelist' )
295      REWIND( numnatp_cfg )              ! Namelist nampismes in configuration namelist : Pisces mesozooplankton
296      READ  ( numnatp_cfg, namp4zmes, IOSTAT = ios, ERR = 902 )
297902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namp4zmes in configuration namelist' )
298      IF(lwm) WRITE( numonp, namp4zmes )
299      !
300      IF(lwp) THEN                         ! control print
301         WRITE(numout,*) '   Namelist : namp4zmes'
302         WRITE(numout,*) '      part of calcite not dissolved in mesozoo guts  part2        =', part2
303         WRITE(numout,*) '      mesozoo preference for phyto                   xpref2n      =', xpref2n
304         WRITE(numout,*) '      mesozoo preference for diatoms                 xpref2d      =', xpref2d
305         WRITE(numout,*) '      mesozoo preference for zoo                     xpref2z      =', xpref2z
306         WRITE(numout,*) '      mesozoo preference for poc                     xpref2c      =', xpref2c
307         WRITE(numout,*) '      microzoo feeding threshold  for mesozoo        xthresh2zoo  =', xthresh2zoo
308         WRITE(numout,*) '      diatoms feeding threshold  for mesozoo         xthresh2dia  =', xthresh2dia
309         WRITE(numout,*) '      nanophyto feeding threshold for mesozoo        xthresh2phy  =', xthresh2phy
310         WRITE(numout,*) '      poc feeding threshold for mesozoo              xthresh2poc  =', xthresh2poc
311         WRITE(numout,*) '      feeding threshold for mesozooplankton          xthresh2     =', xthresh2
312         WRITE(numout,*) '      exsudation rate of mesozooplankton             resrat2      =', resrat2
313         WRITE(numout,*) '      mesozooplankton mortality rate                 mzrat2       =', mzrat2
314         WRITE(numout,*) '      maximal mesozoo grazing rate                   grazrat2     =', grazrat2
315         WRITE(numout,*) '      mesozoo flux feeding rate                      grazflux     =', grazflux
316         WRITE(numout,*) '      non assimilated fraction of P by mesozoo       unass2       =', unass2
317         WRITE(numout,*) '      Efficiency of Mesozoo growth                   epsher2      =', epsher2
318         WRITE(numout,*) '      Minimum Efficiency of Mesozoo growth           epsher2min  =', epsher2min
319         WRITE(numout,*) '      Fraction of mesozoo excretion as DOM           sigma2       =', sigma2
320         WRITE(numout,*) '      half sturation constant for grazing 2          xkgraz2      =', xkgraz2
321      ENDIF
322      !
323   END SUBROUTINE p4z_meso_init
324
325   !!======================================================================
326END MODULE p4zmeso
Note: See TracBrowser for help on using the repository browser.