New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zrem.F90 in NEMO/branches/2019/dev_r11842_SI3-10_EAP/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2019/dev_r11842_SI3-10_EAP/src/TOP/PISCES/P4Z/p4zrem.F90 @ 13662

Last change on this file since 13662 was 13662, checked in by clem, 4 years ago

update to almost r4.0.4
  • Property svn:keywords set to Id
File size: 18.5 KB
Line 
1MODULE p4zrem
2   !!======================================================================
3   !!                         ***  MODULE p4zrem  ***
4   !! TOP :   PISCES Compute remineralization/dissolution of organic compounds
5   !!=========================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!----------------------------------------------------------------------
10   !!   p4z_rem       :  Compute remineralization/dissolution of organic compounds
11   !!   p4z_rem_init  :  Initialisation of parameters for remineralisation
12   !!   p4z_rem_alloc :  Allocate remineralisation variables
13   !!----------------------------------------------------------------------
14   USE oce_trc         !  shared variables between ocean and passive tracers
15   USE trc             !  passive tracers common variables
16   USE sms_pisces      !  PISCES Source Minus Sink variables
17   USE p4zche          !  chemical model
18   USE p4zprod         !  Growth rate of the 2 phyto groups
19   USE p4zlim
20   USE prtctl_trc      !  print control for debugging
21   USE iom             !  I/O manager
22
23
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC   p4z_rem         ! called in p4zbio.F90
28   PUBLIC   p4z_rem_init    ! called in trcsms_pisces.F90
29   PUBLIC   p4z_rem_alloc
30
31   REAL(wp), PUBLIC ::   xremikc    !: remineralisation rate of DOC
32   REAL(wp), PUBLIC ::   xremikn    !: remineralisation rate of DON
33   REAL(wp), PUBLIC ::   xremikp    !: remineralisation rate of DOP
34   REAL(wp), PUBLIC ::   xremik     !: remineralisation rate of POC
35   REAL(wp), PUBLIC ::   nitrif     !: NH4 nitrification rate
36   REAL(wp), PUBLIC ::   xsirem     !: remineralisation rate of POC
37   REAL(wp), PUBLIC ::   xsiremlab  !: fast remineralisation rate of POC
38   REAL(wp), PUBLIC ::   xsilab     !: fraction of labile biogenic silica
39   REAL(wp), PUBLIC ::   feratb     !: Fe/C quota in bacteria
40   REAL(wp), PUBLIC ::   xkferb     !: Half-saturation constant for bacteria Fe/C
41
42   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   denitr   !: denitrification array
43
44   !!----------------------------------------------------------------------
45   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
46   !! $Id$
47   !! Software governed by the CeCILL license (see ./LICENSE)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   SUBROUTINE p4z_rem( kt, knt )
52      !!---------------------------------------------------------------------
53      !!                     ***  ROUTINE p4z_rem  ***
54      !!
55      !! ** Purpose :   Compute remineralization/scavenging of organic compounds
56      !!
57      !! ** Method  : - ???
58      !!---------------------------------------------------------------------
59      INTEGER, INTENT(in) ::   kt, knt ! ocean time step
60      !
61      INTEGER  ::   ji, jj, jk
62      REAL(wp) ::   zremik, zremikc, zremikn, zremikp, zsiremin, zfact 
63      REAL(wp) ::   zsatur, zsatur2, znusil, znusil2, zdep, zdepmin, zfactdep
64      REAL(wp) ::   zbactfer, zolimit, zonitr, zrfact2
65      REAL(wp) ::   zammonic, zoxyremc, zoxyremn, zoxyremp
66      REAL(wp) ::   zosil, ztem, zdenitnh4, zolimic, zolimin, zolimip, zdenitrn, zdenitrp
67      CHARACTER (len=25) :: charout
68      REAL(wp), DIMENSION(jpi,jpj    ) :: ztempbac
69      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zdepbac, zolimi, zdepprod, zfacsi, zfacsib, zdepeff, zfebact
70      !!---------------------------------------------------------------------
71      !
72      IF( ln_timing )   CALL timing_start('p4z_rem')
73      !
74      ! Initialisation of arrys
75      zdepprod(:,:,:) = 1._wp
76      zdepeff (:,:,:) = 0.3_wp
77      ztempbac(:,:)   = 0._wp
78      zfacsib(:,:,:)  = xsilab / ( 1.0 - xsilab )
79      zfebact(:,:,:)  = 0._wp
80      zfacsi(:,:,:)   = xsilab
81
82      ! Computation of the mean phytoplankton concentration as
83      ! a crude estimate of the bacterial biomass
84      ! this parameterization has been deduced from a model version
85      ! that was modeling explicitely bacteria
86      ! -------------------------------------------------------
87      DO jk = 1, jpkm1
88         DO jj = 1, jpj
89            DO ji = 1, jpi
90               zdep = MAX( hmld(ji,jj), heup(ji,jj) )
91               IF( gdept_n(ji,jj,jk) < zdep ) THEN
92                  zdepbac(ji,jj,jk) = MIN( 0.7 * ( trb(ji,jj,jk,jpzoo) + 2.* trb(ji,jj,jk,jpmes) ), 4.e-6 )
93                  ztempbac(ji,jj)   = zdepbac(ji,jj,jk)
94               ELSE
95                  zdepmin = MIN( 1., zdep / gdept_n(ji,jj,jk) )
96                  zdepbac (ji,jj,jk) = zdepmin**0.683 * ztempbac(ji,jj)
97                  zdepprod(ji,jj,jk) = zdepmin**0.273
98                  zdepeff (ji,jj,jk) = zdepeff(ji,jj,jk) * zdepmin**0.3
99               ENDIF
100            END DO
101         END DO
102      END DO
103
104      IF( ln_p4z ) THEN
105         DO jk = 1, jpkm1
106            DO jj = 1, jpj
107               DO ji = 1, jpi
108                  ! DOC ammonification. Depends on depth, phytoplankton biomass
109                  ! and a limitation term which is supposed to be a parameterization of the bacterial activity.
110                  zremik = xremik * xstep / 1.e-6 * xlimbac(ji,jj,jk) * zdepbac(ji,jj,jk) 
111                  zremik = MAX( zremik, 2.74e-4 * xstep )
112                  ! Ammonification in oxic waters with oxygen consumption
113                  ! -----------------------------------------------------
114                  zolimit = zremik * ( 1.- nitrfac(ji,jj,jk) ) * trb(ji,jj,jk,jpdoc) 
115                  zolimi(ji,jj,jk) = MIN( ( trb(ji,jj,jk,jpoxy) - rtrn ) / o2ut, zolimit ) 
116                  ! Ammonification in suboxic waters with denitrification
117                  ! -------------------------------------------------------
118                  zammonic = zremik * nitrfac(ji,jj,jk) * trb(ji,jj,jk,jpdoc)
119                  denitr(ji,jj,jk)  = zammonic * ( 1. - nitrfac2(ji,jj,jk) )
120                  denitr(ji,jj,jk)  = MIN( ( trb(ji,jj,jk,jpno3) - rtrn ) / rdenit, denitr(ji,jj,jk) )
121                  zoxyremc          = zammonic - denitr(ji,jj,jk)
122                  !
123                  zolimi (ji,jj,jk) = MAX( 0.e0, zolimi (ji,jj,jk) )
124                  denitr (ji,jj,jk) = MAX( 0.e0, denitr (ji,jj,jk) )
125                  zoxyremc          = MAX( 0.e0, zoxyremc )
126
127                  !
128                  tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zolimi (ji,jj,jk) + denitr(ji,jj,jk) + zoxyremc
129                  tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zolimi (ji,jj,jk) + denitr(ji,jj,jk) + zoxyremc
130                  tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - denitr (ji,jj,jk) * rdenit
131                  tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zolimi (ji,jj,jk) - denitr(ji,jj,jk) - zoxyremc
132                  tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - zolimi (ji,jj,jk) * o2ut
133                  tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zolimi (ji,jj,jk) + denitr(ji,jj,jk) + zoxyremc
134                  tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zolimi(ji,jj,jk) + zoxyremc    &
135                  &                     + ( rdenit + 1.) * denitr(ji,jj,jk) )
136               END DO
137            END DO
138         END DO
139      ELSE
140         DO jk = 1, jpkm1
141            DO jj = 1, jpj
142               DO ji = 1, jpi
143                  ! DOC ammonification. Depends on depth, phytoplankton biomass
144                  ! and a limitation term which is supposed to be a parameterization of the bacterial activity.
145                  ! -----------------------------------------------------------------
146                  zremik = xstep / 1.e-6 * MAX(0.01, xlimbac(ji,jj,jk)) * zdepbac(ji,jj,jk) 
147                  zremik = MAX( zremik, 2.74e-4 * xstep / xremikc )
148
149                  zremikc = xremikc * zremik
150                  zremikn = xremikn / xremikc
151                  zremikp = xremikp / xremikc
152
153                  ! Ammonification in oxic waters with oxygen consumption
154                  ! -----------------------------------------------------
155                  zolimit = zremikc * ( 1.- nitrfac(ji,jj,jk) ) * trb(ji,jj,jk,jpdoc) 
156                  zolimic = MAX( 0.e0, MIN( ( trb(ji,jj,jk,jpoxy) - rtrn ) / o2ut, zolimit ) ) 
157                  zolimi(ji,jj,jk) = zolimic
158                  zolimin = zremikn * zolimic * trb(ji,jj,jk,jpdon) / ( trb(ji,jj,jk,jpdoc) + rtrn )
159                  zolimip = zremikp * zolimic * trb(ji,jj,jk,jpdop) / ( trb(ji,jj,jk,jpdoc) + rtrn ) 
160
161                  ! Ammonification in suboxic waters with denitrification
162                  ! -------------------------------------------------------
163                  zammonic = zremikc * nitrfac(ji,jj,jk) * trb(ji,jj,jk,jpdoc)
164                  denitr(ji,jj,jk)  = zammonic * ( 1. - nitrfac2(ji,jj,jk) )
165                  denitr(ji,jj,jk)  = MAX(0., MIN(  ( trb(ji,jj,jk,jpno3) - rtrn ) / rdenit, denitr(ji,jj,jk) ) )
166                  zoxyremc          = MAX(0., zammonic - denitr(ji,jj,jk))
167                  zdenitrn  = zremikn * denitr(ji,jj,jk) * trb(ji,jj,jk,jpdon) / ( trb(ji,jj,jk,jpdoc) + rtrn )
168                  zdenitrp  = zremikp * denitr(ji,jj,jk) * trb(ji,jj,jk,jpdop) / ( trb(ji,jj,jk,jpdoc) + rtrn )
169                  zoxyremn  = zremikn * zoxyremc * trb(ji,jj,jk,jpdon) / ( trb(ji,jj,jk,jpdoc) + rtrn )
170                  zoxyremp  = zremikp * zoxyremc * trb(ji,jj,jk,jpdop) / ( trb(ji,jj,jk,jpdoc) + rtrn )
171
172                  tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zolimip + zdenitrp + zoxyremp
173                  tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zolimin + zdenitrn + zoxyremn
174                  tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - denitr(ji,jj,jk) * rdenit
175                  tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zolimic - denitr(ji,jj,jk) - zoxyremc
176                  tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) - zolimin - zdenitrn - zoxyremn
177                  tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) - zolimip - zdenitrp - zoxyremp
178                  tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - zolimic * o2ut
179                  tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zolimic + denitr(ji,jj,jk) + zoxyremc
180                  tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zolimin + zoxyremn + ( rdenit + 1.) * zdenitrn )
181               END DO
182            END DO
183         END DO
184         !
185      ENDIF
186
187
188      DO jk = 1, jpkm1
189         DO jj = 1, jpj
190            DO ji = 1, jpi
191               ! NH4 nitrification to NO3. Ceased for oxygen concentrations
192               ! below 2 umol/L. Inhibited at strong light
193               ! ----------------------------------------------------------
194               zonitr  = nitrif * xstep * trb(ji,jj,jk,jpnh4) * ( 1.- nitrfac(ji,jj,jk) )  &
195               &         / ( 1.+ emoy(ji,jj,jk) ) * ( 1. + fr_i(ji,jj) * emoy(ji,jj,jk) ) 
196               zdenitnh4 = nitrif * xstep * trb(ji,jj,jk,jpnh4) * nitrfac(ji,jj,jk)
197               zdenitnh4 = MIN(  ( trb(ji,jj,jk,jpno3) - rtrn ) / rdenita, zdenitnh4 ) 
198               ! Update of the tracers trends
199               ! ----------------------------
200               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zonitr - zdenitnh4
201               tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) + zonitr - rdenita * zdenitnh4
202               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2nit * zonitr
203               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2 * rno3 * zonitr + rno3 * ( rdenita - 1. ) * zdenitnh4
204            END DO
205         END DO
206      END DO
207
208       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
209         WRITE(charout, FMT="('rem1')")
210         CALL prt_ctl_trc_info(charout)
211         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
212       ENDIF
213
214      DO jk = 1, jpkm1
215         DO jj = 1, jpj
216            DO ji = 1, jpi
217
218               ! Bacterial uptake of iron. No iron is available in DOC. So
219               ! Bacteries are obliged to take up iron from the water. Some
220               ! studies (especially at Papa) have shown this uptake to be significant
221               ! ----------------------------------------------------------
222               zbactfer = feratb *  rfact2 * 0.6_wp / rday * tgfunc(ji,jj,jk) * xlimbacl(ji,jj,jk)     &
223                  &              * trb(ji,jj,jk,jpfer) / ( xkferb + trb(ji,jj,jk,jpfer) )    &
224                  &              * zdepprod(ji,jj,jk) * zdepeff(ji,jj,jk) * zdepbac(ji,jj,jk)
225               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zbactfer*0.33
226               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zbactfer*0.25
227               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zbactfer*0.08
228               zfebact(ji,jj,jk)   = zbactfer * 0.33
229               blim(ji,jj,jk)      = xlimbacl(ji,jj,jk)  * zdepbac(ji,jj,jk) / 1.e-6 * zdepprod(ji,jj,jk)
230            END DO
231         END DO
232      END DO
233
234       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
235         WRITE(charout, FMT="('rem2')")
236         CALL prt_ctl_trc_info(charout)
237         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
238       ENDIF
239
240      ! Initialization of the array which contains the labile fraction
241      ! of bSi. Set to a constant in the upper ocean
242      ! ---------------------------------------------------------------
243
244      DO jk = 1, jpkm1
245         DO jj = 1, jpj
246            DO ji = 1, jpi
247               zdep     = MAX( hmld(ji,jj), heup_01(ji,jj) )
248               zsatur   = MAX( rtrn, ( sio3eq(ji,jj,jk) - trb(ji,jj,jk,jpsil) ) / ( sio3eq(ji,jj,jk) + rtrn ) )
249               zsatur2  = ( 1. + tsn(ji,jj,jk,jp_tem) / 400.)**37
250               znusil   = 0.225  * ( 1. + tsn(ji,jj,jk,jp_tem) / 15.) * zsatur + 0.775 * zsatur2 * zsatur**9.25
251               ! Remineralization rate of BSi depedant on T and saturation
252               ! ---------------------------------------------------------
253               IF ( gdept_n(ji,jj,jk) > zdep ) THEN
254                  zfacsib(ji,jj,jk) = zfacsib(ji,jj,jk-1) * EXP( -0.5 * ( xsiremlab - xsirem )  &
255                  &                   * znusil * e3t_n(ji,jj,jk) / wsbio4(ji,jj,jk) )
256                  zfacsi(ji,jj,jk)  = zfacsib(ji,jj,jk) / ( 1.0 + zfacsib(ji,jj,jk) )
257                  zfacsib(ji,jj,jk) = zfacsib(ji,jj,jk) * EXP( -0.5 * ( xsiremlab - xsirem )    &
258                  &                   * znusil * e3t_n(ji,jj,jk) / wsbio4(ji,jj,jk) )
259               ENDIF
260               zsiremin = ( xsiremlab * zfacsi(ji,jj,jk) + xsirem * ( 1. - zfacsi(ji,jj,jk) ) ) * xstep * znusil
261               zosil    = zsiremin * trb(ji,jj,jk,jpgsi)
262               !
263               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) - zosil
264               tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) + zosil
265            END DO
266         END DO
267      END DO
268
269      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
270         WRITE(charout, FMT="('rem3')")
271         CALL prt_ctl_trc_info(charout)
272         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
273       ENDIF
274
275      IF( lk_iomput .AND. knt == nrdttrc ) THEN
276          zrfact2 = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
277          !
278          IF( iom_use( "REMIN" ) )  THEN !  Remineralisation rate
279             zolimi(:,:,jpk) = 0. ; CALL iom_put( "REMIN"  , zolimi(:,:,:) * tmask(:,:,:) * zrfact2  )
280          ENDIF
281          CALL iom_put( "DENIT"  , denitr(:,:,:) * rdenit * rno3 * tmask(:,:,:) * zrfact2 ) ! Denitrification
282          IF( iom_use( "BACT" ) )  THEN ! Bacterial biomass
283             zdepbac(:,:,jpk) = 0.  ;   CALL iom_put( "BACT", zdepbac(:,:,:) * 1.E6 * tmask(:,:,:) )
284          ENDIF
285          CALL iom_put( "FEBACT" , zfebact(:,:,:) * 1E9 * tmask(:,:,:) * zrfact2  )
286       ENDIF
287      !
288      IF( ln_timing )   CALL timing_stop('p4z_rem')
289      !
290   END SUBROUTINE p4z_rem
291
292
293   SUBROUTINE p4z_rem_init
294      !!----------------------------------------------------------------------
295      !!                  ***  ROUTINE p4z_rem_init  ***
296      !!
297      !! ** Purpose :   Initialization of remineralization parameters
298      !!
299      !! ** Method  :   Read the nampisrem namelist and check the parameters
300      !!      called at the first timestep
301      !!
302      !! ** input   :   Namelist nampisrem
303      !!
304      !!----------------------------------------------------------------------
305      NAMELIST/nampisrem/ xremik, nitrif, xsirem, xsiremlab, xsilab, feratb, xkferb, & 
306         &                xremikc, xremikn, xremikp
307      INTEGER :: ios                 ! Local integer output status for namelist read
308      !!----------------------------------------------------------------------
309      !
310      IF(lwp) THEN
311         WRITE(numout,*)
312         WRITE(numout,*) 'p4z_rem_init : Initialization of remineralization parameters'
313         WRITE(numout,*) '~~~~~~~~~~~~'
314      ENDIF
315      !
316      REWIND( numnatp_ref )
317      READ  ( numnatp_ref, nampisrem, IOSTAT = ios, ERR = 901)
318901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampisrem in reference namelist' )
319
320      REWIND( numnatp_cfg )
321      READ  ( numnatp_cfg, nampisrem, IOSTAT = ios, ERR = 902 )
322902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampisrem in configuration namelist' )
323      IF(lwm) WRITE( numonp, nampisrem )
324
325      IF(lwp) THEN                         ! control print
326         WRITE(numout,*) '   Namelist parameters for remineralization, nampisrem'
327         IF( ln_p4z ) THEN
328            WRITE(numout,*) '      remineralization rate of DOC              xremik    =', xremik
329         ELSE
330            WRITE(numout,*) '      remineralization rate of DOC              xremikc   =', xremikc
331            WRITE(numout,*) '      remineralization rate of DON              xremikn   =', xremikn
332            WRITE(numout,*) '      remineralization rate of DOP              xremikp   =', xremikp
333         ENDIF
334         WRITE(numout,*) '      remineralization rate of Si               xsirem    =', xsirem
335         WRITE(numout,*) '      fast remineralization rate of Si          xsiremlab =', xsiremlab
336         WRITE(numout,*) '      fraction of labile biogenic silica        xsilab    =', xsilab
337         WRITE(numout,*) '      NH4 nitrification rate                    nitrif    =', nitrif
338         WRITE(numout,*) '      Bacterial Fe/C ratio                      feratb    =', feratb
339         WRITE(numout,*) '      Half-saturation constant for bact. Fe/C   xkferb    =', xkferb
340      ENDIF
341      !
342      denitr(:,:,:) = 0._wp
343      !
344   END SUBROUTINE p4z_rem_init
345
346
347   INTEGER FUNCTION p4z_rem_alloc()
348      !!----------------------------------------------------------------------
349      !!                     ***  ROUTINE p4z_rem_alloc  ***
350      !!----------------------------------------------------------------------
351      ALLOCATE( denitr(jpi,jpj,jpk), STAT=p4z_rem_alloc )
352      !
353      IF( p4z_rem_alloc /= 0 )   CALL ctl_stop( 'STOP', 'p4z_rem_alloc: failed to allocate arrays' )
354      !
355   END FUNCTION p4z_rem_alloc
356
357   !!======================================================================
358END MODULE p4zrem
Note: See TracBrowser for help on using the repository browser.