New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
obs_readmdt.F90 in NEMO/branches/2019/dev_r11943_MERGE_2019/src/OCE/OBS – NEMO

source: NEMO/branches/2019/dev_r11943_MERGE_2019/src/OCE/OBS/obs_readmdt.F90 @ 11949

Last change on this file since 11949 was 11949, checked in by acc, 4 years ago

Merge in changes from 2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps. This just creates a fresh copy of this branch to use as the merge base. See ticket #2341

  • Property svn:keywords set to Id
File size: 9.9 KB
Line 
1MODULE obs_readmdt
2   !!======================================================================
3   !!                       ***  MODULE obs_readmdt  ***
4   !! Observation diagnostics: Read the MDT for SLA data (skeleton for now)
5   !!======================================================================
6   !! History :      ! 2007-03 (K. Mogensen) Initial skeleton version
7   !!                ! 2007-04 (E. Remy) migration and improvement from OPAVAR
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   obs_rea_mdt    : Driver for reading MDT
12   !!   obs_offset_mdt : Remove the offset between the model MDT and the used one
13   !!----------------------------------------------------------------------
14   USE par_kind         ! Precision variables
15   USE par_oce          ! Domain parameters
16   USE in_out_manager   ! I/O manager
17   USE obs_surf_def     ! Surface observation definitions
18   USE obs_inter_sup    ! Interpolation support routines
19   USE obs_inter_h2d    ! 2D interpolation
20   USE obs_utils        ! Various observation tools
21   USE iom_nf90         ! IOM NetCDF
22   USE netcdf           ! NetCDF library
23   USE lib_mpp          ! MPP library
24   USE dom_oce, ONLY : &                  ! Domain variables
25      &                    tmask, tmask_i, e1e2t, gphit, glamt
26   USE obs_const, ONLY :   obfillflt      ! Fillvalue
27   USE oce      , ONLY :   ssh            ! Model variables
28
29   IMPLICIT NONE
30   PRIVATE
31   
32   PUBLIC   obs_rea_mdt     ! called by dia_obs_init
33   PUBLIC   obs_offset_mdt  ! called by obs_rea_mdt
34
35   INTEGER , PUBLIC :: nn_msshc    = 1         ! MDT correction scheme
36   REAL(wp), PUBLIC :: rn_mdtcorr   = 1.61_wp  ! User specified MDT correction
37   REAL(wp), PUBLIC :: rn_mdtcutoff = 65.0_wp  ! MDT cutoff for computed correction
38
39   !!----------------------------------------------------------------------
40   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
41   !! $Id$
42   !! Software governed by the CeCILL license (see ./LICENSE)
43   !!----------------------------------------------------------------------
44CONTAINS
45
46   SUBROUTINE obs_rea_mdt( sladata, k2dint, Kmm )
47      !!---------------------------------------------------------------------
48      !!
49      !!                   *** ROUTINE obs_rea_mdt ***
50      !!
51      !! ** Purpose : Read from file the MDT data (skeleton)
52      !!
53      !! ** Method  :
54      !!
55      !! ** Action  :
56      !!----------------------------------------------------------------------
57      USE iom
58      !
59      TYPE(obs_surf), INTENT(inout) ::   sladata   ! SLA data
60      INTEGER       , INTENT(in)    ::   k2dint    ! ?
61      INTEGER       , INTENT(in)    ::   Kmm       ! ?
62      !
63      CHARACTER(LEN=12), PARAMETER ::   cpname  = 'obs_rea_mdt'
64      CHARACTER(LEN=20), PARAMETER ::   mdtname = 'slaReferenceLevel.nc'
65
66      INTEGER ::   jobs                ! Obs loop variable
67      INTEGER ::   jpimdt, jpjmdt      ! Number of grid point in lat/lon for the MDT
68      INTEGER ::   iico, ijco          ! Grid point indicies
69      INTEGER ::   i_nx_id, i_ny_id, i_file_id, i_var_id, i_stat
70      INTEGER ::   nummdt
71      !
72      REAL(wp), DIMENSION(1)     ::   zext, zobsmask
73      REAL(wp), DIMENSION(2,2,1) ::   zweig
74      !
75      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   zmask, zmdtl, zglam, zgphi
76      INTEGER , DIMENSION(:,:,:), ALLOCATABLE ::   igrdi, igrdj
77      !
78      REAL(wp), DIMENSION(jpi,jpj) ::  z_mdt, mdtmask
79         
80      REAL(wp) :: zlam, zphi, zfill, zinfill    ! local scalar
81      !!----------------------------------------------------------------------
82
83      IF(lwp)WRITE(numout,*) 
84      IF(lwp)WRITE(numout,*) ' obs_rea_mdt : Read MDT for referencing altimeter anomalies'
85      IF(lwp)WRITE(numout,*) ' ------------- '
86      CALL FLUSH(numout)
87
88      CALL iom_open( mdtname, nummdt )       ! Open the file
89      !                                      ! Get the MDT data
90      CALL iom_get ( nummdt, jpdom_data, 'sossheig', z_mdt(:,:), 1 )
91      CALL iom_close(nummdt)                 ! Close the file
92     
93      ! Read in the fill value
94      zinfill = 0.0
95      i_stat = nf90_open( mdtname, nf90_nowrite, nummdt )
96      i_stat = nf90_inq_varid( nummdt, 'sossheig', i_var_id )
97      i_stat = nf90_get_att( nummdt, i_var_id, "_FillValue",zinfill)
98      zfill = zinfill
99      i_stat = nf90_close( nummdt )
100
101      ! setup mask based on tmask and MDT mask
102      ! set mask to 0 where the MDT is set to fillvalue
103      WHERE(z_mdt(:,:) /= zfill)   ;   mdtmask(:,:) = tmask(:,:,1)
104      ELSE WHERE                   ;   mdtmask(:,:) = 0
105      END WHERE
106
107      ! Remove the offset between the MDT used with the sla and the model MDT
108      IF( nn_msshc == 1 .OR. nn_msshc == 2 ) &
109         & CALL obs_offset_mdt( jpi, jpj, z_mdt, zfill, Kmm )
110
111      ! Intepolate the MDT already on the model grid at the observation point
112 
113      ALLOCATE( &
114         & igrdi(2,2,sladata%nsurf), &
115         & igrdj(2,2,sladata%nsurf), &
116         & zglam(2,2,sladata%nsurf), &
117         & zgphi(2,2,sladata%nsurf), &
118         & zmask(2,2,sladata%nsurf), &
119         & zmdtl(2,2,sladata%nsurf)  &
120         & )
121         
122      DO jobs = 1, sladata%nsurf
123
124         igrdi(1,1,jobs) = sladata%mi(jobs)-1
125         igrdj(1,1,jobs) = sladata%mj(jobs)-1
126         igrdi(1,2,jobs) = sladata%mi(jobs)-1
127         igrdj(1,2,jobs) = sladata%mj(jobs)
128         igrdi(2,1,jobs) = sladata%mi(jobs)
129         igrdj(2,1,jobs) = sladata%mj(jobs)-1
130         igrdi(2,2,jobs) = sladata%mi(jobs)
131         igrdj(2,2,jobs) = sladata%mj(jobs)
132
133      END DO
134
135      CALL obs_int_comm_2d( 2, 2, sladata%nsurf, jpi, jpj, igrdi, igrdj, glamt  , zglam )
136      CALL obs_int_comm_2d( 2, 2, sladata%nsurf, jpi, jpj, igrdi, igrdj, gphit  , zgphi )
137      CALL obs_int_comm_2d( 2, 2, sladata%nsurf, jpi, jpj, igrdi, igrdj, mdtmask, zmask )
138      CALL obs_int_comm_2d( 2, 2, sladata%nsurf, jpi, jpj, igrdi, igrdj, z_mdt  , zmdtl )
139
140      DO jobs = 1, sladata%nsurf
141           
142         zlam = sladata%rlam(jobs)
143         zphi = sladata%rphi(jobs)
144
145         CALL obs_int_h2d_init( 1, 1, k2dint, zlam, zphi,         &
146            &                   zglam(:,:,jobs), zgphi(:,:,jobs), &
147            &                   zmask(:,:,jobs), zweig, zobsmask )
148           
149         CALL obs_int_h2d( 1, 1, zweig, zmdtl(:,:,jobs),  zext )
150 
151         sladata%rext(jobs,2) = zext(1)
152
153! mark any masked data with a QC flag
154         IF( zobsmask(1) == 0 )   sladata%nqc(jobs) = IBSET(sladata%nqc(jobs),15)
155
156         END DO
157         
158      DEALLOCATE( &
159         & igrdi, &
160         & igrdj, &
161         & zglam, &
162         & zgphi, &
163         & zmask, &
164         & zmdtl  &
165         & )
166
167      IF(lwp)WRITE(numout,*) ' ------------- '
168      !
169   END SUBROUTINE obs_rea_mdt
170
171
172   SUBROUTINE obs_offset_mdt( kpi, kpj, mdt, zfill, Kmm )
173      !!---------------------------------------------------------------------
174      !!
175      !!                   *** ROUTINE obs_offset_mdt ***
176      !!
177      !! ** Purpose : Compute a correction term for the MDT on the model grid
178      !!             !!!!! IF it is on the model grid
179      !!
180      !! ** Method  : Compute the mean difference between the model and the
181      !!              used MDT and remove the offset.
182      !!
183      !! ** Action  :
184      !!----------------------------------------------------------------------
185      INTEGER, INTENT(IN) ::  kpi, kpj
186      INTEGER, INTENT(IN) ::  Kmm
187      REAL(wp), DIMENSION(kpi,kpj), INTENT(INOUT) ::   mdt     ! MDT used on the model grid
188      REAL(wp)                    , INTENT(IN   ) ::   zfill 
189      !
190      INTEGER  :: ji, jj
191      REAL(wp) :: zdxdy, zarea, zeta1, zeta2, zcorr_mdt, zcorr_bcketa, zcorr     ! local scalar
192      REAL(wp), DIMENSION(jpi,jpj) :: zpromsk
193      CHARACTER(LEN=14), PARAMETER ::   cpname = 'obs_offset_mdt'
194      !!----------------------------------------------------------------------
195
196      !  Initialize the local mask, for domain projection
197      !  Also exclude mdt points which are set to missing data
198
199      DO ji = 1, jpi
200        DO jj = 1, jpj
201           zpromsk(ji,jj) = tmask_i(ji,jj)
202           IF (    ( gphit(ji,jj) .GT.  rn_mdtcutoff ) &
203              &.OR.( gphit(ji,jj) .LT. -rn_mdtcutoff ) &
204              &.OR.( mdt(ji,jj) .EQ. zfill ) ) &
205              &        zpromsk(ji,jj) = 0.0
206        END DO
207      END DO 
208
209      ! Compute MSSH mean over [0,360] x [-rn_mdtcutoff,rn_mdtcutoff]
210
211      zarea = 0.0
212      zeta1 = 0.0
213      zeta2 = 0.0
214
215      DO jj = 1, jpj
216         DO ji = 1, jpi
217          zdxdy = e1e2t(ji,jj) * zpromsk(ji,jj)
218          zarea = zarea + zdxdy
219          zeta1 = zeta1 + mdt(ji,jj) * zdxdy
220          zeta2 = zeta2 + ssh(ji,jj,Kmm) * zdxdy
221        END DO     
222      END DO
223
224      CALL mpp_sum( 'obs_readmdt', zeta1 )
225      CALL mpp_sum( 'obs_readmdt', zeta2 )
226      CALL mpp_sum( 'obs_readmdt', zarea )
227     
228      zcorr_mdt    = zeta1 / zarea
229      zcorr_bcketa = zeta2 / zarea
230
231      !  Define correction term
232
233      zcorr = zcorr_mdt - zcorr_bcketa
234
235      !  Correct spatial mean of the MSSH
236
237      IF( nn_msshc == 1 )   mdt(:,:) = mdt(:,:) - zcorr 
238
239      ! User defined value : 1.6 m for the Rio MDT compared to ORCA2 MDT
240
241      IF( nn_msshc == 2 )   mdt(:,:) = mdt(:,:) - rn_mdtcorr
242
243      IF(lwp) THEN
244         WRITE(numout,*)
245         WRITE(numout,*) ' obs_readmdt : rn_mdtcutoff     = ', rn_mdtcutoff
246         WRITE(numout,*) ' -----------   zcorr_mdt     = ', zcorr_mdt
247         WRITE(numout,*) '               zcorr_bcketa  = ', zcorr_bcketa
248         WRITE(numout,*) '               zcorr         = ', zcorr
249         WRITE(numout,*) '               nn_msshc        = ', nn_msshc
250      ENDIF
251
252      IF ( nn_msshc == 0 ) WRITE(numout,*) '           MSSH correction is not applied'
253      IF ( nn_msshc == 1 ) WRITE(numout,*) '           MSSH correction is applied'
254      IF ( nn_msshc == 2 ) WRITE(numout,*) '           User defined MSSH correction' 
255
256      !
257   END SUBROUTINE obs_offset_mdt
258 
259   !!======================================================================
260END MODULE obs_readmdt
Note: See TracBrowser for help on using the repository browser.