New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
divhor.F90 in NEMO/branches/2019/dev_r11943_MERGE_2019/src/OCE/DYN – NEMO

source: NEMO/branches/2019/dev_r11943_MERGE_2019/src/OCE/DYN/divhor.F90 @ 11949

Last change on this file since 11949 was 11949, checked in by acc, 4 years ago

Merge in changes from 2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps. This just creates a fresh copy of this branch to use as the merge base. See ticket #2341

  • Property svn:keywords set to Id
File size: 5.5 KB
Line 
1MODULE divhor
2   !!==============================================================================
3   !!                       ***  MODULE  divhor  ***
4   !! Ocean diagnostic variable : now horizontal divergence
5   !!==============================================================================
6   !! History :  1.0  ! 2002-09  (G. Madec, E. Durand)  Free form, F90
7   !!             -   ! 2005-01  (J. Chanut) Unstructured open boundaries
8   !!             -   ! 2003-08  (G. Madec)  merged of cur and div, free form, F90
9   !!             -   ! 2005-01  (J. Chanut, A. Sellar) unstructured open boundaries
10   !!            3.3  ! 2010-09  (D.Storkey and E.O'Dea) bug fixes for BDY module
11   !!             -   ! 2010-10  (R. Furner, G. Madec) runoff and cla added directly here
12   !!            3.7  ! 2014-01  (G. Madec) suppression of velocity curl from in-core memory
13   !!             -   ! 2014-12  (G. Madec) suppression of cross land advection option
14   !!             -   ! 2015-10  (G. Madec) add velocity and rnf flag in argument of div_hor
15   !!----------------------------------------------------------------------
16
17   !!----------------------------------------------------------------------
18   !!   div_hor    : Compute the horizontal divergence field
19   !!----------------------------------------------------------------------
20   USE oce             ! ocean dynamics and tracers
21   USE dom_oce         ! ocean space and time domain
22   USE sbc_oce, ONLY : ln_rnf, ln_isf ! surface boundary condition: ocean
23   USE sbcrnf          ! river runoff
24   USE sbcisf          ! ice shelf
25   USE iscplhsb        ! ice sheet / ocean coupling
26   USE iscplini        ! ice sheet / ocean coupling
27#if defined key_asminc   
28   USE asminc          ! Assimilation increment
29#endif
30   !
31   USE in_out_manager  ! I/O manager
32   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
33   USE lib_mpp         ! MPP library
34   USE timing          ! Timing
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   div_hor    ! routine called by step.F90 and istate.F90
40
41   !! * Substitutions
42#  include "vectopt_loop_substitute.h90"
43   !!----------------------------------------------------------------------
44   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
45   !! $Id$
46   !! Software governed by the CeCILL license (see ./LICENSE)
47   !!----------------------------------------------------------------------
48CONTAINS
49
50   SUBROUTINE div_hor( kt, Kbb, Kmm )
51      !!----------------------------------------------------------------------
52      !!                  ***  ROUTINE div_hor  ***
53      !!                   
54      !! ** Purpose :   compute the horizontal divergence at now time-step
55      !!
56      !! ** Method  :   the now divergence is computed as :
57      !!         hdiv = 1/(e1e2t*e3t) ( di[e2u*e3u un] + dj[e1v*e3v vn] )
58      !!      and correct with runoff inflow (div_rnf) and cross land flow (div_cla)
59      !!
60      !! ** Action  : - update hdiv, the now horizontal divergence
61      !!----------------------------------------------------------------------
62      INTEGER, INTENT(in) ::   kt        ! ocean time-step index
63      INTEGER, INTENT(in) ::   Kbb, Kmm  ! ocean time level indices
64      !
65      INTEGER  ::   ji, jj, jk    ! dummy loop indices
66      REAL(wp) ::   zraur, zdep   ! local scalars
67      !!----------------------------------------------------------------------
68      !
69      IF( ln_timing )   CALL timing_start('div_hor')
70      !
71      IF( kt == nit000 ) THEN
72         IF(lwp) WRITE(numout,*)
73         IF(lwp) WRITE(numout,*) 'div_hor : horizontal velocity divergence '
74         IF(lwp) WRITE(numout,*) '~~~~~~~   '
75      ENDIF
76      !
77      DO jk = 1, jpkm1                                      !==  Horizontal divergence  ==!
78         DO jj = 2, jpjm1
79            DO ji = fs_2, fs_jpim1   ! vector opt.
80               hdiv(ji,jj,jk) = (  e2u(ji  ,jj) * e3u(ji  ,jj,jk,Kmm) * uu(ji  ,jj,jk,Kmm)      &
81                  &               - e2u(ji-1,jj) * e3u(ji-1,jj,jk,Kmm) * uu(ji-1,jj,jk,Kmm)      &
82                  &               + e1v(ji,jj  ) * e3v(ji,jj  ,jk,Kmm) * vv(ji,jj  ,jk,Kmm)      &
83                  &               - e1v(ji,jj-1) * e3v(ji,jj-1,jk,Kmm) * vv(ji,jj-1,jk,Kmm)  )   &
84                  &            * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
85            END DO 
86         END DO 
87      END DO
88#if defined key_agrif
89      IF( .NOT. Agrif_Root() ) THEN
90         IF( nbondi == -1 .OR. nbondi == 2 )   hdiv(   2   ,  :   ,:) = 0._wp      ! west
91         IF( nbondi ==  1 .OR. nbondi == 2 )   hdiv( nlci-1,  :   ,:) = 0._wp      ! east
92         IF( nbondj == -1 .OR. nbondj == 2 )   hdiv(   :   ,  2   ,:) = 0._wp      ! south
93         IF( nbondj ==  1 .OR. nbondj == 2 )   hdiv(   :   ,nlcj-1,:) = 0._wp      ! north
94      ENDIF
95#endif
96      !
97      IF( ln_rnf )   CALL sbc_rnf_div( hdiv, Kmm )                     !==  runoffs    ==!   (update hdiv field)
98      !
99#if defined key_asminc 
100      IF( ln_sshinc .AND. ln_asmiau )   CALL ssh_asm_div( kt, Kbb, Kmm, hdiv )   !==  SSH assimilation  ==!   (update hdiv field)
101      !
102#endif
103      IF( ln_isf )   CALL sbc_isf_div( hdiv, Kmm )                     !==  ice shelf  ==!   (update hdiv field)
104      !
105      IF( ln_iscpl .AND. ln_hsb )   CALL iscpl_div( Kmm, hdiv ) !==  ice sheet  ==!   (update hdiv field)
106      !
107      CALL lbc_lnk( 'divhor', hdiv, 'T', 1. )   !   (no sign change)
108      !
109      IF( ln_timing )   CALL timing_stop('div_hor')
110      !
111   END SUBROUTINE div_hor
112   
113   !!======================================================================
114END MODULE divhor
Note: See TracBrowser for help on using the repository browser.