New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p5zmicro.F90 in NEMO/branches/2019/dev_r11708_aumont_PISCES_QUOTA/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2019/dev_r11708_aumont_PISCES_QUOTA/src/TOP/PISCES/P4Z/p5zmicro.F90 @ 12349

Last change on this file since 12349 was 12349, checked in by aumont, 4 years ago

update of the quota version of PISCES + some corrections of the GGE of zooplankton
  • Property svn:keywords set to Id
File size: 23.7 KB
Line 
1MODULE p5zmicro
2   !!======================================================================
3   !!                         ***  MODULE p5zmicro  ***
4   !! TOP :   PISCES Compute the sources/sinks for microzooplankton
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
10   !!----------------------------------------------------------------------
11   !!   p5z_micro       :   Compute the sources/sinks for microzooplankton
12   !!   p5z_micro_init  :   Initialize and read the appropriate namelist
13   !!----------------------------------------------------------------------
14   USE oce_trc         !  shared variables between ocean and passive tracers
15   USE trc             !  passive tracers common variables
16   USE sms_pisces      !  PISCES Source Minus Sink variables
17   USE p4zlim
18   USE p5zlim          !  Phytoplankton limitation terms
19   USE iom             !  I/O manager
20   USE prtctl_trc      !  print control for debugging
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC   p5z_micro         ! called in p5zbio.F90
26   PUBLIC   p5z_micro_init    ! called in trcsms_pisces.F90
27
28   !! * Shared module variables
29   REAL(wp), PUBLIC ::  part        !: part of calcite not dissolved in microzoo guts
30   REAL(wp), PUBLIC ::  xprefc     !: microzoo preference for POC
31   REAL(wp), PUBLIC ::  xprefn     !: microzoo preference for nanophyto
32   REAL(wp), PUBLIC ::  xprefp     !: microzoo preference for picophyto
33   REAL(wp), PUBLIC ::  xprefd     !: microzoo preference for diatoms
34   REAL(wp), PUBLIC ::  xprefz     !: microzoo preference for microzoo
35   REAL(wp), PUBLIC ::  xthreshdia  !: diatoms feeding threshold for microzooplankton
36   REAL(wp), PUBLIC ::  xthreshpic  !: picophyto feeding threshold for microzooplankton
37   REAL(wp), PUBLIC ::  xthreshphy  !: nanophyto threshold for microzooplankton
38   REAL(wp), PUBLIC ::  xthreshzoo  !: microzoo threshold for microzooplankton
39   REAL(wp), PUBLIC ::  xthreshpoc  !: poc threshold for microzooplankton
40   REAL(wp), PUBLIC ::  xthresh     !: feeding threshold for microzooplankton
41   REAL(wp), PUBLIC ::  resrat      !: exsudation rate of microzooplankton
42   REAL(wp), PUBLIC ::  mzrat       !: microzooplankton mortality rate
43   REAL(wp), PUBLIC ::  grazrat     !: maximal microzoo grazing rate
44   REAL(wp), PUBLIC ::  xkgraz      !: Half-saturation constant of assimilation
45   REAL(wp), PUBLIC ::  unassc      !: Non-assimilated part of food
46   REAL(wp), PUBLIC ::  unassn      !: Non-assimilated part of food
47   REAL(wp), PUBLIC ::  unassp      !: Non-assimilated part of food
48   REAL(wp), PUBLIC ::  epsher      !: Growth efficiency for microzoo
49   REAL(wp), PUBLIC ::  epshermin   !: Minimum growth efficiency for microzoo
50   REAL(wp), PUBLIC ::  srespir     !: half sturation constant for grazing 1
51   REAL(wp), PUBLIC ::  ssigma      !: Fraction excreted as semi-labile DOM
52   LOGICAL,  PUBLIC ::  bmetexc     !: Use of excess carbon for respiration
53
54   !!----------------------------------------------------------------------
55   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
56   !! $Id$
57   !! Software governed by the CeCILL license (see ./LICENSE)
58   !!----------------------------------------------------------------------
59
60CONTAINS
61
62   SUBROUTINE p5z_micro( kt, knt )
63      !!---------------------------------------------------------------------
64      !!                     ***  ROUTINE p5z_micro  ***
65      !!
66      !! ** Purpose :   Compute the sources/sinks for microzooplankton
67      !!
68      !! ** Method  : - ???
69      !!---------------------------------------------------------------------
70      INTEGER, INTENT(in) ::  kt  ! ocean time step
71      INTEGER, INTENT(in) ::  knt 
72      !
73      INTEGER  :: ji, jj, jk
74      REAL(wp) :: zcompadi, zcompaz , zcompaph, zcompapoc, zcompapon, zcompapop
75      REAL(wp) :: zcompapi, zgraze  , zdenom, zfact, zfood, zfoodlim
76      REAL(wp) :: ztmp1, ztmp2, ztmp3, ztmp4, ztmp5, ztmptot
77      REAL(wp) :: zepsherf, zepshert, zepsherq, zepsherv, zrespirc, zrespirn, zrespirp, zbasresb, zbasresi
78      REAL(wp) :: zgraztotc, zgraztotn, zgraztotp, zgraztotf, zbasresn, zbasresp, zbasresf
79      REAL(wp) :: zgradoc, zgradon, zgradop, zgraref, zgradoct, zgradont, zgradopt, zgrareft
80      REAL(wp) :: zexcess, zgraren, zgrarep, zgrarem
81      REAL(wp) :: zgrapoc, zgrapon, zgrapop, zgrapof, zprcaca, zmortz
82      REAL(wp) :: zrespz, ztortz, zgrasratf, zgrasratn, zgrasratp
83      REAL(wp) :: zgraznc, zgraznn, zgraznp, zgrazpoc, zgrazpon, zgrazpop, zgrazpof
84      REAL(wp) :: zgrazdc, zgrazdn, zgrazdp, zgrazdf, zgraznf, zgrazz
85      REAL(wp) :: zgrazpc, zgrazpn, zgrazpp, zgrazpf, zbeta, zrfact2, zmetexcess
86      REAL(wp) :: zsigma, zdiffdn, zdiffpn, zdiffdp, zproport, zproport2
87      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zgrazing, zfezoo
88      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: zw3d, zzligprod
89      CHARACTER (len=25) :: charout
90      !!---------------------------------------------------------------------
91      !
92      IF( ln_timing )   CALL timing_start('p5z_micro')
93      !
94      IF (ln_ligand) THEN
95         ALLOCATE( zzligprod(jpi,jpj,jpk) )
96         zzligprod(:,:,:) = 0._wp
97      ENDIF
98      !
99      zmetexcess = 0.0
100      IF ( bmetexc ) zmetexcess = 1.0
101      !
102      DO jk = 1, jpkm1
103         DO jj = 1, jpj
104            DO ji = 1, jpi
105               zcompaz = MAX( ( trb(ji,jj,jk,jpzoo) - 1.e-9 ), 0.e0 )
106               zfact   = xstep * tgfunc2(ji,jj,jk) * zcompaz
107               ! Proportion of nano and diatoms that are within the size range
108               ! accessible to microzooplankton.
109               zproport  = min(1.0, exp(-1.1 * MAX(0., ( sized(ji,jj,jk) - 1.8 ))**0.8 ))
110               zproport2 = sizen(ji,jj,jk)**(-0.54)
111               !   Michaelis-Menten mortality rates of microzooplankton
112               !   -----------------------------------------------------
113               zrespz = resrat * zfact * ( trb(ji,jj,jk,jpzoo) / ( xkmort + trb(ji,jj,jk,jpzoo) )  &
114               &        + 3. * nitrfac(ji,jj,jk) )
115
116               !   Zooplankton mortality. A square function has been selected with
117               !   no real reason except that it seems to be more stable and may mimic predation.
118               !   ------------------------------------------------------------------------------
119               ztortz = mzrat * 1.e6 * zfact * trb(ji,jj,jk,jpzoo) * (1. - nitrfac(ji,jj,jk))
120
121               !   Computation of the abundance of the preys
122               !   A threshold can be specified in the namelist
123               !   --------------------------------------------
124               zcompadi  = zproport * MAX( ( trb(ji,jj,jk,jpdia) - xthreshdia ), 0.e0 )
125               zcompaph  = zproport2 * MAX( ( trb(ji,jj,jk,jpphy) - xthreshphy ), 0.e0 )
126               zcompaz   = MAX( ( trb(ji,jj,jk,jpzoo) - xthreshzoo ), 0.e0 )
127               zcompapi  = MAX( ( trb(ji,jj,jk,jppic) - xthreshpic ), 0.e0 )
128               zcompapoc = MAX( ( trb(ji,jj,jk,jppoc) - xthreshpoc ), 0.e0 )
129               
130               !   Microzooplankton grazing
131               !   ------------------------
132               zfood     = xprefn * zcompaph + xprefc * zcompapoc + xprefd * zcompadi   &
133               &           + xprefz * zcompaz + xprefp * zcompapi
134               zfoodlim  = MAX( 0. , zfood - min(xthresh,0.5*zfood) )
135               zdenom    = zfoodlim / ( xkgraz + zfoodlim )
136               zgraze    = grazrat * xstep * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jpzoo) * (1. - nitrfac(ji,jj,jk)) 
137
138               !   An active switching parameterization is used here.
139               !   We don't use the KTW parameterization proposed by
140               !   Vallina et al. because it tends to produce to steady biomass
141               !   composition and the variance of Chl is too low as it grazes
142               !   too strongly on winning organisms. Thus, instead of a square
143               !   a 1.5 power value is used which decreases the pressure on the
144               !   most abundant species
145               !   ------------------------------------------------------------ 
146               zsigma = 1.0 - zdenom**2/(0.05**2+zdenom**2)
147               zsigma = 0.5 + 1.0*zsigma
148               zdiffpn = exp( -ABS(log(0.5 * sizep(ji,jj,jk) / (3.0 * sizen(ji,jj,jk) + rtrn )) )**2 / zsigma**2 )
149               zdiffdn = exp( -ABS(log(3.0 * sizen(ji,jj,jk) / (5.0 * sized(ji,jj,jk) + rtrn )) )**2 / zsigma**2)
150               zdiffdp = exp( -ABS(log(0.5 * sizep(ji,jj,jk) / (5.0 * sized(ji,jj,jk) + rtrn )) )**2 / zsigma**2)
151               ztmp1 = xprefn * zcompaph * ( zcompaph + zdiffdn * zcompadi + zdiffpn * zcompapi ) / ( 1.0 + zdiffdn + zdiffpn )
152               ztmp2 = xprefp * zcompapi * ( zcompapi + zdiffpn * zcompaph + zdiffdp * zcompadi ) / ( 1.0 + zdiffpn + zdiffdp )
153               ztmp3 = xprefc * zcompapoc**2
154               ztmp4 = xprefd * zcompadi * ( zdiffdp * zcompapi + zdiffdn * zcompaph + zcompadi ) / ( 1.0 + zdiffdn + zdiffdp )
155               ztmp5 = xprefz * zcompaz**2
156               ztmptot = ztmp1 + ztmp2 + ztmp3 + ztmp4 + ztmp5 + rtrn
157               ztmp1 = ztmp1 / ztmptot
158               ztmp2 = ztmp2 / ztmptot
159               ztmp3 = ztmp3 / ztmptot
160               ztmp4 = ztmp4 / ztmptot
161               ztmp5 = ztmp5 / ztmptot
162
163               !   Microzooplankton regular grazing on the different preys
164               !   -------------------------------------------------------
165               zgraznc   = zgraze  * ztmp1  * zdenom
166               zgraznn   = zgraznc * trb(ji,jj,jk,jpnph) / (trb(ji,jj,jk,jpphy) + rtrn)
167               zgraznp   = zgraznc * trb(ji,jj,jk,jppph) / (trb(ji,jj,jk,jpphy) + rtrn)
168               zgraznf   = zgraznc * trb(ji,jj,jk,jpnfe) / (trb(ji,jj,jk,jpphy) + rtrn)
169               zgrazpc   = zgraze  * ztmp2  * zdenom
170               zgrazpn   = zgrazpc * trb(ji,jj,jk,jpnpi) / (trb(ji,jj,jk,jppic) + rtrn)
171               zgrazpp   = zgrazpc * trb(ji,jj,jk,jpppi) / (trb(ji,jj,jk,jppic) + rtrn)
172               zgrazpf   = zgrazpc * trb(ji,jj,jk,jppfe) / (trb(ji,jj,jk,jppic) + rtrn)
173               zgrazz    = zgraze  * ztmp5   * zdenom
174               zgrazpoc  = zgraze  * ztmp3   * zdenom
175               zgrazpon  = zgrazpoc * trb(ji,jj,jk,jppon) / ( trb(ji,jj,jk,jppoc) + rtrn )
176               zgrazpop  = zgrazpoc * trb(ji,jj,jk,jppop) / ( trb(ji,jj,jk,jppoc) + rtrn )
177               zgrazpof  = zgrazpoc* trb(ji,jj,jk,jpsfe) / (trb(ji,jj,jk,jppoc) + rtrn)
178               zgrazdc   = zgraze  * ztmp4  * zdenom
179               zgrazdn   = zgrazdc * trb(ji,jj,jk,jpndi) / (trb(ji,jj,jk,jpdia) + rtrn)
180               zgrazdp   = zgrazdc * trb(ji,jj,jk,jppdi) / (trb(ji,jj,jk,jpdia) + rtrn)
181               zgrazdf   = zgrazdc * trb(ji,jj,jk,jpdfe) / (trb(ji,jj,jk,jpdia) + rtrn)
182               !
183               zgraztotc = zgraznc + zgrazpoc + zgrazdc + zgrazz + zgrazpc
184               zgraztotn = zgraznn + zgrazpn + zgrazpon + zgrazdn + zgrazz * no3rat3
185               zgraztotp = zgraznp + zgrazpp + zgrazpop + zgrazdp + zgrazz * po4rat3
186               zgraztotf = zgraznf + zgrazpf + zgrazpof + zgrazdf + zgrazz * ferat3
187               !
188               ! Grazing by microzooplankton
189               zgrazing(ji,jj,jk) = zgraztotc
190
191               !   Stoichiometruc ratios of the food ingested by zooplanton
192               !   --------------------------------------------------------
193               zgrasratf =  (zgraztotf + rtrn) / ( zgraztotc + rtrn )
194               zgrasratn =  (zgraztotn + rtrn) / ( zgraztotc + rtrn )
195               zgrasratp =  (zgraztotp + rtrn) / ( zgraztotc + rtrn )
196
197               !   Growth efficiency is made a function of the quality
198               !   and the quantity of the preys
199               !   ---------------------------------------------------
200               zepshert  = MIN( 1., zgrasratn/ no3rat3, zgrasratp/ po4rat3, zgrasratf / ferat3)
201               zbeta     = MAX( 0., (epsher - epshermin) )
202               zepsherf  = epshermin + zbeta / ( 1.0 + 0.04E6 * 12. * zfood * zbeta )
203               zepsherq  = 0.5 + (1.0 - 0.5) * zepshert * ( 1.0 + 1.0 ) / ( zepshert + 1.0 )
204               zepsherv  = zepsherf * zepshert * zepsherq
205
206               !   Respiration of microzooplankton
207               !   Excess carbon in the food is used preferentially
208               !   ------------------------------------------------
209               zexcess  = zgraztotc * zepsherf * (1.0 - zepshert) * zmetexcess
210               zbasresb = MAX(0., zrespz - zexcess)
211               zbasresi = zexcess + MIN(0., zrespz - zexcess) 
212               zrespirc = srespir * zepsherv * zgraztotc + zbasresb
213               
214               !   When excess carbon is used, the other elements in excess
215               !   are also used proportionally to their abundance
216               !   --------------------------------------------------------
217               zexcess  = ( zgrasratn/ no3rat3 - zepshert ) / ( 1.0 - zepshert + rtrn)
218               zbasresn = zbasresi * zexcess * zgrasratn 
219               zexcess  = ( zgrasratp/ po4rat3 - zepshert ) / ( 1.0 - zepshert + rtrn)
220               zbasresp = zbasresi * zexcess * zgrasratp
221               zexcess  = ( zgrasratf/ ferat3 - zepshert ) / ( 1.0 - zepshert + rtrn)
222               zbasresf = zbasresi * zexcess * zgrasratf
223
224               !   Voiding of the excessive elements as DOM
225               !   ----------------------------------------
226               zgradoct   = (1. - unassc - zepsherv) * zgraztotc - zbasresi 
227               zgradont   = (1. - unassn) * zgraztotn - zepsherv * no3rat3 * zgraztotc - zbasresn
228               zgradopt   = (1. - unassp) * zgraztotp - zepsherv * po4rat3 * zgraztotc - zbasresp
229               zgrareft   = (1. - unassc) * zgraztotf - zepsherv * ferat3 * zgraztotc - zbasresf
230
231               !  Since only semilabile DOM is represented in PISCES
232               !  part of DOM is in fact labile and is then released
233               !  as dissolved inorganic compounds (ssigma)
234               !  --------------------------------------------------
235               zgradoc =  zgradoct * ssigma
236               zgradon =  zgradont * ssigma
237               zgradop =  zgradopt * ssigma
238               zgrarem = (1.0 - ssigma) * zgradoct
239               zgraren = (1.0 - ssigma) * zgradont
240               zgrarep = (1.0 - ssigma) * zgradopt
241               zgraref = zgrareft
242
243               !   Defecation as a result of non assimilated products
244               !   --------------------------------------------------
245               zgrapoc   = zgraztotc * unassc
246               zgrapon   = zgraztotn * unassn
247               zgrapop   = zgraztotp * unassp
248               zgrapof   = zgraztotf * unassc
249
250               !  Addition of respiration to the release of inorganic nutrients
251               !  -------------------------------------------------------------
252               zgrarem = zgrarem + zbasresi + zrespirc
253               zgraren = zgraren + zbasresn + zrespirc * no3rat3
254               zgrarep = zgrarep + zbasresp + zrespirc * po4rat3
255               zgraref = zgraref + zbasresf + zrespirc * ferat3
256
257               !   Update of the TRA arrays
258               !   ------------------------
259               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zgrarep
260               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zgraren
261               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zgradoc
262               !
263               IF( ln_ligand ) THEN
264                  tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) + zgradoc * ldocz
265                  zzligprod(ji,jj,jk) = zgradoc * ldocz
266               ENDIF
267               !
268               tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) + zgradon
269               tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) + zgradop
270               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2ut * zgrarem 
271               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zgraref
272               zfezoo(ji,jj,jk)    = zgraref
273               tra(ji,jj,jk,jpzoo) = tra(ji,jj,jk,jpzoo) + zepsherv * zgraztotc - zrespirc - ztortz - zgrazz
274               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zgraznc
275               tra(ji,jj,jk,jpnph) = tra(ji,jj,jk,jpnph) - zgraznn
276               tra(ji,jj,jk,jppph) = tra(ji,jj,jk,jppph) - zgraznp
277               tra(ji,jj,jk,jppic) = tra(ji,jj,jk,jppic) - zgrazpc
278               tra(ji,jj,jk,jpnpi) = tra(ji,jj,jk,jpnpi) - zgrazpn
279               tra(ji,jj,jk,jpppi) = tra(ji,jj,jk,jpppi) - zgrazpp
280               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zgrazdc
281               tra(ji,jj,jk,jpndi) = tra(ji,jj,jk,jpndi) - zgrazdn
282               tra(ji,jj,jk,jppdi) = tra(ji,jj,jk,jppdi) - zgrazdp
283               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zgraznc * trb(ji,jj,jk,jpnch)/(trb(ji,jj,jk,jpphy)+rtrn)
284               tra(ji,jj,jk,jppch) = tra(ji,jj,jk,jppch) - zgrazpc * trb(ji,jj,jk,jppch)/(trb(ji,jj,jk,jppic)+rtrn)
285               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zgrazdc * trb(ji,jj,jk,jpdch)/(trb(ji,jj,jk,jpdia)+rtrn)
286               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) - zgrazdc * trb(ji,jj,jk,jpdsi)/(trb(ji,jj,jk,jpdia)+rtrn)
287               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) + zgrazdc * trb(ji,jj,jk,jpdsi)/(trb(ji,jj,jk,jpdia)+rtrn)
288               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zgraznf
289               tra(ji,jj,jk,jppfe) = tra(ji,jj,jk,jppfe) - zgrazpf
290               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zgrazdf
291               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + ztortz + zgrapoc - zgrazpoc 
292               prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + ztortz + zgrapoc
293               conspoc(ji,jj,jk) = conspoc(ji,jj,jk) - zgrazpoc
294               tra(ji,jj,jk,jppon) = tra(ji,jj,jk,jppon) + no3rat3 * ztortz + zgrapon - zgrazpon
295               tra(ji,jj,jk,jppop) = tra(ji,jj,jk,jppop) + po4rat3 * ztortz + zgrapop - zgrazpop
296               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + ferat3 * ztortz  + zgrapof - zgrazpof
297               !
298               ! calcite production
299               zprcaca = xfracal(ji,jj,jk) * zgraznc
300               prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
301               !
302               zprcaca = part * zprcaca
303               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrarem - zprcaca
304               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * zprcaca     &
305               &                     + rno3 * zgraren
306               tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) + zprcaca
307            END DO
308         END DO
309      END DO
310      !
311      IF( lk_iomput ) THEN
312         IF( knt == nrdttrc ) THEN
313            ALLOCATE( zw3d(jpi,jpj,jpk) )
314            IF( iom_use( "GRAZ1" ) ) THEN
315               zw3d(:,:,:) = zgrazing(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:)  !  Total grazing of phyto by zooplankton
316               CALL iom_put( "GRAZ1", zw3d )
317            ENDIF
318            IF( iom_use( "FEZOO" ) ) THEN
319               zw3d(:,:,:) = zfezoo(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:)   !
320               CALL iom_put( "FEZOO", zw3d )
321            ENDIF
322            IF( iom_use( "LPRODZ" ) .AND. ln_ligand )  THEN
323               zw3d(:,:,:) = zzligprod(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:)
324               CALL iom_put( "LPRODZ"  , zw3d )
325            ENDIF
326            DEALLOCATE( zw3d )
327         ENDIF
328      ENDIF
329      !
330      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
331         WRITE(charout, FMT="('micro')")
332         CALL prt_ctl_trc_info(charout)
333         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
334      ENDIF
335      !
336      IF( ln_timing )   CALL timing_stop('p5z_micro')
337      !
338   END SUBROUTINE p5z_micro
339
340
341   SUBROUTINE p5z_micro_init
342      !!----------------------------------------------------------------------
343      !!                  ***  ROUTINE p5z_micro_init  ***
344      !!
345      !! ** Purpose :   Initialization of microzooplankton parameters
346      !!
347      !! ** Method  :   Read the nampiszoo namelist and check the parameters
348      !!                called at the first timestep (nittrc000)
349      !!
350      !! ** input   :   Namelist nampiszoo
351      !!
352      !!----------------------------------------------------------------------
353      INTEGER ::   ios   ! Local integer
354      !!
355      NAMELIST/namp5zzoo/ part, grazrat, bmetexc, resrat, mzrat, xprefc, xprefn, &
356         &                xprefp, xprefd, xprefz, xthreshdia, xthreshphy, &
357         &                xthreshpic, xthreshpoc, xthreshzoo, xthresh, xkgraz, &
358         &                epsher, epshermin, ssigma, srespir, unassc, unassn, unassp
359      !!----------------------------------------------------------------------
360      !
361      REWIND( numnatp_ref )              ! Namelist nampiszoo in reference namelist : Pisces microzooplankton
362      READ  ( numnatp_ref, namp5zzoo, IOSTAT = ios, ERR = 901)
363901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp5zzoo in reference namelist' )
364      !
365      REWIND( numnatp_cfg )              ! Namelist nampiszoo in configuration namelist : Pisces microzooplankton
366      READ  ( numnatp_cfg, namp5zzoo, IOSTAT = ios, ERR = 902 )
367902   IF( ios >  0 ) CALL ctl_nam ( ios , 'namp5zzoo in configuration namelist' )
368      IF(lwm) WRITE ( numonp, namp5zzoo )
369      !
370      IF(lwp) THEN                         ! control print
371         WRITE(numout,*) ' '
372         WRITE(numout,*) ' Namelist parameters for microzooplankton, nampiszooq'
373         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
374         WRITE(numout,*) '    part of calcite not dissolved in microzoo guts  part        =', part
375         WRITE(numout,*) '    microzoo preference for POC                     xprefc     =', xprefc
376         WRITE(numout,*) '    microzoo preference for nano                    xprefn     =', xprefn
377         WRITE(numout,*) '    microzoo preference for pico                    xprefp     =', xprefp
378         WRITE(numout,*) '    microzoo preference for diatoms                 xprefd     =', xprefd
379         WRITE(numout,*) '    microzoo preference for microzoo                xprefz     =', xprefz
380         WRITE(numout,*) '    diatoms feeding threshold  for microzoo         xthreshdia  =', xthreshdia
381         WRITE(numout,*) '    nanophyto feeding threshold for microzoo        xthreshphy  =', xthreshphy
382         WRITE(numout,*) '    picophyto feeding threshold for microzoo        xthreshpic  =', xthreshpic
383         WRITE(numout,*) '    poc feeding threshold for microzoo              xthreshpoc  =', xthreshpoc
384         WRITE(numout,*) '    microzoo feeding threshold for microzoo         xthreshzoo  =', xthreshzoo
385         WRITE(numout,*) '    feeding threshold for microzooplankton          xthresh     =', xthresh
386         WRITE(numout,*) '    exsudation rate of microzooplankton             resrat      =', resrat
387         WRITE(numout,*) '    microzooplankton mortality rate                 mzrat       =', mzrat
388         WRITE(numout,*) '    maximal microzoo grazing rate                   grazrat     =', grazrat
389         WRITE(numout,*) '    C egested fraction of fodd by microzoo          unassc      =', unassc
390         WRITE(numout,*) '    N egested fraction of fodd by microzoo          unassn      =', unassn
391         WRITE(numout,*) '    P egested fraction of fodd by microzoo          unassp      =', unassp
392         WRITE(numout,*) '    Efficicency of microzoo growth                  epsher      =', epsher
393         WRITE(numout,*) '    Minimum Efficiency of Microzoo growth           epshermin   =', epshermin
394         WRITE(numout,*) '    Fraction excreted as semi-labile DOM            ssigma      =', ssigma
395         WRITE(numout,*) '    Active respiration                              srespir     =', srespir
396         WRITE(numout,*) '    half sturation constant for grazing 1           xkgraz      =', xkgraz
397         WRITE(numout,*) '    Use of excess carbon for respiration            bmetexc     =', bmetexc
398      ENDIF
399      !
400   END SUBROUTINE p5z_micro_init
401
402   !!======================================================================
403END MODULE p5zmicro
Note: See TracBrowser for help on using the repository browser.