New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zrem.F90 in NEMO/branches/2019/dev_r11708_aumont_PISCES_QUOTA/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2019/dev_r11708_aumont_PISCES_QUOTA/src/TOP/PISCES/P4Z/p4zrem.F90 @ 13233

Last change on this file since 13233 was 13233, checked in by aumont, 4 years ago

update of the PISCES comments
  • Property svn:keywords set to Id
File size: 20.9 KB
Line 
1MODULE p4zrem
2   !!======================================================================
3   !!                         ***  MODULE p4zrem  ***
4   !! TOP :   PISCES Compute remineralization/dissolution of organic compounds
5   !!         except for POC which is treated in p4zpoc.F90
6   !!         This module is common to both PISCES and PISCES-QUOTA
7   !!=========================================================================
8   !! History :   1.0  !  2004     (O. Aumont) Original code
9   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
10   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
11   !!----------------------------------------------------------------------
12   !!   p4z_rem       :  Compute remineralization/dissolution of organic compounds
13   !!   p4z_rem_init  :  Initialisation of parameters for remineralisation
14   !!   p4z_rem_alloc :  Allocate remineralisation variables
15   !!----------------------------------------------------------------------
16   USE oce_trc         !  shared variables between ocean and passive tracers
17   USE trc             !  passive tracers common variables
18   USE sms_pisces      !  PISCES Source Minus Sink variables
19   USE p4zche          !  chemical model
20   USE p4zprod         !  Growth rate of the 2 phyto groups
21   USE p4zlim          !  Nutrient limitation terms
22   USE prtctl_trc      !  print control for debugging
23   USE iom             !  I/O manager
24
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   p4z_rem         ! called in p4zbio.F90
30   PUBLIC   p4z_rem_init    ! called in trcini_pisces.F90
31   PUBLIC   p4z_rem_alloc   ! called in trcini_pisces.F90
32
33   !! * Shared module variables
34   REAL(wp), PUBLIC ::   xremikc    !: remineralisation rate of DOC (p5z)
35   REAL(wp), PUBLIC ::   xremikn    !: remineralisation rate of DON (p5z)
36   REAL(wp), PUBLIC ::   xremikp    !: remineralisation rate of DOP (p5z)
37   REAL(wp), PUBLIC ::   xremik     !: remineralisation rate of DOC (p4z)
38   REAL(wp), PUBLIC ::   nitrif     !: NH4 nitrification rate
39   REAL(wp), PUBLIC ::   xsirem     !: remineralisation rate of biogenic silica
40   REAL(wp), PUBLIC ::   xsiremlab  !: fast remineralisation rate of BSi
41   REAL(wp), PUBLIC ::   xsilab     !: fraction of labile biogenic silica
42   REAL(wp), PUBLIC ::   feratb     !: Fe/C quota in bacteria
43   REAL(wp), PUBLIC ::   xkferb     !: Half-saturation constant for bacterial Fe/C
44
45   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   denitr   !: denitrification array
46
47   !!----------------------------------------------------------------------
48   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
49   !! $Id$
50   !! Software governed by the CeCILL license (see ./LICENSE)
51   !!----------------------------------------------------------------------
52CONTAINS
53
54   SUBROUTINE p4z_rem( kt, knt )
55      !!---------------------------------------------------------------------
56      !!                     ***  ROUTINE p4z_rem  ***
57      !!
58      !! ** Purpose :   Compute remineralization/dissolution of organic compounds
59      !!                Computes also nitrification of ammonium
60      !!                The solubilization/remineralization of POC is treated
61      !!                in p4zpoc.F90. The dissolution of calcite is processed
62      !!                in p4zlys.F90.
63      !!
64      !! ** Method  : - Bacterial biomass is computed implicitely based on a
65      !!                parameterization developed from an explicit modeling
66      !!                of PISCES in an alternative version
67      !!---------------------------------------------------------------------
68      INTEGER, INTENT(in) ::   kt, knt ! ocean time step
69      !
70      INTEGER  ::   ji, jj, jk
71      REAL(wp) ::   zremik, zremikc, zremikn, zremikp, zsiremin, zfact 
72      REAL(wp) ::   zsatur, zsatur2, znusil, znusil2, zdep, zdepmin, zfactdep
73      REAL(wp) ::   zbactfer, zolimit, zonitr, zrfact2
74      REAL(wp) ::   zammonic, zoxyremc, zoxyremn, zoxyremp
75      REAL(wp) ::   zosil, ztem, zdenitnh4, zolimic, zolimin, zolimip, zdenitrn, zdenitrp
76      CHARACTER (len=25) :: charout
77      REAL(wp), DIMENSION(jpi,jpj    ) :: ztempbac
78      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zdepbac, zolimi, zdepprod, zfacsi, zfacsib, zdepeff, zfebact
79      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: zw3d
80      !!---------------------------------------------------------------------
81      !
82      IF( ln_timing )   CALL timing_start('p4z_rem')
83      !
84      ! Initialisation of arrays
85      zdepprod(:,:,:) = 1._wp
86      zdepeff (:,:,:) = 0.3_wp
87      ztempbac(:,:)   = 0._wp
88      zfacsib(:,:,:)  = xsilab / ( 1.0 - xsilab )
89      zfebact(:,:,:)  = 0._wp
90      zfacsi(:,:,:)   = xsilab
91
92      ! Computation of the mean bacterial concentration
93      ! this parameterization has been deduced from a model version
94      ! that was modeling explicitely bacteria. This is a very old param
95      ! that will be very soon updated based on results from a much more
96      ! recent version of PISCES with bacteria.
97      ! ----------------------------------------------------------------
98      DO jk = 1, jpkm1
99         DO jj = 1, jpj
100            DO ji = 1, jpi
101               zdep = MAX( hmld(ji,jj), heup(ji,jj) )
102               IF( gdept_n(ji,jj,jk) < zdep ) THEN
103                  zdepbac(ji,jj,jk) = MIN( 0.7 * ( trb(ji,jj,jk,jpzoo) + 2.* trb(ji,jj,jk,jpmes) ), 4.e-6 )
104                  ztempbac(ji,jj)   = zdepbac(ji,jj,jk)
105               ELSE
106                  zdepmin = MIN( 1., zdep / gdept_n(ji,jj,jk) )
107                  zdepbac (ji,jj,jk) = zdepmin**0.683 * ztempbac(ji,jj)
108                  zdepprod(ji,jj,jk) = zdepmin**0.273
109                  zdepeff (ji,jj,jk) = zdepeff(ji,jj,jk) * zdepmin**0.3
110               ENDIF
111            END DO
112         END DO
113      END DO
114
115      IF( ln_p4z ) THEN ! Standard PISCES code
116         DO jk = 1, jpkm1
117            DO jj = 1, jpj
118               DO ji = 1, jpi
119                  ! DOC ammonification. Depends on a limitation term of the bacterial activity
120                  ! and on the implicit bacteria concentration
121                  ! --------------------------------------------------------------------------
122                  zremik = xremik * xstep / 1.e-6 * xlimbac(ji,jj,jk) * zdepbac(ji,jj,jk) 
123                  zremik = MAX( zremik, 2.74e-4 * xstep )
124
125                  ! Ammonification in oxic waters with oxygen consumption
126                  ! -----------------------------------------------------
127                  zolimit = zremik * ( 1.- nitrfac(ji,jj,jk) ) * trb(ji,jj,jk,jpdoc) 
128                  zolimi(ji,jj,jk) = MIN( ( trb(ji,jj,jk,jpoxy) - rtrn ) / o2ut, zolimit ) 
129
130                  ! Ammonification in suboxic waters with denitrification
131                  ! -----------------------------------------------------
132                  zammonic = zremik * nitrfac(ji,jj,jk) * trb(ji,jj,jk,jpdoc)
133                  denitr(ji,jj,jk)  = zammonic * ( 1. - nitrfac2(ji,jj,jk) )
134                  denitr(ji,jj,jk)  = MIN( ( trb(ji,jj,jk,jpno3) - rtrn ) / rdenit, denitr(ji,jj,jk) )
135
136                  ! Ammonification in waters depleted in O2 and NO3 based on
137                  ! other redox processes
138                  ! --------------------------------------------------------
139                  zoxyremc          = zammonic - denitr(ji,jj,jk)
140                  !
141                  zolimi (ji,jj,jk) = MAX( 0.e0, zolimi (ji,jj,jk) )
142                  denitr (ji,jj,jk) = MAX( 0.e0, denitr (ji,jj,jk) )
143                  zoxyremc          = MAX( 0.e0, zoxyremc )
144                  ! Update of the TRA arrays
145                  tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zolimi (ji,jj,jk) + denitr(ji,jj,jk) + zoxyremc
146                  tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zolimi (ji,jj,jk) + denitr(ji,jj,jk) + zoxyremc
147                  tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - denitr (ji,jj,jk) * rdenit
148                  tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zolimi (ji,jj,jk) - denitr(ji,jj,jk) - zoxyremc
149                  tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - zolimi (ji,jj,jk) * o2ut
150                  tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zolimi (ji,jj,jk) + denitr(ji,jj,jk) + zoxyremc
151                  tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zolimi(ji,jj,jk) + zoxyremc    &
152                  &                     + ( rdenit + 1.) * denitr(ji,jj,jk) )
153               END DO
154            END DO
155         END DO
156      ELSE ! PISCES-QUOTA
157         DO jk = 1, jpkm1
158            DO jj = 1, jpj
159               DO ji = 1, jpi
160                  ! DOC ammonification. Depends on a limitation term of the bacterial activity
161                  ! and on the implicit bacteria concentration
162                  ! ---------------------------------------------------------------
163                  zremik = xstep / 1.e-6 * MAX(0.01, xlimbac(ji,jj,jk)) * zdepbac(ji,jj,jk) 
164                  zremik = MAX( zremik, 2.74e-4 * xstep / xremikc )
165
166                  zremikc = xremikc * zremik
167                  zremikn = xremikn / xremikc
168                  zremikp = xremikp / xremikc
169
170                  ! Ammonification in oxic waters with oxygen consumption
171                  ! -----------------------------------------------------
172                  zolimit = zremikc * ( 1.- nitrfac(ji,jj,jk) ) * trb(ji,jj,jk,jpdoc) 
173                  zolimic = MAX( 0.e0, MIN( ( trb(ji,jj,jk,jpoxy) - rtrn ) / o2ut, zolimit ) ) 
174                  zolimi(ji,jj,jk) = zolimic
175                  zolimin = zremikn * zolimic * trb(ji,jj,jk,jpdon) / ( trb(ji,jj,jk,jpdoc) + rtrn )
176                  zolimip = zremikp * zolimic * trb(ji,jj,jk,jpdop) / ( trb(ji,jj,jk,jpdoc) + rtrn ) 
177
178                  ! Ammonification in suboxic waters with denitrification
179                  ! -------------------------------------------------------
180                  zammonic = zremikc * nitrfac(ji,jj,jk) * trb(ji,jj,jk,jpdoc)
181                  denitr(ji,jj,jk)  = zammonic * ( 1. - nitrfac2(ji,jj,jk) )
182                  denitr(ji,jj,jk)  = MAX(0., MIN(  ( trb(ji,jj,jk,jpno3) - rtrn ) / rdenit, denitr(ji,jj,jk) ) )
183                  zoxyremc          = MAX(0., zammonic - denitr(ji,jj,jk))
184                  zdenitrn  = zremikn * denitr(ji,jj,jk) * trb(ji,jj,jk,jpdon) / ( trb(ji,jj,jk,jpdoc) + rtrn )
185                  zdenitrp  = zremikp * denitr(ji,jj,jk) * trb(ji,jj,jk,jpdop) / ( trb(ji,jj,jk,jpdoc) + rtrn )
186                  zoxyremn  = zremikn * zoxyremc * trb(ji,jj,jk,jpdon) / ( trb(ji,jj,jk,jpdoc) + rtrn )
187                  zoxyremp  = zremikp * zoxyremc * trb(ji,jj,jk,jpdop) / ( trb(ji,jj,jk,jpdoc) + rtrn )
188                  ! Update of the TRA arrays
189                  tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zolimip + zdenitrp + zoxyremp
190                  tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zolimin + zdenitrn + zoxyremn
191                  tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - denitr(ji,jj,jk) * rdenit
192                  tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zolimic - denitr(ji,jj,jk) - zoxyremc
193                  tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) - zolimin - zdenitrn - zoxyremn
194                  tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) - zolimip - zdenitrp - zoxyremp
195                  tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - zolimic * o2ut
196                  tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zolimic + denitr(ji,jj,jk) + zoxyremc
197                  tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zolimin + zoxyremn + ( rdenit + 1.) * zdenitrn )
198               END DO
199            END DO
200         END DO
201         !
202      ENDIF
203
204      DO jk = 1, jpkm1
205         DO jj = 1, jpj
206            DO ji = 1, jpi
207               ! NH4 nitrification to NO3. Ceased for oxygen concentrations
208               ! below 2 umol/L. Inhibited at strong light
209               ! ----------------------------------------------------------
210               zonitr  = nitrif * xstep * trb(ji,jj,jk,jpnh4) * ( 1.- nitrfac(ji,jj,jk) )  &
211               &         / ( 1.+ emoy(ji,jj,jk) ) * ( 1. + fr_i(ji,jj) * emoy(ji,jj,jk) ) 
212               zdenitnh4 = nitrif * xstep * trb(ji,jj,jk,jpnh4) * nitrfac(ji,jj,jk)
213               zdenitnh4 = MIN(  ( trb(ji,jj,jk,jpno3) - rtrn ) / rdenita, zdenitnh4 ) 
214               ! Update of the tracers trends
215               ! ----------------------------
216               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zonitr - zdenitnh4
217               tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) + zonitr - rdenita * zdenitnh4
218               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2nit * zonitr
219               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2 * rno3 * zonitr + rno3 * ( rdenita - 1. ) * zdenitnh4
220            END DO
221         END DO
222      END DO
223
224       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
225         WRITE(charout, FMT="('rem1')")
226         CALL prt_ctl_trc_info(charout)
227         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
228       ENDIF
229
230      DO jk = 1, jpkm1
231         DO jj = 1, jpj
232            DO ji = 1, jpi
233
234               ! Bacterial uptake of iron. No iron is available in DOC. So
235               ! Bacteria are obliged to take up iron from the water. Some
236               ! studies (especially at Papa) have shown this uptake to be significant
237               ! ---------------------------------------------------------------------
238               zbactfer = feratb *  rfact2 * 0.6_wp / rday * tgfunc(ji,jj,jk) * xlimbacl(ji,jj,jk)     &
239                  &              * trb(ji,jj,jk,jpfer) / ( xkferb + trb(ji,jj,jk,jpfer) )    &
240                  &              * zdepeff(ji,jj,jk) * zdepbac(ji,jj,jk)
241
242               ! Only the transfer of iron from its dissolved form to particles
243               ! is treated here. The GGE of bacteria supposed to be equal to
244               ! 0.33. This is hard-coded.
245               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zbactfer*0.33
246               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zbactfer*0.25
247               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zbactfer*0.08
248               zfebact(ji,jj,jk)   = zbactfer * 0.33
249               blim(ji,jj,jk)      = xlimbacl(ji,jj,jk)  * zdepbac(ji,jj,jk) / 1.e-6
250            END DO
251         END DO
252      END DO
253
254       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
255         WRITE(charout, FMT="('rem2')")
256         CALL prt_ctl_trc_info(charout)
257         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
258       ENDIF
259
260      ! Initialization of the array which contains the labile fraction
261      ! of bSi. Set to a constant in the upper ocean
262      ! ---------------------------------------------------------------
263      DO jk = 1, jpkm1
264         DO jj = 1, jpj
265            DO ji = 1, jpi
266
267               ! Remineralization rate of BSi dependent on T and saturation
268               ! The parameterization is taken from Ridgwell et al. (2002)
269               ! ---------------------------------------------------------
270               zdep     = MAX( hmld(ji,jj), heup_01(ji,jj) )
271               zsatur   = MAX( rtrn, ( sio3eq(ji,jj,jk) - trb(ji,jj,jk,jpsil) ) / ( sio3eq(ji,jj,jk) + rtrn ) )
272               zsatur2  = ( 1. + tsn(ji,jj,jk,jp_tem) / 400.)**37
273               znusil   = 0.225  * ( 1. + tsn(ji,jj,jk,jp_tem) / 15.) * zsatur + 0.775 * zsatur2 * zsatur**9.25
274
275               ! Two fractions of bSi are considered : a labile one and a more
276               ! refractory one based on the commonly observed two step
277               ! dissolution of bSi (initial rapid dissolution followed by
278               ! more slowly dissolution).
279               ! Computation of the vertical evolution of the labile fraction
280               ! of bSi. This is computed assuming steady state.
281               ! --------------------------------------------------------------
282               IF ( gdept_n(ji,jj,jk) > zdep ) THEN
283                  zfacsib(ji,jj,jk) = zfacsib(ji,jj,jk-1) * EXP( -0.5 * ( xsiremlab - xsirem )  &
284                  &                   * znusil * e3t_n(ji,jj,jk) / wsbio4(ji,jj,jk) )
285                  zfacsi(ji,jj,jk)  = zfacsib(ji,jj,jk) / ( 1.0 + zfacsib(ji,jj,jk) )
286                  zfacsib(ji,jj,jk) = zfacsib(ji,jj,jk) * EXP( -0.5 * ( xsiremlab - xsirem )    &
287                  &                   * znusil * e3t_n(ji,jj,jk) / wsbio4(ji,jj,jk) )
288               ENDIF
289               zsiremin = ( xsiremlab * zfacsi(ji,jj,jk) + xsirem * ( 1. - zfacsi(ji,jj,jk) ) ) * xstep * znusil
290               zosil    = zsiremin * trb(ji,jj,jk,jpgsi)
291
292               ! Update of the TRA arrays
293               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) - zosil
294               tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) + zosil
295            END DO
296         END DO
297      END DO
298
299      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
300         WRITE(charout, FMT="('rem3')")
301         CALL prt_ctl_trc_info(charout)
302         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
303       ENDIF
304
305      IF( knt == nrdttrc ) THEN
306          zrfact2 = 1.e3 * rfact2r
307          ALLOCATE( zw3d(jpi,jpj,jpk) )
308          zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
309          !
310          IF( iom_use( "REMIN" ) )  THEN
311              zw3d(:,:,:) = zolimi(:,:,:) * tmask(:,:,:) * zfact !  Remineralisation rate
312              CALL iom_put( "REMIN"  , zw3d )
313          ENDIF
314          IF( iom_use( "DENIT" ) )  THEN
315              zw3d(:,:,:) = denitr(:,:,:) * rdenit * rno3 * tmask(:,:,:) * zfact ! Denitrification
316              CALL iom_put( "DENIT"  , zw3d )
317          ENDIF
318          IF( iom_use( "BACT" ) )  THEN
319               zw3d(:,:,:) = zdepbac(:,:,:) * 1.E6 * tmask(:,:,:)  ! Bacterial biomass
320               CALL iom_put( "BACT", zw3d )
321          ENDIF
322          IF( iom_use( "FEBACT" ) )  THEN
323               zw3d(:,:,:) = zfebact(:,:,:) * 1E9 * tmask(:,:,:) * zrfact2   ! Bacterial iron consumption
324               CALL iom_put( "FEBACT" , zw3d )
325          ENDIF
326          !
327          DEALLOCATE( zw3d )
328       ENDIF
329      !
330      IF( ln_timing )   CALL timing_stop('p4z_rem')
331      !
332   END SUBROUTINE p4z_rem
333
334
335   SUBROUTINE p4z_rem_init
336      !!----------------------------------------------------------------------
337      !!                  ***  ROUTINE p4z_rem_init  ***
338      !!
339      !! ** Purpose :   Initialization of remineralization parameters
340      !!
341      !! ** Method  :   Read the nampisrem namelist and check the parameters
342      !!      called at the first timestep
343      !!
344      !! ** input   :   Namelist nampisrem
345      !!
346      !!----------------------------------------------------------------------
347      NAMELIST/nampisrem/ xremik, nitrif, xsirem, xsiremlab, xsilab, feratb, xkferb, & 
348         &                xremikc, xremikn, xremikp
349      INTEGER :: ios                 ! Local integer output status for namelist read
350      !!----------------------------------------------------------------------
351      !
352      IF(lwp) THEN
353         WRITE(numout,*)
354         WRITE(numout,*) 'p4z_rem_init : Initialization of remineralization parameters'
355         WRITE(numout,*) '~~~~~~~~~~~~'
356      ENDIF
357      !
358      REWIND( numnatp_ref )              ! Namelist nampisrem in reference namelist : Pisces remineralization
359      READ  ( numnatp_ref, nampisrem, IOSTAT = ios, ERR = 901)
360901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampisrem in reference namelist' )
361      REWIND( numnatp_cfg )              ! Namelist nampisrem in configuration namelist : Pisces remineralization
362      READ  ( numnatp_cfg, nampisrem, IOSTAT = ios, ERR = 902 )
363902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampisrem in configuration namelist' )
364      IF(lwm) WRITE( numonp, nampisrem )
365
366      IF(lwp) THEN                         ! control print
367         WRITE(numout,*) '   Namelist parameters for remineralization, nampisrem'
368         IF( ln_p4z ) THEN
369            WRITE(numout,*) '      remineralization rate of DOC              xremik    =', xremik
370         ELSE
371            WRITE(numout,*) '      remineralization rate of DOC              xremikc   =', xremikc
372            WRITE(numout,*) '      remineralization rate of DON              xremikn   =', xremikn
373            WRITE(numout,*) '      remineralization rate of DOP              xremikp   =', xremikp
374         ENDIF
375         WRITE(numout,*) '      remineralization rate of Si               xsirem    =', xsirem
376         WRITE(numout,*) '      fast remineralization rate of Si          xsiremlab =', xsiremlab
377         WRITE(numout,*) '      fraction of labile biogenic silica        xsilab    =', xsilab
378         WRITE(numout,*) '      NH4 nitrification rate                    nitrif    =', nitrif
379         WRITE(numout,*) '      Bacterial Fe/C ratio                      feratb    =', feratb
380         WRITE(numout,*) '      Half-saturation constant for bact. Fe/C   xkferb    =', xkferb
381      ENDIF
382      !
383      denitr(:,:,:) = 0._wp
384      !
385   END SUBROUTINE p4z_rem_init
386
387
388   INTEGER FUNCTION p4z_rem_alloc()
389      !!----------------------------------------------------------------------
390      !!                     ***  ROUTINE p4z_rem_alloc  ***
391      !!----------------------------------------------------------------------
392      ALLOCATE( denitr(jpi,jpj,jpk), STAT=p4z_rem_alloc )
393      !
394      IF( p4z_rem_alloc /= 0 )   CALL ctl_stop( 'STOP', 'p4z_rem_alloc: failed to allocate arrays' )
395      !
396   END FUNCTION p4z_rem_alloc
397
398   !!======================================================================
399END MODULE p4zrem
Note: See TracBrowser for help on using the repository browser.