New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
diaharm.F90 in NEMO/branches/2019/dev_r11943_MERGE_2019/src/OCE/DIA – NEMO

source: NEMO/branches/2019/dev_r11943_MERGE_2019/src/OCE/DIA/diaharm.F90 @ 11960

Last change on this file since 11960 was 11960, checked in by acc, 4 years ago

Branch 2019/dev_r11943_MERGE_2019. Merge in changes from 2019/dev_r11613_ENHANCE-04_namelists_as_internalfiles. (svn merge -r 11614:11954). Resolved tree conflicts and one actual conflict. Sette tested(these changes alter the ext/AGRIF reference; remember to update). See ticket #2341
  • Property svn:keywords set to Id
File size: 18.4 KB
Line 
1MODULE diaharm 
2   !!======================================================================
3   !!                       ***  MODULE  diaharm  ***
4   !! Harmonic analysis of tidal constituents
5   !!======================================================================
6   !! History :  3.1  !  2007  (O. Le Galloudec, J. Chanut)  Original code
7   !!----------------------------------------------------------------------
8   USE oce             ! ocean dynamics and tracers variables
9   USE dom_oce         ! ocean space and time domain
10   USE phycst
11   USE daymod
12   USE tide_mod
13   USE sbctide         ! Tidal forcing or not
14   !
15   USE in_out_manager  ! I/O units
16   USE iom             ! I/0 library
17   USE ioipsl          ! NetCDF IPSL library
18   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
19   USE timing          ! preformance summary
20   USE lib_mpp           ! MPP library
21
22   IMPLICIT NONE
23   PRIVATE
24   
25   INTEGER, PARAMETER :: jpincomax    = 2.*jpmax_harmo
26   INTEGER, PARAMETER :: jpdimsparse  = jpincomax*300*24
27
28   !                         !!** namelist variables **
29   LOGICAL, PUBLIC ::   ln_diaharm    ! Choose tidal harmonic output or not
30   INTEGER         ::   nit000_han    ! First time step used for harmonic analysis
31   INTEGER         ::   nitend_han    ! Last time step used for harmonic analysis
32   INTEGER         ::   nstep_han     ! Time step frequency for harmonic analysis
33   INTEGER         ::   nb_ana        ! Number of harmonics to analyse
34
35   INTEGER , ALLOCATABLE, DIMENSION(:)       ::   name
36   REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:) ::   ana_temp
37   REAL(wp), ALLOCATABLE, DIMENSION(:)       ::   ana_freq, ut   , vt   , ft
38   REAL(wp), ALLOCATABLE, DIMENSION(:,:,:)   ::   out_eta , out_u, out_v
39
40   INTEGER ::   ninco, nsparse
41   INTEGER ,       DIMENSION(jpdimsparse)         ::   njsparse, nisparse
42   INTEGER , SAVE, DIMENSION(jpincomax)           ::   ipos1
43   REAL(wp),       DIMENSION(jpdimsparse)         ::   valuesparse
44   REAL(wp),       DIMENSION(jpincomax)           ::   ztmp4 , ztmp7
45   REAL(wp), SAVE, DIMENSION(jpincomax,jpincomax) ::   ztmp3 , zpilier
46   REAL(wp), SAVE, DIMENSION(jpincomax)           ::   zpivot
47
48   CHARACTER (LEN=4), DIMENSION(jpmax_harmo) ::   tname   ! Names of tidal constituents ('M2', 'K1',...)
49
50   PUBLIC   dia_harm        ! routine called by step.F90
51   PUBLIC   dia_harm_init   ! routine called by nemogcm.F90
52
53   !!----------------------------------------------------------------------
54   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
55   !! $Id$
56   !! Software governed by the CeCILL license (see ./LICENSE)
57   !!----------------------------------------------------------------------
58CONTAINS
59
60   SUBROUTINE dia_harm_init 
61      !!----------------------------------------------------------------------
62      !!                 ***  ROUTINE dia_harm_init  ***
63      !!         
64      !! ** Purpose :   Initialization of tidal harmonic analysis
65      !!
66      !! ** Method  :   Initialize frequency array and  nodal factor for nit000_han
67      !!
68      !!--------------------------------------------------------------------
69      INTEGER ::   jh, nhan, ji
70      INTEGER ::   ios                 ! Local integer output status for namelist read
71
72      NAMELIST/nam_diaharm/ ln_diaharm, nit000_han, nitend_han, nstep_han, tname
73      !!----------------------------------------------------------------------
74
75      IF(lwp) THEN
76         WRITE(numout,*)
77         WRITE(numout,*) 'dia_harm_init: Tidal harmonic analysis initialization'
78         WRITE(numout,*) '~~~~~~~ '
79      ENDIF
80      !
81      READ  ( numnam_ref, nam_diaharm, IOSTAT = ios, ERR = 901)
82901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nam_diaharm in reference namelist' )
83      READ  ( numnam_cfg, nam_diaharm, IOSTAT = ios, ERR = 902 )
84902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nam_diaharm in configuration namelist' )
85      IF(lwm) WRITE ( numond, nam_diaharm )
86      !
87      IF(lwp) THEN
88         WRITE(numout,*) 'Tidal diagnostics = ', ln_diaharm
89         WRITE(numout,*) '   First time step used for analysis:         nit000_han= ', nit000_han
90         WRITE(numout,*) '   Last  time step used for analysis:         nitend_han= ', nitend_han
91         WRITE(numout,*) '   Time step frequency for harmonic analysis: nstep_han = ', nstep_han
92      ENDIF
93
94      IF( ln_diaharm .AND. .NOT.ln_tide )   CALL ctl_stop( 'dia_harm_init : ln_tide must be true for harmonic analysis')
95
96      IF( ln_diaharm ) THEN
97
98         CALL tide_init_Wave
99         !
100         ! Basic checks on harmonic analysis time window:
101         ! ----------------------------------------------
102         IF( nit000 > nit000_han )   CALL ctl_stop( 'dia_harm_init : nit000_han must be greater than nit000',   &
103            &                                       ' restart capability not implemented' )
104         IF( nitend < nitend_han )   CALL ctl_stop( 'dia_harm_init : nitend_han must be lower than nitend',   &
105            &                                       'restart capability not implemented' )
106
107         IF( MOD( nitend_han-nit000_han+1 , nstep_han ) /= 0 )   &
108            &                        CALL ctl_stop( 'dia_harm_init : analysis time span must be a multiple of nstep_han' )
109         !
110         nb_ana = 0
111         DO jh=1,jpmax_harmo
112            DO ji=1,jpmax_harmo
113               IF(TRIM(tname(jh)) == Wave(ji)%cname_tide) THEN
114                  nb_ana=nb_ana+1
115               ENDIF
116            END DO
117         END DO
118         !
119         IF(lwp) THEN
120            WRITE(numout,*) '        Namelist nam_diaharm'
121            WRITE(numout,*) '        nb_ana    = ', nb_ana
122            CALL flush(numout)
123         ENDIF
124         !
125         IF (nb_ana > jpmax_harmo) THEN
126            WRITE(ctmp1,*) ' nb_ana must be lower than jpmax_harmo'
127            WRITE(ctmp2,*) ' jpmax_harmo= ', jpmax_harmo
128            CALL ctl_stop( 'dia_harm_init', ctmp1, ctmp2 )
129         ENDIF
130
131         ALLOCATE(name    (nb_ana))
132         DO jh=1,nb_ana
133            DO ji=1,jpmax_harmo
134               IF (TRIM(tname(jh)) ==  Wave(ji)%cname_tide) THEN
135                  name(jh) = ji
136                  EXIT
137               END IF
138            END DO
139         END DO
140
141         ! Initialize frequency array:
142         ! ---------------------------
143         ALLOCATE( ana_freq(nb_ana), ut(nb_ana), vt(nb_ana), ft(nb_ana) )
144
145         CALL tide_harmo( ana_freq, vt, ut, ft, name, nb_ana )
146
147         IF(lwp) WRITE(numout,*) 'Analysed frequency  : ',nb_ana ,'Frequency '
148
149         DO jh = 1, nb_ana
150            IF(lwp) WRITE(numout,*) '                    : ',tname(jh),' ',ana_freq(jh)
151         END DO
152
153         ! Initialize temporary arrays:
154         ! ----------------------------
155         ALLOCATE( ana_temp(jpi,jpj,2*nb_ana,3) )
156         ana_temp(:,:,:,:) = 0._wp
157
158      ENDIF
159
160   END SUBROUTINE dia_harm_init
161
162
163   SUBROUTINE dia_harm ( kt, Kmm )
164      !!----------------------------------------------------------------------
165      !!                 ***  ROUTINE dia_harm  ***
166      !!         
167      !! ** Purpose :   Tidal harmonic analysis main routine
168      !!
169      !! ** Action  :   Sums ssh/u/v over time analysis [nit000_han,nitend_han]
170      !!
171      !!--------------------------------------------------------------------
172      INTEGER, INTENT( IN ) :: kt
173      INTEGER, INTENT( IN ) :: Kmm     ! time level index
174      !
175      INTEGER  :: ji, jj, jh, jc, nhc
176      REAL(wp) :: ztime, ztemp
177      !!--------------------------------------------------------------------
178      IF( ln_timing )   CALL timing_start('dia_harm')
179      !
180      IF( kt >= nit000_han .AND. kt <= nitend_han .AND. MOD(kt,nstep_han) == 0 ) THEN
181         !
182         ztime = (kt-nit000+1) * rdt 
183         !
184         nhc = 0
185         DO jh = 1, nb_ana
186            DO jc = 1, 2
187               nhc = nhc+1
188               ztemp =(     MOD(jc,2) * ft(jh) *COS(ana_freq(jh)*ztime + vt(jh) + ut(jh))  &
189                  &    +(1.-MOD(jc,2))* ft(jh) *SIN(ana_freq(jh)*ztime + vt(jh) + ut(jh)))
190                  !
191               DO jj = 1,jpj
192                  DO ji = 1,jpi
193                     ! Elevation
194                     ana_temp(ji,jj,nhc,1) = ana_temp(ji,jj,nhc,1) + ztemp*ssh(ji,jj,Kmm)*ssmask (ji,jj)       
195                     ana_temp(ji,jj,nhc,2) = ana_temp(ji,jj,nhc,2) + ztemp*uu_b(ji,jj,Kmm)*ssumask(ji,jj)
196                     ana_temp(ji,jj,nhc,3) = ana_temp(ji,jj,nhc,3) + ztemp*vv_b(ji,jj,Kmm)*ssvmask(ji,jj)
197                  END DO
198               END DO
199               !
200            END DO
201         END DO
202         !       
203      END IF
204      !
205      IF( kt == nitend_han )   CALL dia_harm_end
206      !
207      IF( ln_timing )   CALL timing_stop('dia_harm')
208      !
209   END SUBROUTINE dia_harm
210
211
212   SUBROUTINE dia_harm_end
213      !!----------------------------------------------------------------------
214      !!                 ***  ROUTINE diaharm_end  ***
215      !!         
216      !! ** Purpose :  Compute the Real and Imaginary part of tidal constituents
217      !!
218      !! ** Action  :  Decompose the signal on the harmonic constituents
219      !!
220      !!--------------------------------------------------------------------
221      INTEGER :: ji, jj, jh, jc, jn, nhan, jl
222      INTEGER :: ksp, kun, keq
223      REAL(wp) :: ztime, ztime_ini, ztime_end
224      REAL(wp) :: X1, X2
225      REAL(wp), DIMENSION(jpi,jpj,jpmax_harmo,2) ::   ana_amp   ! workspace
226      !!--------------------------------------------------------------------
227      !
228      IF(lwp) WRITE(numout,*)
229      IF(lwp) WRITE(numout,*) 'anharmo_end: kt=nitend_han: Perform harmonic analysis'
230      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~'
231
232      ztime_ini = nit000_han*rdt                 ! Initial time in seconds at the beginning of analysis
233      ztime_end = nitend_han*rdt                 ! Final time in seconds at the end of analysis
234      nhan = (nitend_han-nit000_han+1)/nstep_han ! Number of dumps used for analysis
235
236      ninco = 2*nb_ana
237
238      ksp = 0
239      keq = 0       
240      DO jn = 1, nhan
241         ztime=( (nhan-jn)*ztime_ini + (jn-1)*ztime_end )/FLOAT(nhan-1)
242         keq = keq + 1
243         kun = 0
244         DO jh = 1, nb_ana
245            DO jc = 1, 2
246               kun = kun + 1
247               ksp = ksp + 1
248               nisparse(ksp) = keq
249               njsparse(ksp) = kun
250               valuesparse(ksp) = (   MOD(jc,2) * ft(jh) * COS(ana_freq(jh)*ztime + vt(jh) + ut(jh))   &
251                  &             + (1.-MOD(jc,2))* ft(jh) * SIN(ana_freq(jh)*ztime + vt(jh) + ut(jh)) )
252            END DO
253         END DO
254      END DO
255
256      nsparse = ksp
257
258      ! Elevation:
259      DO jj = 1, jpj
260         DO ji = 1, jpi
261            ! Fill input array
262            kun = 0
263            DO jh = 1, nb_ana
264               DO jc = 1, 2
265                  kun = kun + 1
266                  ztmp4(kun)=ana_temp(ji,jj,kun,1)
267               END DO
268            END DO
269
270            CALL SUR_DETERMINE(jj)
271
272            ! Fill output array
273            DO jh = 1, nb_ana
274               ana_amp(ji,jj,jh,1)=ztmp7((jh-1)*2+1)
275               ana_amp(ji,jj,jh,2)=ztmp7((jh-1)*2+2)
276            END DO
277         END DO
278      END DO
279
280      ALLOCATE( out_eta(jpi,jpj,2*nb_ana),   & 
281         &      out_u  (jpi,jpj,2*nb_ana),   &
282         &      out_v  (jpi,jpj,2*nb_ana)  )
283
284      DO jj = 1, jpj
285         DO ji = 1, jpi
286            DO jh = 1, nb_ana 
287               X1 = ana_amp(ji,jj,jh,1)
288               X2 =-ana_amp(ji,jj,jh,2)
289               out_eta(ji,jj,jh       ) = X1 * tmask_i(ji,jj)
290               out_eta(ji,jj,jh+nb_ana) = X2 * tmask_i(ji,jj)
291            END DO
292         END DO
293      END DO
294
295      ! ubar:
296      DO jj = 1, jpj
297         DO ji = 1, jpi
298            ! Fill input array
299            kun=0
300            DO jh = 1,nb_ana
301               DO jc = 1,2
302                  kun = kun + 1
303                  ztmp4(kun)=ana_temp(ji,jj,kun,2)
304               END DO
305            END DO
306
307            CALL SUR_DETERMINE(jj+1)
308
309            ! Fill output array
310            DO jh = 1, nb_ana
311               ana_amp(ji,jj,jh,1) = ztmp7((jh-1)*2+1)
312               ana_amp(ji,jj,jh,2) = ztmp7((jh-1)*2+2)
313            END DO
314
315         END DO
316      END DO
317
318      DO jj = 1, jpj
319         DO ji = 1, jpi
320            DO jh = 1, nb_ana 
321               X1= ana_amp(ji,jj,jh,1)
322               X2=-ana_amp(ji,jj,jh,2)
323               out_u(ji,jj,       jh) = X1 * ssumask(ji,jj)
324               out_u(ji,jj,nb_ana+jh) = X2 * ssumask(ji,jj)
325            ENDDO
326         ENDDO
327      ENDDO
328
329      ! vbar:
330      DO jj = 1, jpj
331         DO ji = 1, jpi
332            ! Fill input array
333            kun=0
334            DO jh = 1,nb_ana
335               DO jc = 1,2
336                  kun = kun + 1
337                  ztmp4(kun)=ana_temp(ji,jj,kun,3)
338               END DO
339            END DO
340
341            CALL SUR_DETERMINE(jj+1)
342
343            ! Fill output array
344            DO jh = 1, nb_ana
345               ana_amp(ji,jj,jh,1)=ztmp7((jh-1)*2+1)
346               ana_amp(ji,jj,jh,2)=ztmp7((jh-1)*2+2)
347            END DO
348
349         END DO
350      END DO
351
352      DO jj = 1, jpj
353         DO ji = 1, jpi
354            DO jh = 1, nb_ana 
355               X1=ana_amp(ji,jj,jh,1)
356               X2=-ana_amp(ji,jj,jh,2)
357               out_v(ji,jj,       jh)=X1 * ssvmask(ji,jj)
358               out_v(ji,jj,nb_ana+jh)=X2 * ssvmask(ji,jj)
359            END DO
360         END DO
361      END DO
362      !
363      CALL dia_wri_harm ! Write results in files
364      !
365   END SUBROUTINE dia_harm_end
366
367
368   SUBROUTINE dia_wri_harm
369      !!--------------------------------------------------------------------
370      !!                 ***  ROUTINE dia_wri_harm  ***
371      !!         
372      !! ** Purpose : Write tidal harmonic analysis results in a netcdf file
373      !!--------------------------------------------------------------------
374      CHARACTER(LEN=lc) :: cltext
375      CHARACTER(LEN=lc) ::   &
376         cdfile_name_T   ,   & ! name of the file created (T-points)
377         cdfile_name_U   ,   & ! name of the file created (U-points)
378         cdfile_name_V         ! name of the file created (V-points)
379      INTEGER  ::   jh
380      !!----------------------------------------------------------------------
381
382      IF(lwp) WRITE(numout,*) '  '
383      IF(lwp) WRITE(numout,*) 'dia_wri_harm : Write harmonic analysis results'
384      IF(lwp) WRITE(numout,*) '  '
385
386      ! A) Elevation
387      !/////////////
388      !
389      DO jh = 1, nb_ana
390      CALL iom_put( TRIM(tname(jh))//'x', out_eta(:,:,jh) )
391      CALL iom_put( TRIM(tname(jh))//'y', out_eta(:,:,nb_ana+jh) )
392      END DO
393
394      ! B) ubar
395      !/////////
396      !
397      DO jh = 1, nb_ana
398      CALL iom_put( TRIM(tname(jh))//'x_u', out_u(:,:,jh) )
399      CALL iom_put( TRIM(tname(jh))//'y_u', out_u(:,:,nb_ana+jh) )
400      END DO
401
402      ! C) vbar
403      !/////////
404      !
405      DO jh = 1, nb_ana
406         CALL iom_put( TRIM(tname(jh))//'x_v', out_v(:,:,jh       ) )
407         CALL iom_put( TRIM(tname(jh))//'y_v', out_v(:,:,jh+nb_ana) )
408      END DO
409      !
410   END SUBROUTINE dia_wri_harm
411
412
413   SUBROUTINE SUR_DETERMINE(init)
414      !!---------------------------------------------------------------------------------
415      !!                      *** ROUTINE SUR_DETERMINE ***
416      !!   
417      !!   
418      !!       
419      !!---------------------------------------------------------------------------------
420      INTEGER, INTENT(in) ::   init 
421      !
422      INTEGER                         :: ji_sd, jj_sd, ji1_sd, ji2_sd, jh1_sd, jh2_sd
423      REAL(wp)                        :: zval1, zval2, zx1
424      REAL(wp), DIMENSION(jpincomax) :: ztmpx, zcol1, zcol2
425      INTEGER , DIMENSION(jpincomax) :: ipos2, ipivot
426      !---------------------------------------------------------------------------------
427      !           
428      IF( init == 1 ) THEN
429         IF( nsparse > jpdimsparse )   CALL ctl_stop( 'STOP', 'SUR_DETERMINE : nsparse .GT. jpdimsparse')
430         IF( ninco   > jpincomax   )   CALL ctl_stop( 'STOP', 'SUR_DETERMINE : ninco .GT. jpincomax')
431         !
432         ztmp3(:,:) = 0._wp
433         !
434         DO jh1_sd = 1, nsparse
435            DO jh2_sd = 1, nsparse
436               nisparse(jh2_sd) = nisparse(jh2_sd)
437               njsparse(jh2_sd) = njsparse(jh2_sd)
438               IF( nisparse(jh2_sd) == nisparse(jh1_sd) ) THEN
439                  ztmp3(njsparse(jh1_sd),njsparse(jh2_sd)) = ztmp3(njsparse(jh1_sd),njsparse(jh2_sd))  &
440                     &                                     + valuesparse(jh1_sd)*valuesparse(jh2_sd)
441               ENDIF
442            END DO
443         END DO
444         !
445         DO jj_sd = 1 ,ninco
446            ipos1(jj_sd) = jj_sd
447            ipos2(jj_sd) = jj_sd
448         END DO
449         !
450         DO ji_sd = 1 , ninco
451            !
452            !find greatest non-zero pivot:
453            zval1 = ABS(ztmp3(ji_sd,ji_sd))
454            !
455            ipivot(ji_sd) = ji_sd
456            DO jj_sd = ji_sd, ninco
457               zval2 = ABS(ztmp3(ji_sd,jj_sd))
458               IF( zval2 >= zval1 )THEN
459                  ipivot(ji_sd) = jj_sd
460                  zval1         = zval2
461               ENDIF
462            END DO
463            !
464            DO ji1_sd = 1, ninco
465               zcol1(ji1_sd)               = ztmp3(ji1_sd,ji_sd)
466               zcol2(ji1_sd)               = ztmp3(ji1_sd,ipivot(ji_sd))
467               ztmp3(ji1_sd,ji_sd)         = zcol2(ji1_sd)
468               ztmp3(ji1_sd,ipivot(ji_sd)) = zcol1(ji1_sd)
469            END DO
470            !
471            ipos2(ji_sd)         = ipos1(ipivot(ji_sd))
472            ipos2(ipivot(ji_sd)) = ipos1(ji_sd)
473            ipos1(ji_sd)         = ipos2(ji_sd)
474            ipos1(ipivot(ji_sd)) = ipos2(ipivot(ji_sd))
475            zpivot(ji_sd)        = ztmp3(ji_sd,ji_sd)
476            DO jj_sd = 1, ninco
477               ztmp3(ji_sd,jj_sd) = ztmp3(ji_sd,jj_sd) / zpivot(ji_sd)
478            END DO
479            !
480            DO ji2_sd = ji_sd+1, ninco
481               zpilier(ji2_sd,ji_sd)=ztmp3(ji2_sd,ji_sd)
482               DO jj_sd=1,ninco
483                  ztmp3(ji2_sd,jj_sd)=  ztmp3(ji2_sd,jj_sd) - ztmp3(ji_sd,jj_sd) * zpilier(ji2_sd,ji_sd)
484               END DO
485            END DO
486            !
487         END DO
488         !
489      ENDIF ! End init==1
490
491      DO ji_sd = 1, ninco
492         ztmp4(ji_sd) = ztmp4(ji_sd) / zpivot(ji_sd)
493         DO ji2_sd = ji_sd+1, ninco
494            ztmp4(ji2_sd) = ztmp4(ji2_sd) - ztmp4(ji_sd) * zpilier(ji2_sd,ji_sd)
495         END DO
496      END DO
497
498      !system solving:
499      ztmpx(ninco) = ztmp4(ninco) / ztmp3(ninco,ninco)
500      ji_sd = ninco
501      DO ji_sd = ninco-1, 1, -1
502         zx1 = 0._wp
503         DO jj_sd = ji_sd+1, ninco
504            zx1 = zx1 + ztmpx(jj_sd) * ztmp3(ji_sd,jj_sd)
505         END DO
506         ztmpx(ji_sd) = ztmp4(ji_sd)-zx1
507      END DO
508
509      DO jj_sd =1, ninco
510         ztmp7(ipos1(jj_sd))=ztmpx(jj_sd)
511      END DO
512      !
513   END SUBROUTINE SUR_DETERMINE
514
515   !!======================================================================
516END MODULE diaharm
Note: See TracBrowser for help on using the repository browser.