New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p5zmicro.F90 in NEMO/branches/2019/dev_r11708_aumont_PISCES_QUOTA/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2019/dev_r11708_aumont_PISCES_QUOTA/src/TOP/PISCES/P4Z/p5zmicro.F90 @ 12537

Last change on this file since 12537 was 12537, checked in by aumont, 4 years ago

Comments in routines have been revised and significantly augmented

  • Property svn:keywords set to Id
File size: 25.4 KB
Line 
1MODULE p5zmicro
2   !!======================================================================
3   !!                         ***  MODULE p5zmicro  ***
4   !! TOP :   PISCES Compute the sources/sinks for microzooplankton
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
10   !!----------------------------------------------------------------------
11   !!   p5z_micro       :   Compute the sources/sinks for microzooplankton
12   !!   p5z_micro_init  :   Initialize and read the appropriate namelist
13   !!----------------------------------------------------------------------
14   USE oce_trc         !  shared variables between ocean and passive tracers
15   USE trc             !  passive tracers common variables
16   USE sms_pisces      !  PISCES Source Minus Sink variables
17   USE p4zlim
18   USE p5zlim          !  Phytoplankton limitation terms
19   USE iom             !  I/O manager
20   USE prtctl_trc      !  print control for debugging
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC   p5z_micro         ! called in p5zbio.F90
26   PUBLIC   p5z_micro_init    ! called in trcsms_pisces.F90
27
28   !! * Shared module variables
29   REAL(wp), PUBLIC ::  part        !: part of calcite not dissolved in microzoo guts
30   REAL(wp), PUBLIC ::  xprefc     !: microzoo preference for POC
31   REAL(wp), PUBLIC ::  xprefn     !: microzoo preference for nanophyto
32   REAL(wp), PUBLIC ::  xprefp     !: microzoo preference for picophyto
33   REAL(wp), PUBLIC ::  xprefd     !: microzoo preference for diatoms
34   REAL(wp), PUBLIC ::  xprefz     !: microzoo preference for microzoo
35   REAL(wp), PUBLIC ::  xthreshdia  !: diatoms feeding threshold for microzooplankton
36   REAL(wp), PUBLIC ::  xthreshpic  !: picophyto feeding threshold for microzooplankton
37   REAL(wp), PUBLIC ::  xthreshphy  !: nanophyto threshold for microzooplankton
38   REAL(wp), PUBLIC ::  xthreshzoo  !: microzoo threshold for microzooplankton
39   REAL(wp), PUBLIC ::  xthreshpoc  !: poc threshold for microzooplankton
40   REAL(wp), PUBLIC ::  xthresh     !: feeding threshold for microzooplankton
41   REAL(wp), PUBLIC ::  resrat      !: exsudation rate of microzooplankton
42   REAL(wp), PUBLIC ::  mzrat       !: microzooplankton mortality rate
43   REAL(wp), PUBLIC ::  grazrat     !: maximal microzoo grazing rate
44   REAL(wp), PUBLIC ::  xkgraz      !: Half-saturation constant of assimilation
45   REAL(wp), PUBLIC ::  unassc      !: Non-assimilated part of food
46   REAL(wp), PUBLIC ::  unassn      !: Non-assimilated part of food
47   REAL(wp), PUBLIC ::  unassp      !: Non-assimilated part of food
48   REAL(wp), PUBLIC ::  epsher      !: Growth efficiency for microzoo
49   REAL(wp), PUBLIC ::  epshermin   !: Minimum growth efficiency for microzoo
50   REAL(wp), PUBLIC ::  srespir     !: half sturation constant for grazing 1
51   REAL(wp), PUBLIC ::  ssigma      !: Fraction excreted as semi-labile DOM
52   LOGICAL,  PUBLIC ::  bmetexc     !: Use of excess carbon for respiration
53
54   !!----------------------------------------------------------------------
55   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
56   !! $Id$
57   !! Software governed by the CeCILL license (see ./LICENSE)
58   !!----------------------------------------------------------------------
59
60CONTAINS
61
62   SUBROUTINE p5z_micro( kt, knt )
63      !!---------------------------------------------------------------------
64      !!                     ***  ROUTINE p5z_micro  ***
65      !!
66      !! ** Purpose :   Compute the sources/sinks for microzooplankton
67      !!
68      !! ** Method  : - ???
69      !!---------------------------------------------------------------------
70      INTEGER, INTENT(in) ::  kt  ! ocean time step
71      INTEGER, INTENT(in) ::  knt 
72      !
73      INTEGER  :: ji, jj, jk
74      REAL(wp) :: zcompadi, zcompaz , zcompaph, zcompapoc, zcompapon, zcompapop
75      REAL(wp) :: zcompapi, zgraze  , zdenom, zfact, zfood, zfoodlim
76      REAL(wp) :: ztmp1, ztmp2, ztmp3, ztmp4, ztmp5, ztmptot
77      REAL(wp) :: zepsherf, zepshert, zepsherq, zepsherv, zrespirc, zrespirn, zrespirp, zbasresb, zbasresi
78      REAL(wp) :: zgraztotc, zgraztotn, zgraztotp, zgraztotf, zbasresn, zbasresp, zbasresf
79      REAL(wp) :: zgradoc, zgradon, zgradop, zgraref, zgradoct, zgradont, zgradopt, zgrareft
80      REAL(wp) :: zexcess, zgraren, zgrarep, zgrarem
81      REAL(wp) :: zgrapoc, zgrapon, zgrapop, zgrapof, zprcaca, zmortz
82      REAL(wp) :: zrespz, ztortz, zgrasratf, zgrasratn, zgrasratp
83      REAL(wp) :: zgraznc, zgraznn, zgraznp, zgrazpoc, zgrazpon, zgrazpop, zgrazpof
84      REAL(wp) :: zgrazdc, zgrazdn, zgrazdp, zgrazdf, zgraznf, zgrazz
85      REAL(wp) :: zgrazpc, zgrazpn, zgrazpp, zgrazpf, zbeta, zrfact2, zmetexcess
86      REAL(wp) :: zsigma, zdiffdn, zdiffpn, zdiffdp, zproport, zproport2
87      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zgrazing, zfezoo
88      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: zw3d, zzligprod
89      CHARACTER (len=25) :: charout
90      !!---------------------------------------------------------------------
91      !
92      IF( ln_timing )   CALL timing_start('p5z_micro')
93      !
94      IF (ln_ligand) THEN
95         ALLOCATE( zzligprod(jpi,jpj,jpk) )
96         zzligprod(:,:,:) = 0._wp
97      ENDIF
98      !
99      ! Use of excess carbon for metabolism
100      zmetexcess = 0.0
101      IF ( bmetexc ) zmetexcess = 1.0
102      !
103      DO jk = 1, jpkm1
104         DO jj = 1, jpj
105            DO ji = 1, jpi
106               zcompaz = MAX( ( trb(ji,jj,jk,jpzoo) - 1.e-9 ), 0.e0 )
107               zfact   = xstep * tgfunc2(ji,jj,jk) * zcompaz
108               ! Proportion of nano and diatoms that are within the size range
109               ! accessible to microzooplankton.
110               zproport  = min(1.0, exp(-1.1 * MAX(0., ( sized(ji,jj,jk) - 1.8 ))**0.8 ))
111               zproport2 = sizen(ji,jj,jk)**(-0.54)
112               !  linear mortality of mesozooplankton
113               !  A michaelis menten modulation term is used to avoid extinction of
114               !  microzooplankton at very low food concentrations. Mortality is
115               !  enhanced in low O2 waters
116               !  -----------------------------------------------------------------
117               zrespz = resrat * zfact * ( trb(ji,jj,jk,jpzoo) / ( xkmort + trb(ji,jj,jk,jpzoo) )  &
118               &        + 3. * nitrfac(ji,jj,jk) )
119
120               !  Zooplankton quadratic mortality. A square function has been selected with
121               !  to mimic predation and disease (density dependent mortality). It also tends
122               !  to stabilise the model
123               !  -------------------------------------------------------------------------
124               ztortz = mzrat * 1.e6 * zfact * trb(ji,jj,jk,jpzoo) * (1. - nitrfac(ji,jj,jk))
125
126               !   Computation of the abundance of the preys
127               !   A threshold can be specified in the namelist
128               !   Nanophyto and diatoms have a specific treatment with
129               !   teir preference decreasing with size.
130               !   --------------------------------------------------------
131               zcompadi  = zproport * MAX( ( trb(ji,jj,jk,jpdia) - xthreshdia ), 0.e0 )
132               zcompaph  = zproport2 * MAX( ( trb(ji,jj,jk,jpphy) - xthreshphy ), 0.e0 )
133               zcompaz   = MAX( ( trb(ji,jj,jk,jpzoo) - xthreshzoo ), 0.e0 )
134               zcompapi  = MAX( ( trb(ji,jj,jk,jppic) - xthreshpic ), 0.e0 )
135               zcompapoc = MAX( ( trb(ji,jj,jk,jppoc) - xthreshpoc ), 0.e0 )
136               
137               ! Microzooplankton grazing
138               ! The total amount of food is the sum of all preys accessible to mesozooplankton
139               ! multiplied by their food preference
140               ! A threshold can be specified in the namelist (xthresh). However, when food
141               ! concentration is close to this threshold, it is decreased to avoid the
142               ! accumulation of food in the mesozoopelagic domain
143               ! -------------------------------------------------------------------------------
144               zfood     = xprefn * zcompaph + xprefc * zcompapoc + xprefd * zcompadi   &
145               &           + xprefz * zcompaz + xprefp * zcompapi
146               zfoodlim  = MAX( 0. , zfood - min(xthresh,0.5*zfood) )
147               zdenom    = zfoodlim / ( xkgraz + zfoodlim )
148               zgraze    = grazrat * xstep * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jpzoo) * (1. - nitrfac(ji,jj,jk)) 
149
150               ! An active switching parameterization is used here.
151               ! We don't use the KTW parameterization proposed by
152               ! Vallina et al. because it tends to produce too steady biomass
153               ! composition and the variance of Chl is too low as it grazes
154               ! too strongly on winning organisms. We use a generalized
155               ! switching parameterization proposed by Morozov and
156               ! Petrovskii (2013)
157               ! ------------------------------------------------------------ 
158               ! The width of the selection window is increased when preys
159               ! have low abundance, .i.e. zooplankton become less specific
160               ! to avoid starvation.
161               ! ----------------------------------------------------------
162               zsigma = 1.0 - zdenom**2/(0.05**2+zdenom**2)
163               zsigma = 0.5 + 1.0*zsigma
164               zdiffpn = exp( -ABS(log(0.5 * sizep(ji,jj,jk) / (3.0 * sizen(ji,jj,jk) + rtrn )) )**2 / zsigma**2 )
165               zdiffdn = exp( -ABS(log(3.0 * sizen(ji,jj,jk) / (5.0 * sized(ji,jj,jk) + rtrn )) )**2 / zsigma**2)
166               zdiffdp = exp( -ABS(log(0.5 * sizep(ji,jj,jk) / (5.0 * sized(ji,jj,jk) + rtrn )) )**2 / zsigma**2)
167               ztmp1 = xprefn * zcompaph * ( zcompaph + zdiffdn * zcompadi + zdiffpn * zcompapi ) / ( 1.0 + zdiffdn + zdiffpn )
168               ztmp2 = xprefp * zcompapi * ( zcompapi + zdiffpn * zcompaph + zdiffdp * zcompadi ) / ( 1.0 + zdiffpn + zdiffdp )
169               ztmp3 = xprefc * zcompapoc**2
170               ztmp4 = xprefd * zcompadi * ( zdiffdp * zcompapi + zdiffdn * zcompaph + zcompadi ) / ( 1.0 + zdiffdn + zdiffdp )
171               ztmp5 = xprefz * zcompaz**2
172               ztmptot = ztmp1 + ztmp2 + ztmp3 + ztmp4 + ztmp5 + rtrn
173               ztmp1 = ztmp1 / ztmptot
174               ztmp2 = ztmp2 / ztmptot
175               ztmp3 = ztmp3 / ztmptot
176               ztmp4 = ztmp4 / ztmptot
177               ztmp5 = ztmp5 / ztmptot
178
179               !   Microzooplankton regular grazing on the different preys
180               !   -------------------------------------------------------
181               zgraznc   = zgraze  * ztmp1  * zdenom
182               zgraznn   = zgraznc * trb(ji,jj,jk,jpnph) / (trb(ji,jj,jk,jpphy) + rtrn)
183               zgraznp   = zgraznc * trb(ji,jj,jk,jppph) / (trb(ji,jj,jk,jpphy) + rtrn)
184               zgraznf   = zgraznc * trb(ji,jj,jk,jpnfe) / (trb(ji,jj,jk,jpphy) + rtrn)
185               zgrazpc   = zgraze  * ztmp2  * zdenom
186               zgrazpn   = zgrazpc * trb(ji,jj,jk,jpnpi) / (trb(ji,jj,jk,jppic) + rtrn)
187               zgrazpp   = zgrazpc * trb(ji,jj,jk,jpppi) / (trb(ji,jj,jk,jppic) + rtrn)
188               zgrazpf   = zgrazpc * trb(ji,jj,jk,jppfe) / (trb(ji,jj,jk,jppic) + rtrn)
189               zgrazz    = zgraze  * ztmp5   * zdenom
190               zgrazpoc  = zgraze  * ztmp3   * zdenom
191               zgrazpon  = zgrazpoc * trb(ji,jj,jk,jppon) / ( trb(ji,jj,jk,jppoc) + rtrn )
192               zgrazpop  = zgrazpoc * trb(ji,jj,jk,jppop) / ( trb(ji,jj,jk,jppoc) + rtrn )
193               zgrazpof  = zgrazpoc* trb(ji,jj,jk,jpsfe) / (trb(ji,jj,jk,jppoc) + rtrn)
194               zgrazdc   = zgraze  * ztmp4  * zdenom
195               zgrazdn   = zgrazdc * trb(ji,jj,jk,jpndi) / (trb(ji,jj,jk,jpdia) + rtrn)
196               zgrazdp   = zgrazdc * trb(ji,jj,jk,jppdi) / (trb(ji,jj,jk,jpdia) + rtrn)
197               zgrazdf   = zgrazdc * trb(ji,jj,jk,jpdfe) / (trb(ji,jj,jk,jpdia) + rtrn)
198               !
199               zgraztotc = zgraznc + zgrazpoc + zgrazdc + zgrazz + zgrazpc
200               zgraztotn = zgraznn + zgrazpn + zgrazpon + zgrazdn + zgrazz * no3rat3
201               zgraztotp = zgraznp + zgrazpp + zgrazpop + zgrazdp + zgrazz * po4rat3
202               zgraztotf = zgraznf + zgrazpf + zgrazpof + zgrazdf + zgrazz * ferat3
203               !
204               ! Grazing by microzooplankton
205               zgrazing(ji,jj,jk) = zgraztotc
206
207               ! Stoichiometruc ratios of the food ingested by zooplanton
208               ! --------------------------------------------------------
209               zgrasratf =  (zgraztotf + rtrn) / ( zgraztotc + rtrn )
210               zgrasratn =  (zgraztotn + rtrn) / ( zgraztotc + rtrn )
211               zgrasratp =  (zgraztotp + rtrn) / ( zgraztotc + rtrn )
212
213               ! Mesozooplankton efficiency.
214               ! We adopt a formulation proposed by Mitra et al. (2007)
215               ! The gross growth efficiency is controled by the most limiting nutrient.
216               ! Growth is also further decreased when the food quality is poor. This is currently
217               ! hard coded : it can be decreased by up to 50% (zepsherq)
218               ! GGE can also be decreased when food quantity is high, zepsherf (Montagnes and
219               ! Fulton, 2012)
220               ! -----------------------------------------------------------------------------------
221               zepshert  = MIN( 1., zgrasratn/ no3rat3, zgrasratp/ po4rat3, zgrasratf / ferat3)
222               zbeta     = MAX( 0., (epsher - epshermin) )
223               zepsherf  = epshermin + zbeta / ( 1.0 + 0.04E6 * 12. * zfood * zbeta )
224               zepsherq  = 0.5 + (1.0 - 0.5) * zepshert * ( 1.0 + 1.0 ) / ( zepshert + 1.0 )
225               zepsherv  = zepsherf * zepshert * zepsherq
226
227               ! Respiration of microzooplankton
228               ! Excess carbon in the food is used preferentially
229               ! ------------------------------------------------
230               zexcess  = zgraztotc * zepsherf * (1.0 - zepshert) * zmetexcess
231               zbasresb = MAX(0., zrespz - zexcess)
232               zbasresi = zexcess + MIN(0., zrespz - zexcess) 
233               zrespirc = srespir * zepsherv * zgraztotc + zbasresb
234               
235               ! When excess carbon is used, the other elements in excess
236               ! are also used proportionally to their abundance
237               ! --------------------------------------------------------
238               zexcess  = ( zgrasratn/ no3rat3 - zepshert ) / ( 1.0 - zepshert + rtrn)
239               zbasresn = zbasresi * zexcess * zgrasratn 
240               zexcess  = ( zgrasratp/ po4rat3 - zepshert ) / ( 1.0 - zepshert + rtrn)
241               zbasresp = zbasresi * zexcess * zgrasratp
242               zexcess  = ( zgrasratf/ ferat3 - zepshert ) / ( 1.0 - zepshert + rtrn)
243               zbasresf = zbasresi * zexcess * zgrasratf
244
245               ! Voiding of the excessive elements as DOM
246               ! ----------------------------------------
247               zgradoct   = (1. - unassc - zepsherv) * zgraztotc - zbasresi 
248               zgradont   = (1. - unassn) * zgraztotn - zepsherv * no3rat3 * zgraztotc - zbasresn
249               zgradopt   = (1. - unassp) * zgraztotp - zepsherv * po4rat3 * zgraztotc - zbasresp
250               zgrareft   = (1. - unassc) * zgraztotf - zepsherv * ferat3 * zgraztotc - zbasresf
251
252               ! Since only semilabile DOM is represented in PISCES
253               ! part of DOM is in fact labile and is then released
254               ! as dissolved inorganic compounds (ssigma)
255               ! --------------------------------------------------
256               zgradoc =  zgradoct * ssigma
257               zgradon =  zgradont * ssigma
258               zgradop =  zgradopt * ssigma
259               zgrarem = (1.0 - ssigma) * zgradoct
260               zgraren = (1.0 - ssigma) * zgradont
261               zgrarep = (1.0 - ssigma) * zgradopt
262               zgraref = zgrareft
263
264               ! Defecation as a result of non assimilated products
265               ! --------------------------------------------------
266               zgrapoc   = zgraztotc * unassc
267               zgrapon   = zgraztotn * unassn
268               zgrapop   = zgraztotp * unassp
269               zgrapof   = zgraztotf * unassc
270
271               ! Addition of respiration to the release of inorganic nutrients
272               ! -------------------------------------------------------------
273               zgrarem = zgrarem + zbasresi + zrespirc
274               zgraren = zgraren + zbasresn + zrespirc * no3rat3
275               zgrarep = zgrarep + zbasresp + zrespirc * po4rat3
276               zgraref = zgraref + zbasresf + zrespirc * ferat3
277
278               ! Update of the TRA arrays
279               ! ------------------------
280               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zgrarep
281               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zgraren
282               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zgradoc
283               !
284               IF( ln_ligand ) THEN
285                  tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) + zgradoc * ldocz
286                  zzligprod(ji,jj,jk) = zgradoc * ldocz
287               ENDIF
288               !
289               tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) + zgradon
290               tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) + zgradop
291               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2ut * zgrarem 
292               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zgraref
293               zfezoo(ji,jj,jk)    = zgraref
294               tra(ji,jj,jk,jpzoo) = tra(ji,jj,jk,jpzoo) + zepsherv * zgraztotc - zrespirc - ztortz - zgrazz
295               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zgraznc
296               tra(ji,jj,jk,jpnph) = tra(ji,jj,jk,jpnph) - zgraznn
297               tra(ji,jj,jk,jppph) = tra(ji,jj,jk,jppph) - zgraznp
298               tra(ji,jj,jk,jppic) = tra(ji,jj,jk,jppic) - zgrazpc
299               tra(ji,jj,jk,jpnpi) = tra(ji,jj,jk,jpnpi) - zgrazpn
300               tra(ji,jj,jk,jpppi) = tra(ji,jj,jk,jpppi) - zgrazpp
301               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zgrazdc
302               tra(ji,jj,jk,jpndi) = tra(ji,jj,jk,jpndi) - zgrazdn
303               tra(ji,jj,jk,jppdi) = tra(ji,jj,jk,jppdi) - zgrazdp
304               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zgraznc * trb(ji,jj,jk,jpnch)/(trb(ji,jj,jk,jpphy)+rtrn)
305               tra(ji,jj,jk,jppch) = tra(ji,jj,jk,jppch) - zgrazpc * trb(ji,jj,jk,jppch)/(trb(ji,jj,jk,jppic)+rtrn)
306               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zgrazdc * trb(ji,jj,jk,jpdch)/(trb(ji,jj,jk,jpdia)+rtrn)
307               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) - zgrazdc * trb(ji,jj,jk,jpdsi)/(trb(ji,jj,jk,jpdia)+rtrn)
308               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) + zgrazdc * trb(ji,jj,jk,jpdsi)/(trb(ji,jj,jk,jpdia)+rtrn)
309               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zgraznf
310               tra(ji,jj,jk,jppfe) = tra(ji,jj,jk,jppfe) - zgrazpf
311               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zgrazdf
312               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + ztortz + zgrapoc - zgrazpoc 
313               prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + ztortz + zgrapoc
314               conspoc(ji,jj,jk) = conspoc(ji,jj,jk) - zgrazpoc
315               tra(ji,jj,jk,jppon) = tra(ji,jj,jk,jppon) + no3rat3 * ztortz + zgrapon - zgrazpon
316               tra(ji,jj,jk,jppop) = tra(ji,jj,jk,jppop) + po4rat3 * ztortz + zgrapop - zgrazpop
317               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + ferat3 * ztortz  + zgrapof - zgrazpof
318               !
319               ! Calcite production
320               ! Calcite remineralization due to zooplankton activity
321               ! part of the ingested calcite is dissolving in the acidic gut
322               ! -------------------------------------------------------------
323               zprcaca = xfracal(ji,jj,jk) * zgraznc
324               prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
325               !
326               zprcaca = part * zprcaca
327               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrarem - zprcaca
328               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * zprcaca     &
329               &                     + rno3 * zgraren
330               tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) + zprcaca
331            END DO
332         END DO
333      END DO
334      !
335      IF( lk_iomput ) THEN
336         IF( knt == nrdttrc ) THEN
337            ALLOCATE( zw3d(jpi,jpj,jpk) )
338            IF( iom_use( "GRAZ1" ) ) THEN
339               zw3d(:,:,:) = zgrazing(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:)  !  Total grazing of phyto by zooplankton
340               CALL iom_put( "GRAZ1", zw3d )
341            ENDIF
342            IF( iom_use( "FEZOO" ) ) THEN
343               zw3d(:,:,:) = zfezoo(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:)   !
344               CALL iom_put( "FEZOO", zw3d )
345            ENDIF
346            IF( iom_use( "LPRODZ" ) .AND. ln_ligand )  THEN
347               zw3d(:,:,:) = zzligprod(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:)
348               CALL iom_put( "LPRODZ"  , zw3d )
349            ENDIF
350            DEALLOCATE( zw3d )
351         ENDIF
352      ENDIF
353      !
354      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
355         WRITE(charout, FMT="('micro')")
356         CALL prt_ctl_trc_info(charout)
357         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
358      ENDIF
359      !
360      IF( ln_timing )   CALL timing_stop('p5z_micro')
361      !
362   END SUBROUTINE p5z_micro
363
364
365   SUBROUTINE p5z_micro_init
366      !!----------------------------------------------------------------------
367      !!                  ***  ROUTINE p5z_micro_init  ***
368      !!
369      !! ** Purpose :   Initialization of microzooplankton parameters
370      !!
371      !! ** Method  :   Read the namp5zzoo namelist and check the parameters
372      !!                called at the first timestep (nittrc000)
373      !!
374      !! ** input   :   Namelist namp5zzoo
375      !!
376      !!----------------------------------------------------------------------
377      INTEGER ::   ios   ! Local integer
378      !!
379      NAMELIST/namp5zzoo/ part, grazrat, bmetexc, resrat, mzrat, xprefc, xprefn, &
380         &                xprefp, xprefd, xprefz, xthreshdia, xthreshphy, &
381         &                xthreshpic, xthreshpoc, xthreshzoo, xthresh, xkgraz, &
382         &                epsher, epshermin, ssigma, srespir, unassc, unassn, unassp
383      !!----------------------------------------------------------------------
384      !
385      REWIND( numnatp_ref )              ! Namelist namp5zzoo in reference namelist : Pisces microzooplankton
386      READ  ( numnatp_ref, namp5zzoo, IOSTAT = ios, ERR = 901)
387901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp5zzoo in reference namelist' )
388      !
389      REWIND( numnatp_cfg )              ! Namelist namp5zzoo in configuration namelist : Pisces microzooplankton
390      READ  ( numnatp_cfg, namp5zzoo, IOSTAT = ios, ERR = 902 )
391902   IF( ios >  0 ) CALL ctl_nam ( ios , 'namp5zzoo in configuration namelist' )
392      IF(lwm) WRITE ( numonp, namp5zzoo )
393      !
394      IF(lwp) THEN                         ! control print
395         WRITE(numout,*) ' '
396         WRITE(numout,*) ' Namelist parameters for microzooplankton, nampiszooq'
397         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
398         WRITE(numout,*) '    part of calcite not dissolved in microzoo guts  part        =', part
399         WRITE(numout,*) '    microzoo preference for POC                     xprefc     =', xprefc
400         WRITE(numout,*) '    microzoo preference for nano                    xprefn     =', xprefn
401         WRITE(numout,*) '    microzoo preference for pico                    xprefp     =', xprefp
402         WRITE(numout,*) '    microzoo preference for diatoms                 xprefd     =', xprefd
403         WRITE(numout,*) '    microzoo preference for microzoo                xprefz     =', xprefz
404         WRITE(numout,*) '    diatoms feeding threshold  for microzoo         xthreshdia  =', xthreshdia
405         WRITE(numout,*) '    nanophyto feeding threshold for microzoo        xthreshphy  =', xthreshphy
406         WRITE(numout,*) '    picophyto feeding threshold for microzoo        xthreshpic  =', xthreshpic
407         WRITE(numout,*) '    poc feeding threshold for microzoo              xthreshpoc  =', xthreshpoc
408         WRITE(numout,*) '    microzoo feeding threshold for microzoo         xthreshzoo  =', xthreshzoo
409         WRITE(numout,*) '    feeding threshold for microzooplankton          xthresh     =', xthresh
410         WRITE(numout,*) '    exsudation rate of microzooplankton             resrat      =', resrat
411         WRITE(numout,*) '    microzooplankton mortality rate                 mzrat       =', mzrat
412         WRITE(numout,*) '    maximal microzoo grazing rate                   grazrat     =', grazrat
413         WRITE(numout,*) '    C egested fraction of fodd by microzoo          unassc      =', unassc
414         WRITE(numout,*) '    N egested fraction of fodd by microzoo          unassn      =', unassn
415         WRITE(numout,*) '    P egested fraction of fodd by microzoo          unassp      =', unassp
416         WRITE(numout,*) '    Efficicency of microzoo growth                  epsher      =', epsher
417         WRITE(numout,*) '    Minimum Efficiency of Microzoo growth           epshermin   =', epshermin
418         WRITE(numout,*) '    Fraction excreted as semi-labile DOM            ssigma      =', ssigma
419         WRITE(numout,*) '    Active respiration                              srespir     =', srespir
420         WRITE(numout,*) '    half sturation constant for grazing 1           xkgraz      =', xkgraz
421         WRITE(numout,*) '    Use of excess carbon for respiration            bmetexc     =', bmetexc
422      ENDIF
423      !
424   END SUBROUTINE p5z_micro_init
425
426   !!======================================================================
427END MODULE p5zmicro
Note: See TracBrowser for help on using the repository browser.