New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
nemogcm.F90 in NEMO/branches/2019/dev_r11613_ENHANCE-04_namelists_as_internalfiles/src/OFF – NEMO

source: NEMO/branches/2019/dev_r11613_ENHANCE-04_namelists_as_internalfiles/src/OFF/nemogcm.F90 @ 12134

Last change on this file since 12134 was 12134, checked in by acc, 4 years ago

Branch 2019/dev_r11613_ENHANCE-04_namelists_as_internalfiles. Merge in trunk changes from 11943 to 12072 in preparation for 2019 merge. Sette tested GYRE_PISCES only. Full SETTE to follow

  • Property svn:keywords set to Id
File size: 27.8 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Off-line Ocean   : passive tracer evolution, dynamics read in files
5   !!======================================================================
6   !! History :  3.3  ! 2010-05  (C. Ethe)  Full reorganization of the off-line: phasing with the on-line
7   !!            3.4  ! 2011-01  (C. Ethe, A. R. Porter, STFC Daresbury) dynamical allocation
8   !!            4.0  ! 2016-10  (C. Ethe, G. Madec, S. Flavoni)  domain configuration / user defined interface
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   nemo_gcm      : off-line: solve ocean tracer only
13   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
14   !!   nemo_init     : initialization of the NEMO system
15   !!   nemo_ctl      : initialisation of the contol print
16   !!   nemo_closefile: close remaining open files
17   !!   nemo_alloc    : dynamical allocation
18   !!   istate_init   : simple initialization to zero of ocean fields
19   !!   stp_ctl       : reduced step control (no dynamics in off-line)
20   !!----------------------------------------------------------------------
21   USE dom_oce        ! ocean space domain variables
22   USE oce            ! dynamics and tracers variables
23   USE trc_oce        ! Shared ocean/passive tracers variables
24   USE c1d            ! 1D configuration
25   USE domain         ! domain initialization from coordinate & bathymetry (dom_init routine)
26   USE closea         ! treatment of closed seas (for ln_closea)
27   USE usrdef_nam     ! user defined configuration
28   USE eosbn2         ! equation of state            (eos bn2 routine)
29   !              ! ocean physics
30   USE ldftra         ! lateral diffusivity setting    (ldf_tra_init routine)
31   USE ldfslp         ! slopes of neutral surfaces     (ldf_slp_init routine)
32   USE traqsr         ! solar radiation penetration    (tra_qsr_init routine)
33   USE trabbl         ! bottom boundary layer          (tra_bbl_init routine)
34   USE traldf         ! lateral physics                (tra_ldf_init routine)
35   USE sbcmod         ! surface boundary condition     (sbc_init     routine)
36   USE phycst         ! physical constant                   (par_cst routine)
37   USE dtadyn         ! Lecture and Interpolation of the dynamical fields
38   USE trcini         ! Initilization of the passive tracers
39   USE daymod         ! calendar                            (day     routine)
40   USE trcstp         ! passive tracer time-stepping        (trc_stp routine)
41   USE dtadyn         ! Lecture and interpolation of the dynamical fields
42   !              ! Passive tracers needs
43   USE trc            ! passive tracer : variables
44   USE trcnam         ! passive tracer : namelist
45   USE trcrst         ! passive tracer restart
46   USE diaptr         ! Need to initialise this as some variables are used in if statements later
47   USE sbc_oce , ONLY : ln_rnf
48   USE sbcrnf         ! surface boundary condition : runoffs
49   !              ! I/O & MPP
50   USE iom            ! I/O library
51   USE in_out_manager ! I/O manager
52   USE mppini         ! shared/distributed memory setting (mpp_init routine)
53   USE lib_mpp        ! distributed memory computing
54#if defined key_iomput
55   USE xios           ! xIOserver
56#endif
57   USE prtctl         ! Print control                    (prt_ctl_init routine)
58   USE timing         ! Timing
59   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
60   USE lbcnfd  , ONLY : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
61
62   IMPLICIT NONE
63   PRIVATE
64   
65   PUBLIC   nemo_gcm   ! called by nemo.F90
66
67   CHARACTER (len=64) ::   cform_aaa="( /, 'AAAAAAAA', / ) "   ! flag for output listing
68
69   !!----------------------------------------------------------------------
70   !! NEMO/OFF 4.0 , NEMO Consortium (2018)
71   !! $Id$
72   !! Software governed by the CeCILL license (see ./LICENSE)
73   !!----------------------------------------------------------------------
74CONTAINS
75
76   SUBROUTINE nemo_gcm
77      !!----------------------------------------------------------------------
78      !!                     ***  ROUTINE nemo_gcm  ***
79      !!
80      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
81      !!              curvilinear mesh on the sphere.
82      !!
83      !! ** Method  : - model general initialization
84      !!              - launch the time-stepping (dta_dyn and trc_stp)
85      !!              - finalize the run by closing files and communications
86      !!
87      !! References : Madec, Delecluse,Imbard, and Levy, 1997:  internal report, IPSL.
88      !!              Madec, 2008, internal report, IPSL.
89      !!----------------------------------------------------------------------
90      INTEGER :: istp, indic       ! time step index
91      !!----------------------------------------------------------------------
92
93      CALL nemo_init  ! Initializations
94
95      ! check that all process are still there... If some process have an error,
96      ! they will never enter in step and other processes will wait until the end of the cpu time!
97      CALL mpp_max( 'nemogcm', nstop )
98
99      !                            !-----------------------!
100      !                            !==   time stepping   ==!
101      !                            !-----------------------!
102      istp = nit000
103      !
104      IF( ln_rnf )   CALL sbc_rnf(istp)   ! runoffs initialization
105      !
106      CALL iom_init( cxios_context )      ! iom_put initialization (must be done after nemo_init for AGRIF+XIOS+OASIS)
107      !
108      DO WHILE ( istp <= nitend .AND. nstop == 0 )    !==  OFF time-stepping  ==!
109         !
110         IF( istp /= nit000 )   CALL day        ( istp )         ! Calendar (day was already called at nit000 in day_init)
111                                CALL iom_setkt  ( istp - nit000 + 1, cxios_context )   ! say to iom that we are at time step kstp
112#if defined key_sed_off
113                                CALL dta_dyn_sed( istp )         ! Interpolation of the dynamical fields
114#else
115                                CALL dta_dyn    ( istp )         ! Interpolation of the dynamical fields
116#endif
117                                CALL trc_stp    ( istp )         ! time-stepping
118#if ! defined key_sed_off
119         IF( .NOT.ln_linssh )   CALL dta_dyn_swp( istp )         ! swap of sea  surface height and vertical scale factors
120#endif
121                                CALL stp_ctl    ( istp, indic )  ! Time loop: control and print
122         istp = istp + 1
123      END DO
124      !
125#if defined key_iomput
126      CALL iom_context_finalize( cxios_context ) ! needed for XIOS+AGRIF
127#endif
128
129      !                            !------------------------!
130      !                            !==  finalize the run  ==!
131      !                            !------------------------!
132      IF(lwp) WRITE(numout,cform_aaa)                 ! Flag AAAAAAA
133
134      IF( nstop /= 0 .AND. lwp ) THEN                 ! error print
135         WRITE(ctmp1,*) '   ==>>>   nemo_gcm: a total of ', nstop, ' errors have been found'
136         CALL ctl_stop( ctmp1 )
137      ENDIF
138      !
139      IF( ln_timing )   CALL timing_finalize
140      !
141      CALL nemo_closefile
142      !
143#if defined key_iomput
144                     CALL xios_finalize   ! end mpp communications with xios
145#else
146      IF( lk_mpp )   CALL mppstop         ! end mpp communications
147#endif
148      !
149      IF(lwm) THEN
150         IF( nstop == 0 ) THEN   ;   STOP 0
151         ELSE                    ;   STOP 123
152         ENDIF
153      ENDIF
154      !
155   END SUBROUTINE nemo_gcm
156
157
158   SUBROUTINE nemo_init
159      !!----------------------------------------------------------------------
160      !!                     ***  ROUTINE nemo_init  ***
161      !!
162      !! ** Purpose :   initialization of the nemo model in off-line mode
163      !!----------------------------------------------------------------------
164      INTEGER ::   ios, ilocal_comm   ! local integers
165      !!
166      NAMELIST/namctl/ ln_ctl   , sn_cfctl, nn_print, nn_ictls, nn_ictle,   &
167         &             nn_isplt , nn_jsplt, nn_jctls, nn_jctle,             &
168         &             ln_timing, ln_diacfl
169      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
170      !!----------------------------------------------------------------------
171      !
172      cxios_context = 'nemo'
173      !
174      !                             !-------------------------------------------------!
175      !                             !     set communicator & select the local rank    !
176      !                             !  must be done as soon as possible to get narea  !
177      !                             !-------------------------------------------------!
178      !
179#if defined key_iomput
180      CALL xios_initialize( "for_xios_mpi_id", return_comm=ilocal_comm )   ! nemo local communicator given by xios
181      CALL mpp_start( ilocal_comm )
182#else
183      CALL mpp_start( )
184#endif
185      !
186      narea = mpprank + 1               ! mpprank: the rank of proc (0 --> mppsize -1 )
187      lwm = (narea == 1)                ! control of output namelists
188      !
189      !                             !---------------------------------------------------------------!
190      !                             ! Open output files, reference and configuration namelist files !
191      !                             !---------------------------------------------------------------!
192      !
193      ! open ocean.output as soon as possible to get all output prints (including errors messages)
194      IF( lwm )   CALL ctl_opn(     numout,        'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
195      ! open reference and configuration namelist files
196                  CALL load_nml( numnam_ref,        'namelist_ref',                                           -1, lwm )
197                  CALL load_nml( numnam_cfg,        'namelist_cfg',                                           -1, lwm )
198      IF( lwm )   CALL ctl_opn(     numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
199      ! open /dev/null file to be able to supress output write easily
200                  CALL ctl_opn(     numnul,           '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
201      !
202      !                             !--------------------!
203      !                             ! Open listing units !  -> need ln_ctl from namctl to define lwp
204      !                             !--------------------!
205      !
206      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
207901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namctl in reference namelist' )
208      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
209902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namctl in configuration namelist' )
210      !
211      lwp = (narea == 1) .OR. ln_ctl    ! control of all listing output print
212      !
213      IF(lwp) THEN                            ! open listing units
214         !
215         IF( .NOT. lwm )   &           ! alreay opened for narea == 1
216            &     CALL ctl_opn(     numout,        'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE., narea )
217         !
218         WRITE(numout,*)
219         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - CMCC'
220         WRITE(numout,*) '                       NEMO team'
221         WRITE(numout,*) '                   Off-line TOP Model'
222         WRITE(numout,*) '                NEMO version 4.0  (2019) '
223         WRITE(numout,*)
224         WRITE(numout,*) "           ._      ._      ._      ._      ._    "
225         WRITE(numout,*) "       _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ "
226         WRITE(numout,*)
227         WRITE(numout,*) "           o         _,           _,             "
228         WRITE(numout,*) "            o      .' (        .-' /             "
229         WRITE(numout,*) "           o     _/..._'.    .'   /              "
230         WRITE(numout,*) "      (    o .-'`      ` '-./  _.'               "
231         WRITE(numout,*) "       )    ( o)           ;= <_         (       "
232         WRITE(numout,*) "      (      '-.,\\__ __.-;`\   '.        )      "
233         WRITE(numout,*) "       )  )       \) |`\ \)  '.   \      (   (   "
234         WRITE(numout,*) "      (  (           \_/       '-._\      )   )  "
235         WRITE(numout,*) "       )  )                        `     (   (   "
236         WRITE(numout,*) "     ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ "
237         WRITE(numout,*)
238         !
239         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
240         !
241      ENDIF
242      !
243      ! finalize the definition of namctl variables
244      IF( sn_cfctl%l_config ) THEN
245         ! Activate finer control of report outputs
246         ! optionally switch off output from selected areas (note this only
247         ! applies to output which does not involve global communications)
248         IF( ( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax  ) .OR. &
249           & ( MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 ) )    &
250           &   CALL nemo_set_cfctl( sn_cfctl, .FALSE., .FALSE. )
251      ELSE
252         ! Use ln_ctl to turn on or off all options.
253         CALL nemo_set_cfctl( sn_cfctl, ln_ctl, .TRUE. )
254      ENDIF
255      !
256      IF(lwm) WRITE( numond, namctl )
257      !
258      !                             !------------------------------------!
259      !                             !  Set global domain size parameters !
260      !                             !------------------------------------!
261      !     
262      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
263903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namcfg in reference namelist' )
264      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
265904   IF( ios >  0 )   CALL ctl_nam ( ios , 'namcfg in configuration namelist' )   
266      !
267      IF( ln_read_cfg ) THEN              ! Read sizes in domain configuration file
268         CALL domain_cfg ( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
269      ELSE                                ! user-defined namelist
270         CALL usr_def_nam( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
271      ENDIF
272      !
273      IF(lwm)   WRITE( numond, namcfg )
274      l_offline = .true.                  ! passive tracers are run offline
275      !
276      !                             !-----------------------------------------!
277      !                             ! mpp parameters and domain decomposition !
278      !                             !-----------------------------------------!
279      !
280      CALL mpp_init
281
282      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
283      CALL nemo_alloc()
284
285      !                             !-------------------------------!
286      !                             !  NEMO general initialization  !
287      !                             !-------------------------------!
288
289      CALL nemo_ctl                          ! Control prints
290      !
291      !                                      ! General initialization
292      IF( ln_timing    )   CALL timing_init
293      IF( ln_timing    )   CALL timing_start( 'nemo_init')
294      !
295                           CALL     phy_cst         ! Physical constants
296                           CALL     eos_init        ! Equation of state
297      IF( lk_c1d       )   CALL     c1d_init        ! 1D column configuration
298                           CALL     dom_init("OPA") ! Domain
299      IF( ln_ctl       )   CALL prt_ctl_init        ! Print control
300
301                           CALL  istate_init    ! ocean initial state (Dynamics and tracers)
302
303                           CALL     sbc_init    ! Forcings : surface module
304
305      !                                      ! Tracer physics
306                           CALL ldf_tra_init    ! Lateral ocean tracer physics
307                           CALL ldf_eiv_init    ! Eddy induced velocity param
308                           CALL tra_ldf_init    ! lateral mixing
309      IF( l_ldfslp     )   CALL ldf_slp_init    ! slope of lateral mixing
310      IF( ln_traqsr    )   CALL tra_qsr_init    ! penetrative solar radiation
311      IF( ln_trabbl    )   CALL tra_bbl_init    ! advective (and/or diffusive) bottom boundary layer scheme
312
313      !                                      ! Passive tracers
314                           CALL trc_nam_run    ! Needed to get restart parameters for passive tracers
315                           CALL trc_rst_cal( nit000, 'READ' )   ! calendar
316#if defined key_sed_off
317                           CALL dta_dyn_sed_init ! Initialization for the dynamics
318#else
319                           CALL dta_dyn_init   ! Initialization for the dynamics
320#endif
321
322                           CALL     trc_init   ! Passive tracers initialization
323                           CALL dia_ptr_init   ! Poleward TRansports initialization
324                           
325      IF(lwp) WRITE(numout,cform_aaa)           ! Flag AAAAAAA
326      !
327      IF( ln_timing    )   CALL timing_stop( 'nemo_init')
328      !
329   END SUBROUTINE nemo_init
330
331
332   SUBROUTINE nemo_ctl
333      !!----------------------------------------------------------------------
334      !!                     ***  ROUTINE nemo_ctl  ***
335      !!
336      !! ** Purpose :   control print setting
337      !!
338      !! ** Method  : - print namctl information and check some consistencies
339      !!----------------------------------------------------------------------
340      !
341      IF(lwp) THEN                  ! control print
342         WRITE(numout,*)
343         WRITE(numout,*) 'nemo_ctl: Control prints'
344         WRITE(numout,*) '~~~~~~~~'
345         WRITE(numout,*) '   Namelist namctl'
346         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
347         WRITE(numout,*) '       finer control over o/p sn_cfctl%l_config  = ', sn_cfctl%l_config
348         WRITE(numout,*) '                              sn_cfctl%l_runstat = ', sn_cfctl%l_runstat
349         WRITE(numout,*) '                              sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat
350         WRITE(numout,*) '                              sn_cfctl%l_oceout  = ', sn_cfctl%l_oceout
351         WRITE(numout,*) '                              sn_cfctl%l_layout  = ', sn_cfctl%l_layout
352         WRITE(numout,*) '                              sn_cfctl%l_mppout  = ', sn_cfctl%l_mppout
353         WRITE(numout,*) '                              sn_cfctl%l_mpptop  = ', sn_cfctl%l_mpptop
354         WRITE(numout,*) '                              sn_cfctl%procmin   = ', sn_cfctl%procmin 
355         WRITE(numout,*) '                              sn_cfctl%procmax   = ', sn_cfctl%procmax 
356         WRITE(numout,*) '                              sn_cfctl%procincr  = ', sn_cfctl%procincr 
357         WRITE(numout,*) '                              sn_cfctl%ptimincr  = ', sn_cfctl%ptimincr 
358         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
359         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
360         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
361         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
362         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
363         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
364         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
365         WRITE(numout,*) '      timing by routine               ln_timing  = ', ln_timing
366         WRITE(numout,*) '      CFL diagnostics                 ln_diacfl  = ', ln_diacfl
367      ENDIF
368      !
369      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
370      nictls    = nn_ictls
371      nictle    = nn_ictle
372      njctls    = nn_jctls
373      njctle    = nn_jctle
374      isplt     = nn_isplt
375      jsplt     = nn_jsplt
376
377      IF(lwp) THEN                  ! control print
378         WRITE(numout,*)
379         WRITE(numout,*) '   Namelist namcfg'
380         WRITE(numout,*) '      read domain configuration file              ln_read_cfg      = ', ln_read_cfg
381         WRITE(numout,*) '         filename to be read                         cn_domcfg     = ', TRIM(cn_domcfg)
382         WRITE(numout,*) '         keep closed seas in the domain (if exist)   ln_closea     = ', ln_closea
383         WRITE(numout,*) '      create a configuration definition file      ln_write_cfg     = ', ln_write_cfg
384         WRITE(numout,*) '         filename to be written                      cn_domcfg_out = ', TRIM(cn_domcfg_out)
385         WRITE(numout,*) '      use file attribute if exists as i/p j-start ln_use_jattr     = ', ln_use_jattr
386      ENDIF
387      IF( .NOT.ln_read_cfg )   ln_closea = .false.   ! dealing possible only with a domcfg file
388      !
389      !                             ! Parameter control
390      !
391      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
392         IF( lk_mpp .AND. jpnij > 1 ) THEN
393            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
394         ELSE
395            IF( isplt == 1 .AND. jsplt == 1  ) THEN
396               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
397                  &           ' - the print control will be done over the whole domain' )
398            ENDIF
399            ijsplt = isplt * jsplt            ! total number of processors ijsplt
400         ENDIF
401         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
402         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
403         !
404         !                              ! indices used for the SUM control
405         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
406            lsp_area = .FALSE.
407         ELSE                                             ! print control done over a specific  area
408            lsp_area = .TRUE.
409            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
410               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
411               nictls = 1
412            ENDIF
413            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
414               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
415               nictle = jpiglo
416            ENDIF
417            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
418               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
419               njctls = 1
420            ENDIF
421            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
422               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
423               njctle = jpjglo
424            ENDIF
425         ENDIF
426      ENDIF
427      !
428      IF( 1._wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.',  &
429         &                                                'Compile with key_nosignedzero enabled' )
430      !
431   END SUBROUTINE nemo_ctl
432
433
434   SUBROUTINE nemo_closefile
435      !!----------------------------------------------------------------------
436      !!                     ***  ROUTINE nemo_closefile  ***
437      !!
438      !! ** Purpose :   Close the files
439      !!----------------------------------------------------------------------
440      !
441      IF( lk_mpp )   CALL mppsync
442      !
443      CALL iom_close                                 ! close all input/output files managed by iom_*
444      !
445      IF( numstp     /= -1 )   CLOSE( numstp     )   ! time-step file
446      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
447      !
448      numout = 6                                     ! redefine numout in case it is used after this point...
449      !
450   END SUBROUTINE nemo_closefile
451
452
453   SUBROUTINE nemo_alloc
454      !!----------------------------------------------------------------------
455      !!                     ***  ROUTINE nemo_alloc  ***
456      !!
457      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
458      !!
459      !! ** Method  :
460      !!----------------------------------------------------------------------
461      USE diawri ,   ONLY : dia_wri_alloc
462      USE dom_oce,   ONLY : dom_oce_alloc
463      USE zdf_oce,   ONLY : zdf_oce_alloc
464      USE trc_oce,   ONLY : trc_oce_alloc
465      !
466      INTEGER :: ierr
467      !!----------------------------------------------------------------------
468      !
469      ierr =        oce_alloc    ()          ! ocean
470      ierr = ierr + dia_wri_alloc()
471      ierr = ierr + dom_oce_alloc()          ! ocean domain
472      ierr = ierr + zdf_oce_alloc()          ! ocean vertical physics
473      ierr = ierr + trc_oce_alloc()          ! shared TRC / TRA arrays
474      !
475      CALL mpp_sum( 'nemogcm', ierr )
476      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
477      !
478   END SUBROUTINE nemo_alloc
479
480   SUBROUTINE nemo_set_cfctl(sn_cfctl, setto, for_all )
481      !!----------------------------------------------------------------------
482      !!                     ***  ROUTINE nemo_set_cfctl  ***
483      !!
484      !! ** Purpose :   Set elements of the output control structure to setto.
485      !!                for_all should be .false. unless all areas are to be
486      !!                treated identically.
487      !!
488      !! ** Method  :   Note this routine can be used to switch on/off some
489      !!                types of output for selected areas but any output types
490      !!                that involve global communications (e.g. mpp_max, glob_sum)
491      !!                should be protected from selective switching by the
492      !!                for_all argument
493      !!----------------------------------------------------------------------
494      LOGICAL :: setto, for_all
495      TYPE(sn_ctl) :: sn_cfctl
496      !!----------------------------------------------------------------------
497      IF( for_all ) THEN
498         sn_cfctl%l_runstat = setto
499         sn_cfctl%l_trcstat = setto
500      ENDIF
501      sn_cfctl%l_oceout  = setto
502      sn_cfctl%l_layout  = setto
503      sn_cfctl%l_mppout  = setto
504      sn_cfctl%l_mpptop  = setto
505   END SUBROUTINE nemo_set_cfctl
506
507   SUBROUTINE istate_init
508      !!----------------------------------------------------------------------
509      !!                   ***  ROUTINE istate_init  ***
510      !!
511      !! ** Purpose :   Initialization to zero of the dynamics and tracers.
512      !!----------------------------------------------------------------------
513      !
514      !     now fields         !     after fields      !
515      un   (:,:,:)   = 0._wp   ;   ua(:,:,:) = 0._wp   !
516      vn   (:,:,:)   = 0._wp   ;   va(:,:,:) = 0._wp   !
517      wn   (:,:,:)   = 0._wp   !                       !
518      hdivn(:,:,:)   = 0._wp   !                       !
519      tsn  (:,:,:,:) = 0._wp   !                       !
520      !
521      rhd  (:,:,:) = 0.e0
522      rhop (:,:,:) = 0.e0
523      rn2  (:,:,:) = 0.e0
524      !
525   END SUBROUTINE istate_init
526
527
528   SUBROUTINE stp_ctl( kt, kindic )
529      !!----------------------------------------------------------------------
530      !!                    ***  ROUTINE stp_ctl  ***
531      !!
532      !! ** Purpose :   Control the run
533      !!
534      !! ** Method  : - Save the time step in numstp
535      !!
536      !! ** Actions :   'time.step' file containing the last ocean time-step
537      !!----------------------------------------------------------------------
538      INTEGER, INTENT(in   ) ::   kt      ! ocean time-step index
539      INTEGER, INTENT(inout) ::   kindic  ! indicator of solver convergence
540      !!----------------------------------------------------------------------
541      !
542      IF( kt == nit000 .AND. lwm ) THEN
543         WRITE(numout,*)
544         WRITE(numout,*) 'stp_ctl : time-stepping control'
545         WRITE(numout,*) '~~~~~~~'
546         ! open time.step file
547         CALL ctl_opn( numstp, 'time.step', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
548      ENDIF
549      !
550      IF(lwm) WRITE ( numstp, '(1x, i8)' )   kt      !* save the current time step in numstp
551      IF(lwm) REWIND( numstp )                       ! --------------------------
552      !
553   END SUBROUTINE stp_ctl
554   !!======================================================================
555END MODULE nemogcm
Note: See TracBrowser for help on using the repository browser.