New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

dynhpg.F90 in NEMO/branches/2019/dev_r11943_MERGE_2019/src/OCE/DYN – NEMO

Context Navigation

source: NEMO/branches/2019/dev_r11943_MERGE_2019/src/OCE/DYN/dynhpg.F90 @ 11960

Last change on this file since 11960 was 11960, checked in by acc, 4 years ago
Branch 2019/dev_r11943_MERGE_2019. Merge in changes from 2019/dev_r11613_ENHANCE-04_namelists_as_internalfiles. (svn merge -r 11614:11954). Resolved tree conflicts and one actual conflict. Sette tested(these changes alter the ext/AGRIF reference; remember to update). See ticket #2341
Property svn:keywords set to `Id`
File size: 75.4 KB

Line
1	MODULE dynhpg
2	!!======================================================================
3	!! * MODULE dynhpg *
4	!! Ocean dynamics: hydrostatic pressure gradient trend
5	!!======================================================================
6	!! History : OPA ! 1987-09 (P. Andrich, M.-A. Foujols) hpg_zco: Original code
7	!! 5.0 ! 1991-11 (G. Madec)
8	!! 7.0 ! 1996-01 (G. Madec) hpg_sco: Original code for s-coordinates
9	!! 8.0 ! 1997-05 (G. Madec) split dynber into dynkeg and dynhpg
10	!! 8.5 ! 2002-07 (G. Madec) F90: Free form and module
11	!! 8.5 ! 2002-08 (A. Bozec) hpg_zps: Original code
12	!! NEMO 1.0 ! 2005-10 (A. Beckmann, B.W. An) various s-coordinate options
13	!! ! Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14	!! - ! 2005-11 (G. Madec) style & small optimisation
15	!! 3.3 ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
16	!! 3.4 ! 2011-11 (H. Liu) hpg_prj: Original code for s-coordinates
17	!! ! (A. Coward) suppression of hel, wdj and rot options
18	!! 3.6 ! 2014-11 (P. Mathiot) hpg_isf: original code for ice shelf cavity
19	!!----------------------------------------------------------------------
20
21	!!----------------------------------------------------------------------
22	!! dyn_hpg : update the momentum trend with the now horizontal
23	!! gradient of the hydrostatic pressure
24	!! dyn_hpg_init : initialisation and control of options
25	!! hpg_zco : z-coordinate scheme
26	!! hpg_zps : z-coordinate plus partial steps (interpolation)
27	!! hpg_sco : s-coordinate (standard jacobian formulation)
28	!! hpg_isf : s-coordinate (sco formulation) adapted to ice shelf
29	!! hpg_djc : s-coordinate (Density Jacobian with Cubic polynomial)
30	!! hpg_prj : s-coordinate (Pressure Jacobian with Cubic polynomial)
31	!!----------------------------------------------------------------------
32	USE oce ! ocean dynamics and tracers
33	USE sbc_oce ! surface variable (only for the flag with ice shelf)
34	USE dom_oce ! ocean space and time domain
35	USE wet_dry ! wetting and drying
36	USE phycst ! physical constants
37	USE trd_oce ! trends: ocean variables
38	USE trddyn ! trend manager: dynamics
39	USE zpshde ! partial step: hor. derivative (zps_hde routine)
40	!
41	USE in_out_manager ! I/O manager
42	USE prtctl ! Print control
43	USE lbclnk ! lateral boundary condition
44	USE lib_mpp ! MPP library
45	USE eosbn2 ! compute density
46	USE timing ! Timing
47	USE iom
48
49	IMPLICIT NONE
50	PRIVATE
51
52	PUBLIC dyn_hpg ! routine called by step module
53	PUBLIC dyn_hpg_init ! routine called by opa module
54
55	! !!* Namelist namdyn_hpg : hydrostatic pressure gradient
56	LOGICAL, PUBLIC :: ln_hpg_zco !: z-coordinate - full steps
57	LOGICAL, PUBLIC :: ln_hpg_zps !: z-coordinate - partial steps (interpolation)
58	LOGICAL, PUBLIC :: ln_hpg_sco !: s-coordinate (standard jacobian formulation)
59	LOGICAL, PUBLIC :: ln_hpg_djc !: s-coordinate (Density Jacobian with Cubic polynomial)
60	LOGICAL, PUBLIC :: ln_hpg_prj !: s-coordinate (Pressure Jacobian scheme)
61	LOGICAL, PUBLIC :: ln_hpg_isf !: s-coordinate similar to sco modify for isf
62
63	! !! Flag to control the type of hydrostatic pressure gradient
64	INTEGER, PARAMETER :: np_ERROR =-10 ! error in specification of lateral diffusion
65	INTEGER, PARAMETER :: np_zco = 0 ! z-coordinate - full steps
66	INTEGER, PARAMETER :: np_zps = 1 ! z-coordinate - partial steps (interpolation)
67	INTEGER, PARAMETER :: np_sco = 2 ! s-coordinate (standard jacobian formulation)
68	INTEGER, PARAMETER :: np_djc = 3 ! s-coordinate (Density Jacobian with Cubic polynomial)
69	INTEGER, PARAMETER :: np_prj = 4 ! s-coordinate (Pressure Jacobian scheme)
70	INTEGER, PARAMETER :: np_isf = 5 ! s-coordinate similar to sco modify for isf
71	!
72	INTEGER, PUBLIC :: nhpg !: type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
73
74	!! * Substitutions
75	# include "vectopt_loop_substitute.h90"
76	!!----------------------------------------------------------------------
77	!! NEMO/OCE 4.0 , NEMO Consortium (2018)
78	!! $Id$
79	!! Software governed by the CeCILL license (see ./LICENSE)
80	!!----------------------------------------------------------------------
81	CONTAINS
82
83	SUBROUTINE dyn_hpg( kt, Kmm, puu, pvv, Krhs )
84	!!---------------------------------------------------------------------
85	!! * ROUTINE dyn_hpg *
86	!!
87	!! ** Method : Call the hydrostatic pressure gradient routine
88	!! using the scheme defined in the namelist
89	!!
90	!! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
91	!! - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
92	!!----------------------------------------------------------------------
93	INTEGER , INTENT( in ) :: kt ! ocean time-step index
94	INTEGER , INTENT( in ) :: Kmm, Krhs ! ocean time level indices
95	REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation
96	!
97	REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: ztrdu, ztrdv
98	!!----------------------------------------------------------------------
99	!
100	IF( ln_timing ) CALL timing_start('dyn_hpg')
101	!
102	IF( l_trddyn ) THEN ! Temporary saving of puu(:,:,:,Krhs) and pvv(:,:,:,Krhs) trends (l_trddyn)
103	ALLOCATE( ztrdu(jpi,jpj,jpk) , ztrdv(jpi,jpj,jpk) )
104	ztrdu(:,:,:) = puu(:,:,:,Krhs)
105	ztrdv(:,:,:) = pvv(:,:,:,Krhs)
106	ENDIF
107	!
108	SELECT CASE ( nhpg ) ! Hydrostatic pressure gradient computation
109	CASE ( np_zco ) ; CALL hpg_zco ( kt, Kmm, puu, pvv, Krhs ) ! z-coordinate
110	CASE ( np_zps ) ; CALL hpg_zps ( kt, Kmm, puu, pvv, Krhs ) ! z-coordinate plus partial steps (interpolation)
111	CASE ( np_sco ) ; CALL hpg_sco ( kt, Kmm, puu, pvv, Krhs ) ! s-coordinate (standard jacobian formulation)
112	CASE ( np_djc ) ; CALL hpg_djc ( kt, Kmm, puu, pvv, Krhs ) ! s-coordinate (Density Jacobian with Cubic polynomial)
113	CASE ( np_prj ) ; CALL hpg_prj ( kt, Kmm, puu, pvv, Krhs ) ! s-coordinate (Pressure Jacobian scheme)
114	CASE ( np_isf ) ; CALL hpg_isf ( kt, Kmm, puu, pvv, Krhs ) ! s-coordinate similar to sco modify for ice shelf
115	END SELECT
116	!
117	IF( l_trddyn ) THEN ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
118	ztrdu(:,:,:) = puu(:,:,:,Krhs) - ztrdu(:,:,:)
119	ztrdv(:,:,:) = pvv(:,:,:,Krhs) - ztrdv(:,:,:)
120	CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt, Kmm )
121	DEALLOCATE( ztrdu , ztrdv )
122	ENDIF
123	!
124	IF(ln_ctl) CALL prt_ctl( tab3d_1=puu(:,:,:,Krhs), clinfo1=' hpg - Ua: ', mask1=umask, &
125	& tab3d_2=pvv(:,:,:,Krhs), clinfo2= ' Va: ', mask2=vmask, clinfo3='dyn' )
126	!
127	IF( ln_timing ) CALL timing_stop('dyn_hpg')
128	!
129	END SUBROUTINE dyn_hpg
130
131
132	SUBROUTINE dyn_hpg_init( Kmm )
133	!!----------------------------------------------------------------------
134	!! * ROUTINE dyn_hpg_init *
135	!!
136	!! ** Purpose : initializations for the hydrostatic pressure gradient
137	!! computation and consistency control
138	!!
139	!! ** Action : Read the namelist namdyn_hpg and check the consistency
140	!! with the type of vertical coordinate used (zco, zps, sco)
141	!!----------------------------------------------------------------------
142	INTEGER, INTENT( in ) :: Kmm ! ocean time level index
143	!
144	INTEGER :: ioptio = 0 ! temporary integer
145	INTEGER :: ios ! Local integer output status for namelist read
146	!!
147	INTEGER :: ji, jj, jk, ikt ! dummy loop indices ISF
148	REAL(wp) :: znad
149	REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: zts_top, zrhd ! hypothesys on isf density
150	REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: zrhdtop_isf ! density at bottom of ISF
151	REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: ziceload ! density at bottom of ISF
152	!!
153	NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco, &
154	& ln_hpg_djc, ln_hpg_prj, ln_hpg_isf
155	!!----------------------------------------------------------------------
156	!
157	READ ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
158	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist' )
159	!
160	READ ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
161	902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist' )
162	IF(lwm) WRITE ( numond, namdyn_hpg )
163	!
164	IF(lwp) THEN ! Control print
165	WRITE(numout,*)
166	WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
167	WRITE(numout,*) '~~~~~~~~~~~~'
168	WRITE(numout,*) ' Namelist namdyn_hpg : choice of hpg scheme'
169	WRITE(numout,*) ' z-coord. - full steps ln_hpg_zco = ', ln_hpg_zco
170	WRITE(numout,*) ' z-coord. - partial steps (interpolation) ln_hpg_zps = ', ln_hpg_zps
171	WRITE(numout,*) ' s-coord. (standard jacobian formulation) ln_hpg_sco = ', ln_hpg_sco
172	WRITE(numout,*) ' s-coord. (standard jacobian formulation) for isf ln_hpg_isf = ', ln_hpg_isf
173	WRITE(numout,*) ' s-coord. (Density Jacobian: Cubic polynomial) ln_hpg_djc = ', ln_hpg_djc
174	WRITE(numout,*) ' s-coord. (Pressure Jacobian: Cubic polynomial) ln_hpg_prj = ', ln_hpg_prj
175	ENDIF
176	!
177	IF( ln_hpg_djc ) &
178	& CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method', &
179	& ' currently disabled (bugs under investigation).' , &
180	& ' Please select either ln_hpg_sco or ln_hpg_prj instead' )
181	!
182	IF( .NOT.ln_linssh .AND. .NOT.(ln_hpg_sco.OR.ln_hpg_prj.OR.ln_hpg_isf) ) &
183	& CALL ctl_stop('dyn_hpg_init : non-linear free surface requires either ', &
184	& ' the standard jacobian formulation hpg_sco or ' , &
185	& ' the pressure jacobian formulation hpg_prj' )
186	!
187	IF( ln_hpg_isf ) THEN
188	IF( .NOT. ln_isfcav ) CALL ctl_stop( ' hpg_isf not available if ln_isfcav = false ' )
189	ELSE
190	IF( ln_isfcav ) CALL ctl_stop( 'Only hpg_isf has been corrected to work with ice shelf cavity.' )
191	ENDIF
192	!
193	! ! Set nhpg from ln_hpg_... flags & consistency check
194	nhpg = np_ERROR
195	ioptio = 0
196	IF( ln_hpg_zco ) THEN ; nhpg = np_zco ; ioptio = ioptio +1 ; ENDIF
197	IF( ln_hpg_zps ) THEN ; nhpg = np_zps ; ioptio = ioptio +1 ; ENDIF
198	IF( ln_hpg_sco ) THEN ; nhpg = np_sco ; ioptio = ioptio +1 ; ENDIF
199	IF( ln_hpg_djc ) THEN ; nhpg = np_djc ; ioptio = ioptio +1 ; ENDIF
200	IF( ln_hpg_prj ) THEN ; nhpg = np_prj ; ioptio = ioptio +1 ; ENDIF
201	IF( ln_hpg_isf ) THEN ; nhpg = np_isf ; ioptio = ioptio +1 ; ENDIF
202	!
203	IF( ioptio /= 1 ) CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
204	!
205	IF(lwp) THEN
206	WRITE(numout,*)
207	SELECT CASE( nhpg )
208	CASE( np_zco ) ; WRITE(numout,*) ' ==>>> z-coord. - full steps '
209	CASE( np_zps ) ; WRITE(numout,*) ' ==>>> z-coord. - partial steps (interpolation)'
210	CASE( np_sco ) ; WRITE(numout,*) ' ==>>> s-coord. (standard jacobian formulation)'
211	CASE( np_djc ) ; WRITE(numout,*) ' ==>>> s-coord. (Density Jacobian: Cubic polynomial)'
212	CASE( np_prj ) ; WRITE(numout,*) ' ==>>> s-coord. (Pressure Jacobian: Cubic polynomial)'
213	CASE( np_isf ) ; WRITE(numout,*) ' ==>>> s-coord. (standard jacobian formulation) for isf'
214	END SELECT
215	WRITE(numout,*)
216	ENDIF
217	!
218	IF ( .NOT. ln_isfcav ) THEN !--- no ice shelf load
219	riceload(:,:) = 0._wp
220	!
221	ELSE !--- set an ice shelf load
222	!
223	IF(lwp) WRITE(numout,*)
224	IF(lwp) WRITE(numout,*) ' ice shelf case: set the ice-shelf load'
225	ALLOCATE( zts_top(jpi,jpj,jpts) , zrhd(jpi,jpj,jpk) , zrhdtop_isf(jpi,jpj) , ziceload(jpi,jpj) )
226	!
227	znad = 1._wp !- To use density and not density anomaly
228	!
229	! !- assume water displaced by the ice shelf is at T=-1.9 and S=34.4 (rude)
230	zts_top(:,:,jp_tem) = -1.9_wp ; zts_top(:,:,jp_sal) = 34.4_wp
231	!
232	DO jk = 1, jpk !- compute density of the water displaced by the ice shelf
233	CALL eos( zts_top(:,:,:), gdept(:,:,jk,Kmm), zrhd(:,:,jk) )
234	END DO
235	!
236	! !- compute rhd at the ice/oce interface (ice shelf side)
237	CALL eos( zts_top , risfdep, zrhdtop_isf )
238	!
239	! !- Surface value + ice shelf gradient
240	ziceload = 0._wp ! compute pressure due to ice shelf load
241	DO jj = 1, jpj ! (used to compute hpgi/j for all the level from 1 to miku/v)
242	DO ji = 1, jpi ! divided by 2 later
243	ikt = mikt(ji,jj)
244	ziceload(ji,jj) = ziceload(ji,jj) + (znad + zrhd(ji,jj,1) ) * e3w(ji,jj,1,Kmm) * (1._wp - tmask(ji,jj,1))
245	DO jk = 2, ikt-1
246	ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhd(ji,jj,jk-1) + zrhd(ji,jj,jk)) * e3w(ji,jj,jk,Kmm) &
247	& * (1._wp - tmask(ji,jj,jk))
248	END DO
249	IF (ikt >= 2) ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhdtop_isf(ji,jj) + zrhd(ji,jj,ikt-1)) &
250	& * ( risfdep(ji,jj) - gdept(ji,jj,ikt-1,Kmm) )
251	END DO
252	END DO
253	riceload(:,:) = ziceload(:,:) ! need to be saved for diaar5
254	!
255	DEALLOCATE( zts_top , zrhd , zrhdtop_isf , ziceload )
256	ENDIF
257	!
258	END SUBROUTINE dyn_hpg_init
259
260
261	SUBROUTINE hpg_zco( kt, Kmm, puu, pvv, Krhs )
262	!!---------------------------------------------------------------------
263	!! * ROUTINE hpg_zco *
264	!!
265	!! ** Method : z-coordinate case, levels are horizontal surfaces.
266	!! The now hydrostatic pressure gradient at a given level, jk,
267	!! is computed by taking the vertical integral of the in-situ
268	!! density gradient along the model level from the suface to that
269	!! level: zhpi = grav .....
270	!! zhpj = grav .....
271	!! add it to the general momentum trend (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)).
272	!! puu(:,:,:,Krhs) = puu(:,:,:,Krhs) - 1/e1u * zhpi
273	!! pvv(:,:,:,Krhs) = pvv(:,:,:,Krhs) - 1/e2v * zhpj
274	!!
275	!! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
276	!!----------------------------------------------------------------------
277	INTEGER , INTENT( in ) :: kt ! ocean time-step index
278	INTEGER , INTENT( in ) :: Kmm, Krhs ! ocean time level indices
279	REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation
280	!
281	INTEGER :: ji, jj, jk ! dummy loop indices
282	REAL(wp) :: zcoef0, zcoef1 ! temporary scalars
283	REAL(wp), DIMENSION(jpi,jpj,jpk) :: zhpi, zhpj
284	!!----------------------------------------------------------------------
285	!
286	IF( kt == nit000 ) THEN
287	IF(lwp) WRITE(numout,*)
288	IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
289	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ z-coordinate case '
290	ENDIF
291
292	zcoef0 = - grav * 0.5_wp ! Local constant initialization
293
294	! Surface value
295	DO jj = 2, jpjm1
296	DO ji = fs_2, fs_jpim1 ! vector opt.
297	zcoef1 = zcoef0 * e3w(ji,jj,1,Kmm)
298	! hydrostatic pressure gradient
299	zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
300	zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
301	! add to the general momentum trend
302	puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj,1)
303	pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj,1)
304	END DO
305	END DO
306
307	!
308	! interior value (2=<jk=<jpkm1)
309	DO jk = 2, jpkm1
310	DO jj = 2, jpjm1
311	DO ji = fs_2, fs_jpim1 ! vector opt.
312	zcoef1 = zcoef0 * e3w(ji,jj,jk,Kmm)
313	! hydrostatic pressure gradient
314	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
315	& + zcoef1 * ( ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) ) &
316	& - ( rhd(ji ,jj,jk)+rhd(ji ,jj,jk-1) ) ) * r1_e1u(ji,jj)
317
318	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
319	& + zcoef1 * ( ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) ) &
320	& - ( rhd(ji,jj, jk)+rhd(ji,jj ,jk-1) ) ) * r1_e2v(ji,jj)
321	! add to the general momentum trend
322	puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj,jk)
323	pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj,jk)
324	END DO
325	END DO
326	END DO
327	!
328	END SUBROUTINE hpg_zco
329
330
331	SUBROUTINE hpg_zps( kt, Kmm, puu, pvv, Krhs )
332	!!---------------------------------------------------------------------
333	!! * ROUTINE hpg_zps *
334	!!
335	!! ** Method : z-coordinate plus partial steps case. blahblah...
336	!!
337	!! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
338	!!----------------------------------------------------------------------
339	INTEGER , INTENT( in ) :: kt ! ocean time-step index
340	INTEGER , INTENT( in ) :: Kmm, Krhs ! ocean time level indices
341	REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation
342	!!
343	INTEGER :: ji, jj, jk ! dummy loop indices
344	INTEGER :: iku, ikv ! temporary integers
345	REAL(wp) :: zcoef0, zcoef1, zcoef2, zcoef3 ! temporary scalars
346	REAL(wp), DIMENSION(jpi,jpj,jpk) :: zhpi, zhpj
347	REAL(wp), DIMENSION(jpi,jpj) :: zgtsu, zgtsv, zgru, zgrv
348	!!----------------------------------------------------------------------
349	!
350	IF( kt == nit000 ) THEN
351	IF(lwp) WRITE(numout,*)
352	IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
353	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ z-coordinate with partial steps - vector optimization'
354	ENDIF
355
356	! Partial steps: Compute NOW horizontal gradient of t, s, rd at the last ocean level
357	CALL zps_hde( kt, Kmm, jpts, ts(:,:,:,:,Kmm), zgtsu, zgtsv, rhd, zgru , zgrv )
358
359	! Local constant initialization
360	zcoef0 = - grav * 0.5_wp
361
362	! Surface value (also valid in partial step case)
363	DO jj = 2, jpjm1
364	DO ji = fs_2, fs_jpim1 ! vector opt.
365	zcoef1 = zcoef0 * e3w(ji,jj,1,Kmm)
366	! hydrostatic pressure gradient
367	zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj ,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
368	zhpj(ji,jj,1) = zcoef1 * ( rhd(ji ,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
369	! add to the general momentum trend
370	puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj,1)
371	pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj,1)
372	END DO
373	END DO
374
375	! interior value (2=<jk=<jpkm1)
376	DO jk = 2, jpkm1
377	DO jj = 2, jpjm1
378	DO ji = fs_2, fs_jpim1 ! vector opt.
379	zcoef1 = zcoef0 * e3w(ji,jj,jk,Kmm)
380	! hydrostatic pressure gradient
381	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
382	& + zcoef1 * ( ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) ) &
383	& - ( rhd(ji ,jj,jk) + rhd(ji ,jj,jk-1) ) ) * r1_e1u(ji,jj)
384
385	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
386	& + zcoef1 * ( ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) ) &
387	& - ( rhd(ji,jj, jk) + rhd(ji,jj ,jk-1) ) ) * r1_e2v(ji,jj)
388	! add to the general momentum trend
389	puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj,jk)
390	pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj,jk)
391	END DO
392	END DO
393	END DO
394
395	! partial steps correction at the last level (use zgru & zgrv computed in zpshde.F90)
396	DO jj = 2, jpjm1
397	DO ji = 2, jpim1
398	iku = mbku(ji,jj)
399	ikv = mbkv(ji,jj)
400	zcoef2 = zcoef0 * MIN( e3w(ji,jj,iku,Kmm), e3w(ji+1,jj ,iku,Kmm) )
401	zcoef3 = zcoef0 * MIN( e3w(ji,jj,ikv,Kmm), e3w(ji ,jj+1,ikv,Kmm) )
402	IF( iku > 1 ) THEN ! on i-direction (level 2 or more)
403	puu (ji,jj,iku,Krhs) = puu(ji,jj,iku,Krhs) - zhpi(ji,jj,iku) ! subtract old value
404	zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1) & ! compute the new one
405	& + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + zgru(ji,jj) ) * r1_e1u(ji,jj)
406	puu (ji,jj,iku,Krhs) = puu(ji,jj,iku,Krhs) + zhpi(ji,jj,iku) ! add the new one to the general momentum trend
407	ENDIF
408	IF( ikv > 1 ) THEN ! on j-direction (level 2 or more)
409	pvv (ji,jj,ikv,Krhs) = pvv(ji,jj,ikv,Krhs) - zhpj(ji,jj,ikv) ! subtract old value
410	zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1) & ! compute the new one
411	& + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + zgrv(ji,jj) ) * r1_e2v(ji,jj)
412	pvv (ji,jj,ikv,Krhs) = pvv(ji,jj,ikv,Krhs) + zhpj(ji,jj,ikv) ! add the new one to the general momentum trend
413	ENDIF
414	END DO
415	END DO
416	!
417	END SUBROUTINE hpg_zps
418
419
420	SUBROUTINE hpg_sco( kt, Kmm, puu, pvv, Krhs )
421	!!---------------------------------------------------------------------
422	!! * ROUTINE hpg_sco *
423	!!
424	!! ** Method : s-coordinate case. Jacobian scheme.
425	!! The now hydrostatic pressure gradient at a given level, jk,
426	!! is computed by taking the vertical integral of the in-situ
427	!! density gradient along the model level from the suface to that
428	!! level. s-coordinates (ln_sco): a corrective term is added
429	!! to the horizontal pressure gradient :
430	!! zhpi = grav ..... + 1/e1u mi(rhd) di[ grav dep3w ]
431	!! zhpj = grav ..... + 1/e2v mj(rhd) dj[ grav dep3w ]
432	!! add it to the general momentum trend (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)).
433	!! puu(:,:,:,Krhs) = puu(:,:,:,Krhs) - 1/e1u * zhpi
434	!! pvv(:,:,:,Krhs) = pvv(:,:,:,Krhs) - 1/e2v * zhpj
435	!!
436	!! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
437	!!----------------------------------------------------------------------
438	INTEGER , INTENT( in ) :: kt ! ocean time-step index
439	INTEGER , INTENT( in ) :: Kmm, Krhs ! ocean time level indices
440	REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation
441	!!
442	INTEGER :: ji, jj, jk, jii, jjj ! dummy loop indices
443	REAL(wp) :: zcoef0, zuap, zvap, znad, ztmp ! temporary scalars
444	LOGICAL :: ll_tmp1, ll_tmp2 ! local logical variables
445	REAL(wp), DIMENSION(jpi,jpj,jpk) :: zhpi, zhpj
446	REAL(wp), DIMENSION(:,:), ALLOCATABLE :: zcpx, zcpy !W/D pressure filter
447	!!----------------------------------------------------------------------
448	!
449	IF( ln_wd_il ) ALLOCATE(zcpx(jpi,jpj), zcpy(jpi,jpj))
450	!
451	IF( kt == nit000 ) THEN
452	IF(lwp) WRITE(numout,*)
453	IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
454	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, OPA original scheme used'
455	ENDIF
456	!
457	zcoef0 = - grav * 0.5_wp
458	IF ( ln_linssh ) THEN ; znad = 0._wp ! Fixed volume: density anomaly
459	ELSE ; znad = 1._wp ! Variable volume: density
460	ENDIF
461	!
462	IF( ln_wd_il ) THEN
463	DO jj = 2, jpjm1
464	DO ji = 2, jpim1
465	ll_tmp1 = MIN( ssh(ji,jj,Kmm) , ssh(ji+1,jj,Kmm) ) > &
466	& MAX( -ht_0(ji,jj) , -ht_0(ji+1,jj) ) .AND. &
467	& MAX( ssh(ji,jj,Kmm) + ht_0(ji,jj), ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) ) &
468	& > rn_wdmin1 + rn_wdmin2
469	ll_tmp2 = ( ABS( ssh(ji,jj,Kmm) - ssh(ji+1,jj,Kmm) ) > 1.E-12 ) .AND. ( &
470	& MAX( ssh(ji,jj,Kmm) , ssh(ji+1,jj,Kmm) ) > &
471	& MAX( -ht_0(ji,jj) , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
472
473	IF(ll_tmp1) THEN
474	zcpx(ji,jj) = 1.0_wp
475	ELSE IF(ll_tmp2) THEN
476	! no worries about ssh(ji+1,jj,Kmm) - ssh(ji ,jj,Kmm) = 0, it won't happen ! here
477	zcpx(ji,jj) = ABS( (ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
478	& / (ssh(ji+1,jj,Kmm) - ssh(ji ,jj,Kmm)) )
479	ELSE
480	zcpx(ji,jj) = 0._wp
481	END IF
482
483	ll_tmp1 = MIN( ssh(ji,jj,Kmm) , ssh(ji,jj+1,Kmm) ) > &
484	& MAX( -ht_0(ji,jj) , -ht_0(ji,jj+1) ) .AND. &
485	& MAX( ssh(ji,jj,Kmm) + ht_0(ji,jj), ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) ) &
486	& > rn_wdmin1 + rn_wdmin2
487	ll_tmp2 = ( ABS( ssh(ji,jj,Kmm) - ssh(ji,jj+1,Kmm) ) > 1.E-12 ) .AND. ( &
488	& MAX( ssh(ji,jj,Kmm) , ssh(ji,jj+1,Kmm) ) > &
489	& MAX( -ht_0(ji,jj) , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
490
491	IF(ll_tmp1) THEN
492	zcpy(ji,jj) = 1.0_wp
493	ELSE IF(ll_tmp2) THEN
494	! no worries about ssh(ji,jj+1,Kmm) - ssh(ji,jj ,Kmm) = 0, it won't happen ! here
495	zcpy(ji,jj) = ABS( (ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
496	& / (ssh(ji,jj+1,Kmm) - ssh(ji,jj ,Kmm)) )
497	ELSE
498	zcpy(ji,jj) = 0._wp
499	END IF
500	END DO
501	END DO
502	CALL lbc_lnk_multi( 'dynhpg', zcpx, 'U', 1., zcpy, 'V', 1. )
503	END IF
504
505	! Surface value
506	DO jj = 2, jpjm1
507	DO ji = fs_2, fs_jpim1 ! vector opt.
508	! hydrostatic pressure gradient along s-surfaces
509	zhpi(ji,jj,1) = zcoef0 * ( e3w(ji+1,jj ,1,Kmm) * ( znad + rhd(ji+1,jj ,1) ) &
510	& - e3w(ji ,jj ,1,Kmm) * ( znad + rhd(ji ,jj ,1) ) ) * r1_e1u(ji,jj)
511	zhpj(ji,jj,1) = zcoef0 * ( e3w(ji ,jj+1,1,Kmm) * ( znad + rhd(ji ,jj+1,1) ) &
512	& - e3w(ji ,jj ,1,Kmm) * ( znad + rhd(ji ,jj ,1) ) ) * r1_e2v(ji,jj)
513	! s-coordinate pressure gradient correction
514	zuap = -zcoef0 * ( rhd (ji+1,jj,1) + rhd (ji,jj,1) + 2._wp * znad ) &
515	& * ( gde3w(ji+1,jj,1) - gde3w(ji,jj,1) ) * r1_e1u(ji,jj)
516	zvap = -zcoef0 * ( rhd (ji,jj+1,1) + rhd (ji,jj,1) + 2._wp * znad ) &
517	& * ( gde3w(ji,jj+1,1) - gde3w(ji,jj,1) ) * r1_e2v(ji,jj)
518	!
519	IF( ln_wd_il ) THEN
520	zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
521	zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj)
522	zuap = zuap * zcpx(ji,jj)
523	zvap = zvap * zcpy(ji,jj)
524	ENDIF
525	!
526	! add to the general momentum trend
527	puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj,1) + zuap
528	pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj,1) + zvap
529	END DO
530	END DO
531
532	! interior value (2=<jk=<jpkm1)
533	DO jk = 2, jpkm1
534	DO jj = 2, jpjm1
535	DO ji = fs_2, fs_jpim1 ! vector opt.
536	! hydrostatic pressure gradient along s-surfaces
537	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 * r1_e1u(ji,jj) &
538	& * ( e3w(ji+1,jj,jk,Kmm) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad ) &
539	& - e3w(ji ,jj,jk,Kmm) * ( rhd(ji ,jj,jk) + rhd(ji ,jj,jk-1) + 2*znad ) )
540	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 * r1_e2v(ji,jj) &
541	& * ( e3w(ji,jj+1,jk,Kmm) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad ) &
542	& - e3w(ji,jj ,jk,Kmm) * ( rhd(ji,jj, jk) + rhd(ji,jj ,jk-1) + 2*znad ) )
543	! s-coordinate pressure gradient correction
544	zuap = -zcoef0 * ( rhd (ji+1,jj ,jk) + rhd (ji,jj,jk) + 2._wp * znad ) &
545	& * ( gde3w(ji+1,jj ,jk) - gde3w(ji,jj,jk) ) * r1_e1u(ji,jj)
546	zvap = -zcoef0 * ( rhd (ji ,jj+1,jk) + rhd (ji,jj,jk) + 2._wp * znad ) &
547	& * ( gde3w(ji ,jj+1,jk) - gde3w(ji,jj,jk) ) * r1_e2v(ji,jj)
548	!
549	IF( ln_wd_il ) THEN
550	zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
551	zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj)
552	zuap = zuap * zcpx(ji,jj)
553	zvap = zvap * zcpy(ji,jj)
554	ENDIF
555	!
556	! add to the general momentum trend
557	puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj,jk) + zuap
558	pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj,jk) + zvap
559	END DO
560	END DO
561	END DO
562	!
563	IF( ln_wd_il ) DEALLOCATE( zcpx , zcpy )
564	!
565	END SUBROUTINE hpg_sco
566
567
568	SUBROUTINE hpg_isf( kt, Kmm, puu, pvv, Krhs )
569	!!---------------------------------------------------------------------
570	!! * ROUTINE hpg_isf *
571	!!
572	!! ** Method : s-coordinate case. Jacobian scheme.
573	!! The now hydrostatic pressure gradient at a given level, jk,
574	!! is computed by taking the vertical integral of the in-situ
575	!! density gradient along the model level from the suface to that
576	!! level. s-coordinates (ln_sco): a corrective term is added
577	!! to the horizontal pressure gradient :
578	!! zhpi = grav ..... + 1/e1u mi(rhd) di[ grav dep3w ]
579	!! zhpj = grav ..... + 1/e2v mj(rhd) dj[ grav dep3w ]
580	!! add it to the general momentum trend (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)).
581	!! puu(:,:,:,Krhs) = puu(:,:,:,Krhs) - 1/e1u * zhpi
582	!! pvv(:,:,:,Krhs) = pvv(:,:,:,Krhs) - 1/e2v * zhpj
583	!! iceload is added and partial cell case are added to the top and bottom
584	!!
585	!! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
586	!!----------------------------------------------------------------------
587	INTEGER , INTENT( in ) :: kt ! ocean time-step index
588	INTEGER , INTENT( in ) :: Kmm, Krhs ! ocean time level indices
589	REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation
590	!!
591	INTEGER :: ji, jj, jk, ikt, iktp1i, iktp1j ! dummy loop indices
592	REAL(wp) :: zcoef0, zuap, zvap, znad ! temporary scalars
593	REAL(wp), DIMENSION(jpi,jpj,jpk ) :: zhpi, zhpj
594	REAL(wp), DIMENSION(jpi,jpj,jpts) :: zts_top
595	REAL(wp), DIMENSION(jpi,jpj) :: zrhdtop_oce
596	!!----------------------------------------------------------------------
597	!
598	zcoef0 = - grav * 0.5_wp ! Local constant initialization
599	!
600	znad=1._wp ! To use density and not density anomaly
601	!
602	! ! iniitialised to 0. zhpi zhpi
603	zhpi(:,:,:) = 0._wp ; zhpj(:,:,:) = 0._wp
604
605	! compute rhd at the ice/oce interface (ocean side)
606	! usefull to reduce residual current in the test case ISOMIP with no melting
607	DO ji = 1, jpi
608	DO jj = 1, jpj
609	ikt = mikt(ji,jj)
610	zts_top(ji,jj,1) = ts(ji,jj,ikt,1,Kmm)
611	zts_top(ji,jj,2) = ts(ji,jj,ikt,2,Kmm)
612	END DO
613	END DO
614	CALL eos( zts_top, risfdep, zrhdtop_oce )
615
616	!==================================================================================
617	!===== Compute surface value =====================================================
618	!==================================================================================
619	DO jj = 2, jpjm1
620	DO ji = fs_2, fs_jpim1 ! vector opt.
621	ikt = mikt(ji,jj)
622	iktp1i = mikt(ji+1,jj)
623	iktp1j = mikt(ji,jj+1)
624	! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
625	! we assume ISF is in isostatic equilibrium
626	zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( 0.5_wp * e3w(ji+1,jj,iktp1i,Kmm) &
627	& * ( 2._wp * znad + rhd(ji+1,jj,iktp1i) + zrhdtop_oce(ji+1,jj) ) &
628	& - 0.5_wp * e3w(ji,jj,ikt,Kmm) &
629	& * ( 2._wp * znad + rhd(ji,jj,ikt) + zrhdtop_oce(ji,jj) ) &
630	& + ( riceload(ji+1,jj) - riceload(ji,jj)) )
631	zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( 0.5_wp * e3w(ji,jj+1,iktp1j,Kmm) &
632	& * ( 2._wp * znad + rhd(ji,jj+1,iktp1j) + zrhdtop_oce(ji,jj+1) ) &
633	& - 0.5_wp * e3w(ji,jj,ikt,Kmm) &
634	& * ( 2._wp * znad + rhd(ji,jj,ikt) + zrhdtop_oce(ji,jj) ) &
635	& + ( riceload(ji,jj+1) - riceload(ji,jj)) )
636	! s-coordinate pressure gradient correction (=0 if z coordinate)
637	zuap = -zcoef0 * ( rhd (ji+1,jj,1) + rhd (ji,jj,1) + 2._wp * znad ) &
638	& * ( gde3w(ji+1,jj,1) - gde3w(ji,jj,1) ) * r1_e1u(ji,jj)
639	zvap = -zcoef0 * ( rhd (ji,jj+1,1) + rhd (ji,jj,1) + 2._wp * znad ) &
640	& * ( gde3w(ji,jj+1,1) - gde3w(ji,jj,1) ) * r1_e2v(ji,jj)
641	! add to the general momentum trend
642	puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
643	pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
644	END DO
645	END DO
646	!==================================================================================
647	!===== Compute interior value =====================================================
648	!==================================================================================
649	! interior value (2=<jk=<jpkm1)
650	DO jk = 2, jpkm1
651	DO jj = 2, jpjm1
652	DO ji = fs_2, fs_jpim1 ! vector opt.
653	! hydrostatic pressure gradient along s-surfaces
654	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj) &
655	& * ( e3w(ji+1,jj,jk,Kmm) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2znad ) wmask(ji+1,jj,jk) &
656	& - e3w(ji ,jj,jk,Kmm) * ( rhd(ji ,jj,jk) + rhd(ji ,jj,jk-1) + 2znad ) wmask(ji ,jj,jk) )
657	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj) &
658	& * ( e3w(ji,jj+1,jk,Kmm) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2znad ) wmask(ji,jj+1,jk) &
659	& - e3w(ji,jj ,jk,Kmm) * ( rhd(ji,jj, jk) + rhd(ji,jj ,jk-1) + 2znad ) wmask(ji,jj ,jk) )
660	! s-coordinate pressure gradient correction
661	zuap = -zcoef0 * ( rhd (ji+1,jj ,jk) + rhd (ji,jj,jk) + 2._wp * znad ) &
662	& * ( gde3w(ji+1,jj ,jk) - gde3w(ji,jj,jk) ) / e1u(ji,jj)
663	zvap = -zcoef0 * ( rhd (ji ,jj+1,jk) + rhd (ji,jj,jk) + 2._wp * znad ) &
664	& * ( gde3w(ji ,jj+1,jk) - gde3w(ji,jj,jk) ) / e2v(ji,jj)
665	! add to the general momentum trend
666	puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + (zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
667	pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + (zhpj(ji,jj,jk) + zvap) * vmask(ji,jj,jk)
668	END DO
669	END DO
670	END DO
671	!
672	END SUBROUTINE hpg_isf
673
674
675	SUBROUTINE hpg_djc( kt, Kmm, puu, pvv, Krhs )
676	!!---------------------------------------------------------------------
677	!! * ROUTINE hpg_djc *
678	!!
679	!! ** Method : Density Jacobian with Cubic polynomial scheme
680	!!
681	!! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
682	!!----------------------------------------------------------------------
683	INTEGER , INTENT( in ) :: kt ! ocean time-step index
684	INTEGER , INTENT( in ) :: Kmm, Krhs ! ocean time level indices
685	REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation
686	!!
687	INTEGER :: ji, jj, jk ! dummy loop indices
688	REAL(wp) :: zcoef0, zep, cffw ! temporary scalars
689	REAL(wp) :: z1_10, cffu, cffx ! " "
690	REAL(wp) :: z1_12, cffv, cffy ! " "
691	LOGICAL :: ll_tmp1, ll_tmp2 ! local logical variables
692	REAL(wp), DIMENSION(jpi,jpj,jpk) :: zhpi, zhpj
693	REAL(wp), DIMENSION(jpi,jpj,jpk) :: dzx, dzy, dzz, dzu, dzv, dzw
694	REAL(wp), DIMENSION(jpi,jpj,jpk) :: drhox, drhoy, drhoz, drhou, drhov, drhow
695	REAL(wp), DIMENSION(jpi,jpj,jpk) :: rho_i, rho_j, rho_k
696	REAL(wp), DIMENSION(:,:), ALLOCATABLE :: zcpx, zcpy !W/D pressure filter
697	!!----------------------------------------------------------------------
698	!
699	IF( ln_wd_il ) THEN
700	ALLOCATE( zcpx(jpi,jpj) , zcpy(jpi,jpj) )
701	DO jj = 2, jpjm1
702	DO ji = 2, jpim1
703	ll_tmp1 = MIN( ssh(ji,jj,Kmm) , ssh(ji+1,jj,Kmm) ) > &
704	& MAX( -ht_0(ji,jj) , -ht_0(ji+1,jj) ) .AND. &
705	& MAX( ssh(ji,jj,Kmm) + ht_0(ji,jj), ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) ) &
706	& > rn_wdmin1 + rn_wdmin2
707	ll_tmp2 = ( ABS( ssh(ji,jj,Kmm) - ssh(ji+1,jj,Kmm) ) > 1.E-12 ) .AND. ( &
708	& MAX( ssh(ji,jj,Kmm) , ssh(ji+1,jj,Kmm) ) > &
709	& MAX( -ht_0(ji,jj) , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
710	IF(ll_tmp1) THEN
711	zcpx(ji,jj) = 1.0_wp
712	ELSE IF(ll_tmp2) THEN
713	! no worries about ssh(ji+1,jj,Kmm) - ssh(ji ,jj,Kmm) = 0, it won't happen ! here
714	zcpx(ji,jj) = ABS( (ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
715	& / (ssh(ji+1,jj,Kmm) - ssh(ji ,jj,Kmm)) )
716	ELSE
717	zcpx(ji,jj) = 0._wp
718	END IF
719
720	ll_tmp1 = MIN( ssh(ji,jj,Kmm) , ssh(ji,jj+1,Kmm) ) > &
721	& MAX( -ht_0(ji,jj) , -ht_0(ji,jj+1) ) .AND. &
722	& MAX( ssh(ji,jj,Kmm) + ht_0(ji,jj), ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) ) &
723	& > rn_wdmin1 + rn_wdmin2
724	ll_tmp2 = ( ABS( ssh(ji,jj,Kmm) - ssh(ji,jj+1,Kmm) ) > 1.E-12 ) .AND. ( &
725	& MAX( ssh(ji,jj,Kmm) , ssh(ji,jj+1,Kmm) ) > &
726	& MAX( -ht_0(ji,jj) , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
727
728	IF(ll_tmp1) THEN
729	zcpy(ji,jj) = 1.0_wp
730	ELSE IF(ll_tmp2) THEN
731	! no worries about ssh(ji,jj+1,Kmm) - ssh(ji,jj ,Kmm) = 0, it won't happen ! here
732	zcpy(ji,jj) = ABS( (ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
733	& / (ssh(ji,jj+1,Kmm) - ssh(ji,jj ,Kmm)) )
734	ELSE
735	zcpy(ji,jj) = 0._wp
736	END IF
737	END DO
738	END DO
739	CALL lbc_lnk_multi( 'dynhpg', zcpx, 'U', 1., zcpy, 'V', 1. )
740	END IF
741
742	IF( kt == nit000 ) THEN
743	IF(lwp) WRITE(numout,*)
744	IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
745	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, density Jacobian with cubic polynomial scheme'
746	ENDIF
747
748	! Local constant initialization
749	zcoef0 = - grav * 0.5_wp
750	z1_10 = 1._wp / 10._wp
751	z1_12 = 1._wp / 12._wp
752
753	!----------------------------------------------------------------------------------------
754	! compute and store in provisional arrays elementary vertical and horizontal differences
755	!----------------------------------------------------------------------------------------
756
757	!!bug gm Not a true bug, but... dzz=e3w for dzx, dzy verify what it is really
758
759	DO jk = 2, jpkm1
760	DO jj = 2, jpjm1
761	DO ji = fs_2, fs_jpim1 ! vector opt.
762	drhoz(ji,jj,jk) = rhd (ji ,jj ,jk) - rhd (ji,jj,jk-1)
763	dzz (ji,jj,jk) = gde3w(ji ,jj ,jk) - gde3w(ji,jj,jk-1)
764	drhox(ji,jj,jk) = rhd (ji+1,jj ,jk) - rhd (ji,jj,jk )
765	dzx (ji,jj,jk) = gde3w(ji+1,jj ,jk) - gde3w(ji,jj,jk )
766	drhoy(ji,jj,jk) = rhd (ji ,jj+1,jk) - rhd (ji,jj,jk )
767	dzy (ji,jj,jk) = gde3w(ji ,jj+1,jk) - gde3w(ji,jj,jk )
768	END DO
769	END DO
770	END DO
771
772	!-------------------------------------------------------------------------
773	! compute harmonic averages using eq. 5.18
774	!-------------------------------------------------------------------------
775	zep = 1.e-15
776
777	!!bug gm drhoz not defined at level 1 and used (jk-1 with jk=2)
778	!!bug gm idem for drhox, drhoy et ji=jpi and jj=jpj
779
780	DO jk = 2, jpkm1
781	DO jj = 2, jpjm1
782	DO ji = fs_2, fs_jpim1 ! vector opt.
783	cffw = 2._wp * drhoz(ji ,jj ,jk) * drhoz(ji,jj,jk-1)
784
785	cffu = 2._wp * drhox(ji+1,jj ,jk) * drhox(ji,jj,jk )
786	cffx = 2._wp * dzx (ji+1,jj ,jk) * dzx (ji,jj,jk )
787
788	cffv = 2._wp * drhoy(ji ,jj+1,jk) * drhoy(ji,jj,jk )
789	cffy = 2._wp * dzy (ji ,jj+1,jk) * dzy (ji,jj,jk )
790
791	IF( cffw > zep) THEN
792	drhow(ji,jj,jk) = 2._wp * drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1) &
793	& / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
794	ELSE
795	drhow(ji,jj,jk) = 0._wp
796	ENDIF
797
798	dzw(ji,jj,jk) = 2._wp * dzz(ji,jj,jk) * dzz(ji,jj,jk-1) &
799	& / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
800
801	IF( cffu > zep ) THEN
802	drhou(ji,jj,jk) = 2._wp * drhox(ji+1,jj,jk) * drhox(ji,jj,jk) &
803	& / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
804	ELSE
805	drhou(ji,jj,jk ) = 0._wp
806	ENDIF
807
808	IF( cffx > zep ) THEN
809	dzu(ji,jj,jk) = 2._wp * dzx(ji+1,jj,jk) * dzx(ji,jj,jk) &
810	& / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
811	ELSE
812	dzu(ji,jj,jk) = 0._wp
813	ENDIF
814
815	IF( cffv > zep ) THEN
816	drhov(ji,jj,jk) = 2._wp * drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk) &
817	& / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
818	ELSE
819	drhov(ji,jj,jk) = 0._wp
820	ENDIF
821
822	IF( cffy > zep ) THEN
823	dzv(ji,jj,jk) = 2._wp * dzy(ji,jj+1,jk) * dzy(ji,jj,jk) &
824	& / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
825	ELSE
826	dzv(ji,jj,jk) = 0._wp
827	ENDIF
828
829	END DO
830	END DO
831	END DO
832
833	!----------------------------------------------------------------------------------
834	! apply boundary conditions at top and bottom using 5.36-5.37
835	!----------------------------------------------------------------------------------
836	drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:, 1 ) ) - 0.5_wp * drhow(:,:, 2 )
837	drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:, 1 ) ) - 0.5_wp * drhou(:,:, 2 )
838	drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:, 1 ) ) - 0.5_wp * drhov(:,:, 2 )
839
840	drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
841	drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
842	drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
843
844
845	!--------------------------------------------------------------
846	! Upper half of top-most grid box, compute and store
847	!-------------------------------------------------------------
848
849	!!bug gm : e3w-gde3w = 0.5*e3w .... and gde3w(2)-gde3w(1)=e3w(2) .... to be verified
850	! true if gde3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
851
852	DO jj = 2, jpjm1
853	DO ji = fs_2, fs_jpim1 ! vector opt.
854	rho_k(ji,jj,1) = -grav * ( e3w(ji,jj,1,Kmm) - gde3w(ji,jj,1) ) &
855	& * ( rhd(ji,jj,1) &
856	& + 0.5_wp * ( rhd (ji,jj,2) - rhd (ji,jj,1) ) &
857	& * ( e3w (ji,jj,1,Kmm) - gde3w(ji,jj,1) ) &
858	& / ( gde3w(ji,jj,2) - gde3w(ji,jj,1) ) )
859	END DO
860	END DO
861
862	!!bug gm : here also, simplification is possible
863	!!bug gm : optimisation: 1/10 and 1/12 the division should be done before the loop
864
865	DO jk = 2, jpkm1
866	DO jj = 2, jpjm1
867	DO ji = fs_2, fs_jpim1 ! vector opt.
868
869	rho_k(ji,jj,jk) = zcoef0 * ( rhd (ji,jj,jk) + rhd (ji,jj,jk-1) ) &
870	& * ( gde3w(ji,jj,jk) - gde3w(ji,jj,jk-1) ) &
871	& - grav * z1_10 * ( &
872	& ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) ) &
873	& * ( gde3w(ji,jj,jk) - gde3w(ji,jj,jk-1) - z1_12 * ( dzw (ji,jj,jk) + dzw (ji,jj,jk-1) ) ) &
874	& - ( dzw (ji,jj,jk) - dzw (ji,jj,jk-1) ) &
875	& * ( rhd (ji,jj,jk) - rhd (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) ) &
876	& )
877
878	rho_i(ji,jj,jk) = zcoef0 * ( rhd (ji+1,jj,jk) + rhd (ji,jj,jk) ) &
879	& * ( gde3w(ji+1,jj,jk) - gde3w(ji,jj,jk) ) &
880	& - grav* z1_10 * ( &
881	& ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) ) &
882	& * ( gde3w(ji+1,jj,jk) - gde3w(ji,jj,jk) - z1_12 * ( dzu (ji+1,jj,jk) + dzu (ji,jj,jk) ) ) &
883	& - ( dzu (ji+1,jj,jk) - dzu (ji,jj,jk) ) &
884	& * ( rhd (ji+1,jj,jk) - rhd (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) ) &
885	& )
886
887	rho_j(ji,jj,jk) = zcoef0 * ( rhd (ji,jj+1,jk) + rhd (ji,jj,jk) ) &
888	& * ( gde3w(ji,jj+1,jk) - gde3w(ji,jj,jk) ) &
889	& - grav* z1_10 * ( &
890	& ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) ) &
891	& * ( gde3w(ji,jj+1,jk) - gde3w(ji,jj,jk) - z1_12 * ( dzv (ji,jj+1,jk) + dzv (ji,jj,jk) ) ) &
892	& - ( dzv (ji,jj+1,jk) - dzv (ji,jj,jk) ) &
893	& * ( rhd (ji,jj+1,jk) - rhd (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) ) &
894	& )
895
896	END DO
897	END DO
898	END DO
899	CALL lbc_lnk_multi( 'dynhpg', rho_k, 'W', 1., rho_i, 'U', 1., rho_j, 'V', 1. )
900
901	! ---------------
902	! Surface value
903	! ---------------
904	DO jj = 2, jpjm1
905	DO ji = fs_2, fs_jpim1 ! vector opt.
906	zhpi(ji,jj,1) = ( rho_k(ji+1,jj ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) * r1_e1u(ji,jj)
907	zhpj(ji,jj,1) = ( rho_k(ji ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) * r1_e2v(ji,jj)
908	IF( ln_wd_il ) THEN
909	zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
910	zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj)
911	ENDIF
912	! add to the general momentum trend
913	puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj,1)
914	pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj,1)
915	END DO
916	END DO
917
918	! ----------------
919	! interior value (2=<jk=<jpkm1)
920	! ----------------
921	DO jk = 2, jpkm1
922	DO jj = 2, jpjm1
923	DO ji = fs_2, fs_jpim1 ! vector opt.
924	! hydrostatic pressure gradient along s-surfaces
925	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
926	& + ( ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk ) ) &
927	& - ( rho_i(ji ,jj,jk) - rho_i(ji,jj,jk-1) ) ) * r1_e1u(ji,jj)
928	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
929	& + ( ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk ) ) &
930	& -( rho_j(ji,jj ,jk) - rho_j(ji,jj,jk-1) ) ) * r1_e2v(ji,jj)
931	IF( ln_wd_il ) THEN
932	zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
933	zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj)
934	ENDIF
935	! add to the general momentum trend
936	puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj,jk)
937	pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj,jk)
938	END DO
939	END DO
940	END DO
941	!
942	IF( ln_wd_il ) DEALLOCATE( zcpx, zcpy )
943	!
944	END SUBROUTINE hpg_djc
945
946
947	SUBROUTINE hpg_prj( kt, Kmm, puu, pvv, Krhs )
948	!!---------------------------------------------------------------------
949	!! * ROUTINE hpg_prj *
950	!!
951	!! ** Method : s-coordinate case.
952	!! A Pressure-Jacobian horizontal pressure gradient method
953	!! based on the constrained cubic-spline interpolation for
954	!! all vertical coordinate systems
955	!!
956	!! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
957	!!----------------------------------------------------------------------
958	INTEGER, PARAMETER :: polynomial_type = 1 ! 1: cubic spline, 2: linear
959	INTEGER , INTENT( in ) :: kt ! ocean time-step index
960	INTEGER , INTENT( in ) :: Kmm, Krhs ! ocean time level indices
961	REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation
962	!!
963	INTEGER :: ji, jj, jk, jkk ! dummy loop indices
964	REAL(wp) :: zcoef0, znad ! local scalars
965	!
966	!! The local variables for the correction term
967	INTEGER :: jk1, jis, jid, jjs, jjd
968	LOGICAL :: ll_tmp1, ll_tmp2 ! local logical variables
969	REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
970	REAL(wp) :: zrhdt1
971	REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
972	REAL(wp), DIMENSION(jpi,jpj,jpk) :: zdept, zrhh
973	REAL(wp), DIMENSION(jpi,jpj,jpk) :: zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
974	REAL(wp), DIMENSION(jpi,jpj) :: zsshu_n, zsshv_n
975	REAL(wp), DIMENSION(:,:), ALLOCATABLE :: zcpx, zcpy !W/D pressure filter
976	!!----------------------------------------------------------------------
977	!
978	IF( kt == nit000 ) THEN
979	IF(lwp) WRITE(numout,*)
980	IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
981	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, cubic spline pressure Jacobian'
982	ENDIF
983
984	! Local constant initialization
985	zcoef0 = - grav
986	znad = 1._wp
987	IF( ln_linssh ) znad = 0._wp
988
989	IF( ln_wd_il ) THEN
990	ALLOCATE( zcpx(jpi,jpj) , zcpy(jpi,jpj) )
991	DO jj = 2, jpjm1
992	DO ji = 2, jpim1
993	ll_tmp1 = MIN( ssh(ji,jj,Kmm) , ssh(ji+1,jj,Kmm) ) > &
994	& MAX( -ht_0(ji,jj) , -ht_0(ji+1,jj) ) .AND. &
995	& MAX( ssh(ji,jj,Kmm) + ht_0(ji,jj), ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) ) &
996	& > rn_wdmin1 + rn_wdmin2
997	ll_tmp2 = ( ABS( ssh(ji,jj,Kmm) - ssh(ji+1,jj,Kmm) ) > 1.E-12 ) .AND. ( &
998	& MAX( ssh(ji,jj,Kmm) , ssh(ji+1,jj,Kmm) ) > &
999	& MAX( -ht_0(ji,jj) , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
1000
1001	IF(ll_tmp1) THEN
1002	zcpx(ji,jj) = 1.0_wp
1003	ELSE IF(ll_tmp2) THEN
1004	! no worries about ssh(ji+1,jj,Kmm) - ssh(ji ,jj,Kmm) = 0, it won't happen ! here
1005	zcpx(ji,jj) = ABS( (ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
1006	& / (ssh(ji+1,jj,Kmm) - ssh(ji ,jj,Kmm)) )
1007
1008	zcpx(ji,jj) = max(min( zcpx(ji,jj) , 1.0_wp),0.0_wp)
1009	ELSE
1010	zcpx(ji,jj) = 0._wp
1011	END IF
1012
1013	ll_tmp1 = MIN( ssh(ji,jj,Kmm) , ssh(ji,jj+1,Kmm) ) > &
1014	& MAX( -ht_0(ji,jj) , -ht_0(ji,jj+1) ) .AND. &
1015	& MAX( ssh(ji,jj,Kmm) + ht_0(ji,jj), ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) ) &
1016	& > rn_wdmin1 + rn_wdmin2
1017	ll_tmp2 = ( ABS( ssh(ji,jj,Kmm) - ssh(ji,jj+1,Kmm) ) > 1.E-12 ) .AND. ( &
1018	& MAX( ssh(ji,jj,Kmm) , ssh(ji,jj+1,Kmm) ) > &
1019	& MAX( -ht_0(ji,jj) , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
1020
1021	IF(ll_tmp1) THEN
1022	zcpy(ji,jj) = 1.0_wp
1023	ELSE IF(ll_tmp2) THEN
1024	! no worries about ssh(ji,jj+1,Kmm) - ssh(ji,jj ,Kmm) = 0, it won't happen ! here
1025	zcpy(ji,jj) = ABS( (ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
1026	& / (ssh(ji,jj+1,Kmm) - ssh(ji,jj ,Kmm)) )
1027	zcpy(ji,jj) = max(min( zcpy(ji,jj) , 1.0_wp),0.0_wp)
1028
1029	ELSE
1030	zcpy(ji,jj) = 0._wp
1031	ENDIF
1032	END DO
1033	END DO
1034	CALL lbc_lnk_multi( 'dynhpg', zcpx, 'U', 1., zcpy, 'V', 1. )
1035	ENDIF
1036
1037	! Clean 3-D work arrays
1038	zhpi(:,:,:) = 0._wp
1039	zrhh(:,:,:) = rhd(:,:,:)
1040
1041	! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
1042	DO jj = 1, jpj
1043	DO ji = 1, jpi
1044	jk = mbkt(ji,jj)+1
1045	IF( jk <= 0 ) THEN ; zrhh(ji,jj, : ) = 0._wp
1046	ELSEIF( jk == 1 ) THEN ; zrhh(ji,jj,jk+1:jpk) = rhd(ji,jj,jk)
1047	ELSEIF( jk < jpkm1 ) THEN
1048	DO jkk = jk+1, jpk
1049	zrhh(ji,jj,jkk) = interp1(gde3w(ji,jj,jkk ), gde3w(ji,jj,jkk-1), &
1050	& gde3w(ji,jj,jkk-2), rhd (ji,jj,jkk-1), rhd(ji,jj,jkk-2))
1051	END DO
1052	ENDIF
1053	END DO
1054	END DO
1055
1056	! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
1057	DO jj = 1, jpj
1058	DO ji = 1, jpi
1059	zdept(ji,jj,1) = 0.5_wp * e3w(ji,jj,1,Kmm) - ssh(ji,jj,Kmm) * znad
1060	END DO
1061	END DO
1062
1063	DO jk = 2, jpk
1064	DO jj = 1, jpj
1065	DO ji = 1, jpi
1066	zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + e3w(ji,jj,jk,Kmm)
1067	END DO
1068	END DO
1069	END DO
1070
1071	fsp(:,:,:) = zrhh (:,:,:)
1072	xsp(:,:,:) = zdept(:,:,:)
1073
1074	! Construct the vertical density profile with the
1075	! constrained cubic spline interpolation
1076	! rho(z) = asp + bspz + cspz^2 + dsp*z^3
1077	CALL cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1078
1079	! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
1080	DO jj = 2, jpj
1081	DO ji = 2, jpi
1082	zrhdt1 = zrhh(ji,jj,1) - interp3( zdept(ji,jj,1), asp(ji,jj,1), bsp(ji,jj,1), &
1083	& csp(ji,jj,1), dsp(ji,jj,1) ) * 0.25_wp * e3w(ji,jj,1,Kmm)
1084
1085	! assuming linear profile across the top half surface layer
1086	zhpi(ji,jj,1) = 0.5_wp * e3w(ji,jj,1,Kmm) * zrhdt1
1087	END DO
1088	END DO
1089
1090	! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1091	DO jk = 2, jpkm1
1092	DO jj = 2, jpj
1093	DO ji = 2, jpi
1094	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + &
1095	& integ_spline( zdept(ji,jj,jk-1), zdept(ji,jj,jk), &
1096	& asp (ji,jj,jk-1), bsp (ji,jj,jk-1), &
1097	& csp (ji,jj,jk-1), dsp (ji,jj,jk-1) )
1098	END DO
1099	END DO
1100	END DO
1101
1102	! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1103
1104	! Prepare zsshu_n and zsshv_n
1105	DO jj = 2, jpjm1
1106	DO ji = 2, jpim1
1107	!!gm BUG ? if it is ssh at u- & v-point then it should be:
1108	! zsshu_n(ji,jj) = (e1e2t(ji,jj) * ssh(ji,jj,Kmm) + e1e2t(ji+1,jj) * ssh(ji+1,jj,Kmm)) * &
1109	! & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp
1110	! zsshv_n(ji,jj) = (e1e2t(ji,jj) * ssh(ji,jj,Kmm) + e1e2t(ji,jj+1) * ssh(ji,jj+1,Kmm)) * &
1111	! & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp
1112	!!gm not this:
1113	zsshu_n(ji,jj) = (e1e2u(ji,jj) * ssh(ji,jj,Kmm) + e1e2u(ji+1, jj) * ssh(ji+1,jj,Kmm)) * &
1114	& r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp
1115	zsshv_n(ji,jj) = (e1e2v(ji,jj) * ssh(ji,jj,Kmm) + e1e2v(ji+1, jj) * ssh(ji,jj+1,Kmm)) * &
1116	& r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp
1117	END DO
1118	END DO
1119
1120	CALL lbc_lnk_multi ('dynhpg', zsshu_n, 'U', 1., zsshv_n, 'V', 1. )
1121
1122	DO jj = 2, jpjm1
1123	DO ji = 2, jpim1
1124	zu(ji,jj,1) = - ( e3u(ji,jj,1,Kmm) - zsshu_n(ji,jj) * znad)
1125	zv(ji,jj,1) = - ( e3v(ji,jj,1,Kmm) - zsshv_n(ji,jj) * znad)
1126	END DO
1127	END DO
1128
1129	DO jk = 2, jpkm1
1130	DO jj = 2, jpjm1
1131	DO ji = 2, jpim1
1132	zu(ji,jj,jk) = zu(ji,jj,jk-1) - e3u(ji,jj,jk,Kmm)
1133	zv(ji,jj,jk) = zv(ji,jj,jk-1) - e3v(ji,jj,jk,Kmm)
1134	END DO
1135	END DO
1136	END DO
1137
1138	DO jk = 1, jpkm1
1139	DO jj = 2, jpjm1
1140	DO ji = 2, jpim1
1141	zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * e3u(ji,jj,jk,Kmm)
1142	zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * e3v(ji,jj,jk,Kmm)
1143	END DO
1144	END DO
1145	END DO
1146
1147	DO jk = 1, jpkm1
1148	DO jj = 2, jpjm1
1149	DO ji = 2, jpim1
1150	zu(ji,jj,jk) = MIN( zu(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) ) )
1151	zu(ji,jj,jk) = MAX( zu(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) ) )
1152	zv(ji,jj,jk) = MIN( zv(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) ) )
1153	zv(ji,jj,jk) = MAX( zv(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) ) )
1154	END DO
1155	END DO
1156	END DO
1157
1158
1159	DO jk = 1, jpkm1
1160	DO jj = 2, jpjm1
1161	DO ji = 2, jpim1
1162	zpwes = 0._wp; zpwed = 0._wp
1163	zpnss = 0._wp; zpnsd = 0._wp
1164	zuijk = zu(ji,jj,jk)
1165	zvijk = zv(ji,jj,jk)
1166
1167	!!!!! for u equation
1168	IF( jk <= mbku(ji,jj) ) THEN
1169	IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1170	jis = ji + 1; jid = ji
1171	ELSE
1172	jis = ji; jid = ji +1
1173	ENDIF
1174
1175	! integrate the pressure on the shallow side
1176	jk1 = jk
1177	DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1178	IF( jk1 == mbku(ji,jj) ) THEN
1179	zuijk = -zdept(jis,jj,jk1)
1180	EXIT
1181	ENDIF
1182	zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1183	zpwes = zpwes + &
1184	integ_spline(zdept(jis,jj,jk1), zdeps, &
1185	asp(jis,jj,jk1), bsp(jis,jj,jk1), &
1186	csp(jis,jj,jk1), dsp(jis,jj,jk1))
1187	jk1 = jk1 + 1
1188	END DO
1189
1190	! integrate the pressure on the deep side
1191	jk1 = jk
1192	DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1193	IF( jk1 == 1 ) THEN
1194	zdeps = zdept(jid,jj,1) + MIN(zuijk, ssh(jid,jj,Kmm)*znad)
1195	zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1196	bsp(jid,jj,1), csp(jid,jj,1), &
1197	dsp(jid,jj,1)) * zdeps
1198	zpwed = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1199	EXIT
1200	ENDIF
1201	zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1202	zpwed = zpwed + &
1203	integ_spline(zdeps, zdept(jid,jj,jk1), &
1204	asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1), &
1205	csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1206	jk1 = jk1 - 1
1207	END DO
1208
1209	! update the momentum trends in u direction
1210
1211	zdpdx1 = zcoef0 * r1_e1u(ji,jj) * ( zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk) )
1212	IF( .NOT.ln_linssh ) THEN
1213	zdpdx2 = zcoef0 * r1_e1u(ji,jj) * &
1214	& ( REAL(jis-jid, wp) * (zpwes + zpwed) + (ssh(ji+1,jj,Kmm)-ssh(ji,jj,Kmm)) )
1215	ELSE
1216	zdpdx2 = zcoef0 * r1_e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1217	ENDIF
1218	IF( ln_wd_il ) THEN
1219	zdpdx1 = zdpdx1 * zcpx(ji,jj) * wdrampu(ji,jj)
1220	zdpdx2 = zdpdx2 * zcpx(ji,jj) * wdrampu(ji,jj)
1221	ENDIF
1222	puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + (zdpdx1 + zdpdx2) * umask(ji,jj,jk)
1223	ENDIF
1224
1225	!!!!! for v equation
1226	IF( jk <= mbkv(ji,jj) ) THEN
1227	IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1228	jjs = jj + 1; jjd = jj
1229	ELSE
1230	jjs = jj ; jjd = jj + 1
1231	ENDIF
1232
1233	! integrate the pressure on the shallow side
1234	jk1 = jk
1235	DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1236	IF( jk1 == mbkv(ji,jj) ) THEN
1237	zvijk = -zdept(ji,jjs,jk1)
1238	EXIT
1239	ENDIF
1240	zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1241	zpnss = zpnss + &
1242	integ_spline(zdept(ji,jjs,jk1), zdeps, &
1243	asp(ji,jjs,jk1), bsp(ji,jjs,jk1), &
1244	csp(ji,jjs,jk1), dsp(ji,jjs,jk1) )
1245	jk1 = jk1 + 1
1246	END DO
1247
1248	! integrate the pressure on the deep side
1249	jk1 = jk
1250	DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1251	IF( jk1 == 1 ) THEN
1252	zdeps = zdept(ji,jjd,1) + MIN(zvijk, ssh(ji,jjd,Kmm)*znad)
1253	zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1254	bsp(ji,jjd,1), csp(ji,jjd,1), &
1255	dsp(ji,jjd,1) ) * zdeps
1256	zpnsd = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1257	EXIT
1258	ENDIF
1259	zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1260	zpnsd = zpnsd + &
1261	integ_spline(zdeps, zdept(ji,jjd,jk1), &
1262	asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1263	csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1264	jk1 = jk1 - 1
1265	END DO
1266
1267
1268	! update the momentum trends in v direction
1269
1270	zdpdy1 = zcoef0 * r1_e2v(ji,jj) * ( zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk) )
1271	IF( .NOT.ln_linssh ) THEN
1272	zdpdy2 = zcoef0 * r1_e2v(ji,jj) * &
1273	( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (ssh(ji,jj+1,Kmm)-ssh(ji,jj,Kmm)) )
1274	ELSE
1275	zdpdy2 = zcoef0 * r1_e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1276	ENDIF
1277	IF( ln_wd_il ) THEN
1278	zdpdy1 = zdpdy1 * zcpy(ji,jj) * wdrampv(ji,jj)
1279	zdpdy2 = zdpdy2 * zcpy(ji,jj) * wdrampv(ji,jj)
1280	ENDIF
1281
1282	pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + (zdpdy1 + zdpdy2) * vmask(ji,jj,jk)
1283	ENDIF
1284	!
1285	END DO
1286	END DO
1287	END DO
1288	!
1289	IF( ln_wd_il ) DEALLOCATE( zcpx, zcpy )
1290	!
1291	END SUBROUTINE hpg_prj
1292
1293
1294	SUBROUTINE cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1295	!!----------------------------------------------------------------------
1296	!! * ROUTINE cspline *
1297	!!
1298	!! ** Purpose : constrained cubic spline interpolation
1299	!!
1300	!! ** Method : f(x) = asp + bspx + cspx^2 + dsp*x^3
1301	!!
1302	!! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1303	!!----------------------------------------------------------------------
1304	REAL(wp), DIMENSION(:,:,:), INTENT(in ) :: fsp, xsp ! value and coordinate
1305	REAL(wp), DIMENSION(:,:,:), INTENT( out) :: asp, bsp, csp, dsp ! coefficients of the interpoated function
1306	INTEGER , INTENT(in ) :: polynomial_type ! 1: cubic spline ; 2: Linear
1307	!
1308	INTEGER :: ji, jj, jk ! dummy loop indices
1309	INTEGER :: jpi, jpj, jpkm1
1310	REAL(wp) :: zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1311	REAL(wp) :: zdxtmp1, zdxtmp2, zalpha
1312	REAL(wp) :: zdf(size(fsp,3))
1313	!!----------------------------------------------------------------------
1314	!
1315	!!gm WHAT !!!!! THIS IS VERY DANGEROUS !!!!!
1316	jpi = size(fsp,1)
1317	jpj = size(fsp,2)
1318	jpkm1 = MAX( 1, size(fsp,3) - 1 )
1319	!
1320	IF (polynomial_type == 1) THEN ! Constrained Cubic Spline
1321	DO ji = 1, jpi
1322	DO jj = 1, jpj
1323	!!Fritsch&Butland's method, 1984 (preferred, but more computation)
1324	! DO jk = 2, jpkm1-1
1325	! zdxtmp1 = xsp(ji,jj,jk) - xsp(ji,jj,jk-1)
1326	! zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1327	! zdf1 = ( fsp(ji,jj,jk) - fsp(ji,jj,jk-1) ) / zdxtmp1
1328	! zdf2 = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp2
1329	!
1330	! zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1331	!
1332	! IF(zdf1 * zdf2 <= 0._wp) THEN
1333	! zdf(jk) = 0._wp
1334	! ELSE
1335	! zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1336	! ENDIF
1337	! END DO
1338
1339	!!Simply geometric average
1340	DO jk = 2, jpkm1-1
1341	zdf1 = (fsp(ji,jj,jk ) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk ) - xsp(ji,jj,jk-1))
1342	zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk )) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk ))
1343
1344	IF(zdf1 * zdf2 <= 0._wp) THEN
1345	zdf(jk) = 0._wp
1346	ELSE
1347	zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1348	ENDIF
1349	END DO
1350
1351	zdf(1) = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1352	& ( xsp(ji,jj,2) - xsp(ji,jj,1) ) - 0.5_wp * zdf(2)
1353	zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1354	& ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - 0.5_wp * zdf(jpkm1 - 1)
1355
1356	DO jk = 1, jpkm1 - 1
1357	zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1358	ztmp1 = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1359	ztmp2 = 6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1360	zddf1 = -2._wp * ztmp1 + ztmp2
1361	ztmp1 = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1362	zddf2 = 2._wp * ztmp1 - ztmp2
1363
1364	dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1365	csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1366	bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1367	& csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1368	& dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1369	& xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1370	asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1371	& (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1372	& dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1373	END DO
1374	END DO
1375	END DO
1376
1377	ELSEIF ( polynomial_type == 2 ) THEN ! Linear
1378	DO ji = 1, jpi
1379	DO jj = 1, jpj
1380	DO jk = 1, jpkm1-1
1381	zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1382	ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1383
1384	dsp(ji,jj,jk) = 0._wp
1385	csp(ji,jj,jk) = 0._wp
1386	bsp(ji,jj,jk) = ztmp1 / zdxtmp
1387	asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1388	END DO
1389	END DO
1390	END DO
1391	!
1392	ELSE
1393	CALL ctl_stop( 'invalid polynomial type in cspline' )
1394	ENDIF
1395	!
1396	END SUBROUTINE cspline
1397
1398
1399	FUNCTION interp1(x, xl, xr, fl, fr) RESULT(f)
1400	!!----------------------------------------------------------------------
1401	!! * ROUTINE interp1 *
1402	!!
1403	!! ** Purpose : 1-d linear interpolation
1404	!!
1405	!! ** Method : interpolation is straight forward
1406	!! extrapolation is also permitted (no value limit)
1407	!!----------------------------------------------------------------------
1408	REAL(wp), INTENT(in) :: x, xl, xr, fl, fr
1409	REAL(wp) :: f ! result of the interpolation (extrapolation)
1410	REAL(wp) :: zdeltx
1411	!!----------------------------------------------------------------------
1412	!
1413	zdeltx = xr - xl
1414	IF( abs(zdeltx) <= 10._wp * EPSILON(x) ) THEN
1415	f = 0.5_wp * (fl + fr)
1416	ELSE
1417	f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1418	ENDIF
1419	!
1420	END FUNCTION interp1
1421
1422
1423	FUNCTION interp2( x, a, b, c, d ) RESULT(f)
1424	!!----------------------------------------------------------------------
1425	!! * ROUTINE interp1 *
1426	!!
1427	!! ** Purpose : 1-d constrained cubic spline interpolation
1428	!!
1429	!! ** Method : cubic spline interpolation
1430	!!
1431	!!----------------------------------------------------------------------
1432	REAL(wp), INTENT(in) :: x, a, b, c, d
1433	REAL(wp) :: f ! value from the interpolation
1434	!!----------------------------------------------------------------------
1435	!
1436	f = a + x* ( b + x * ( c + d * x ) )
1437	!
1438	END FUNCTION interp2
1439
1440
1441	FUNCTION interp3( x, a, b, c, d ) RESULT(f)
1442	!!----------------------------------------------------------------------
1443	!! * ROUTINE interp1 *
1444	!!
1445	!! ** Purpose : Calculate the first order of derivative of
1446	!! a cubic spline function y=a+bx+cx^2+d*x^3
1447	!!
1448	!! ** Method : f=dy/dx=b+2cx+3dx^2
1449	!!
1450	!!----------------------------------------------------------------------
1451	REAL(wp), INTENT(in) :: x, a, b, c, d
1452	REAL(wp) :: f ! value from the interpolation
1453	!!----------------------------------------------------------------------
1454	!
1455	f = b + x * ( 2._wp * c + 3._wp * d * x)
1456	!
1457	END FUNCTION interp3
1458
1459
1460	FUNCTION integ_spline( xl, xr, a, b, c, d ) RESULT(f)
1461	!!----------------------------------------------------------------------
1462	!! * ROUTINE interp1 *
1463	!!
1464	!! ** Purpose : 1-d constrained cubic spline integration
1465	!!
1466	!! ** Method : integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1467	!!
1468	!!----------------------------------------------------------------------
1469	REAL(wp), INTENT(in) :: xl, xr, a, b, c, d
1470	REAL(wp) :: za1, za2, za3
1471	REAL(wp) :: f ! integration result
1472	!!----------------------------------------------------------------------
1473	!
1474	za1 = 0.5_wp * b
1475	za2 = c / 3.0_wp
1476	za3 = 0.25_wp * d
1477	!
1478	f = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1479	& xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1480	!
1481	END FUNCTION integ_spline
1482
1483	!!======================================================================
1484	END MODULE dynhpg
1485

Note: See TracBrowser for help on using the repository browser.

Download in other formats: