New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zdfiwm.F90 in NEMO/branches/2019/dev_r11943_MERGE_2019/src/OCE/ZDF – NEMO

source: NEMO/branches/2019/dev_r11943_MERGE_2019/src/OCE/ZDF/zdfiwm.F90 @ 11960

Last change on this file since 11960 was 11960, checked in by acc, 4 years ago

Branch 2019/dev_r11943_MERGE_2019. Merge in changes from 2019/dev_r11613_ENHANCE-04_namelists_as_internalfiles. (svn merge -r 11614:11954). Resolved tree conflicts and one actual conflict. Sette tested(these changes alter the ext/AGRIF reference; remember to update). See ticket #2341
  • Property svn:keywords set to Id
File size: 25.7 KB
Line 
1MODULE zdfiwm
2   !!========================================================================
3   !!                       ***  MODULE  zdfiwm  ***
4   !! Ocean physics: Internal gravity wave-driven vertical mixing
5   !!========================================================================
6   !! History :  1.0  !  2004-04  (L. Bessieres, G. Madec)  Original code
7   !!             -   !  2006-08  (A. Koch-Larrouy)  Indonesian strait
8   !!            3.3  !  2010-10  (C. Ethe, G. Madec)  reorganisation of initialisation phase
9   !!            3.6  !  2016-03  (C. de Lavergne)  New param: internal wave-driven mixing
10   !!            4.0  !  2017-04  (G. Madec)  renamed module, remove the old param. and the CPP keys
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   zdf_iwm       : global     momentum & tracer Kz with wave induced Kz
15   !!   zdf_iwm_init  : global     momentum & tracer Kz with wave induced Kz
16   !!----------------------------------------------------------------------
17   USE oce            ! ocean dynamics and tracers variables
18   USE dom_oce        ! ocean space and time domain variables
19   USE zdf_oce        ! ocean vertical physics variables
20   USE zdfddm         ! ocean vertical physics: double diffusive mixing
21   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
22   USE eosbn2         ! ocean equation of state
23   USE phycst         ! physical constants
24   !
25   USE prtctl         ! Print control
26   USE in_out_manager ! I/O manager
27   USE iom            ! I/O Manager
28   USE lib_mpp        ! MPP library
29   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   zdf_iwm        ! called in step module
35   PUBLIC   zdf_iwm_init   ! called in nemogcm module
36
37   !                      !!* Namelist  namzdf_iwm : internal wave-driven mixing *
38   INTEGER ::  nn_zpyc     ! pycnocline-intensified mixing energy proportional to N (=1) or N^2 (=2)
39   LOGICAL ::  ln_mevar    ! variable (=T) or constant (=F) mixing efficiency
40   LOGICAL ::  ln_tsdiff   ! account for differential T/S wave-driven mixing (=T) or not (=F)
41
42   REAL(wp)::  r1_6 = 1._wp / 6._wp
43
44   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   ebot_iwm   ! power available from high-mode wave breaking (W/m2)
45   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   epyc_iwm   ! power available from low-mode, pycnocline-intensified wave breaking (W/m2)
46   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   ecri_iwm   ! power available from low-mode, critical slope wave breaking (W/m2)
47   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   hbot_iwm   ! WKB decay scale for high-mode energy dissipation (m)
48   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   hcri_iwm   ! decay scale for low-mode critical slope dissipation (m)
49
50   !! * Substitutions
51#  include "vectopt_loop_substitute.h90"
52   !!----------------------------------------------------------------------
53   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
54   !! $Id$
55   !! Software governed by the CeCILL license (see ./LICENSE)
56   !!----------------------------------------------------------------------
57CONTAINS
58
59   INTEGER FUNCTION zdf_iwm_alloc()
60      !!----------------------------------------------------------------------
61      !!                ***  FUNCTION zdf_iwm_alloc  ***
62      !!----------------------------------------------------------------------
63      ALLOCATE( ebot_iwm(jpi,jpj),  epyc_iwm(jpi,jpj),  ecri_iwm(jpi,jpj) ,     &
64      &         hbot_iwm(jpi,jpj),  hcri_iwm(jpi,jpj)                     , STAT=zdf_iwm_alloc )
65      !
66      CALL mpp_sum ( 'zdfiwm', zdf_iwm_alloc )
67      IF( zdf_iwm_alloc /= 0 )   CALL ctl_stop( 'STOP', 'zdf_iwm_alloc: failed to allocate arrays' )
68   END FUNCTION zdf_iwm_alloc
69
70
71   SUBROUTINE zdf_iwm( kt, Kmm, p_avm, p_avt, p_avs )
72      !!----------------------------------------------------------------------
73      !!                  ***  ROUTINE zdf_iwm  ***
74      !!                   
75      !! ** Purpose :   add to the vertical mixing coefficients the effect of
76      !!              breaking internal waves.
77      !!
78      !! ** Method  : - internal wave-driven vertical mixing is given by:
79      !!                  Kz_wave = min(  100 cm2/s, f(  Reb = zemx_iwm /( Nu * N^2 )  )
80      !!              where zemx_iwm is the 3D space distribution of the wave-breaking
81      !!              energy and Nu the molecular kinematic viscosity.
82      !!              The function f(Reb) is linear (constant mixing efficiency)
83      !!              if the namelist parameter ln_mevar = F and nonlinear if ln_mevar = T.
84      !!
85      !!              - Compute zemx_iwm, the 3D power density that allows to compute
86      !!              Reb and therefrom the wave-induced vertical diffusivity.
87      !!              This is divided into three components:
88      !!                 1. Bottom-intensified low-mode dissipation at critical slopes
89      !!                     zemx_iwm(z) = ( ecri_iwm / rau0 ) * EXP( -(H-z)/hcri_iwm )
90      !!                                   / ( 1. - EXP( - H/hcri_iwm ) ) * hcri_iwm
91      !!              where hcri_iwm is the characteristic length scale of the bottom
92      !!              intensification, ecri_iwm a map of available power, and H the ocean depth.
93      !!                 2. Pycnocline-intensified low-mode dissipation
94      !!                     zemx_iwm(z) = ( epyc_iwm / rau0 ) * ( sqrt(rn2(z))^nn_zpyc )
95      !!                                   / SUM( sqrt(rn2(z))^nn_zpyc * e3w(z) )
96      !!              where epyc_iwm is a map of available power, and nn_zpyc
97      !!              is the chosen stratification-dependence of the internal wave
98      !!              energy dissipation.
99      !!                 3. WKB-height dependent high mode dissipation
100      !!                     zemx_iwm(z) = ( ebot_iwm / rau0 ) * rn2(z) * EXP(-z_wkb(z)/hbot_iwm)
101      !!                                   / SUM( rn2(z) * EXP(-z_wkb(z)/hbot_iwm) * e3w(z) )
102      !!              where hbot_iwm is the characteristic length scale of the WKB bottom
103      !!              intensification, ebot_iwm is a map of available power, and z_wkb is the
104      !!              WKB-stretched height above bottom defined as
105      !!                    z_wkb(z) = H * SUM( sqrt(rn2(z'>=z)) * e3w(z'>=z) )
106      !!                                 / SUM( sqrt(rn2(z'))    * e3w(z')    )
107      !!
108      !!              - update the model vertical eddy viscosity and diffusivity:
109      !!                     avt  = avt  +    av_wave
110      !!                     avm  = avm  +    av_wave
111      !!
112      !!              - if namelist parameter ln_tsdiff = T, account for differential mixing:
113      !!                     avs  = avt  +    av_wave * diffusivity_ratio(Reb)
114      !!
115      !! ** Action  : - avt, avs, avm, increased by tide internal wave-driven mixing   
116      !!
117      !! References :  de Lavergne et al. 2015, JPO; 2016, in prep.
118      !!----------------------------------------------------------------------
119      INTEGER                    , INTENT(in   ) ::   kt             ! ocean time step
120      INTEGER                    , INTENT(in   ) ::   Kmm            ! time level index
121      REAL(wp), DIMENSION(:,:,:) , INTENT(inout) ::   p_avm          ! momentum Kz (w-points)
122      REAL(wp), DIMENSION(:,:,:) , INTENT(inout) ::   p_avt, p_avs   ! tracer   Kz (w-points)
123      !
124      INTEGER  ::   ji, jj, jk   ! dummy loop indices
125      REAL(wp) ::   zztmp, ztmp1, ztmp2        ! scalar workspace
126      REAL(wp), DIMENSION(jpi,jpj)     ::   zfact       ! Used for vertical structure
127      REAL(wp), DIMENSION(jpi,jpj)     ::   zhdep       ! Ocean depth
128      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zwkb        ! WKB-stretched height above bottom
129      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zweight     ! Weight for high mode vertical distribution
130      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   znu_t       ! Molecular kinematic viscosity (T grid)
131      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   znu_w       ! Molecular kinematic viscosity (W grid)
132      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zReb        ! Turbulence intensity parameter
133      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zemx_iwm    ! local energy density available for mixing (W/kg)
134      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zav_ratio   ! S/T diffusivity ratio (only for ln_tsdiff=T)
135      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zav_wave    ! Internal wave-induced diffusivity
136      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   z3d  ! 3D workspace used for iom_put
137      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::   z2d  ! 2D     -      -    -     -
138      !!----------------------------------------------------------------------
139      !
140      !                       !* Set to zero the 1st and last vertical levels of appropriate variables
141      zemx_iwm (:,:,1) = 0._wp   ;   zemx_iwm (:,:,jpk) = 0._wp
142      zav_ratio(:,:,1) = 0._wp   ;   zav_ratio(:,:,jpk) = 0._wp
143      zav_wave (:,:,1) = 0._wp   ;   zav_wave (:,:,jpk) = 0._wp
144      !
145      !                       ! ----------------------------- !
146      !                       !  Internal wave-driven mixing  !  (compute zav_wave)
147      !                       ! ----------------------------- !
148      !                             
149      !                       !* Critical slope mixing: distribute energy over the time-varying ocean depth,
150      !                                                 using an exponential decay from the seafloor.
151      DO jj = 1, jpj                ! part independent of the level
152         DO ji = 1, jpi
153            zhdep(ji,jj) = gdepw_0(ji,jj,mbkt(ji,jj)+1)       ! depth of the ocean
154            zfact(ji,jj) = rau0 * (  1._wp - EXP( -zhdep(ji,jj) / hcri_iwm(ji,jj) )  )
155            IF( zfact(ji,jj) /= 0._wp )   zfact(ji,jj) = ecri_iwm(ji,jj) / zfact(ji,jj)
156         END DO
157      END DO
158!!gm gde3w ==>>>  check for ssh taken into account.... seem OK gde3w_n=gdept(:,:,:,Kmm) - ssh(:,:,Kmm)
159      DO jk = 2, jpkm1              ! complete with the level-dependent part
160         DO jj = 1, jpj             
161            DO ji = 1, jpi
162               IF ( zfact(ji,jj) == 0._wp .OR. wmask(ji,jj,jk) == 0._wp ) THEN   ! optimization
163                  zemx_iwm(ji,jj,jk) = 0._wp
164               ELSE
165                  zemx_iwm(ji,jj,jk) = zfact(ji,jj) * (  EXP( ( gde3w(ji,jj,jk  ) - zhdep(ji,jj) ) / hcri_iwm(ji,jj) )     &
166                       &                               - EXP( ( gde3w(ji,jj,jk-1) - zhdep(ji,jj) ) / hcri_iwm(ji,jj) ) )   &
167                       &                            / ( gde3w(ji,jj,jk) - gde3w(ji,jj,jk-1) )
168               ENDIF
169            END DO
170         END DO
171!!gm delta(gde3w) = e3t(:,:,:,Kmm)  !!  Please verify the grid-point position w versus t-point
172!!gm it seems to me that only 1/hcri_iwm  is used ==>  compute it one for all
173
174      END DO
175
176      !                        !* Pycnocline-intensified mixing: distribute energy over the time-varying
177      !                        !* ocean depth as proportional to sqrt(rn2)^nn_zpyc
178      !                                          ! (NB: N2 is masked, so no use of wmask here)
179      SELECT CASE ( nn_zpyc )
180      !
181      CASE ( 1 )               ! Dissipation scales as N (recommended)
182         !
183         zfact(:,:) = 0._wp
184         DO jk = 2, jpkm1              ! part independent of the level
185            zfact(:,:) = zfact(:,:) + e3w(:,:,jk,Kmm) * SQRT(  MAX( 0._wp, rn2(:,:,jk) )  ) * wmask(:,:,jk)
186         END DO
187         !
188         DO jj = 1, jpj
189            DO ji = 1, jpi
190               IF( zfact(ji,jj) /= 0 )   zfact(ji,jj) = epyc_iwm(ji,jj) / ( rau0 * zfact(ji,jj) )
191            END DO
192         END DO
193         !
194         DO jk = 2, jpkm1              ! complete with the level-dependent part
195            zemx_iwm(:,:,jk) = zemx_iwm(:,:,jk) + zfact(:,:) * SQRT(  MAX( 0._wp, rn2(:,:,jk) )  ) * wmask(:,:,jk)
196         END DO
197         !
198      CASE ( 2 )               ! Dissipation scales as N^2
199         !
200         zfact(:,:) = 0._wp
201         DO jk = 2, jpkm1              ! part independent of the level
202            zfact(:,:) = zfact(:,:) + e3w(:,:,jk,Kmm) * MAX( 0._wp, rn2(:,:,jk) ) * wmask(:,:,jk)
203         END DO
204         !
205         DO jj= 1, jpj
206            DO ji = 1, jpi
207               IF( zfact(ji,jj) /= 0 )   zfact(ji,jj) = epyc_iwm(ji,jj) / ( rau0 * zfact(ji,jj) )
208            END DO
209         END DO
210         !
211         DO jk = 2, jpkm1              ! complete with the level-dependent part
212            zemx_iwm(:,:,jk) = zemx_iwm(:,:,jk) + zfact(:,:) * MAX( 0._wp, rn2(:,:,jk) ) * wmask(:,:,jk)
213         END DO
214         !
215      END SELECT
216
217      !                        !* WKB-height dependent mixing: distribute energy over the time-varying
218      !                        !* ocean depth as proportional to rn2 * exp(-z_wkb/rn_hbot)
219      !
220      zwkb (:,:,:) = 0._wp
221      zfact(:,:)   = 0._wp
222      DO jk = 2, jpkm1
223         zfact(:,:) = zfact(:,:) + e3w(:,:,jk,Kmm) * SQRT(  MAX( 0._wp, rn2(:,:,jk) )  ) * wmask(:,:,jk)
224         zwkb(:,:,jk) = zfact(:,:)
225      END DO
226!!gm even better:
227!      DO jk = 2, jpkm1
228!         zwkb(:,:) = zwkb(:,:) + e3w(:,:,jk,Kmm) * SQRT(  MAX( 0._wp, rn2(:,:,jk) )  )
229!      END DO
230!      zfact(:,:) = zwkb(:,:,jpkm1)
231!!gm or just use zwkb(k=jpk-1) instead of zfact...
232!!gm
233      !
234      DO jk = 2, jpkm1
235         DO jj = 1, jpj
236            DO ji = 1, jpi
237               IF( zfact(ji,jj) /= 0 )   zwkb(ji,jj,jk) = zhdep(ji,jj) * ( zfact(ji,jj) - zwkb(ji,jj,jk) )   &
238                  &                                     * wmask(ji,jj,jk) / zfact(ji,jj)
239            END DO
240         END DO
241      END DO
242      zwkb(:,:,1) = zhdep(:,:) * wmask(:,:,1)
243      !
244      DO jk = 2, jpkm1
245         DO jj = 1, jpj
246            DO ji = 1, jpi
247               IF ( rn2(ji,jj,jk) <= 0._wp .OR. wmask(ji,jj,jk) == 0._wp ) THEN   ! optimization
248                  zweight(ji,jj,jk) = 0._wp
249               ELSE
250                  zweight(ji,jj,jk) = rn2(ji,jj,jk) * hbot_iwm(ji,jj)    &
251                     &   * (  EXP( -zwkb(ji,jj,jk) / hbot_iwm(ji,jj) ) - EXP( -zwkb(ji,jj,jk-1) / hbot_iwm(ji,jj) )  )
252               ENDIF
253            END DO
254         END DO
255      END DO
256      !
257      zfact(:,:) = 0._wp
258      DO jk = 2, jpkm1              ! part independent of the level
259         zfact(:,:) = zfact(:,:) + zweight(:,:,jk)
260      END DO
261      !
262      DO jj = 1, jpj
263         DO ji = 1, jpi
264            IF( zfact(ji,jj) /= 0 )   zfact(ji,jj) = ebot_iwm(ji,jj) / ( rau0 * zfact(ji,jj) )
265         END DO
266      END DO
267      !
268      DO jk = 2, jpkm1              ! complete with the level-dependent part
269         zemx_iwm(:,:,jk) = zemx_iwm(:,:,jk) + zweight(:,:,jk) * zfact(:,:) * wmask(:,:,jk)   &
270            &                                / ( gde3w(:,:,jk) - gde3w(:,:,jk-1) )
271!!gm  use of e3t(:,:,:,Kmm) just above?
272      END DO
273      !
274!!gm  this is to be replaced by just a constant value znu=1.e-6 m2/s
275      ! Calculate molecular kinematic viscosity
276      znu_t(:,:,:) = 1.e-4_wp * (  17.91_wp - 0.53810_wp * ts(:,:,:,jp_tem,Kmm) + 0.00694_wp * ts(:,:,:,jp_tem,Kmm) * ts(:,:,:,jp_tem,Kmm)  &
277         &                                  + 0.02305_wp * ts(:,:,:,jp_sal,Kmm)  ) * tmask(:,:,:) * r1_rau0
278      DO jk = 2, jpkm1
279         znu_w(:,:,jk) = 0.5_wp * ( znu_t(:,:,jk-1) + znu_t(:,:,jk) ) * wmask(:,:,jk)
280      END DO
281!!gm end
282      !
283      ! Calculate turbulence intensity parameter Reb
284      DO jk = 2, jpkm1
285         zReb(:,:,jk) = zemx_iwm(:,:,jk) / MAX( 1.e-20_wp, znu_w(:,:,jk) * rn2(:,:,jk) )
286      END DO
287      !
288      ! Define internal wave-induced diffusivity
289      DO jk = 2, jpkm1
290         zav_wave(:,:,jk) = znu_w(:,:,jk) * zReb(:,:,jk) * r1_6   ! This corresponds to a constant mixing efficiency of 1/6
291      END DO
292      !
293      IF( ln_mevar ) THEN              ! Variable mixing efficiency case : modify zav_wave in the
294         DO jk = 2, jpkm1              ! energetic (Reb > 480) and buoyancy-controlled (Reb <10.224 ) regimes
295            DO jj = 1, jpj
296               DO ji = 1, jpi
297                  IF( zReb(ji,jj,jk) > 480.00_wp ) THEN
298                     zav_wave(ji,jj,jk) = 3.6515_wp * znu_w(ji,jj,jk) * SQRT( zReb(ji,jj,jk) )
299                  ELSEIF( zReb(ji,jj,jk) < 10.224_wp ) THEN
300                     zav_wave(ji,jj,jk) = 0.052125_wp * znu_w(ji,jj,jk) * zReb(ji,jj,jk) * SQRT( zReb(ji,jj,jk) )
301                  ENDIF
302               END DO
303            END DO
304         END DO
305      ENDIF
306      !
307      DO jk = 2, jpkm1                 ! Bound diffusivity by molecular value and 100 cm2/s
308         zav_wave(:,:,jk) = MIN(  MAX( 1.4e-7_wp, zav_wave(:,:,jk) ), 1.e-2_wp  ) * wmask(:,:,jk)
309      END DO
310      !
311      IF( kt == nit000 ) THEN        !* Control print at first time-step: diagnose the energy consumed by zav_wave
312         zztmp = 0._wp
313!!gm used of glosum 3D....
314         DO jk = 2, jpkm1
315            DO jj = 1, jpj
316               DO ji = 1, jpi
317                  zztmp = zztmp + e3w(ji,jj,jk,Kmm) * e1e2t(ji,jj)   &
318                     &          * MAX( 0._wp, rn2(ji,jj,jk) ) * zav_wave(ji,jj,jk) * wmask(ji,jj,jk) * tmask_i(ji,jj)
319               END DO
320            END DO
321         END DO
322         CALL mpp_sum( 'zdfiwm', zztmp )
323         zztmp = rau0 * zztmp ! Global integral of rauo * Kz * N^2 = power contributing to mixing
324         !
325         IF(lwp) THEN
326            WRITE(numout,*)
327            WRITE(numout,*) 'zdf_iwm : Internal wave-driven mixing (iwm)'
328            WRITE(numout,*) '~~~~~~~ '
329            WRITE(numout,*)
330            WRITE(numout,*) '      Total power consumption by av_wave =  ', zztmp * 1.e-12_wp, 'TW'
331         ENDIF
332      ENDIF
333
334      !                          ! ----------------------- !
335      !                          !   Update  mixing coefs  !                         
336      !                          ! ----------------------- !
337      !     
338      IF( ln_tsdiff ) THEN          !* Option for differential mixing of salinity and temperature
339         ztmp1 = 0.505_wp + 0.495_wp * TANH( 0.92_wp * ( LOG10( 1.e-20_wp ) - 0.60_wp ) )
340         DO jk = 2, jpkm1              ! Calculate S/T diffusivity ratio as a function of Reb
341            DO jj = 1, jpj
342               DO ji = 1, jpi
343                  ztmp2 = zReb(ji,jj,jk) * 5._wp * r1_6
344                  IF ( ztmp2 > 1.e-20_wp .AND. wmask(ji,jj,jk) == 1._wp ) THEN
345                     zav_ratio(ji,jj,jk) = 0.505_wp + 0.495_wp * TANH( 0.92_wp * ( LOG10(ztmp2) - 0.60_wp ) )
346                  ELSE
347                     zav_ratio(ji,jj,jk) = ztmp1 * wmask(ji,jj,jk)
348                  ENDIF
349               END DO
350            END DO
351         END DO
352         CALL iom_put( "av_ratio", zav_ratio )
353         DO jk = 2, jpkm1           !* update momentum & tracer diffusivity with wave-driven mixing
354            p_avs(:,:,jk) = p_avs(:,:,jk) + zav_wave(:,:,jk) * zav_ratio(:,:,jk)
355            p_avt(:,:,jk) = p_avt(:,:,jk) + zav_wave(:,:,jk)
356            p_avm(:,:,jk) = p_avm(:,:,jk) + zav_wave(:,:,jk)
357         END DO
358         !
359      ELSE                          !* update momentum & tracer diffusivity with wave-driven mixing
360         DO jk = 2, jpkm1
361            p_avs(:,:,jk) = p_avs(:,:,jk) + zav_wave(:,:,jk)
362            p_avt(:,:,jk) = p_avt(:,:,jk) + zav_wave(:,:,jk)
363            p_avm(:,:,jk) = p_avm(:,:,jk) + zav_wave(:,:,jk)
364         END DO
365      ENDIF
366
367      !                             !* output internal wave-driven mixing coefficient
368      CALL iom_put( "av_wave", zav_wave )
369                                    !* output useful diagnostics: Kz*N^2 ,
370!!gm Kz*N2 should take into account the ratio avs/avt if it is used.... (see diaar5)
371                                    !  vertical integral of rau0 * Kz * N^2 , energy density (zemx_iwm)
372      IF( iom_use("bflx_iwm") .OR. iom_use("pcmap_iwm") ) THEN
373         ALLOCATE( z2d(jpi,jpj) , z3d(jpi,jpj,jpk) )
374         z3d(:,:,:) = MAX( 0._wp, rn2(:,:,:) ) * zav_wave(:,:,:)
375         z2d(:,:) = 0._wp
376         DO jk = 2, jpkm1
377            z2d(:,:) = z2d(:,:) + e3w(:,:,jk,Kmm) * z3d(:,:,jk) * wmask(:,:,jk)
378         END DO
379         z2d(:,:) = rau0 * z2d(:,:)
380         CALL iom_put( "bflx_iwm", z3d )
381         CALL iom_put( "pcmap_iwm", z2d )
382         DEALLOCATE( z2d , z3d )
383      ENDIF
384      CALL iom_put( "emix_iwm", zemx_iwm )
385     
386      IF(ln_ctl)   CALL prt_ctl(tab3d_1=zav_wave , clinfo1=' iwm - av_wave: ', tab3d_2=avt, clinfo2=' avt: ', kdim=jpk)
387      !
388   END SUBROUTINE zdf_iwm
389
390
391   SUBROUTINE zdf_iwm_init
392      !!----------------------------------------------------------------------
393      !!                  ***  ROUTINE zdf_iwm_init  ***
394      !!                     
395      !! ** Purpose :   Initialization of the wave-driven vertical mixing, reading
396      !!              of input power maps and decay length scales in netcdf files.
397      !!
398      !! ** Method  : - Read the namzdf_iwm namelist and check the parameters
399      !!
400      !!              - Read the input data in NetCDF files :
401      !!              power available from high-mode wave breaking (mixing_power_bot.nc)
402      !!              power available from pycnocline-intensified wave-breaking (mixing_power_pyc.nc)
403      !!              power available from critical slope wave-breaking (mixing_power_cri.nc)
404      !!              WKB decay scale for high-mode wave-breaking (decay_scale_bot.nc)
405      !!              decay scale for critical slope wave-breaking (decay_scale_cri.nc)
406      !!
407      !! ** input   : - Namlist namzdf_iwm
408      !!              - NetCDF files : mixing_power_bot.nc, mixing_power_pyc.nc, mixing_power_cri.nc,
409      !!              decay_scale_bot.nc decay_scale_cri.nc
410      !!
411      !! ** Action  : - Increase by 1 the nstop flag is setting problem encounter
412      !!              - Define ebot_iwm, epyc_iwm, ecri_iwm, hbot_iwm, hcri_iwm
413      !!
414      !! References : de Lavergne et al. JPO, 2015 ; de Lavergne PhD 2016
415      !!              de Lavergne et al. in prep., 2017
416      !!----------------------------------------------------------------------
417      INTEGER  ::   ji, jj, jk   ! dummy loop indices
418      INTEGER  ::   inum         ! local integer
419      INTEGER  ::   ios
420      REAL(wp) ::   zbot, zpyc, zcri   ! local scalars
421      !!
422      NAMELIST/namzdf_iwm/ nn_zpyc, ln_mevar, ln_tsdiff
423      !!----------------------------------------------------------------------
424      !
425      READ  ( numnam_ref, namzdf_iwm, IOSTAT = ios, ERR = 901)
426901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namzdf_iwm in reference namelist' )
427      !
428      READ  ( numnam_cfg, namzdf_iwm, IOSTAT = ios, ERR = 902 )
429902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namzdf_iwm in configuration namelist' )
430      IF(lwm) WRITE ( numond, namzdf_iwm )
431      !
432      IF(lwp) THEN                  ! Control print
433         WRITE(numout,*)
434         WRITE(numout,*) 'zdf_iwm_init : internal wave-driven mixing'
435         WRITE(numout,*) '~~~~~~~~~~~~'
436         WRITE(numout,*) '   Namelist namzdf_iwm : set wave-driven mixing parameters'
437         WRITE(numout,*) '      Pycnocline-intensified diss. scales as N (=1) or N^2 (=2) = ', nn_zpyc
438         WRITE(numout,*) '      Variable (T) or constant (F) mixing efficiency            = ', ln_mevar
439         WRITE(numout,*) '      Differential internal wave-driven mixing (T) or not (F)   = ', ln_tsdiff
440      ENDIF
441     
442      ! The new wave-driven mixing parameterization elevates avt and avm in the interior, and
443      ! ensures that avt remains larger than its molecular value (=1.4e-7). Therefore, avtb should
444      ! be set here to a very small value, and avmb to its (uniform) molecular value (=1.4e-6).
445      avmb(:) = 1.4e-6_wp        ! viscous molecular value
446      avtb(:) = 1.e-10_wp        ! very small diffusive minimum (background avt is specified in zdf_iwm)   
447      avtb_2d(:,:) = 1.e0_wp     ! uniform
448      IF(lwp) THEN                  ! Control print
449         WRITE(numout,*)
450         WRITE(numout,*) '   Force the background value applied to avm & avt in TKE to be everywhere ',   &
451            &               'the viscous molecular value & a very small diffusive value, resp.'
452      ENDIF
453           
454      !                             ! allocate iwm arrays
455      IF( zdf_iwm_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'zdf_iwm_init : unable to allocate iwm arrays' )
456      !
457      !                             ! read necessary fields
458      CALL iom_open('mixing_power_bot',inum)       ! energy flux for high-mode wave breaking [W/m2]
459      CALL iom_get  (inum, jpdom_data, 'field', ebot_iwm, 1 ) 
460      CALL iom_close(inum)
461      !
462      CALL iom_open('mixing_power_pyc',inum)       ! energy flux for pynocline-intensified wave breaking [W/m2]
463      CALL iom_get  (inum, jpdom_data, 'field', epyc_iwm, 1 )
464      CALL iom_close(inum)
465      !
466      CALL iom_open('mixing_power_cri',inum)       ! energy flux for critical slope wave breaking [W/m2]
467      CALL iom_get  (inum, jpdom_data, 'field', ecri_iwm, 1 )
468      CALL iom_close(inum)
469      !
470      CALL iom_open('decay_scale_bot',inum)        ! spatially variable decay scale for high-mode wave breaking [m]
471      CALL iom_get  (inum, jpdom_data, 'field', hbot_iwm, 1 )
472      CALL iom_close(inum)
473      !
474      CALL iom_open('decay_scale_cri',inum)        ! spatially variable decay scale for critical slope wave breaking [m]
475      CALL iom_get  (inum, jpdom_data, 'field', hcri_iwm, 1 )
476      CALL iom_close(inum)
477
478      ebot_iwm(:,:) = ebot_iwm(:,:) * ssmask(:,:)
479      epyc_iwm(:,:) = epyc_iwm(:,:) * ssmask(:,:)
480      ecri_iwm(:,:) = ecri_iwm(:,:) * ssmask(:,:)
481
482      zbot = glob_sum( 'zdfiwm', e1e2t(:,:) * ebot_iwm(:,:) )
483      zpyc = glob_sum( 'zdfiwm', e1e2t(:,:) * epyc_iwm(:,:) )
484      zcri = glob_sum( 'zdfiwm', e1e2t(:,:) * ecri_iwm(:,:) )
485      IF(lwp) THEN
486         WRITE(numout,*) '      High-mode wave-breaking energy:             ', zbot * 1.e-12_wp, 'TW'
487         WRITE(numout,*) '      Pycnocline-intensifed wave-breaking energy: ', zpyc * 1.e-12_wp, 'TW'
488         WRITE(numout,*) '      Critical slope wave-breaking energy:        ', zcri * 1.e-12_wp, 'TW'
489      ENDIF
490      !
491   END SUBROUTINE zdf_iwm_init
492
493   !!======================================================================
494END MODULE zdfiwm
Note: See TracBrowser for help on using the repository browser.