New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
icestp.F90 in NEMO/branches/2019/dev_r11943_MERGE_2019/src/ICE – NEMO

source: NEMO/branches/2019/dev_r11943_MERGE_2019/src/ICE/icestp.F90 @ 11949

Last change on this file since 11949 was 11949, checked in by acc, 4 years ago

Merge in changes from 2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps. This just creates a fresh copy of this branch to use as the merge base. See ticket #2341

  • Property svn:keywords set to Id
File size: 23.1 KB
Line 
1MODULE icestp
2   !!======================================================================
3   !!                       ***  MODULE  icestp  ***
4   !! sea ice : Master routine for all the sea ice model
5   !!=====================================================================
6   !!
7   !! The sea ice model SI3 (Sea Ice modelling Integrated Initiative),
8   !!                        aka Sea Ice cube for its nickname
9   !!
10   !!    is originally based on LIM3, developed in Louvain-la-Neuve by:
11   !!       * Martin Vancoppenolle (UCL-ASTR, Belgium)
12   !!       * Sylvain Bouillon (UCL-ASTR, Belgium)
13   !!       * Miguel Angel Morales Maqueda (NOC-L, UK)
14   !!      thanks to valuable earlier work by
15   !!       * Thierry Fichefet
16   !!       * Hugues Goosse
17   !!      thanks also to the following persons who contributed
18   !!       * Gurvan Madec, Claude Talandier, Christian Ethe (LOCEAN, France)
19   !!       * Xavier Fettweis (UCL-ASTR), Ralph Timmermann (AWI, Germany)
20   !!       * Bill Lipscomb (LANL), Cecilia Bitz (UWa) and Elisabeth Hunke (LANL), USA.
21   !!
22   !! SI3 has been made possible by a handful of persons who met as working group
23   !!      (from France, Belgium, UK and Italy)
24   !!    * Clement Rousset, Martin Vancoppenolle & Gurvan Madec (LOCEAN, France)
25   !!    * Matthieu Chevalier & David Salas (Meteo France, France)
26   !!    * Gilles Garric (Mercator Ocean, France)
27   !!    * Thierry Fichefet & Francois Massonnet (UCL, Belgium)
28   !!    * Ed Blockley & Jeff Ridley (Met Office, UK)
29   !!    * Danny Feltham & David Schroeder (CPOM, UK)
30   !!    * Yevgeny Aksenov (NOC, UK)
31   !!    * Paul Holland (BAS, UK)
32   !!    * Dorotea Iovino (CMCC, Italy)
33   !!======================================================================
34   !! History :  4.0  !  2018     (C. Rousset)      Original code SI3
35   !!----------------------------------------------------------------------
36#if defined key_si3
37   !!----------------------------------------------------------------------
38   !!   'key_si3'                                       SI3 sea-ice model
39   !!----------------------------------------------------------------------
40   !!   ice_stp       : sea-ice model time-stepping and update ocean SBC over ice-covered area
41   !!   ice_init      : initialize sea-ice
42   !!----------------------------------------------------------------------
43   USE oce            ! ocean dynamics and tracers
44   USE dom_oce        ! ocean space and time domain
45   USE c1d            ! 1D vertical configuration
46   USE ice            ! sea-ice: variables
47   USE ice1D          ! sea-ice: thermodynamical 1D variables
48   !
49   USE phycst         ! Define parameters for the routines
50   USE eosbn2         ! equation of state
51   USE sbc_oce        ! Surface boundary condition: ocean fields
52   USE sbc_ice        ! Surface boundary condition: ice   fields
53   !
54   USE icesbc         ! sea-ice: Surface boundary conditions
55   USE icedyn         ! sea-ice: dynamics
56   USE icethd         ! sea-ice: thermodynamics
57   USE icecor         ! sea-ice: corrections
58   USE iceupdate      ! sea-ice: sea surface boundary condition update
59   USE icedia         ! sea-ice: budget diagnostics
60   USE icewri         ! sea-ice: outputs
61   USE icerst         ! sea-ice: restarts
62   USE icevar         ! sea-ice: operations
63   USE icectl         ! sea-ice: control
64   USE iceistate      ! sea-ice: initial state
65   USE iceitd         ! sea-ice: remapping thickness distribution
66   USE icealb         ! sea-ice: albedo
67   !
68   USE bdy_oce , ONLY : ln_bdy   ! flag for bdy
69   USE bdyice         ! unstructured open boundary data for sea-ice
70# if defined key_agrif
71   USE agrif_ice
72   USE agrif_ice_interp
73# endif
74   !
75   USE in_out_manager ! I/O manager
76   USE iom            ! I/O manager library
77   USE lib_mpp        ! MPP library
78   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
79   USE timing         ! Timing
80   USE prtctl         ! Print control
81
82   IMPLICIT NONE
83   PRIVATE
84
85   PUBLIC   ice_stp    ! called by sbcmod.F90
86   PUBLIC   ice_init   ! called by sbcmod.F90
87
88   !! * Substitutions
89#  include "vectopt_loop_substitute.h90"
90   !!----------------------------------------------------------------------
91   !! NEMO/ICE 4.0 , NEMO Consortium (2018)
92   !! $Id$
93   !! Software governed by the CeCILL license (see ./LICENSE)
94   !!----------------------------------------------------------------------
95CONTAINS
96
97   SUBROUTINE ice_stp( kt, Kbb, Kmm, ksbc )
98      !!---------------------------------------------------------------------
99      !!                  ***  ROUTINE ice_stp  ***
100      !!
101      !! ** Purpose :   sea-ice model time-stepping and update ocean surface
102      !!              boundary condition over ice-covered area
103      !!
104      !! ** Method  :   ice model time stepping
105      !!              - call the ice dynamics routine
106      !!              - call the ice advection/diffusion routine
107      !!              - call the ice thermodynamics routine
108      !!              - call the routine that computes mass and
109      !!                heat fluxes at the ice/ocean interface
110      !!              - save the outputs
111      !!              - save the outputs for restart when necessary
112      !!
113      !! ** Action  : - time evolution of the LIM sea-ice model
114      !!              - update all sbc variables below sea-ice:
115      !!                utau, vtau, taum, wndm, qns , qsr, emp , sfx
116      !!---------------------------------------------------------------------
117      INTEGER, INTENT(in) ::   kt       ! ocean time step
118      INTEGER, INTENT(in) ::   Kbb, Kmm ! ocean time level indices
119      INTEGER, INTENT(in) ::   ksbc     ! flux formulation (user defined, bulk, or Pure Coupled)
120      !
121      INTEGER ::   jl   ! dummy loop index
122      !!----------------------------------------------------------------------
123      !
124      IF( ln_timing )   CALL timing_start('ice_stp')
125      !
126      !                                      !-----------------------!
127      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN   ! --- Ice time step --- !
128         !                                   !-----------------------!
129         !
130         kt_ice = kt                              ! -- Ice model time step
131         !
132         u_oce(:,:) = ssu_m(:,:)                  ! -- mean surface ocean current
133         v_oce(:,:) = ssv_m(:,:)
134         !
135         CALL eos_fzp( sss_m(:,:) , t_bo(:,:) )   ! -- freezing temperature [Kelvin] (set to rt0 over land)
136         t_bo(:,:) = ( t_bo(:,:) + rt0 ) * tmask(:,:,1) + rt0 * ( 1._wp - tmask(:,:,1) )
137         !
138         !                          !==  AGRIF Parent to Child  ==!
139#if defined key_agrif
140         !                              ! nbstep_ice ranges from 1 to the nb of child ocean steps inside one parent ice step
141         IF( .NOT. Agrif_Root() )       nbstep_ice = MOD( nbstep_ice, Agrif_irhot() * Agrif_Parent(nn_fsbc) / nn_fsbc ) + 1
142         !                              ! these calls must remain here for restartability purposes
143                                        CALL agrif_interp_ice( 'T' ) 
144                                        CALL agrif_interp_ice( 'U' )
145                                        CALL agrif_interp_ice( 'V' )
146#endif
147                                        CALL store_fields             ! Store now ice values
148         !
149         !------------------------------------------------!
150         ! --- Dynamical coupling with the atmosphere --- !
151         !------------------------------------------------!
152         ! It provides the following fields used in sea ice model:
153         !    utau_ice, vtau_ice = surface ice stress [N/m2]
154         !------------------------------------------------!
155                                        CALL ice_sbc_tau( kt, ksbc, utau_ice, vtau_ice )         
156         !-------------------------------------!
157         ! --- ice dynamics and advection  --- !
158         !-------------------------------------!
159                                        CALL diag_set0                ! set diag of mass, heat and salt fluxes to 0
160                                        CALL ice_rst_opn( kt )        ! Open Ice restart file (if necessary)
161         !
162         IF( ln_icedyn .AND. .NOT.lk_c1d )   &
163            &                           CALL ice_dyn( kt, Kmm )       ! -- Ice dynamics
164         !
165         !                          !==  lateral boundary conditions  ==!
166         IF( ln_icethd .AND. ln_bdy )   CALL bdy_ice( kt )            ! -- bdy ice thermo
167         !
168         !                          !==  previous lead fraction and ice volume for flux calculations
169                                        CALL ice_var_glo2eqv          ! h_i and h_s for ice albedo calculation
170                                        CALL ice_var_agg(1)           ! at_i for coupling
171                                        CALL store_fields             ! Store now ice values
172         !
173         !------------------------------------------------------!
174         ! --- Thermodynamical coupling with the atmosphere --- !
175         !------------------------------------------------------!
176         ! It provides the following fields used in sea ice model:
177         !    emp_oce , emp_ice    = E-P over ocean and sea ice                    [Kg/m2/s]
178         !    sprecip              = solid precipitation                           [Kg/m2/s]
179         !    evap_ice             = sublimation                                   [Kg/m2/s]
180         !    qsr_tot , qns_tot    = solar & non solar heat flux (total)           [W/m2]
181         !    qsr_ice , qns_ice    = solar & non solar heat flux over ice          [W/m2]
182         !    dqns_ice             = non solar  heat sensistivity                  [W/m2]
183         !    qemp_oce, qemp_ice,  = sensible heat (associated with evap & precip) [W/m2]
184         !    qprec_ice, qevap_ice
185         !------------------------------------------------------!
186                                        CALL ice_sbc_flx( kt, ksbc )
187         !----------------------------!
188         ! --- ice thermodynamics --- !
189         !----------------------------!
190         IF( ln_icethd )                CALL ice_thd( kt )            ! -- Ice thermodynamics     
191         !
192                                        CALL ice_cor( kt , 2 )        ! -- Corrections
193         !
194                                        CALL ice_var_glo2eqv          ! necessary calls (at least for coupling)
195                                        CALL ice_var_agg( 2 )         ! necessary calls (at least for coupling)
196         !
197                                        CALL ice_update_flx( kt )     ! -- Update ocean surface mass, heat and salt fluxes
198         !
199         IF( ln_icediahsb )             CALL ice_dia( kt )            ! -- Diagnostics outputs
200         !
201                                        CALL ice_wri( kt )            ! -- Ice outputs
202         !
203         IF( lrst_ice )                 CALL ice_rst_write( kt )      ! -- Ice restart file
204         !
205         IF( ln_icectl )                CALL ice_ctl( kt )            ! -- alerts in case of model crash
206         !
207      ENDIF   ! End sea-ice time step only
208
209      !-------------------------!
210      ! --- Ocean time step --- !
211      !-------------------------!
212      IF( ln_icedyn )                   CALL ice_update_tau( kt, uu(:,:,1,Kbb), vv(:,:,1,Kbb) )   ! -- update surface ocean stresses
213!!gm   remark, the ocean-ice stress is not saved in ice diag call above .....  find a solution!!!
214      !
215      IF( ln_timing )   CALL timing_stop('ice_stp')
216      !
217   END SUBROUTINE ice_stp
218
219
220   SUBROUTINE ice_init( Kbb, Kmm, Kaa )
221      !!----------------------------------------------------------------------
222      !!                  ***  ROUTINE ice_init  ***
223      !!
224      !! ** purpose :   Initialize sea-ice parameters
225      !!----------------------------------------------------------------------
226      INTEGER, INTENT(in) :: Kbb, Kmm, Kaa
227      !
228      INTEGER :: ji, jj, ierr
229      !!----------------------------------------------------------------------
230      IF(lwp) WRITE(numout,*)
231      IF(lwp) WRITE(numout,*) 'Sea Ice Model: SI3 (Sea Ice modelling Integrated Initiative)' 
232      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~'
233      IF(lwp) WRITE(numout,*)
234      IF(lwp) WRITE(numout,*) 'ice_init: Arrays allocation & Initialization of all routines & init state' 
235      IF(lwp) WRITE(numout,*) '~~~~~~~~'
236      !
237      !                                ! Open the reference and configuration namelist files and namelist output file
238      CALL ctl_opn( numnam_ice_ref, 'namelist_ice_ref',    'OLD',     'FORMATTED', 'SEQUENTIAL', -1, numout, lwp )
239      CALL ctl_opn( numnam_ice_cfg, 'namelist_ice_cfg',    'OLD',     'FORMATTED', 'SEQUENTIAL', -1, numout, lwp )
240      IF(lwm) CALL ctl_opn( numoni, 'output.namelist.ice', 'UNKNOWN', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, 1 )
241      !
242      CALL par_init                ! set some ice run parameters
243      !
244      !                                ! Allocate the ice arrays (sbc_ice already allocated in sbc_init)
245      ierr =        ice_alloc        ()      ! ice variables
246      ierr = ierr + sbc_ice_alloc    ()      ! surface boundary conditions
247      ierr = ierr + ice1D_alloc      ()      ! thermodynamics
248      !
249      CALL mpp_sum( 'icestp', ierr )
250      IF( ierr /= 0 )   CALL ctl_stop('STOP', 'ice_init : unable to allocate ice arrays')
251      !
252      CALL ice_itd_init                ! ice thickness distribution initialization
253      !
254      CALL ice_thd_init                ! set ice thermodynics parameters (clem: important to call it first for melt ponds)
255      !
256      !                                ! Initial sea-ice state
257      IF( .NOT. ln_rstart ) THEN              ! start from rest: sea-ice deduced from sst
258         CALL ice_istate_init
259         CALL ice_istate( nit000, Kbb, Kmm, Kaa )
260      ELSE                                    ! start from a restart file
261         CALL ice_rst_read( Kbb, Kmm, Kaa )
262      ENDIF
263      CALL ice_var_glo2eqv
264      CALL ice_var_agg(1)
265      !
266      CALL ice_sbc_init                ! set ice-ocean and ice-atm. coupling parameters
267      !
268      CALL ice_dyn_init                ! set ice dynamics parameters
269      !
270      CALL ice_update_init             ! ice surface boundary condition
271      !
272      CALL ice_alb_init                ! ice surface albedo
273      !
274      CALL ice_dia_init                ! initialization for diags
275      !
276      fr_i  (:,:)   = at_i(:,:)        ! initialisation of sea-ice fraction
277      tn_ice(:,:,:) = t_su(:,:,:)      ! initialisation of surface temp for coupled simu
278      !
279      !                                ! set max concentration in both hemispheres
280      WHERE( gphit(:,:) > 0._wp )   ;   rn_amax_2d(:,:) = rn_amax_n  ! NH
281      ELSEWHERE                     ;   rn_amax_2d(:,:) = rn_amax_s  ! SH
282      END WHERE
283
284      IF( ln_rstart )   CALL iom_close( numrir )  ! close input ice restart file
285      !
286   END SUBROUTINE ice_init
287
288
289   SUBROUTINE par_init
290      !!-------------------------------------------------------------------
291      !!                  ***  ROUTINE par_init ***
292      !!
293      !! ** Purpose :   Definition generic parameters for ice model
294      !!
295      !! ** Method  :   Read namelist and check the parameter
296      !!                values called at the first timestep (nit000)
297      !!
298      !! ** input   :   Namelist nampar
299      !!-------------------------------------------------------------------
300      INTEGER  ::   ios                 ! Local integer
301      !!
302      NAMELIST/nampar/ jpl, nlay_i, nlay_s, ln_virtual_itd, ln_icedyn, ln_icethd, rn_amax_n, rn_amax_s,  &
303         &             cn_icerst_in, cn_icerst_indir, cn_icerst_out, cn_icerst_outdir
304      !!-------------------------------------------------------------------
305      !
306      REWIND( numnam_ice_ref )      ! Namelist nampar in reference namelist : Parameters for ice
307      READ  ( numnam_ice_ref, nampar, IOSTAT = ios, ERR = 901)
308901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampar in reference namelist' )
309      REWIND( numnam_ice_cfg )      ! Namelist nampar in configuration namelist : Parameters for ice
310      READ  ( numnam_ice_cfg, nampar, IOSTAT = ios, ERR = 902 )
311902   IF( ios > 0 )   CALL ctl_nam ( ios , 'nampar in configuration namelist' )
312      IF(lwm) WRITE( numoni, nampar )
313      !
314      IF(lwp) THEN                  ! control print
315         WRITE(numout,*)
316         WRITE(numout,*) '   par_init: ice parameters shared among all the routines'
317         WRITE(numout,*) '   ~~~~~~~~'
318         WRITE(numout,*) '      Namelist nampar: '
319         WRITE(numout,*) '         number of ice  categories                           jpl       = ', jpl
320         WRITE(numout,*) '         number of ice  layers                               nlay_i    = ', nlay_i
321         WRITE(numout,*) '         number of snow layers                               nlay_s    = ', nlay_s
322         WRITE(numout,*) '         virtual ITD param for jpl=1 (T) or not (F)     ln_virtual_itd = ', ln_virtual_itd
323         WRITE(numout,*) '         Ice dynamics       (T) or not (F)                   ln_icedyn = ', ln_icedyn
324         WRITE(numout,*) '         Ice thermodynamics (T) or not (F)                   ln_icethd = ', ln_icethd
325         WRITE(numout,*) '         maximum ice concentration for NH                              = ', rn_amax_n 
326         WRITE(numout,*) '         maximum ice concentration for SH                              = ', rn_amax_s
327      ENDIF
328      !                                        !--- change max ice concentration for roundoff errors
329      rn_amax_n = MIN( rn_amax_n, 1._wp - epsi10 )
330      rn_amax_s = MIN( rn_amax_s, 1._wp - epsi10 )
331      !                                        !--- check consistency
332      IF ( jpl > 1 .AND. ln_virtual_itd ) THEN
333         ln_virtual_itd = .FALSE.
334         IF(lwp) WRITE(numout,*)
335         IF(lwp) WRITE(numout,*) '   ln_virtual_itd forced to false as jpl>1, no need with multiple categories to emulate them'
336      ENDIF
337      !
338      IF( ln_cpl .AND. nn_cats_cpl /= 1 .AND. nn_cats_cpl /= jpl ) THEN
339         CALL ctl_stop( 'STOP', 'par_init: in coupled mode, nn_cats_cpl should be either 1 or jpl' )
340      ENDIF
341      !
342      IF( ln_bdy .AND. ln_icediachk )   CALL ctl_warn('par_init: online conservation check does not work with BDY')
343      !
344      rdt_ice   = REAL(nn_fsbc) * rdt          !--- sea-ice timestep and its inverse
345      r1_rdtice = 1._wp / rdt_ice
346      IF(lwp) WRITE(numout,*)
347      IF(lwp) WRITE(numout,*) '      ice timestep rdt_ice = nn_fsbc*rdt = ', rdt_ice
348      !
349      r1_nlay_i = 1._wp / REAL( nlay_i, wp )   !--- inverse of nlay_i and nlay_s
350      r1_nlay_s = 1._wp / REAL( nlay_s, wp )
351      !
352   END SUBROUTINE par_init
353
354
355   SUBROUTINE store_fields
356      !!----------------------------------------------------------------------
357      !!                  ***  ROUTINE store_fields  ***
358      !!
359      !! ** purpose :  store ice variables at "before" time step
360      !!----------------------------------------------------------------------
361      INTEGER  ::   ji, jj, jl      ! dummy loop index
362      !!----------------------------------------------------------------------
363      !
364      a_i_b (:,:,:)   = a_i (:,:,:)     ! ice area
365      v_i_b (:,:,:)   = v_i (:,:,:)     ! ice volume
366      v_s_b (:,:,:)   = v_s (:,:,:)     ! snow volume
367      sv_i_b(:,:,:)   = sv_i(:,:,:)     ! salt content
368      oa_i_b(:,:,:)   = oa_i(:,:,:)     ! areal age content
369      e_s_b (:,:,:,:) = e_s (:,:,:,:)   ! snow thermal energy
370      e_i_b (:,:,:,:) = e_i (:,:,:,:)   ! ice thermal energy
371      WHERE( a_i_b(:,:,:) >= epsi20 )
372         h_i_b(:,:,:) = v_i_b(:,:,:) / a_i_b(:,:,:)   ! ice thickness
373         h_s_b(:,:,:) = v_s_b(:,:,:) / a_i_b(:,:,:)   ! snw thickness
374      ELSEWHERE
375         h_i_b(:,:,:) = 0._wp
376         h_s_b(:,:,:) = 0._wp
377      END WHERE
378     
379      WHERE( a_ip(:,:,:) >= epsi20 )
380         h_ip_b(:,:,:) = v_ip(:,:,:) / a_ip(:,:,:)   ! ice pond thickness
381      ELSEWHERE
382         h_ip_b(:,:,:) = 0._wp
383      END WHERE
384      !
385      ! ice velocities & total concentration
386      at_i_b(:,:)  = SUM( a_i_b(:,:,:), dim=3 )
387      u_ice_b(:,:) = u_ice(:,:)
388      v_ice_b(:,:) = v_ice(:,:)
389      !
390   END SUBROUTINE store_fields
391
392
393   SUBROUTINE diag_set0
394      !!----------------------------------------------------------------------
395      !!                  ***  ROUTINE diag_set0  ***
396      !!
397      !! ** purpose :  set ice-ocean and ice-atm. fluxes to zeros at the beggining
398      !!               of the time step
399      !!----------------------------------------------------------------------
400      INTEGER  ::   ji, jj      ! dummy loop index
401      !!----------------------------------------------------------------------
402      sfx    (:,:) = 0._wp   ;
403      sfx_bri(:,:) = 0._wp   ;   sfx_lam(:,:) = 0._wp
404      sfx_sni(:,:) = 0._wp   ;   sfx_opw(:,:) = 0._wp
405      sfx_bog(:,:) = 0._wp   ;   sfx_dyn(:,:) = 0._wp
406      sfx_bom(:,:) = 0._wp   ;   sfx_sum(:,:) = 0._wp
407      sfx_res(:,:) = 0._wp   ;   sfx_sub(:,:) = 0._wp
408      !
409      wfx_snw(:,:) = 0._wp   ;   wfx_ice(:,:) = 0._wp
410      wfx_sni(:,:) = 0._wp   ;   wfx_opw(:,:) = 0._wp
411      wfx_bog(:,:) = 0._wp   ;   wfx_dyn(:,:) = 0._wp
412      wfx_bom(:,:) = 0._wp   ;   wfx_sum(:,:) = 0._wp
413      wfx_res(:,:) = 0._wp   ;   wfx_sub(:,:) = 0._wp
414      wfx_spr(:,:) = 0._wp   ;   wfx_lam(:,:) = 0._wp 
415      wfx_snw_dyn(:,:) = 0._wp ; wfx_snw_sum(:,:) = 0._wp
416      wfx_snw_sub(:,:) = 0._wp ; wfx_ice_sub(:,:) = 0._wp
417      wfx_snw_sni(:,:) = 0._wp 
418      wfx_pnd(:,:) = 0._wp
419
420      hfx_thd(:,:) = 0._wp   ;
421      hfx_snw(:,:) = 0._wp   ;   hfx_opw(:,:) = 0._wp
422      hfx_bog(:,:) = 0._wp   ;   hfx_dyn(:,:) = 0._wp
423      hfx_bom(:,:) = 0._wp   ;   hfx_sum(:,:) = 0._wp
424      hfx_res(:,:) = 0._wp   ;   hfx_sub(:,:) = 0._wp
425      hfx_spr(:,:) = 0._wp   ;   hfx_dif(:,:) = 0._wp
426      hfx_err_rem(:,:) = 0._wp
427      hfx_err_dif(:,:) = 0._wp
428      wfx_err_sub(:,:) = 0._wp
429      !
430      diag_heat(:,:) = 0._wp ;   diag_sice(:,:) = 0._wp
431      diag_vice(:,:) = 0._wp ;   diag_vsnw(:,:) = 0._wp
432
433      ! SIMIP diagnostics
434      qcn_ice_bot(:,:,:) = 0._wp ; qcn_ice_top(:,:,:) = 0._wp ! conductive fluxes
435      t_si       (:,:,:) = rt0   ! temp at the ice-snow interface
436
437      tau_icebfr (:,:)   = 0._wp   ! landfast ice param only (clem: important to keep the init here)
438      cnd_ice    (:,:,:) = 0._wp   ! initialisation: effective conductivity at the top of ice/snow (ln_cndflx=T)
439      qcn_ice    (:,:,:) = 0._wp   ! initialisation: conductive flux (ln_cndflx=T & ln_cndemule=T)
440      qtr_ice_bot(:,:,:) = 0._wp   ! initialization: part of solar radiation transmitted through the ice needed at least for outputs
441      qsb_ice_bot(:,:)   = 0._wp   ! (needed if ln_icethd=F)
442      !
443      ! for control checks (ln_icediachk)
444      diag_trp_vi(:,:) = 0._wp   ;   diag_trp_vs(:,:) = 0._wp
445      diag_trp_ei(:,:) = 0._wp   ;   diag_trp_es(:,:) = 0._wp
446      diag_trp_sv(:,:) = 0._wp
447
448   END SUBROUTINE diag_set0
449
450#else
451   !!----------------------------------------------------------------------
452   !!   Default option           Dummy module         NO SI3 sea-ice model
453   !!----------------------------------------------------------------------
454CONTAINS
455   SUBROUTINE ice_stp ( kt, ksbc )     ! Dummy routine
456      INTEGER, INTENT(in) ::   kt, ksbc
457      WRITE(*,*) 'ice_stp: You should not have seen this print! error?', kt
458   END SUBROUTINE ice_stp
459   SUBROUTINE ice_init                 ! Dummy routine
460   END SUBROUTINE ice_init
461#endif
462
463   !!======================================================================
464END MODULE icestp
Note: See TracBrowser for help on using the repository browser.