New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p5zmort.F90 in NEMO/branches/2019/dev_r11708_aumont_PISCES_QUOTA/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2019/dev_r11708_aumont_PISCES_QUOTA/src/TOP/PISCES/P4Z/p5zmort.F90 @ 13233

Last change on this file since 13233 was 13233, checked in by aumont, 4 years ago

update of the PISCES comments
  • Property svn:keywords set to Id
File size: 15.7 KB
Line 
1MODULE p5zmort
2   !!======================================================================
3   !!                         ***  MODULE p5zmort  ***
4   !! TOP :   PISCES-QUOTA Compute the mortality terms for phytoplankton
5   !!======================================================================
6   !! History :   1.0  !  2002     (O. Aumont)  Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
9   !!----------------------------------------------------------------------
10   !!   p5z_mort       :   Compute the mortality terms for phytoplankton
11   !!   p5z_mort_init  :   Initialize the mortality params for phytoplankton
12   !!----------------------------------------------------------------------
13   USE oce_trc         !  shared variables between ocean and passive tracers
14   USE trc             !  passive tracers common variables
15   USE sms_pisces      !  PISCES Source Minus Sink variables
16   USE p4zlim          !  Phytoplankton limitation terms (p4z)
17   USE p5zlim          !  Phytoplankton limitation terms (p5z)
18   USE prtctl_trc      !  print control for debugging
19
20   IMPLICIT NONE
21   PRIVATE
22
23   PUBLIC   p5z_mort           ! Called from p4zbio.F90
24   PUBLIC   p5z_mort_init      ! Called from trcini_pisces.F90
25
26   !! * Shared module variables
27   REAL(wp), PUBLIC :: wchln   !! Quadratic mortality rate of nanophytoplankton
28   REAL(wp), PUBLIC :: wchlp   !: Quadratic mortality rate of picophytoplankton
29   REAL(wp), PUBLIC :: wchld   !: Quadratic mortality rate of diatoms
30   REAL(wp), PUBLIC :: wchldm  !: Maximum quadratic mortality rate of diatoms
31   REAL(wp), PUBLIC :: mpratn  !: Linear mortality rate of nanophytoplankton
32   REAL(wp), PUBLIC :: mpratp  !: Linear mortality rate of picophytoplankton
33   REAL(wp), PUBLIC :: mpratd  !: Linear mortality rate of diatoms
34
35   !!----------------------------------------------------------------------
36   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
37   !! $Id$
38   !! Software governed by the CeCILL license (see ./LICENSE)
39   !!----------------------------------------------------------------------
40
41CONTAINS
42
43   SUBROUTINE p5z_mort( kt )
44      !!---------------------------------------------------------------------
45      !!                     ***  ROUTINE p5z_mort  ***
46      !!
47      !! ** Purpose :   Calls the different subroutine to compute
48      !!                the different phytoplankton mortality terms
49      !!
50      !! ** Method  : - ???
51      !!---------------------------------------------------------------------
52      INTEGER, INTENT(in) ::   kt ! ocean time step
53      !!---------------------------------------------------------------------
54
55      CALL p5z_mort_nano            ! nanophytoplankton
56      CALL p5z_mort_pico            ! picophytoplankton
57      CALL p5z_mort_diat            ! diatoms
58
59   END SUBROUTINE p5z_mort
60
61
62   SUBROUTINE p5z_mort_nano
63      !!---------------------------------------------------------------------
64      !!                     ***  ROUTINE p5z_mort_nano  ***
65      !!
66      !! ** Purpose :   Compute the mortality terms for nanophytoplankton
67      !!
68      !! ** Method  : - Both quadratic and simili linear mortality terms
69      !!---------------------------------------------------------------------
70      INTEGER  :: ji, jj, jk
71      REAL(wp) :: zcompaph
72      REAL(wp) :: zfactfe, zfactch, zfactn, zfactp, zprcaca
73      REAL(wp) :: ztortp , zrespp , zmortp
74      CHARACTER (len=25) :: charout
75      !!---------------------------------------------------------------------
76      !
77      IF( ln_timing )   CALL timing_start('p5z_mort_nano')
78      !
79      prodcal(:,:,:) = 0.  !: calcite production variable set to zero
80      DO jk = 1, jpkm1
81         DO jj = 1, jpj
82            DO ji = 1, jpi
83               zcompaph = MAX( ( trb(ji,jj,jk,jpphy) - 1e-9 ), 0.e0 )
84
85               ! Quadratic mortality of nano due to aggregation during
86               ! blooms (Doney et al. 1996)
87               ! -----------------------------------------------------
88               zrespp = wchln * 1.e6 * xstep * xdiss(ji,jj,jk) * zcompaph * trb(ji,jj,jk,jpphy)
89
90               ! Phytoplankton linear mortality
91               ! A michaelis-menten like term is introduced to avoid
92               ! extinction of nanophyto in highly limited areas
93               ! ----------------------------------------------------
94               ztortp = mpratn * xstep * zcompaph * trb(ji,jj,jk,jpphy) / ( xkmort + trb(ji,jj,jk,jpphy) )
95               zmortp = zrespp + ztortp
96
97               ! Update the arrays TRA which contains the biological sources and sinks
98
99               zfactn  = trb(ji,jj,jk,jpnph)/(trb(ji,jj,jk,jpphy)+rtrn)
100               zfactp  = trb(ji,jj,jk,jppph)/(trb(ji,jj,jk,jpphy)+rtrn)
101               zfactfe = trb(ji,jj,jk,jpnfe)/(trb(ji,jj,jk,jpphy)+rtrn)
102               zfactch = trb(ji,jj,jk,jpnch)/(trb(ji,jj,jk,jpphy)+rtrn)
103               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zmortp
104               tra(ji,jj,jk,jpnph) = tra(ji,jj,jk,jpnph) - zmortp * zfactn
105               tra(ji,jj,jk,jppph) = tra(ji,jj,jk,jppph) - zmortp * zfactp
106               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zmortp * zfactch
107               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zmortp * zfactfe
108               ! Production PIC particles due to mortality
109               zprcaca = xfracal(ji,jj,jk) * zmortp
110               prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
111               !
112               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprcaca
113               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * zprcaca
114               tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) + zprcaca
115               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zmortp
116               tra(ji,jj,jk,jppon) = tra(ji,jj,jk,jppon) + zmortp * zfactn
117               tra(ji,jj,jk,jppop) = tra(ji,jj,jk,jppop) + zmortp * zfactp
118               prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + zmortp
119               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zmortp * zfactfe
120            END DO
121         END DO
122      END DO
123      !
124       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
125         WRITE(charout, FMT="('nano')")
126         CALL prt_ctl_trc_info(charout)
127         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
128       ENDIF
129      !
130      IF( ln_timing )   CALL timing_stop('p5z_mort_nano')
131      !
132   END SUBROUTINE p5z_mort_nano
133
134
135   SUBROUTINE p5z_mort_pico
136      !!---------------------------------------------------------------------
137      !!                     ***  ROUTINE p5z_mort_pico  ***
138      !!
139      !! ** Purpose :   Compute the mortality terms for picophytoplankton
140      !!
141      !! ** Method  : - Both quadratic and semilininear terms are used
142      !!---------------------------------------------------------------------
143      INTEGER  :: ji, jj, jk
144      REAL(wp) :: zcompaph
145      REAL(wp) :: zfactfe, zfactch, zfactn, zfactp
146      REAL(wp) :: ztortp , zrespp , zmortp 
147      CHARACTER (len=25) :: charout
148      !!---------------------------------------------------------------------
149      !
150      IF( ln_timing )   CALL timing_start('p5z_mort_pico')
151      !
152      DO jk = 1, jpkm1
153         DO jj = 1, jpj
154            DO ji = 1, jpi
155               zcompaph = MAX( ( trb(ji,jj,jk,jppic) - 1e-9 ), 0.e0 )
156
157               ! Quadratic mortality of pico due to aggregation during
158               ! blooms (Doney et al. 1996)
159               ! -----------------------------------------------------
160               zrespp = wchlp * 1.e6 * xstep * xdiss(ji,jj,jk) * zcompaph * trb(ji,jj,jk,jppic)
161
162               ! Phytoplankton linear mortality
163               ! A michaelis-menten like term is introduced to avoid
164               ! extinction of picophyto in highly limited areas
165               ! ----------------------------------------------------
166               ztortp = mpratp * xstep  * zcompaph * trb(ji,jj,jk,jppic) /  ( xkmort + trb(ji,jj,jk,jppic) )
167               zmortp = zrespp + ztortp
168
169               !   Update the arrays TRA which contains the biological sources and sinks
170               zfactn = trb(ji,jj,jk,jpnpi)/(trb(ji,jj,jk,jppic)+rtrn)
171               zfactp = trb(ji,jj,jk,jpppi)/(trb(ji,jj,jk,jppic)+rtrn)
172               zfactfe = trb(ji,jj,jk,jppfe)/(trb(ji,jj,jk,jppic)+rtrn)
173               zfactch = trb(ji,jj,jk,jppch)/(trb(ji,jj,jk,jppic)+rtrn)
174               tra(ji,jj,jk,jppic) = tra(ji,jj,jk,jppic) - zmortp
175               tra(ji,jj,jk,jpnpi) = tra(ji,jj,jk,jpnpi) - zmortp * zfactn
176               tra(ji,jj,jk,jpppi) = tra(ji,jj,jk,jpppi) - zmortp * zfactp
177               tra(ji,jj,jk,jppch) = tra(ji,jj,jk,jppch) - zmortp * zfactch
178               tra(ji,jj,jk,jppfe) = tra(ji,jj,jk,jppfe) - zmortp * zfactfe
179               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zmortp
180               tra(ji,jj,jk,jppon) = tra(ji,jj,jk,jppon) + zmortp * zfactn
181               tra(ji,jj,jk,jppop) = tra(ji,jj,jk,jppop) + zmortp * zfactp
182               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zmortp * zfactfe
183               prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + zmortp
184            END DO
185         END DO
186      END DO
187      !
188       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
189         WRITE(charout, FMT="('pico')")
190         CALL prt_ctl_trc_info(charout)
191         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
192       ENDIF
193      !
194      IF( ln_timing )   CALL timing_stop('p5z_mort_pico')
195      !
196   END SUBROUTINE p5z_mort_pico
197
198
199   SUBROUTINE p5z_mort_diat
200      !!---------------------------------------------------------------------
201      !!                     ***  ROUTINE p5z_mort_diat  ***
202      !!
203      !! ** Purpose :   Compute the mortality terms for diatoms
204      !!
205      !! ** Method  : - ???
206      !!---------------------------------------------------------------------
207      INTEGER  ::  ji, jj, jk
208      REAL(wp) ::  zfactfe,zfactsi,zfactch, zfactn, zfactp, zcompadi
209      REAL(wp) ::  zrespp2, ztortp2, zmortp2
210      REAL(wp) ::  zlim2, zlim1
211      CHARACTER (len=25) :: charout
212      !!---------------------------------------------------------------------
213      !
214      IF( ln_timing )   CALL timing_start('p5z_mort_diat')
215      !
216
217      DO jk = 1, jpkm1
218         DO jj = 1, jpj
219            DO ji = 1, jpi
220
221               zcompadi = MAX( ( trb(ji,jj,jk,jpdia) - 1E-9), 0. )
222
223               !   Aggregation term for diatoms is increased in case of nutrient
224               !   stress as observed in reality. The stressed cells become more
225               !   sticky and coagulate to sink quickly out of the euphotic zone
226               !   -------------------------------------------------------------
227               !  Phytoplankton squared mortality
228               !  -------------------------------
229               zlim2   = xlimdia(ji,jj,jk) * xlimdia(ji,jj,jk)
230               zlim1   = 0.25 * ( 1. - zlim2 ) / ( 0.25 + zlim2 ) 
231               zrespp2 = 1.e6 * xstep * (  wchld + wchldm * zlim1 ) * xdiss(ji,jj,jk) * zcompadi * trb(ji,jj,jk,jpdia)
232
233               ! Phytoplankton linear mortality
234               ! A michaelis-menten like term is introduced to avoid
235               ! extinction of diatoms in highly limited areas
236               !  ---------------------------------------------------
237               ztortp2 = mpratd * xstep  * zcompadi * trb(ji,jj,jk,jpdia) /  ( xkmort + trb(ji,jj,jk,jpdia) )
238               zmortp2 = zrespp2 + ztortp2
239
240               !   Update the arrays tra which contains the biological sources and sinks
241               !   ---------------------------------------------------------------------
242               zfactn  = trb(ji,jj,jk,jpndi) / ( trb(ji,jj,jk,jpdia) + rtrn )
243               zfactp  = trb(ji,jj,jk,jppdi) / ( trb(ji,jj,jk,jpdia) + rtrn )
244               zfactch = trb(ji,jj,jk,jpdch) / ( trb(ji,jj,jk,jpdia) + rtrn )
245               zfactfe = trb(ji,jj,jk,jpdfe) / ( trb(ji,jj,jk,jpdia) + rtrn )
246               zfactsi = trb(ji,jj,jk,jpdsi) / ( trb(ji,jj,jk,jpdia) + rtrn )
247               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zmortp2 
248               tra(ji,jj,jk,jpndi) = tra(ji,jj,jk,jpndi) - zmortp2 * zfactn
249               tra(ji,jj,jk,jppdi) = tra(ji,jj,jk,jppdi) - zmortp2 * zfactp
250               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zmortp2 * zfactch
251               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zmortp2 * zfactfe
252               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) - zmortp2 * zfactsi
253               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) + zmortp2 * zfactsi
254               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zrespp2 
255               tra(ji,jj,jk,jpgon) = tra(ji,jj,jk,jpgon) + zrespp2 * zfactn
256               tra(ji,jj,jk,jpgop) = tra(ji,jj,jk,jpgop) + zrespp2 * zfactp
257               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zrespp2 * zfactfe
258               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + ztortp2
259               tra(ji,jj,jk,jppon) = tra(ji,jj,jk,jppon) + ztortp2 * zfactn
260               tra(ji,jj,jk,jppop) = tra(ji,jj,jk,jppop) + ztortp2 * zfactp
261               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + ztortp2 * zfactfe
262               prodpoc(ji,jj,jk)   = prodpoc(ji,jj,jk) + ztortp2
263               prodgoc(ji,jj,jk)   = prodgoc(ji,jj,jk) + zrespp2
264            END DO
265         END DO
266      END DO
267      !
268      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
269         WRITE(charout, FMT="('diat')")
270         CALL prt_ctl_trc_info(charout)
271         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
272      ENDIF
273      !
274      IF( ln_timing )   CALL timing_stop('p5z_mort_diat')
275      !
276   END SUBROUTINE p5z_mort_diat
277
278
279   SUBROUTINE p5z_mort_init
280      !!----------------------------------------------------------------------
281      !!                  ***  ROUTINE p5z_mort_init  ***
282      !!
283      !! ** Purpose :   Initialization of phytoplankton mortality parameters
284      !!
285      !! ** Method  :   Read the namp5zmort namelist and check the parameters
286      !!      called at the first timestep
287      !!
288      !! ** input   :   Namelist namp5zmort
289      !!
290      !!----------------------------------------------------------------------
291      INTEGER :: ios   ! Local integer output status for namelist read
292      !!
293      NAMELIST/namp5zmort/ wchln, wchlp, wchld, wchldm, mpratn, mpratp, mpratd
294      !!----------------------------------------------------------------------
295
296      REWIND( numnatp_ref )              ! Namelist namp5zmort in reference namelist : Pisces phytoplankton
297      READ  ( numnatp_ref, namp5zmort, IOSTAT = ios, ERR = 901)
298901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp5zmort in reference namelist' )
299
300      REWIND( numnatp_cfg )              ! Namelist namp5zmort in configuration namelist : Pisces phytoplankton
301      READ  ( numnatp_cfg, namp5zmort, IOSTAT = ios, ERR = 902 )
302902   IF( ios >  0 ) CALL ctl_nam ( ios , 'namp5zmort in configuration namelist' )
303      IF(lwm) WRITE ( numonp, namp5zmort )
304
305      IF(lwp) THEN                         ! control print
306         WRITE(numout,*) ' '
307         WRITE(numout,*) ' Namelist parameters for phytoplankton mortality, namp5zmort'
308         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
309         WRITE(numout,*) '    quadratic mortality of phytoplankton      wchln     =', wchln
310         WRITE(numout,*) '    quadratic mortality of picophyto.         wchlp     =', wchlp
311         WRITE(numout,*) '    quadratic mortality of diatoms            wchld     =', wchld
312         WRITE(numout,*) '    Additional quadratic mortality of diatoms wchldm    =', wchldm
313         WRITE(numout,*) '    nanophyto. mortality rate                 mpratn    =', mpratn
314         WRITE(numout,*) '    picophyto. mortality rate                 mpratp    =', mpratp
315         WRITE(numout,*) '    Diatoms mortality rate                    mpratd    =', mpratd
316      ENDIF
317
318   END SUBROUTINE p5z_mort_init
319
320   !!======================================================================
321END MODULE p5zmort
Note: See TracBrowser for help on using the repository browser.