New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
icesbc.F90 in NEMO/branches/2019/dev_r11842_SI3-10_EAP/src/ICE – NEMO

source: NEMO/branches/2019/dev_r11842_SI3-10_EAP/src/ICE/icesbc.F90 @ 13662

Last change on this file since 13662 was 13662, checked in by clem, 3 years ago

update to almost r4.0.4
  • Property svn:keywords set to Id
File size: 17.3 KB
Line 
1MODULE icesbc
2   !!======================================================================
3   !!                       ***  MODULE  icesbc  ***
4   !! Sea-Ice :   air-ice sbc fields
5   !!=====================================================================
6   !! History :  4.0  !  2017-08  (C. Rousset)       Original code
7   !!            4.0  !  2018     (many people)      SI3 [aka Sea Ice cube]
8   !!----------------------------------------------------------------------
9#if defined key_si3
10   !!----------------------------------------------------------------------
11   !!   'key_si3' :                                     SI3 sea-ice model
12   !!----------------------------------------------------------------------
13   USE oce            ! ocean dynamics and tracers
14   USE dom_oce        ! ocean space and time domain
15   USE ice            ! sea-ice: variables
16   USE sbc_oce        ! Surface boundary condition: ocean fields
17   USE sbc_ice        ! Surface boundary condition: ice   fields
18   USE usrdef_sbc     ! Surface boundary condition: user defined
19   USE sbcblk         ! Surface boundary condition: bulk
20   USE sbccpl         ! Surface boundary condition: coupled interface
21   USE icealb         ! sea-ice: albedo
22   !
23   USE in_out_manager ! I/O manager
24   USE iom            ! I/O manager library
25   USE lib_mpp        ! MPP library
26   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
27   USE lbclnk         ! lateral boundary conditions (or mpp links)
28   USE timing         ! Timing
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC ice_sbc_tau   ! called by icestp.F90
34   PUBLIC ice_sbc_flx   ! called by icestp.F90
35   PUBLIC ice_sbc_init  ! called by icestp.F90
36
37   !! * Substitutions
38#  include "vectopt_loop_substitute.h90"
39   !!----------------------------------------------------------------------
40   !! NEMO/ICE 4.0 , NEMO Consortium (2018)
41   !! $Id$
42   !! Software governed by the CeCILL license (see ./LICENSE)
43   !!----------------------------------------------------------------------
44CONTAINS
45
46   SUBROUTINE ice_sbc_tau( kt, ksbc, utau_ice, vtau_ice )
47      !!-------------------------------------------------------------------
48      !!                  ***  ROUTINE ice_sbc_tau  ***
49      !!
50      !! ** Purpose : provide surface boundary condition for sea ice (momentum)
51      !!
52      !! ** Action  : It provides the following fields:
53      !!              utau_ice, vtau_ice : surface ice stress (U- & V-points) [N/m2]
54      !!-------------------------------------------------------------------
55      INTEGER                     , INTENT(in   ) ::   kt                   ! ocean time step
56      INTEGER                     , INTENT(in   ) ::   ksbc                 ! type of sbc flux
57      REAL(wp), DIMENSION(jpi,jpj), INTENT(  out) ::   utau_ice, vtau_ice   ! air-ice stress   [N/m2]
58      !!
59      INTEGER  ::   ji, jj                 ! dummy loop index
60      REAL(wp), DIMENSION(jpi,jpj) ::   zutau_ice, zvtau_ice 
61      !!-------------------------------------------------------------------
62      !
63      IF( ln_timing )   CALL timing_start('ice_sbc')
64      !
65      IF( kt == nit000 .AND. lwp ) THEN
66         WRITE(numout,*)
67         WRITE(numout,*)'ice_sbc_tau: Surface boundary condition for sea ice (momentum)'
68         WRITE(numout,*)'~~~~~~~~~~~~~~~'
69      ENDIF
70      !
71      SELECT CASE( ksbc )
72         CASE( jp_usr     )   ;    CALL usrdef_sbc_ice_tau( kt )                 ! user defined formulation
73         CASE( jp_blk     )   ;    CALL blk_ice_tau                              ! Bulk         formulation
74         CASE( jp_purecpl )   ;    CALL sbc_cpl_ice_tau( utau_ice , vtau_ice )   ! Coupled      formulation
75      END SELECT
76      !
77      IF( ln_mixcpl) THEN                                                        ! Case of a mixed Bulk/Coupled formulation
78                                   CALL sbc_cpl_ice_tau( zutau_ice , zvtau_ice )
79         DO jj = 2, jpjm1
80            DO ji = 2, jpim1
81               utau_ice(ji,jj) = utau_ice(ji,jj) * xcplmask(ji,jj,0) + zutau_ice(ji,jj) * ( 1. - xcplmask(ji,jj,0) )
82               vtau_ice(ji,jj) = vtau_ice(ji,jj) * xcplmask(ji,jj,0) + zvtau_ice(ji,jj) * ( 1. - xcplmask(ji,jj,0) )
83            END DO
84         END DO
85         CALL lbc_lnk_multi( 'icesbc', utau_ice, 'U', -1., vtau_ice, 'V', -1. )
86      ENDIF
87      !
88      IF( ln_timing )   CALL timing_stop('ice_sbc')
89      !
90   END SUBROUTINE ice_sbc_tau
91
92   
93   SUBROUTINE ice_sbc_flx( kt, ksbc )
94      !!-------------------------------------------------------------------
95      !!                  ***  ROUTINE ice_sbc_flx  ***
96      !!
97      !! ** Purpose : provide surface boundary condition for sea ice (flux)
98      !!
99      !! ** Action  : It provides the following fields used in sea ice model:
100      !!                emp_oce , emp_ice                        = E-P over ocean and sea ice                    [Kg/m2/s]
101      !!                sprecip                                  = solid precipitation                           [Kg/m2/s]
102      !!                evap_ice                                 = sublimation                                   [Kg/m2/s]
103      !!                qsr_tot , qns_tot                        = solar & non solar heat flux (total)           [W/m2]
104      !!                qsr_ice , qns_ice                        = solar & non solar heat flux over ice          [W/m2]
105      !!                dqns_ice                                 = non solar  heat sensistivity                  [W/m2]
106      !!                qemp_oce, qemp_ice, qprec_ice, qevap_ice = sensible heat (associated with evap & precip) [W/m2]
107      !!            + some fields that are not used outside this module:
108      !!                qla_ice                                  = latent heat flux over ice                     [W/m2]
109      !!                dqla_ice                                 = latent heat sensistivity                      [W/m2]
110      !!                tprecip                                  = total  precipitation                          [Kg/m2/s]
111      !!                alb_ice                                  = albedo above sea ice
112      !!-------------------------------------------------------------------
113      INTEGER, INTENT(in) ::   kt     ! ocean time step
114      INTEGER, INTENT(in) ::   ksbc   ! flux formulation (user defined, bulk or Pure Coupled)
115      !
116      INTEGER  ::   ji, jj, jl      ! dummy loop index
117      REAL(wp) ::   zmiss_val       ! missing value retrieved from xios
118      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zalb, zmsk00      ! 2D workspace
119      !!--------------------------------------------------------------------
120      !
121      IF( ln_timing )   CALL timing_start('ice_sbc_flx')
122
123      IF( kt == nit000 .AND. lwp ) THEN
124         WRITE(numout,*)
125         WRITE(numout,*)'ice_sbc_flx: Surface boundary condition for sea ice (flux)'
126         WRITE(numout,*)'~~~~~~~~~~~~~~~'
127      ENDIF
128
129      ! get missing value from xml
130      CALL iom_miss_val( "icetemp", zmiss_val )
131
132      ! --- ice albedo --- !
133      CALL ice_alb( t_su, h_i, h_s, ln_pnd_alb, a_ip_eff, h_ip, cloud_fra, alb_ice )
134
135      !
136      SELECT CASE( ksbc )   !== fluxes over sea ice ==!
137      !
138      CASE( jp_usr )              !--- user defined formulation
139                                  CALL usrdef_sbc_ice_flx( kt, h_s, h_i )
140      CASE( jp_blk )              !--- bulk formulation
141                                  CALL blk_ice_flx    ( t_su, h_s, h_i, alb_ice )    !
142         IF( ln_mixcpl        )   CALL sbc_cpl_ice_flx( picefr=at_i_b, palbi=alb_ice, psst=sst_m, pist=t_su, phs=h_s, phi=h_i )
143         IF( nn_flxdist /= -1 )   CALL ice_flx_dist   ( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_flxdist )
144         !                        !    compute conduction flux and surface temperature (as in Jules surface module)
145         IF( ln_cndflx .AND. .NOT.ln_cndemulate ) &
146            &                     CALL blk_ice_qcn    ( ln_virtual_itd, t_su, t_bo, h_s, h_i )
147      CASE ( jp_purecpl )         !--- coupled formulation
148                                  CALL sbc_cpl_ice_flx( picefr=at_i_b, palbi=alb_ice, psst=sst_m, pist=t_su, phs=h_s, phi=h_i )
149         IF( nn_flxdist /= -1 )   CALL ice_flx_dist   ( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_flxdist )
150      END SELECT
151
152      !--- output ice albedo and surface albedo ---!
153      IF( iom_use('icealb') .OR. iom_use('albedo') ) THEN
154
155         ALLOCATE( zalb(jpi,jpj), zmsk00(jpi,jpj) )
156
157         WHERE( at_i_b < 1.e-03 )
158            zmsk00(:,:) = 0._wp
159            zalb  (:,:) = rn_alb_oce
160         ELSEWHERE
161            zmsk00(:,:) = 1._wp           
162            zalb  (:,:) = SUM( alb_ice * a_i_b, dim=3 ) / at_i_b
163         END WHERE
164         ! ice albedo
165         CALL iom_put( 'icealb' , zalb * zmsk00 + zmiss_val * ( 1._wp - zmsk00 ) )
166         ! ice+ocean albedo
167         zalb(:,:) = SUM( alb_ice * a_i_b, dim=3 ) + rn_alb_oce * ( 1._wp - at_i_b )
168         CALL iom_put( 'albedo' , zalb )
169
170         DEALLOCATE( zalb, zmsk00 )
171
172      ENDIF
173      !
174      IF( ln_timing )   CALL timing_stop('ice_sbc_flx')
175      !
176   END SUBROUTINE ice_sbc_flx
177
178
179   SUBROUTINE ice_flx_dist( ptn_ice, palb_ice, pqns_ice, pqsr_ice, pdqn_ice, pevap_ice, pdevap_ice, k_flxdist )
180      !!-------------------------------------------------------------------
181      !!                  ***  ROUTINE ice_flx_dist  ***
182      !!
183      !! ** Purpose :   update the ice surface boundary condition by averaging
184      !!              and/or redistributing fluxes on ice categories
185      !!
186      !! ** Method  :   average then redistribute
187      !!
188      !! ** Action  :   depends on k_flxdist
189      !!                = -1  Do nothing (needs N(cat) fluxes)
190      !!                =  0  Average N(cat) fluxes then apply the average over the N(cat) ice
191      !!                =  1  Average N(cat) fluxes then redistribute over the N(cat) ice
192      !!                                                 using T-ice and albedo sensitivity
193      !!                =  2  Redistribute a single flux over categories
194      !!-------------------------------------------------------------------
195      INTEGER                   , INTENT(in   ) ::   k_flxdist  ! redistributor
196      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   ptn_ice    ! ice surface temperature
197      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   palb_ice   ! ice albedo
198      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pqns_ice   ! non solar flux
199      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pqsr_ice   ! net solar flux
200      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pdqn_ice   ! non solar flux sensitivity
201      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pevap_ice  ! sublimation
202      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pdevap_ice ! sublimation sensitivity
203      !
204      INTEGER  ::   jl      ! dummy loop index
205      !
206      REAL(wp), DIMENSION(jpi,jpj) ::   z1_at_i   ! inverse of concentration
207      !
208      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   z_qsr_m   ! Mean solar heat flux over all categories
209      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   z_qns_m   ! Mean non solar heat flux over all categories
210      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   z_evap_m  ! Mean sublimation over all categories
211      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   z_dqn_m   ! Mean d(qns)/dT over all categories
212      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   z_devap_m ! Mean d(evap)/dT over all categories
213      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   zalb_m    ! Mean albedo over all categories
214      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   ztem_m    ! Mean temperature over all categories
215      !!----------------------------------------------------------------------
216      !
217      WHERE ( at_i (:,:) > 0._wp )   ; z1_at_i(:,:) = 1._wp / at_i (:,:)
218      ELSEWHERE                      ; z1_at_i(:,:) = 0._wp
219      END WHERE
220     
221      SELECT CASE( k_flxdist )       !==  averaged on all ice categories  ==!
222      !
223      CASE( 0 , 1 )
224         !
225         ALLOCATE( z_qns_m(jpi,jpj), z_qsr_m(jpi,jpj), z_dqn_m(jpi,jpj), z_evap_m(jpi,jpj), z_devap_m(jpi,jpj) ) 
226         !
227         z_qns_m  (:,:) = SUM( a_i(:,:,:) * pqns_ice  (:,:,:) , dim=3 ) * z1_at_i(:,:)
228         z_qsr_m  (:,:) = SUM( a_i(:,:,:) * pqsr_ice  (:,:,:) , dim=3 ) * z1_at_i(:,:)
229         z_dqn_m  (:,:) = SUM( a_i(:,:,:) * pdqn_ice  (:,:,:) , dim=3 ) * z1_at_i(:,:)
230         z_evap_m (:,:) = SUM( a_i(:,:,:) * pevap_ice (:,:,:) , dim=3 ) * z1_at_i(:,:)
231         z_devap_m(:,:) = SUM( a_i(:,:,:) * pdevap_ice(:,:,:) , dim=3 ) * z1_at_i(:,:)
232         DO jl = 1, jpl
233            pqns_ice  (:,:,jl) = z_qns_m (:,:)
234            pqsr_ice  (:,:,jl) = z_qsr_m (:,:)
235            pdqn_ice  (:,:,jl) = z_dqn_m  (:,:)
236            pevap_ice (:,:,jl) = z_evap_m(:,:)
237            pdevap_ice(:,:,jl) = z_devap_m(:,:)
238         END DO
239         !
240         DEALLOCATE( z_qns_m, z_qsr_m, z_dqn_m, z_evap_m, z_devap_m ) 
241         !
242      END SELECT
243      !
244      SELECT CASE( k_flxdist )       !==  redistribution on all ice categories  ==!
245      !
246      CASE( 1 , 2 )
247         !
248         ALLOCATE( zalb_m(jpi,jpj), ztem_m(jpi,jpj) ) 
249         !
250         zalb_m(:,:) = SUM( a_i(:,:,:) * palb_ice(:,:,:) , dim=3 ) * z1_at_i(:,:)
251         ztem_m(:,:) = SUM( a_i(:,:,:) * ptn_ice (:,:,:) , dim=3 ) * z1_at_i(:,:)
252         DO jl = 1, jpl
253            pqns_ice (:,:,jl) = pqns_ice (:,:,jl) + pdqn_ice  (:,:,jl) * ( ptn_ice(:,:,jl) - ztem_m(:,:) )
254            pevap_ice(:,:,jl) = pevap_ice(:,:,jl) + pdevap_ice(:,:,jl) * ( ptn_ice(:,:,jl) - ztem_m(:,:) )
255            pqsr_ice (:,:,jl) = pqsr_ice (:,:,jl) * ( 1._wp - palb_ice(:,:,jl) ) / ( 1._wp - zalb_m(:,:) )
256         END DO
257         !
258         DEALLOCATE( zalb_m, ztem_m ) 
259         !
260      END SELECT
261      !
262   END SUBROUTINE ice_flx_dist
263
264
265   SUBROUTINE ice_sbc_init
266      !!-------------------------------------------------------------------
267      !!                  ***  ROUTINE ice_sbc_init  ***
268      !!
269      !! ** Purpose :   Physical constants and parameters linked to the ice dynamics
270      !!     
271      !! ** Method  :   Read the namsbc namelist and check the ice-dynamic
272      !!              parameter values called at the first timestep (nit000)
273      !!
274      !! ** input   :   Namelist namsbc
275      !!-------------------------------------------------------------------
276      INTEGER ::   ios, ioptio   ! Local integer
277      !!
278      NAMELIST/namsbc/ rn_cio, nn_snwfra, rn_snwblow, nn_flxdist, ln_cndflx, ln_cndemulate, nn_qtrice
279      !!-------------------------------------------------------------------
280      !
281      REWIND( numnam_ice_ref )         ! Namelist namsbc in reference namelist : Ice dynamics
282      READ  ( numnam_ice_ref, namsbc, IOSTAT = ios, ERR = 901)
283901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namsbc in reference namelist' )
284      REWIND( numnam_ice_cfg )         ! Namelist namsbc in configuration namelist : Ice dynamics
285      READ  ( numnam_ice_cfg, namsbc, IOSTAT = ios, ERR = 902 )
286902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namsbc in configuration namelist' )
287      IF(lwm) WRITE( numoni, namsbc )
288      !
289      IF(lwp) THEN                     ! control print
290         WRITE(numout,*)
291         WRITE(numout,*) 'ice_sbc_init: ice parameters for ice dynamics '
292         WRITE(numout,*) '~~~~~~~~~~~~~~~~'
293         WRITE(numout,*) '   Namelist namsbc:'
294         WRITE(numout,*) '      drag coefficient for oceanic stress                       rn_cio        = ', rn_cio
295         WRITE(numout,*) '      fraction of ice covered by snow (options 0,1,2)           nn_snwfra     = ', nn_snwfra
296         WRITE(numout,*) '      coefficient for ice-lead partition of snowfall            rn_snwblow    = ', rn_snwblow
297         WRITE(numout,*) '      Multicategory heat flux formulation                       nn_flxdist    = ', nn_flxdist
298         WRITE(numout,*) '      Use conduction flux as surface condition                  ln_cndflx     = ', ln_cndflx
299         WRITE(numout,*) '         emulate conduction flux                                ln_cndemulate = ', ln_cndemulate
300         WRITE(numout,*) '      solar flux transmitted thru the surface scattering layer  nn_qtrice     = ', nn_qtrice
301         WRITE(numout,*) '         = 0  Grenfell and Maykut 1977'
302         WRITE(numout,*) '         = 1  Lebrun 2019'
303      ENDIF
304      !
305      IF(lwp) WRITE(numout,*)
306      SELECT CASE( nn_flxdist )         ! SI3 Multi-category heat flux formulation
307      CASE( -1  )
308         IF(lwp) WRITE(numout,*) '   SI3: use per-category fluxes (nn_flxdist = -1) '
309      CASE(  0  )
310         IF(lwp) WRITE(numout,*) '   SI3: use average per-category fluxes (nn_flxdist = 0) '
311      CASE(  1  )
312         IF(lwp) WRITE(numout,*) '   SI3: use average then redistribute per-category fluxes (nn_flxdist = 1) '
313         IF( ln_cpl )         CALL ctl_stop( 'ice_thd_init: the chosen nn_flxdist for SI3 in coupled mode must be /=1' )
314      CASE(  2  )
315         IF(lwp) WRITE(numout,*) '   SI3: Redistribute a single flux over categories (nn_flxdist = 2) '
316         IF( .NOT. ln_cpl )   CALL ctl_stop( 'ice_thd_init: the chosen nn_flxdist for SI3 in forced mode must be /=2' )
317      CASE DEFAULT
318         CALL ctl_stop( 'ice_thd_init: SI3 option, nn_flxdist, should be between -1 and 2' )
319      END SELECT
320      !
321   END SUBROUTINE ice_sbc_init
322
323#else
324   !!----------------------------------------------------------------------
325   !!   Default option :         Empty module         NO SI3 sea-ice model
326   !!----------------------------------------------------------------------
327#endif
328
329   !!======================================================================
330END MODULE icesbc
Note: See TracBrowser for help on using the repository browser.