New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p5zmort.F90 in NEMO/branches/2019/dev_r11708_aumont_PISCES_QUOTA/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2019/dev_r11708_aumont_PISCES_QUOTA/src/TOP/PISCES/P4Z/p5zmort.F90 @ 12537

Last change on this file since 12537 was 12537, checked in by aumont, 4 years ago

Comments in routines have been revised and significantly augmented
  • Property svn:keywords set to Id
File size: 15.5 KB
Line 
1MODULE p5zmort
2   !!======================================================================
3   !!                         ***  MODULE p5zmort  ***
4   !! TOP :   PISCES-QUOTA Compute the mortality terms for phytoplankton
5   !!======================================================================
6   !! History :   1.0  !  2002     (O. Aumont)  Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
9   !!----------------------------------------------------------------------
10   !!   p5z_mort       :   Compute the mortality terms for phytoplankton
11   !!   p5z_mort_init  :   Initialize the mortality params for phytoplankton
12   !!----------------------------------------------------------------------
13   USE oce_trc         !  shared variables between ocean and passive tracers
14   USE trc             !  passive tracers common variables
15   USE sms_pisces      !  PISCES Source Minus Sink variables
16   USE p4zlim          !  Phytoplankton limitation terms (p4z)
17   USE p5zlim          !  Phytoplankton limitation terms (p5z)
18   USE prtctl_trc      !  print control for debugging
19
20   IMPLICIT NONE
21   PRIVATE
22
23   PUBLIC   p5z_mort           ! Called from p4zbio.F90
24   PUBLIC   p5z_mort_init      ! Called from trcini_pisces.F90
25
26   !! * Shared module variables
27   REAL(wp), PUBLIC :: wchln   !! Quadratic mortality rate of nanophytoplankton
28   REAL(wp), PUBLIC :: wchlp   !: Quadratic mortality rate of picophytoplankton
29   REAL(wp), PUBLIC :: wchld   !: Quadratic mortality rate of diatoms
30   REAL(wp), PUBLIC :: wchldm  !: Maximum quadratic mortality rate of diatoms
31   REAL(wp), PUBLIC :: mpratn  !: Linear mortality rate of nanophytoplankton
32   REAL(wp), PUBLIC :: mpratp  !: Linear mortality rate of picophytoplankton
33   REAL(wp), PUBLIC :: mpratd  !: Linear mortality rate of diatoms
34
35   !!----------------------------------------------------------------------
36   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
37   !! $Id$
38   !! Software governed by the CeCILL license (see ./LICENSE)
39   !!----------------------------------------------------------------------
40
41CONTAINS
42
43   SUBROUTINE p5z_mort( kt )
44      !!---------------------------------------------------------------------
45      !!                     ***  ROUTINE p5z_mort  ***
46      !!
47      !! ** Purpose :   Calls the different subroutine to compute
48      !!                the different phytoplankton mortality terms
49      !!
50      !! ** Method  : - ???
51      !!---------------------------------------------------------------------
52      INTEGER, INTENT(in) ::   kt ! ocean time step
53      !!---------------------------------------------------------------------
54
55      CALL p5z_nano            ! nanophytoplankton
56      CALL p5z_pico            ! picophytoplankton
57      CALL p5z_diat            ! diatoms
58
59   END SUBROUTINE p5z_mort
60
61
62   SUBROUTINE p5z_nano
63      !!---------------------------------------------------------------------
64      !!                     ***  ROUTINE p5z_nano  ***
65      !!
66      !! ** Purpose :   Compute the mortality terms for nanophytoplankton
67      !!
68      !! ** Method  : - ???
69      !!---------------------------------------------------------------------
70      INTEGER  :: ji, jj, jk
71      REAL(wp) :: zcompaph
72      REAL(wp) :: zfactfe, zfactch, zfactn, zfactp, zprcaca
73      REAL(wp) :: ztortp , zrespp , zmortp
74      CHARACTER (len=25) :: charout
75      !!---------------------------------------------------------------------
76      !
77      IF( ln_timing )   CALL timing_start('p5z_nano')
78      !
79      prodcal(:,:,:) = 0.  !: calcite production variable set to zero
80      DO jk = 1, jpkm1
81         DO jj = 1, jpj
82            DO ji = 1, jpi
83               zcompaph = MAX( ( trb(ji,jj,jk,jpphy) - 1e-9 ), 0.e0 )
84               ! Quadratic mortality of nano due to aggregation during
85               ! blooms (Doney et al. 1996)
86               ! -----------------------------------------------------
87               zrespp = wchln * 1.e6 * xstep * xdiss(ji,jj,jk) * zcompaph * trb(ji,jj,jk,jpphy)
88
89               ! Phytoplankton linear mortality
90               ! A michaelis-menten like term is introduced to avoid
91               ! extinction of nanophyto in highly limited areas
92               ! ----------------------------------------------------
93               ztortp = mpratn * xstep  * zcompaphi * trb(ji,jj,jk,jpphy) /  ( xkmort + trb(ji,jj,jk,jpphy) )
94               zmortp = zrespp + ztortp
95
96               ! Update the arrays TRA which contains the biological sources and sinks
97
98               zfactn  = trb(ji,jj,jk,jpnph)/(trb(ji,jj,jk,jpphy)+rtrn)
99               zfactp  = trb(ji,jj,jk,jppph)/(trb(ji,jj,jk,jpphy)+rtrn)
100               zfactfe = trb(ji,jj,jk,jpnfe)/(trb(ji,jj,jk,jpphy)+rtrn)
101               zfactch = trb(ji,jj,jk,jpnch)/(trb(ji,jj,jk,jpphy)+rtrn)
102               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zmortp
103               tra(ji,jj,jk,jpnph) = tra(ji,jj,jk,jpnph) - zmortp * zfactn
104               tra(ji,jj,jk,jppph) = tra(ji,jj,jk,jppph) - zmortp * zfactp
105               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zmortp * zfactch
106               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zmortp * zfactfe
107               ! Production PIC particles due to mortality
108               zprcaca = xfracal(ji,jj,jk) * zmortp
109               prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
110               !
111               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprcaca
112               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * zprcaca
113               tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) + zprcaca
114               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zmortp
115               tra(ji,jj,jk,jppon) = tra(ji,jj,jk,jppon) + zmortp * zfactn
116               tra(ji,jj,jk,jppop) = tra(ji,jj,jk,jppop) + zmortp * zfactp
117               prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + zmortp
118               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zmortp * zfactfe
119            END DO
120         END DO
121      END DO
122      !
123       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
124         WRITE(charout, FMT="('nano')")
125         CALL prt_ctl_trc_info(charout)
126         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
127       ENDIF
128      !
129      IF( ln_timing )   CALL timing_stop('p5z_nano')
130      !
131   END SUBROUTINE p5z_nano
132
133
134   SUBROUTINE p5z_pico
135      !!---------------------------------------------------------------------
136      !!                     ***  ROUTINE p5z_pico  ***
137      !!
138      !! ** Purpose :   Compute the mortality terms for picophytoplankton
139      !!
140      !! ** Method  : - ???
141      !!---------------------------------------------------------------------
142      INTEGER  :: ji, jj, jk
143      REAL(wp) :: zcompaph
144      REAL(wp) :: zfactfe, zfactch, zfactn, zfactp
145      REAL(wp) :: ztortp , zrespp , zmortp 
146      CHARACTER (len=25) :: charout
147      !!---------------------------------------------------------------------
148      !
149      IF( ln_timing )   CALL timing_start('p5z_pico')
150      !
151      DO jk = 1, jpkm1
152         DO jj = 1, jpj
153            DO ji = 1, jpi
154               zcompaph = MAX( ( trb(ji,jj,jk,jppic) - 1e-9 ), 0.e0 )
155
156               ! Quadratic mortality of pico due to aggregation during
157               ! blooms (Doney et al. 1996)
158               ! -----------------------------------------------------
159               zrespp = wchlp * 1.e6 * xstep * xdiss(ji,jj,jk) * zcompaph * trb(ji,jj,jk,jppic)
160
161               ! Phytoplankton linear mortality
162               ! A michaelis-menten like term is introduced to avoid
163               ! extinction of picophyto in highly limited areas
164               ! ----------------------------------------------------
165               ztortp = mpratp * xstep  * zcompaph * trb(ji,jj,jk,jppic) /  ( xkmort + trb(ji,jj,jk,jppic) )
166               zmortp = zrespp + ztortp
167
168               !   Update the arrays TRA which contains the biological sources and sinks
169               zfactn = trb(ji,jj,jk,jpnpi)/(trb(ji,jj,jk,jppic)+rtrn)
170               zfactp = trb(ji,jj,jk,jpppi)/(trb(ji,jj,jk,jppic)+rtrn)
171               zfactfe = trb(ji,jj,jk,jppfe)/(trb(ji,jj,jk,jppic)+rtrn)
172               zfactch = trb(ji,jj,jk,jppch)/(trb(ji,jj,jk,jppic)+rtrn)
173               tra(ji,jj,jk,jppic) = tra(ji,jj,jk,jppic) - zmortp
174               tra(ji,jj,jk,jpnpi) = tra(ji,jj,jk,jpnpi) - zmortp * zfactn
175               tra(ji,jj,jk,jpppi) = tra(ji,jj,jk,jpppi) - zmortp * zfactp
176               tra(ji,jj,jk,jppch) = tra(ji,jj,jk,jppch) - zmortp * zfactch
177               tra(ji,jj,jk,jppfe) = tra(ji,jj,jk,jppfe) - zmortp * zfactfe
178               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zmortp
179               tra(ji,jj,jk,jppon) = tra(ji,jj,jk,jppon) + zmortp * zfactn
180               tra(ji,jj,jk,jppop) = tra(ji,jj,jk,jppop) + zmortp * zfactp
181               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zmortp * zfactfe
182               prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + zmortp
183            END DO
184         END DO
185      END DO
186      !
187       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
188         WRITE(charout, FMT="('pico')")
189         CALL prt_ctl_trc_info(charout)
190         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
191       ENDIF
192      !
193      IF( ln_timing )   CALL timing_stop('p5z_pico')
194      !
195   END SUBROUTINE p5z_pico
196
197
198   SUBROUTINE p5z_diat
199      !!---------------------------------------------------------------------
200      !!                     ***  ROUTINE p5z_diat  ***
201      !!
202      !! ** Purpose :   Compute the mortality terms for diatoms
203      !!
204      !! ** Method  : - ???
205      !!---------------------------------------------------------------------
206      INTEGER  ::  ji, jj, jk
207      REAL(wp) ::  zfactfe,zfactsi,zfactch, zfactn, zfactp, zcompadi
208      REAL(wp) ::  zrespp2, ztortp2, zmortp2
209      REAL(wp) ::  zlim2, zlim1
210      CHARACTER (len=25) :: charout
211      !!---------------------------------------------------------------------
212      !
213      IF( ln_timing )   CALL timing_start('p5z_diat')
214      !
215
216      DO jk = 1, jpkm1
217         DO jj = 1, jpj
218            DO ji = 1, jpi
219
220               zcompadi = MAX( ( trb(ji,jj,jk,jpdia) - 1E-9), 0. )
221
222               !   Aggregation term for diatoms is increased in case of nutrient
223               !   stress as observed in reality. The stressed cells become more
224               !   sticky and coagulate to sink quickly out of the euphotic zone
225               !   -------------------------------------------------------------
226               !  Phytoplankton squared mortality
227               !  -------------------------------
228               zlim2   = xlimdia(ji,jj,jk) * xlimdia(ji,jj,jk)
229               zlim1   = 0.25 * ( 1. - zlim2 ) / ( 0.25 + zlim2 ) 
230               zrespp2 = 1.e6 * xstep * (  wchld + wchldm * zlim1 ) * xdiss(ji,jj,jk) * zcompadi * trb(ji,jj,jk,jpdia)
231
232               ! Phytoplankton linear mortality
233               ! A michaelis-menten like term is introduced to avoid
234               ! extinction of diatoms in highly limited areas
235               !  ---------------------------------------------------
236               ztortp2 = mpratd * xstep  * zcompadi * trb(ji,jj,jk,jpdia) /  ( xkmort + trb(ji,jj,jk,jpdia) )
237               zmortp2 = zrespp2 + ztortp2
238
239               !   Update the arrays tra which contains the biological sources and sinks
240               !   ---------------------------------------------------------------------
241               zfactn  = trb(ji,jj,jk,jpndi) / ( trb(ji,jj,jk,jpdia) + rtrn )
242               zfactp  = trb(ji,jj,jk,jppdi) / ( trb(ji,jj,jk,jpdia) + rtrn )
243               zfactch = trb(ji,jj,jk,jpdch) / ( trb(ji,jj,jk,jpdia) + rtrn )
244               zfactfe = trb(ji,jj,jk,jpdfe) / ( trb(ji,jj,jk,jpdia) + rtrn )
245               zfactsi = trb(ji,jj,jk,jpdsi) / ( trb(ji,jj,jk,jpdia) + rtrn )
246               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zmortp2 
247               tra(ji,jj,jk,jpndi) = tra(ji,jj,jk,jpndi) - zmortp2 * zfactn
248               tra(ji,jj,jk,jppdi) = tra(ji,jj,jk,jppdi) - zmortp2 * zfactp
249               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zmortp2 * zfactch
250               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zmortp2 * zfactfe
251               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) - zmortp2 * zfactsi
252               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) + zmortp2 * zfactsi
253               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zrespp2 
254               tra(ji,jj,jk,jpgon) = tra(ji,jj,jk,jpgon) + zrespp2 * zfactn
255               tra(ji,jj,jk,jpgop) = tra(ji,jj,jk,jpgop) + zrespp2 * zfactp
256               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zrespp2 * zfactfe
257               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + ztortp2
258               tra(ji,jj,jk,jppon) = tra(ji,jj,jk,jppon) + ztortp2 * zfactn
259               tra(ji,jj,jk,jppop) = tra(ji,jj,jk,jppop) + ztortp2 * zfactp
260               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + ztortp2 * zfactfe
261               prodpoc(ji,jj,jk)   = prodpoc(ji,jj,jk) + ztortp2
262               prodgoc(ji,jj,jk)   = prodgoc(ji,jj,jk) + zrespp2
263            END DO
264         END DO
265      END DO
266      !
267      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
268         WRITE(charout, FMT="('diat')")
269         CALL prt_ctl_trc_info(charout)
270         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
271      ENDIF
272      !
273      IF( ln_timing )   CALL timing_stop('p5z_diat')
274      !
275   END SUBROUTINE p5z_diat
276
277
278   SUBROUTINE p5z_mort_init
279      !!----------------------------------------------------------------------
280      !!                  ***  ROUTINE p5z_mort_init  ***
281      !!
282      !! ** Purpose :   Initialization of phytoplankton mortality parameters
283      !!
284      !! ** Method  :   Read the namp5zmort namelist and check the parameters
285      !!      called at the first timestep
286      !!
287      !! ** input   :   Namelist namp5zmort
288      !!
289      !!----------------------------------------------------------------------
290      INTEGER :: ios   ! Local integer output status for namelist read
291      !!
292      NAMELIST/namp5zmort/ wchln, wchlp, wchld, wchldm, mpratn, mpratp, mpratd
293      !!----------------------------------------------------------------------
294
295      REWIND( numnatp_ref )              ! Namelist namp5zmort in reference namelist : Pisces phytoplankton
296      READ  ( numnatp_ref, namp5zmort, IOSTAT = ios, ERR = 901)
297901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp5zmort in reference namelist' )
298
299      REWIND( numnatp_cfg )              ! Namelist namp5zmort in configuration namelist : Pisces phytoplankton
300      READ  ( numnatp_cfg, namp5zmort, IOSTAT = ios, ERR = 902 )
301902   IF( ios >  0 ) CALL ctl_nam ( ios , 'namp5zmort in configuration namelist' )
302      IF(lwm) WRITE ( numonp, namp5zmort )
303
304      IF(lwp) THEN                         ! control print
305         WRITE(numout,*) ' '
306         WRITE(numout,*) ' Namelist parameters for phytoplankton mortality, namp5zmort'
307         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
308         WRITE(numout,*) '    quadratic mortality of phytoplankton      wchln     =', wchln
309         WRITE(numout,*) '    quadratic mortality of picophyto.         wchlp     =', wchlp
310         WRITE(numout,*) '    quadratic mortality of diatoms            wchld     =', wchld
311         WRITE(numout,*) '    Additional quadratic mortality of diatoms wchldm    =', wchldm
312         WRITE(numout,*) '    nanophyto. mortality rate                 mpratn    =', mpratn
313         WRITE(numout,*) '    picophyto. mortality rate                 mpratp    =', mpratp
314         WRITE(numout,*) '    Diatoms mortality rate                    mpratd    =', mpratd
315      ENDIF
316
317   END SUBROUTINE p5z_mort_init
318
319   !!======================================================================
320END MODULE p5zmort
Note: See TracBrowser for help on using the repository browser.