New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zmicro.F90 in NEMO/branches/2019/dev_r11708_aumont_PISCES_QUOTA/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2019/dev_r11708_aumont_PISCES_QUOTA/src/TOP/PISCES/P4Z/p4zmicro.F90 @ 12537

Last change on this file since 12537 was 12537, checked in by aumont, 4 years ago

Comments in routines have been revised and significantly augmented
  • Property svn:keywords set to Id
File size: 17.0 KB
Line 
1MODULE p4zmicro
2   !!======================================================================
3   !!                         ***  MODULE p4zmicro  ***
4   !! TOP :   PISCES Compute the sources/sinks for microzooplankton
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!----------------------------------------------------------------------
10   !!   p4z_micro      : Compute the sources/sinks for microzooplankton
11   !!   p4z_micro_init : Initialize and read the appropriate namelist
12   !!----------------------------------------------------------------------
13   USE oce_trc         ! shared variables between ocean and passive tracers
14   USE trc             ! passive tracers common variables
15   USE sms_pisces      ! PISCES Source Minus Sink variables
16   USE p4zlim          ! Co-limitations
17   USE p4zprod         ! production
18   USE iom             ! I/O manager
19   USE prtctl_trc      ! print control for debugging
20
21   IMPLICIT NONE
22   PRIVATE
23
24   !! * Shared module variables
25   PUBLIC   p4z_micro         ! called in p4zbio.F90
26   PUBLIC   p4z_micro_init    ! called in trcsms_pisces.F90
27
28   REAL(wp), PUBLIC ::   part        !: part of calcite not dissolved in microzoo guts
29   REAL(wp), PUBLIC ::   xprefc      !: microzoo preference for POC
30   REAL(wp), PUBLIC ::   xprefn      !: microzoo preference for nanophyto
31   REAL(wp), PUBLIC ::   xprefd      !: microzoo preference for diatoms
32   REAL(wp), PUBLIC ::   xthreshdia  !: diatoms feeding threshold for microzooplankton
33   REAL(wp), PUBLIC ::   xthreshphy  !: nanophyto threshold for microzooplankton
34   REAL(wp), PUBLIC ::   xthreshpoc  !: poc threshold for microzooplankton
35   REAL(wp), PUBLIC ::   xthresh     !: feeding threshold for microzooplankton
36   REAL(wp), PUBLIC ::   resrat      !: exsudation rate of microzooplankton
37   REAL(wp), PUBLIC ::   mzrat       !: microzooplankton mortality rate
38   REAL(wp), PUBLIC ::   grazrat     !: maximal microzoo grazing rate
39   REAL(wp), PUBLIC ::   xkgraz      !: Half-saturation constant of assimilation
40   REAL(wp), PUBLIC ::   unass       !: Non-assimilated part of food
41   REAL(wp), PUBLIC ::   sigma1      !: Fraction of microzoo excretion as DOM
42   REAL(wp), PUBLIC ::   epsher      !: growth efficiency for grazing 1
43   REAL(wp), PUBLIC ::   epshermin   !: minimum growth efficiency for grazing 1
44
45   !!----------------------------------------------------------------------
46   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
47   !! $Id$
48   !! Software governed by the CeCILL license (see ./LICENSE)
49   !!----------------------------------------------------------------------
50CONTAINS
51
52   SUBROUTINE p4z_micro( kt, knt )
53      !!---------------------------------------------------------------------
54      !!                     ***  ROUTINE p4z_micro  ***
55      !!
56      !! ** Purpose :   Compute the sources/sinks for microzooplankton
57      !!                This includes ingestion and assimilation, flux feeding
58      !!                and mortality. We use a passive prey switching 
59      !!                parameterization.
60      !!                All living compartments smaller than microzooplankton
61      !!                are potential preys of mesozooplankton
62      !!
63      !! ** Method  : - ???
64      !!---------------------------------------------------------------------
65      INTEGER, INTENT(in) ::   kt    ! ocean time step
66      INTEGER, INTENT(in) ::   knt   ! ???
67      !
68      INTEGER  :: ji, jj, jk
69      REAL(wp) :: zcompadi, zcompaz , zcompaph, zcompapoc
70      REAL(wp) :: zgraze  , zdenom, zdenom2
71      REAL(wp) :: zfact   , zfood, zfoodlim, zbeta
72      REAL(wp) :: zepsherf, zepshert, zepsherq, zepsherv, zgrarsig, zgraztotc, zgraztotn, zgraztotf
73      REAL(wp) :: zgrarem, zgrafer, zgrapoc, zprcaca, zmortz
74      REAL(wp) :: zrespz, ztortz, zgrasrat, zgrasratn
75      REAL(wp) :: zgrazp, zgrazm, zgrazsd
76      REAL(wp) :: zgrazmf, zgrazsf, zgrazpf
77      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zgrazing, zfezoo
78      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: zw3d, zzligprod
79      CHARACTER (len=25) :: charout
80      !!---------------------------------------------------------------------
81      !
82      IF( ln_timing )   CALL timing_start('p4z_micro')
83      !
84      IF (ln_ligand) THEN
85         ALLOCATE( zzligprod(jpi,jpj,jpk) )
86         zzligprod(:,:,:) = 0._wp
87      ENDIF
88      !
89      DO jk = 1, jpkm1
90         DO jj = 1, jpj
91            DO ji = 1, jpi
92               zcompaz = MAX( ( trb(ji,jj,jk,jpzoo) - 1.e-9 ), 0.e0 )
93               zfact   = xstep * tgfunc2(ji,jj,jk) * zcompaz
94
95               !  linear mortality of mesozooplankton
96               !  A michaelis menten modulation term is used to avoid extinction of
97               !  microzooplankton at very low food concentrations. Mortality is
98               !  enhanced in low O2 waters
99               !  -----------------------------------------------------------------
100               zrespz = resrat * zfact * trb(ji,jj,jk,jpzoo) / ( xkmort + trb(ji,jj,jk,jpzoo) )  &
101                  &   + resrat * zfact * 3. * nitrfac(ji,jj,jk)
102
103               !  Zooplankton quadratic mortality. A square function has been selected with
104               !  to mimic predation and disease (density dependent mortality). It also tends
105               !  to stabilise the model
106               !  -------------------------------------------------------------------------
107               ztortz = mzrat * 1.e6 * zfact * trb(ji,jj,jk,jpzoo) * (1. - nitrfac(ji,jj,jk))
108
109               !   Computation of the abundance of the preys
110               !   A threshold can be specified in the namelist
111               !   Diatoms have a specific treatment. WHen concentrations
112               !   exceed a certain value, diatoms are suppposed to be too
113               !   big for microzooplankton.
114               !   --------------------------------------------------------
115               zcompadi  = MIN( MAX( ( trb(ji,jj,jk,jpdia) - xthreshdia ), 0.e0 ), xsizedia )
116               zcompaph  = MAX( ( trb(ji,jj,jk,jpphy) - xthreshphy ), 0.e0 )
117               zcompapoc = MAX( ( trb(ji,jj,jk,jppoc) - xthreshpoc ), 0.e0 )
118               
119               ! Microzooplankton grazing
120               ! The total amount of food is the sum of all preys accessible to mesozooplankton
121               ! multiplied by their food preference
122               ! A threshold can be specified in the namelist (xthresh). However, when food
123               ! concentration is close to this threshold, it is decreased to avoid the
124               ! accumulation of food in the mesozoopelagic domain
125               ! -------------------------------------------------------------------------------
126               zfood     = xprefn * zcompaph + xprefc * zcompapoc + xprefd * zcompadi
127               zfoodlim  = MAX( 0. , zfood - min(xthresh,0.5*zfood) )
128               zdenom    = zfoodlim / ( xkgraz + zfoodlim )
129               zdenom2   = zdenom / ( zfood + rtrn )
130               zgraze    = grazrat * xstep * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jpzoo) * (1. - nitrfac(ji,jj,jk))
131
132               ! The grazing pressure on each prey is computed assuming passive switching. This
133               ! is equivalent to assuming that microzooplankton have an opportunistic feeding
134               ! behaviour.
135               ! -----------------------------------------------------------------------------
136               zgrazp    = zgraze  * xprefn * zcompaph  * zdenom2 
137               zgrazm    = zgraze  * xprefc * zcompapoc * zdenom2 
138               zgrazsd   = zgraze  * xprefd * zcompadi  * zdenom2 
139
140               zgrazpf   = zgrazp  * trb(ji,jj,jk,jpnfe) / (trb(ji,jj,jk,jpphy) + rtrn)
141               zgrazmf   = zgrazm  * trb(ji,jj,jk,jpsfe) / (trb(ji,jj,jk,jppoc) + rtrn)
142               zgrazsf   = zgrazsd * trb(ji,jj,jk,jpdfe) / (trb(ji,jj,jk,jpdia) + rtrn)
143               !
144               zgraztotc = zgrazp  + zgrazm  + zgrazsd 
145               zgraztotf = zgrazpf + zgrazsf + zgrazmf 
146               zgraztotn = zgrazp * quotan(ji,jj,jk) + zgrazm + zgrazsd * quotad(ji,jj,jk)
147
148               ! Grazing by microzooplankton
149               zgrazing(ji,jj,jk) = zgraztotc
150
151               ! Microzooplankton efficiency.
152               ! We adopt a formulation proposed by Mitra et al. (2007)
153               ! The gross growth efficiency is controled by the most limiting nutrient.
154               ! Growth is also further decreased when the food quality is poor. This is currently
155               ! hard coded : it can be decreased by up to 50% (zepsherq)
156               ! GGE can also be decreased when food quantity is high, zepsherf (Montagnes and
157               ! Fulton, 2012)
158               ! -----------------------------------------------------------------------------
159               zgrasrat  = ( zgraztotf + rtrn ) / ( zgraztotc + rtrn )
160               zgrasratn = ( zgraztotn + rtrn ) / ( zgraztotc + rtrn )
161               zepshert  =  MIN( 1., zgrasratn, zgrasrat / ferat3)
162               zbeta     = MAX(0., (epsher - epshermin) )
163               zepsherf  = epshermin + zbeta / ( 1.0 + 0.04E6 * 12. * zfood * zbeta )
164               zepsherq  = 0.5 + (1.0 - 0.5) * zepshert * ( 1.0 + 1.0 ) / ( zepshert + 1.0 )
165               zepsherv  = zepsherf * zepshert * zepsherq
166               zgrafer   = zgraztotc * MAX( 0. , ( 1. - unass ) * zgrasrat - ferat3 * zepsherv ) 
167               zgrarem   = zgraztotc * ( 1. - zepsherv - unass )
168               zgrapoc   = zgraztotc * unass
169
170               !  Update of the TRA arrays
171               !  ------------------------
172               zgrarsig  = zgrarem * sigma1
173               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zgrarsig
174               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zgrarsig
175               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zgrarem - zgrarsig
176               !
177               IF( ln_ligand ) THEN
178                  tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) + (zgrarem - zgrarsig) * ldocz
179                  zzligprod(ji,jj,jk) = (zgrarem - zgrarsig) * ldocz
180               ENDIF
181               !
182               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2ut * zgrarsig
183               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zgrafer
184               zfezoo(ji,jj,jk)    = zgrafer
185               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zgrapoc
186               prodpoc(ji,jj,jk)   = prodpoc(ji,jj,jk) + zgrapoc
187               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zgraztotf * unass
188               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrarsig
189               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * zgrarsig
190               zmortz = ztortz + zrespz
191               tra(ji,jj,jk,jpzoo) = tra(ji,jj,jk,jpzoo) - zmortz + zepsherv * zgraztotc 
192               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zgrazp
193               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zgrazsd
194               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zgrazp  * trb(ji,jj,jk,jpnch)/(trb(ji,jj,jk,jpphy)+rtrn)
195               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zgrazsd * trb(ji,jj,jk,jpdch)/(trb(ji,jj,jk,jpdia)+rtrn)
196               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) - zgrazsd * trb(ji,jj,jk,jpdsi)/(trb(ji,jj,jk,jpdia)+rtrn)
197               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) + zgrazsd * trb(ji,jj,jk,jpdsi)/(trb(ji,jj,jk,jpdia)+rtrn)
198               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zgrazpf
199               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zgrazsf
200               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zmortz - zgrazm
201               prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + zmortz
202               conspoc(ji,jj,jk) = conspoc(ji,jj,jk) - zgrazm
203               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + ferat3 * zmortz - zgrazmf
204               !
205               ! Calcite remineralization due to zooplankton activity
206               ! part of the ingested calcite is dissolving in the acidic gut
207               zprcaca = xfracal(ji,jj,jk) * zgrazp
208               prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
209               !
210               zprcaca = part * zprcaca
211               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprcaca
212               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * zprcaca
213               tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) + zprcaca
214            END DO
215         END DO
216      END DO
217      !
218      IF( lk_iomput ) THEN
219         IF( knt == nrdttrc ) THEN
220           ALLOCATE( zw3d(jpi,jpj,jpk) )
221           IF( iom_use( "GRAZ1" ) ) THEN
222              zw3d(:,:,:) = zgrazing(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:)  !  Total grazing of phyto by zooplankton
223              CALL iom_put( "GRAZ1", zw3d )
224           ENDIF
225           IF( iom_use( "FEZOO" ) ) THEN
226              zw3d(:,:,:) = zfezoo(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:)   !
227              CALL iom_put( "FEZOO", zw3d )
228           ENDIF
229           IF( iom_use( "LPRODZ" ) .AND. ln_ligand )  THEN
230              zw3d(:,:,:) = zzligprod(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:)
231              CALL iom_put( "LPRODZ"  , zw3d )
232           ENDIF
233           DEALLOCATE( zw3d )
234         ENDIF
235      ENDIF
236      !
237      IF (ln_ligand)  DEALLOCATE( zzligprod )
238      !
239      IF(ln_ctl) THEN      ! print mean trends (used for debugging)
240         WRITE(charout, FMT="('micro')")
241         CALL prt_ctl_trc_info(charout)
242         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
243      ENDIF
244      !
245      IF( ln_timing )   CALL timing_stop('p4z_micro')
246      !
247   END SUBROUTINE p4z_micro
248
249
250   SUBROUTINE p4z_micro_init
251      !!----------------------------------------------------------------------
252      !!                  ***  ROUTINE p4z_micro_init  ***
253      !!
254      !! ** Purpose :   Initialization of microzooplankton parameters
255      !!
256      !! ** Method  :   Read the namp4zzoo namelist and check the parameters
257      !!                called at the first timestep (nittrc000)
258      !!
259      !! ** input   :   Namelist namp4zzoo
260      !!
261      !!----------------------------------------------------------------------
262      INTEGER ::   ios   ! Local integer
263      !
264      NAMELIST/namp4zzoo/ part, grazrat, resrat, mzrat, xprefn, xprefc, &
265         &                xprefd,  xthreshdia,  xthreshphy,  xthreshpoc, &
266         &                xthresh, xkgraz, epsher, epshermin, sigma1, unass
267      !!----------------------------------------------------------------------
268      !
269      IF(lwp) THEN
270         WRITE(numout,*) 
271         WRITE(numout,*) 'p4z_micro_init : Initialization of microzooplankton parameters'
272         WRITE(numout,*) '~~~~~~~~~~~~~~'
273      ENDIF
274      !
275      REWIND( numnatp_ref )              ! Namelist namp4zzoo in reference namelist : Pisces microzooplankton
276      READ  ( numnatp_ref, namp4zzoo, IOSTAT = ios, ERR = 901)
277901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namp4zzoo in reference namelist' )
278      REWIND( numnatp_cfg )              ! Namelist namp4zzoo in configuration namelist : Pisces microzooplankton
279      READ  ( numnatp_cfg, namp4zzoo, IOSTAT = ios, ERR = 902 )
280902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namp4zzoo in configuration namelist' )
281      IF(lwm) WRITE( numonp, namp4zzoo )
282      !
283      IF(lwp) THEN                         ! control print
284         WRITE(numout,*) '   Namelist : namp4zzoo'
285         WRITE(numout,*) '      part of calcite not dissolved in microzoo guts  part        =', part
286         WRITE(numout,*) '      microzoo preference for POC                     xprefc      =', xprefc
287         WRITE(numout,*) '      microzoo preference for nano                    xprefn      =', xprefn
288         WRITE(numout,*) '      microzoo preference for diatoms                 xprefd      =', xprefd
289         WRITE(numout,*) '      diatoms feeding threshold  for microzoo         xthreshdia  =', xthreshdia
290         WRITE(numout,*) '      nanophyto feeding threshold for microzoo        xthreshphy  =', xthreshphy
291         WRITE(numout,*) '      poc feeding threshold for microzoo              xthreshpoc  =', xthreshpoc
292         WRITE(numout,*) '      feeding threshold for microzooplankton          xthresh     =', xthresh
293         WRITE(numout,*) '      exsudation rate of microzooplankton             resrat      =', resrat
294         WRITE(numout,*) '      microzooplankton mortality rate                 mzrat       =', mzrat
295         WRITE(numout,*) '      maximal microzoo grazing rate                   grazrat     =', grazrat
296         WRITE(numout,*) '      non assimilated fraction of P by microzoo       unass       =', unass
297         WRITE(numout,*) '      Efficicency of microzoo growth                  epsher      =', epsher
298         WRITE(numout,*) '      Minimum efficicency of microzoo growth          epshermin   =', epshermin
299         WRITE(numout,*) '      Fraction of microzoo excretion as DOM           sigma1      =', sigma1
300         WRITE(numout,*) '      half sturation constant for grazing 1           xkgraz      =', xkgraz
301      ENDIF
302      !
303   END SUBROUTINE p4z_micro_init
304
305   !!======================================================================
306END MODULE p4zmicro
Note: See TracBrowser for help on using the repository browser.