source: NEMO/branches/2019/dev_r11943_MERGE_2019/src/OCE/DYN/divhor.F90 @ 12252

Last change on this file since 12252 was 12252, checked in by smasson, 11 months ago

rev12240_dev_r11943_MERGE_2019: same as [12251], merge trunk 12072:12248, all sette tests ok, GYRE_PISCES, AMM12, ISOMIP, VORTEX intentical to 12236

  • Property svn:keywords set to Id
File size: 5.4 KB
Line 
1MODULE divhor
2   !!==============================================================================
3   !!                       ***  MODULE  divhor  ***
4   !! Ocean diagnostic variable : now horizontal divergence
5   !!==============================================================================
6   !! History :  1.0  ! 2002-09  (G. Madec, E. Durand)  Free form, F90
7   !!             -   ! 2005-01  (J. Chanut) Unstructured open boundaries
8   !!             -   ! 2003-08  (G. Madec)  merged of cur and div, free form, F90
9   !!             -   ! 2005-01  (J. Chanut, A. Sellar) unstructured open boundaries
10   !!            3.3  ! 2010-09  (D.Storkey and E.O'Dea) bug fixes for BDY module
11   !!             -   ! 2010-10  (R. Furner, G. Madec) runoff and cla added directly here
12   !!            3.7  ! 2014-01  (G. Madec) suppression of velocity curl from in-core memory
13   !!             -   ! 2014-12  (G. Madec) suppression of cross land advection option
14   !!             -   ! 2015-10  (G. Madec) add velocity and rnf flag in argument of div_hor
15   !!----------------------------------------------------------------------
16
17   !!----------------------------------------------------------------------
18   !!   div_hor    : Compute the horizontal divergence field
19   !!----------------------------------------------------------------------
20   USE oce             ! ocean dynamics and tracers
21   USE dom_oce         ! ocean space and time domain
22   USE sbc_oce, ONLY : ln_rnf      ! river runoff
23   USE sbcrnf , ONLY : sbc_rnf_div ! river runoff
24   USE isf_oce, ONLY : ln_isf      ! ice shelf
25   USE isfhdiv, ONLY : isf_hdiv    ! ice shelf
26#if defined key_asminc   
27   USE asminc          ! Assimilation increment
28#endif
29   !
30   USE in_out_manager  ! I/O manager
31   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
32   USE lib_mpp         ! MPP library
33   USE timing          ! Timing
34
35   IMPLICIT NONE
36   PRIVATE
37
38   PUBLIC   div_hor    ! routine called by step.F90 and istate.F90
39
40   !! * Substitutions
41#  include "vectopt_loop_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
44   !! $Id$
45   !! Software governed by the CeCILL license (see ./LICENSE)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   SUBROUTINE div_hor( kt, Kbb, Kmm )
50      !!----------------------------------------------------------------------
51      !!                  ***  ROUTINE div_hor  ***
52      !!                   
53      !! ** Purpose :   compute the horizontal divergence at now time-step
54      !!
55      !! ** Method  :   the now divergence is computed as :
56      !!         hdiv = 1/(e1e2t*e3t) ( di[e2u*e3u un] + dj[e1v*e3v vn] )
57      !!      and correct with runoff inflow (div_rnf) and cross land flow (div_cla)
58      !!
59      !! ** Action  : - update hdiv, the now horizontal divergence
60      !!----------------------------------------------------------------------
61      INTEGER, INTENT(in) ::   kt        ! ocean time-step index
62      INTEGER, INTENT(in) ::   Kbb, Kmm  ! ocean time level indices
63      !
64      INTEGER  ::   ji, jj, jk    ! dummy loop indices
65      REAL(wp) ::   zraur, zdep   ! local scalars
66      REAL(wp), DIMENSION(jpi,jpj) :: ztmp
67      !!----------------------------------------------------------------------
68      !
69      IF( ln_timing )   CALL timing_start('div_hor')
70      !
71      IF( kt == nit000 ) THEN
72         IF(lwp) WRITE(numout,*)
73         IF(lwp) WRITE(numout,*) 'div_hor : horizontal velocity divergence '
74         IF(lwp) WRITE(numout,*) '~~~~~~~   '
75         hdiv(:,:,:) = 0._wp    ! initialize hdiv for the halos at the first time step
76      ENDIF
77      !
78      DO jk = 1, jpkm1                                      !==  Horizontal divergence  ==!
79         DO jj = 2, jpjm1
80            DO ji = fs_2, fs_jpim1   ! vector opt.
81               hdiv(ji,jj,jk) = (  e2u(ji  ,jj) * e3u(ji  ,jj,jk,Kmm) * uu(ji  ,jj,jk,Kmm)      &
82                  &               - e2u(ji-1,jj) * e3u(ji-1,jj,jk,Kmm) * uu(ji-1,jj,jk,Kmm)      &
83                  &               + e1v(ji,jj  ) * e3v(ji,jj  ,jk,Kmm) * vv(ji,jj  ,jk,Kmm)      &
84                  &               - e1v(ji,jj-1) * e3v(ji,jj-1,jk,Kmm) * vv(ji,jj-1,jk,Kmm)  )   &
85                  &            * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
86            END DO 
87         END DO 
88      END DO
89      !
90#if defined key_agrif
91      IF( .NOT. Agrif_Root() ) THEN
92         IF( nbondi == -1 .OR. nbondi == 2 )   hdiv(   2   ,  :   ,:) = 0._wp      ! west
93         IF( nbondi ==  1 .OR. nbondi == 2 )   hdiv( nlci-1,  :   ,:) = 0._wp      ! east
94         IF( nbondj == -1 .OR. nbondj == 2 )   hdiv(   :   ,  2   ,:) = 0._wp      ! south
95         IF( nbondj ==  1 .OR. nbondj == 2 )   hdiv(   :   ,nlcj-1,:) = 0._wp      ! north
96      ENDIF
97#endif
98      !
99      IF( ln_rnf )   CALL sbc_rnf_div( hdiv, Kmm )                     !==  runoffs    ==!   (update hdiv field)
100      !
101#if defined key_asminc 
102      IF( ln_sshinc .AND. ln_asmiau )   CALL ssh_asm_div( kt, Kbb, Kmm, hdiv )   !==  SSH assimilation  ==!   (update hdiv field)
103      !
104#endif
105      !
106      IF( ln_isf )                      CALL isf_hdiv( kt, Kmm, hdiv )           !==  ice shelf         ==!   (update hdiv field)
107      !
108      CALL lbc_lnk( 'divhor', hdiv, 'T', 1. )   !   (no sign change)
109      !
110      IF( ln_timing )   CALL timing_stop('div_hor')
111      !
112   END SUBROUTINE div_hor
113   
114   !!======================================================================
115END MODULE divhor
Note: See TracBrowser for help on using the repository browser.