New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynzad.F90 in NEMO/branches/2019/dev_r11879_ENHANCE-05_SimonM-Harmonic_Analysis/src/OCE/DYN – NEMO

source: NEMO/branches/2019/dev_r11879_ENHANCE-05_SimonM-Harmonic_Analysis/src/OCE/DYN/dynzad.F90 @ 12097

Last change on this file since 12097 was 10068, checked in by nicolasmartin, 6 years ago

First part of modifications to have a common default header : fix typos and SVN keywords properties

  • Property svn:keywords set to Id
File size: 5.3 KB
Line 
1MODULE dynzad
2   !!======================================================================
3   !!                       ***  MODULE  dynzad  ***
4   !! Ocean dynamics : vertical advection trend
5   !!======================================================================
6   !! History :  OPA  ! 1991-01  (G. Madec) Original code
7   !!   NEMO     0.5  ! 2002-07  (G. Madec) Free form, F90
8   !!----------------------------------------------------------------------
9   
10   !!----------------------------------------------------------------------
11   !!   dyn_zad       : vertical advection momentum trend
12   !!----------------------------------------------------------------------
13   USE oce            ! ocean dynamics and tracers
14   USE dom_oce        ! ocean space and time domain
15   USE sbc_oce        ! surface boundary condition: ocean
16   USE trd_oce        ! trends: ocean variables
17   USE trddyn         ! trend manager: dynamics
18   !
19   USE in_out_manager ! I/O manager
20   USE lib_mpp        ! MPP library
21   USE prtctl         ! Print control
22   USE timing         ! Timing
23
24   IMPLICIT NONE
25   PRIVATE
26   
27   PUBLIC   dyn_zad       ! routine called by dynadv.F90
28
29   !! * Substitutions
30#  include "vectopt_loop_substitute.h90"
31   !!----------------------------------------------------------------------
32   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
33   !! $Id$
34   !! Software governed by the CeCILL license (see ./LICENSE)
35   !!----------------------------------------------------------------------
36CONTAINS
37
38   SUBROUTINE dyn_zad ( kt )
39      !!----------------------------------------------------------------------
40      !!                  ***  ROUTINE dynzad  ***
41      !!
42      !! ** Purpose :   Compute the now vertical momentum advection trend and
43      !!      add it to the general trend of momentum equation.
44      !!
45      !! ** Method  :   The now vertical advection of momentum is given by:
46      !!         w dz(u) = ua + 1/(e1e2u*e3u) mk+1[ mi(e1e2t*wn) dk(un) ]
47      !!         w dz(v) = va + 1/(e1e2v*e3v) mk+1[ mj(e1e2t*wn) dk(vn) ]
48      !!      Add this trend to the general trend (ua,va):
49      !!         (ua,va) = (ua,va) + w dz(u,v)
50      !!
51      !! ** Action  : - Update (ua,va) with the vert. momentum adv. trends
52      !!              - Send the trends to trddyn for diagnostics (l_trddyn=T)
53      !!----------------------------------------------------------------------
54      INTEGER, INTENT(in) ::   kt   ! ocean time-step inedx
55      !
56      INTEGER  ::   ji, jj, jk   ! dummy loop indices
57      REAL(wp) ::   zua, zva     ! local scalars
58      REAL(wp), DIMENSION(jpi,jpj)     ::   zww
59      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zwuw, zwvw
60      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrdu, ztrdv
61      !!----------------------------------------------------------------------
62      !
63      IF( ln_timing )   CALL timing_start('dyn_zad')
64      !
65      IF( kt == nit000 ) THEN
66         IF(lwp) WRITE(numout,*)
67         IF(lwp) WRITE(numout,*) 'dyn_zad : 2nd order vertical advection scheme'
68      ENDIF
69
70      IF( l_trddyn )   THEN         ! Save ua and va trends
71         ALLOCATE( ztrdu(jpi,jpj,jpk) , ztrdv(jpi,jpj,jpk) ) 
72         ztrdu(:,:,:) = ua(:,:,:) 
73         ztrdv(:,:,:) = va(:,:,:) 
74      ENDIF
75     
76      DO jk = 2, jpkm1              ! Vertical momentum advection at level w and u- and v- vertical
77         DO jj = 2, jpj                   ! vertical fluxes
78            DO ji = fs_2, jpi             ! vector opt.
79               zww(ji,jj) = 0.25_wp * e1e2t(ji,jj) * wn(ji,jj,jk)
80            END DO
81         END DO
82         DO jj = 2, jpjm1                 ! vertical momentum advection at w-point
83            DO ji = fs_2, fs_jpim1        ! vector opt.
84               zwuw(ji,jj,jk) = ( zww(ji+1,jj  ) + zww(ji,jj) ) * ( un(ji,jj,jk-1) - un(ji,jj,jk) )
85               zwvw(ji,jj,jk) = ( zww(ji  ,jj+1) + zww(ji,jj) ) * ( vn(ji,jj,jk-1) - vn(ji,jj,jk) )
86            END DO 
87         END DO   
88      END DO
89      !
90      ! Surface and bottom advective fluxes set to zero
91      DO jj = 2, jpjm1       
92         DO ji = fs_2, fs_jpim1           ! vector opt.
93            zwuw(ji,jj, 1 ) = 0._wp
94            zwvw(ji,jj, 1 ) = 0._wp
95            zwuw(ji,jj,jpk) = 0._wp
96            zwvw(ji,jj,jpk) = 0._wp
97         END DO 
98      END DO
99      !
100      DO jk = 1, jpkm1              ! Vertical momentum advection at u- and v-points
101         DO jj = 2, jpjm1
102            DO ji = fs_2, fs_jpim1       ! vector opt.
103               ua(ji,jj,jk) = ua(ji,jj,jk) - ( zwuw(ji,jj,jk) + zwuw(ji,jj,jk+1) ) * r1_e1e2u(ji,jj) / e3u_n(ji,jj,jk)
104               va(ji,jj,jk) = va(ji,jj,jk) - ( zwvw(ji,jj,jk) + zwvw(ji,jj,jk+1) ) * r1_e1e2v(ji,jj) / e3v_n(ji,jj,jk)
105            END DO 
106         END DO 
107      END DO
108
109      IF( l_trddyn ) THEN           ! save the vertical advection trends for diagnostic
110         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
111         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
112         CALL trd_dyn( ztrdu, ztrdv, jpdyn_zad, kt )
113         DEALLOCATE( ztrdu, ztrdv ) 
114      ENDIF
115      !                             ! Control print
116      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' zad  - Ua: ', mask1=umask,   &
117         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
118      !
119      IF( ln_timing )   CALL timing_stop('dyn_zad')
120      !
121   END SUBROUTINE dyn_zad
122
123   !!======================================================================
124END MODULE dynzad
Note: See TracBrowser for help on using the repository browser.