New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

nemogcm.F90 in NEMO/branches/2019/dev_r11943_MERGE_2019/src/OFF – NEMO

Context Navigation

source: NEMO/branches/2019/dev_r11943_MERGE_2019/src/OFF/nemogcm.F90 @ 11949

Last change on this file since 11949 was 11949, checked in by acc, 4 years ago
Merge in changes from 2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps. This just creates a fresh copy of this branch to use as the merge base. See ticket #2341
Property svn:keywords set to `Id`
File size: 29.1 KB

Line
1	MODULE nemogcm
2	!!======================================================================
3	!! * MODULE nemogcm *
4	!! Off-line Ocean : passive tracer evolution, dynamics read in files
5	!!======================================================================
6	!! History : 3.3 ! 2010-05 (C. Ethe) Full reorganization of the off-line: phasing with the on-line
7	!! 3.4 ! 2011-01 (C. Ethe, A. R. Porter, STFC Daresbury) dynamical allocation
8	!! 4.0 ! 2016-10 (C. Ethe, G. Madec, S. Flavoni) domain configuration / user defined interface
9	!! 4.1 ! 2019-08 (A. Coward, D. Storkey) rewrite in preparation for new timestepping scheme
10	!!----------------------------------------------------------------------
11
12	!!----------------------------------------------------------------------
13	!! nemo_gcm : off-line: solve ocean tracer only
14	!! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
15	!! nemo_init : initialization of the NEMO system
16	!! nemo_ctl : initialisation of the contol print
17	!! nemo_closefile: close remaining open files
18	!! nemo_alloc : dynamical allocation
19	!! istate_init : simple initialization to zero of ocean fields
20	!! stp_ctl : reduced step control (no dynamics in off-line)
21	!!----------------------------------------------------------------------
22	USE dom_oce ! ocean space domain variables
23	USE oce ! dynamics and tracers variables
24	USE trc_oce ! Shared ocean/passive tracers variables
25	USE c1d ! 1D configuration
26	USE domain ! domain initialization from coordinate & bathymetry (dom_init routine)
27	USE closea ! treatment of closed seas (for ln_closea)
28	USE usrdef_nam ! user defined configuration
29	USE eosbn2 ! equation of state (eos bn2 routine)
30	! ! ocean physics
31	USE ldftra ! lateral diffusivity setting (ldf_tra_init routine)
32	USE ldfslp ! slopes of neutral surfaces (ldf_slp_init routine)
33	USE traqsr ! solar radiation penetration (tra_qsr_init routine)
34	USE trabbl ! bottom boundary layer (tra_bbl_init routine)
35	USE traldf ! lateral physics (tra_ldf_init routine)
36	USE sbcmod ! surface boundary condition (sbc_init routine)
37	USE phycst ! physical constant (par_cst routine)
38	USE dtadyn ! Lecture and Interpolation of the dynamical fields
39	USE trcini ! Initilization of the passive tracers
40	USE daymod ! calendar (day routine)
41	USE trcstp ! passive tracer time-stepping (trc_stp routine)
42	USE dtadyn ! Lecture and interpolation of the dynamical fields
43	! ! Passive tracers needs
44	USE trc ! passive tracer : variables
45	USE trcnam ! passive tracer : namelist
46	USE trcrst ! passive tracer restart
47	USE diaptr ! Need to initialise this as some variables are used in if statements later
48	USE sbc_oce , ONLY : ln_rnf
49	USE sbcrnf ! surface boundary condition : runoffs
50	! ! I/O & MPP
51	USE iom ! I/O library
52	USE in_out_manager ! I/O manager
53	USE mppini ! shared/distributed memory setting (mpp_init routine)
54	USE lib_mpp ! distributed memory computing
55	#if defined key_iomput
56	USE xios ! xIOserver
57	#endif
58	USE prtctl ! Print control (prt_ctl_init routine)
59	USE timing ! Timing
60	USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
61	USE lbcnfd , ONLY : isendto, nsndto, nfsloop, nfeloop ! Setup of north fold exchanges
62	USE step, ONLY : Nbb, Nnn, Naa, Nrhs ! time level indices
63
64	IMPLICIT NONE
65	PRIVATE
66
67	PUBLIC nemo_gcm ! called by nemo.F90
68
69	CHARACTER (len=64) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing
70
71	!!----------------------------------------------------------------------
72	!! NEMO/OFF 4.0 , NEMO Consortium (2018)
73	!! $Id$
74	!! Software governed by the CeCILL license (see ./LICENSE)
75	!!----------------------------------------------------------------------
76	CONTAINS
77
78	SUBROUTINE nemo_gcm
79	!!----------------------------------------------------------------------
80	!! * ROUTINE nemo_gcm *
81	!!
82	!! ** Purpose : NEMO solves the primitive equations on an orthogonal
83	!! curvilinear mesh on the sphere.
84	!!
85	!! ** Method : - model general initialization
86	!! - launch the time-stepping (dta_dyn and trc_stp)
87	!! - finalize the run by closing files and communications
88	!!
89	!! References : Madec, Delecluse,Imbard, and Levy, 1997: internal report, IPSL.
90	!! Madec, 2008, internal report, IPSL.
91	!!----------------------------------------------------------------------
92	INTEGER :: istp, indic ! time step index
93	!!----------------------------------------------------------------------
94
95	CALL nemo_init ! Initializations
96
97	! check that all process are still there... If some process have an error,
98	! they will never enter in step and other processes will wait until the end of the cpu time!
99	CALL mpp_max( 'nemogcm', nstop )
100
101	! !-----------------------!
102	! !== time stepping ==!
103	! !-----------------------!
104	istp = nit000
105	!
106	IF( ln_rnf ) CALL sbc_rnf(istp) ! runoffs initialization
107	!
108	CALL iom_init( cxios_context ) ! iom_put initialization (must be done after nemo_init for AGRIF+XIOS+OASIS)
109	!
110	DO WHILE ( istp <= nitend .AND. nstop == 0 ) !== OFF time-stepping ==!
111	!
112	IF( istp /= nit000 ) CALL day ( istp ) ! Calendar (day was already called at nit000 in day_init)
113	CALL iom_setkt ( istp - nit000 + 1, cxios_context ) ! say to iom that we are at time step kstp
114	#if defined key_sed_off
115	CALL dta_dyn_sed( istp, Nnn ) ! Interpolation of the dynamical fields
116	#else
117	CALL dta_dyn ( istp, Nbb, Nnn, Naa ) ! Interpolation of the dynamical fields
118	#endif
119	CALL trc_stp ( istp, Nbb, Nnn, Nrhs, Naa ) ! time-stepping
120	#if ! defined key_sed_off
121	IF( .NOT.ln_linssh ) CALL dta_dyn_atf( istp, Nbb, Nnn, Naa ) ! time filter of sea surface height and vertical scale factors
122	#endif
123	! Swap time levels
124	Nrhs = Nbb
125	Nbb = Nnn
126	Nnn = Naa
127	Naa = Nrhs
128	!
129	#if ! defined key_sed_off
130	IF( .NOT.ln_linssh ) CALL dta_dyn_sf_interp( istp, Nnn ) ! calculate now grid parameters
131	#endif
132	CALL stp_ctl ( istp, indic ) ! Time loop: control and print
133	istp = istp + 1
134	END DO
135	!
136	#if defined key_iomput
137	CALL iom_context_finalize( cxios_context ) ! needed for XIOS+AGRIF
138	#endif
139
140	! !------------------------!
141	! !== finalize the run ==!
142	! !------------------------!
143	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
144
145	IF( nstop /= 0 .AND. lwp ) THEN ! error print
146	WRITE(ctmp1,*) ' ==>>> nemo_gcm: a total of ', nstop, ' errors have been found'
147	CALL ctl_stop( ctmp1 )
148	ENDIF
149	!
150	IF( ln_timing ) CALL timing_finalize
151	!
152	CALL nemo_closefile
153	!
154	#if defined key_iomput
155	CALL xios_finalize ! end mpp communications with xios
156	#else
157	IF( lk_mpp ) CALL mppstop ! end mpp communications
158	#endif
159	!
160	IF(lwm) THEN
161	IF( nstop == 0 ) THEN ; STOP 0
162	ELSE ; STOP 123
163	ENDIF
164	ENDIF
165	!
166	END SUBROUTINE nemo_gcm
167
168
169	SUBROUTINE nemo_init
170	!!----------------------------------------------------------------------
171	!! * ROUTINE nemo_init *
172	!!
173	!! ** Purpose : initialization of the nemo model in off-line mode
174	!!----------------------------------------------------------------------
175	INTEGER :: ios, ilocal_comm ! local integers
176	!!
177	NAMELIST/namctl/ ln_ctl , sn_cfctl, nn_print, nn_ictls, nn_ictle, &
178	& nn_isplt , nn_jsplt, nn_jctls, nn_jctle, &
179	& ln_timing, ln_diacfl
180	NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
181	!!----------------------------------------------------------------------
182	!
183	cxios_context = 'nemo'
184	!
185	! !-------------------------------------------------!
186	! ! set communicator & select the local rank !
187	! ! must be done as soon as possible to get narea !
188	! !-------------------------------------------------!
189	!
190	#if defined key_iomput
191	CALL xios_initialize( "for_xios_mpi_id", return_comm=ilocal_comm ) ! nemo local communicator given by xios
192	CALL mpp_start( ilocal_comm )
193	#else
194	CALL mpp_start( )
195	#endif
196	!
197	narea = mpprank + 1 ! mpprank: the rank of proc (0 --> mppsize -1 )
198	lwm = (narea == 1) ! control of output namelists
199	!
200	! !---------------------------------------------------------------!
201	! ! Open output files, reference and configuration namelist files !
202	! !---------------------------------------------------------------!
203	!
204	! open ocean.output as soon as possible to get all output prints (including errors messages)
205	IF( lwm ) CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
206	! open reference and configuration namelist files
207	CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
208	CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
209	IF( lwm ) CALL ctl_opn( numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
210	! open /dev/null file to be able to supress output write easily
211	CALL ctl_opn( numnul, '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
212	!
213	! !--------------------!
214	! ! Open listing units ! -> need ln_ctl from namctl to define lwp
215	! !--------------------!
216	!
217	REWIND( numnam_ref ) ! Namelist namctl in reference namelist
218	READ ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
219	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist' )
220	REWIND( numnam_cfg ) ! Namelist namctl in confguration namelist
221	READ ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
222	902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist' )
223	!
224	lwp = (narea == 1) .OR. ln_ctl ! control of all listing output print
225	!
226	IF(lwp) THEN ! open listing units
227	!
228	IF( .NOT. lwm ) & ! alreay opened for narea == 1
229	& CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE., narea )
230	!
231	WRITE(numout,*)
232	WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - CMCC'
233	WRITE(numout,*) ' NEMO team'
234	WRITE(numout,*) ' Off-line TOP Model'
235	WRITE(numout,*) ' NEMO version 4.0 (2019) '
236	WRITE(numout,*)
237	WRITE(numout,*) " ._ ._ ._ ._ ._ "
238	WRITE(numout,*) " _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ "
239	WRITE(numout,*)
240	WRITE(numout,*) " o _, _, "
241	WRITE(numout,*) " o .' ( .-' / "
242	WRITE(numout,*) " o _/..._'. .' / "
243	WRITE(numout,*) " ( o .-'` ` '-./ _.' "
244	WRITE(numout,*) " ) ( o) ;= <_ ( "
245	WRITE(numout,*) " ( '-.,\\__ __.-;`\ '. ) "
246	WRITE(numout,*) " ) ) \) \|`\ \) '. \ ( ( "
247	WRITE(numout,*) " ( ( \_/ '-._\ ) ) "
248	WRITE(numout,*) " ) ) ` ( ( "
249	WRITE(numout,*) " ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ "
250	WRITE(numout,*)
251	!
252	WRITE(numout,cform_aaa) ! Flag AAAAAAA
253	!
254	ENDIF
255	!
256	! finalize the definition of namctl variables
257	IF( sn_cfctl%l_config ) THEN
258	! Activate finer control of report outputs
259	! optionally switch off output from selected areas (note this only
260	! applies to output which does not involve global communications)
261	IF( ( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax ) .OR. &
262	& ( MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 ) ) &
263	& CALL nemo_set_cfctl( sn_cfctl, .FALSE., .FALSE. )
264	ELSE
265	! Use ln_ctl to turn on or off all options.
266	CALL nemo_set_cfctl( sn_cfctl, ln_ctl, .TRUE. )
267	ENDIF
268	!
269	IF(lwm) WRITE( numond, namctl )
270	!
271	! !------------------------------------!
272	! ! Set global domain size parameters !
273	! !------------------------------------!
274	!
275	REWIND( numnam_ref ) ! Namelist namcfg in reference namelist
276	READ ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
277	903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist' )
278	REWIND( numnam_cfg ) ! Namelist namcfg in confguration namelist
279	READ ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
280	904 IF( ios > 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist' )
281	!
282	IF( ln_read_cfg ) THEN ! Read sizes in domain configuration file
283	CALL domain_cfg ( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
284	ELSE ! user-defined namelist
285	CALL usr_def_nam( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
286	ENDIF
287	!
288	IF(lwm) WRITE( numond, namcfg )
289	l_offline = .true. ! passive tracers are run offline
290	!
291	! !-----------------------------------------!
292	! ! mpp parameters and domain decomposition !
293	! !-----------------------------------------!
294	!
295	CALL mpp_init
296
297	! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
298	CALL nemo_alloc()
299
300	! Initialise time level indices
301	Nbb = 1; Nnn = 2; Naa = 3; Nrhs = Naa
302
303
304	! !-------------------------------!
305	! ! NEMO general initialization !
306	! !-------------------------------!
307
308	CALL nemo_ctl ! Control prints
309	!
310	! ! General initialization
311	IF( ln_timing ) CALL timing_init
312	IF( ln_timing ) CALL timing_start( 'nemo_init')
313	!
314	CALL phy_cst ! Physical constants
315	CALL eos_init ! Equation of state
316	IF( lk_c1d ) CALL c1d_init ! 1D column configuration
317	CALL dom_init( Nbb, Nnn, Naa, "OPA") ! Domain
318	IF( ln_ctl ) CALL prt_ctl_init ! Print control
319
320	CALL istate_init( Nnn, Naa ) ! ocean initial state (Dynamics and tracers)
321
322	CALL sbc_init( Nbb, Nnn, Naa ) ! Forcings : surface module
323
324	! ! Tracer physics
325	CALL ldf_tra_init ! Lateral ocean tracer physics
326	CALL ldf_eiv_init ! Eddy induced velocity param
327	CALL tra_ldf_init ! lateral mixing
328	IF( l_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing
329	IF( ln_traqsr ) CALL tra_qsr_init ! penetrative solar radiation
330	IF( ln_trabbl ) CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme
331
332	! ! Passive tracers
333	CALL trc_nam_run ! Needed to get restart parameters for passive tracers
334	CALL trc_rst_cal( nit000, 'READ' ) ! calendar
335	#if defined key_sed_off
336	CALL dta_dyn_sed_init( Nnn ) ! Initialization for the dynamics
337	#else
338	CALL dta_dyn_init( Nbb, Nnn, Naa ) ! Initialization for the dynamics
339	#endif
340
341	CALL trc_init( Nbb, Nnn, Naa ) ! Passive tracers initialization
342	CALL dia_ptr_init ! Poleward TRansports initialization
343
344	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
345	!
346	IF( ln_timing ) CALL timing_stop( 'nemo_init')
347	!
348	END SUBROUTINE nemo_init
349
350
351	SUBROUTINE nemo_ctl
352	!!----------------------------------------------------------------------
353	!! * ROUTINE nemo_ctl *
354	!!
355	!! ** Purpose : control print setting
356	!!
357	!! ** Method : - print namctl information and check some consistencies
358	!!----------------------------------------------------------------------
359	!
360	IF(lwp) THEN ! control print
361	WRITE(numout,*)
362	WRITE(numout,*) 'nemo_ctl: Control prints'
363	WRITE(numout,*) '~~~~~~~~'
364	WRITE(numout,*) ' Namelist namctl'
365	WRITE(numout,*) ' run control (for debugging) ln_ctl = ', ln_ctl
366	WRITE(numout,*) ' finer control over o/p sn_cfctl%l_config = ', sn_cfctl%l_config
367	WRITE(numout,*) ' sn_cfctl%l_runstat = ', sn_cfctl%l_runstat
368	WRITE(numout,*) ' sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat
369	WRITE(numout,*) ' sn_cfctl%l_oceout = ', sn_cfctl%l_oceout
370	WRITE(numout,*) ' sn_cfctl%l_layout = ', sn_cfctl%l_layout
371	WRITE(numout,*) ' sn_cfctl%l_mppout = ', sn_cfctl%l_mppout
372	WRITE(numout,*) ' sn_cfctl%l_mpptop = ', sn_cfctl%l_mpptop
373	WRITE(numout,*) ' sn_cfctl%procmin = ', sn_cfctl%procmin
374	WRITE(numout,*) ' sn_cfctl%procmax = ', sn_cfctl%procmax
375	WRITE(numout,*) ' sn_cfctl%procincr = ', sn_cfctl%procincr
376	WRITE(numout,*) ' sn_cfctl%ptimincr = ', sn_cfctl%ptimincr
377	WRITE(numout,*) ' level of print nn_print = ', nn_print
378	WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls
379	WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle
380	WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls
381	WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle
382	WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt
383	WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt
384	WRITE(numout,*) ' timing by routine ln_timing = ', ln_timing
385	WRITE(numout,*) ' CFL diagnostics ln_diacfl = ', ln_diacfl
386	ENDIF
387	!
388	nprint = nn_print ! convert DOCTOR namelist names into OLD names
389	nictls = nn_ictls
390	nictle = nn_ictle
391	njctls = nn_jctls
392	njctle = nn_jctle
393	isplt = nn_isplt
394	jsplt = nn_jsplt
395
396	IF(lwp) THEN ! control print
397	WRITE(numout,*)
398	WRITE(numout,*) ' Namelist namcfg'
399	WRITE(numout,*) ' read domain configuration file ln_read_cfg = ', ln_read_cfg
400	WRITE(numout,*) ' filename to be read cn_domcfg = ', TRIM(cn_domcfg)
401	WRITE(numout,*) ' keep closed seas in the domain (if exist) ln_closea = ', ln_closea
402	WRITE(numout,*) ' create a configuration definition file ln_write_cfg = ', ln_write_cfg
403	WRITE(numout,*) ' filename to be written cn_domcfg_out = ', TRIM(cn_domcfg_out)
404	WRITE(numout,*) ' use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr
405	ENDIF
406	IF( .NOT.ln_read_cfg ) ln_closea = .false. ! dealing possible only with a domcfg file
407	!
408	! ! Parameter control
409	!
410	IF( ln_ctl ) THEN ! sub-domain area indices for the control prints
411	IF( lk_mpp .AND. jpnij > 1 ) THEN
412	isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real split domain
413	ELSE
414	IF( isplt == 1 .AND. jsplt == 1 ) THEN
415	CALL ctl_warn( ' - isplt & jsplt are equal to 1', &
416	& ' - the print control will be done over the whole domain' )
417	ENDIF
418	ijsplt = isplt * jsplt ! total number of processors ijsplt
419	ENDIF
420	IF(lwp) WRITE(numout,*)' - The total number of processors over which the'
421	IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt
422	!
423	! ! indices used for the SUM control
424	IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area
425	lsp_area = .FALSE.
426	ELSE ! print control done over a specific area
427	lsp_area = .TRUE.
428	IF( nictls < 1 .OR. nictls > jpiglo ) THEN
429	CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
430	nictls = 1
431	ENDIF
432	IF( nictle < 1 .OR. nictle > jpiglo ) THEN
433	CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
434	nictle = jpiglo
435	ENDIF
436	IF( njctls < 1 .OR. njctls > jpjglo ) THEN
437	CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
438	njctls = 1
439	ENDIF
440	IF( njctle < 1 .OR. njctle > jpjglo ) THEN
441	CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
442	njctle = jpjglo
443	ENDIF
444	ENDIF
445	ENDIF
446	!
447	IF( 1._wp /= SIGN(1._wp,-0._wp) ) CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.', &
448	& 'Compile with key_nosignedzero enabled' )
449	!
450	END SUBROUTINE nemo_ctl
451
452
453	SUBROUTINE nemo_closefile
454	!!----------------------------------------------------------------------
455	!! * ROUTINE nemo_closefile *
456	!!
457	!! ** Purpose : Close the files
458	!!----------------------------------------------------------------------
459	!
460	IF( lk_mpp ) CALL mppsync
461	!
462	CALL iom_close ! close all input/output files managed by iom_*
463	!
464	IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file
465	IF( numnam_ref /= -1 ) CLOSE( numnam_ref ) ! oce reference namelist
466	IF( numnam_cfg /= -1 ) CLOSE( numnam_cfg ) ! oce configuration namelist
467	IF( numout /= 6 ) CLOSE( numout ) ! standard model output file
468	IF( lwm.AND.numond /= -1 ) CLOSE( numond ) ! oce output namelist
469	!
470	numout = 6 ! redefine numout in case it is used after this point...
471	!
472	END SUBROUTINE nemo_closefile
473
474
475	SUBROUTINE nemo_alloc
476	!!----------------------------------------------------------------------
477	!! * ROUTINE nemo_alloc *
478	!!
479	!! ** Purpose : Allocate all the dynamic arrays of the OPA modules
480	!!
481	!! ** Method :
482	!!----------------------------------------------------------------------
483	USE diawri , ONLY : dia_wri_alloc
484	USE dom_oce, ONLY : dom_oce_alloc
485	USE zdf_oce, ONLY : zdf_oce_alloc
486	USE trc_oce, ONLY : trc_oce_alloc
487	!
488	INTEGER :: ierr
489	!!----------------------------------------------------------------------
490	!
491	ierr = oce_alloc () ! ocean
492	ierr = ierr + dia_wri_alloc()
493	ierr = ierr + dom_oce_alloc() ! ocean domain
494	ierr = ierr + zdf_oce_alloc() ! ocean vertical physics
495	ierr = ierr + trc_oce_alloc() ! shared TRC / TRA arrays
496	!
497	CALL mpp_sum( 'nemogcm', ierr )
498	IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
499	!
500	END SUBROUTINE nemo_alloc
501
502	SUBROUTINE nemo_set_cfctl(sn_cfctl, setto, for_all )
503	!!----------------------------------------------------------------------
504	!! * ROUTINE nemo_set_cfctl *
505	!!
506	!! ** Purpose : Set elements of the output control structure to setto.
507	!! for_all should be .false. unless all areas are to be
508	!! treated identically.
509	!!
510	!! ** Method : Note this routine can be used to switch on/off some
511	!! types of output for selected areas but any output types
512	!! that involve global communications (e.g. mpp_max, glob_sum)
513	!! should be protected from selective switching by the
514	!! for_all argument
515	!!----------------------------------------------------------------------
516	LOGICAL :: setto, for_all
517	TYPE(sn_ctl) :: sn_cfctl
518	!!----------------------------------------------------------------------
519	IF( for_all ) THEN
520	sn_cfctl%l_runstat = setto
521	sn_cfctl%l_trcstat = setto
522	ENDIF
523	sn_cfctl%l_oceout = setto
524	sn_cfctl%l_layout = setto
525	sn_cfctl%l_mppout = setto
526	sn_cfctl%l_mpptop = setto
527	END SUBROUTINE nemo_set_cfctl
528
529	SUBROUTINE istate_init( Kmm, Kaa )
530	!!----------------------------------------------------------------------
531	!! * ROUTINE istate_init *
532	!!
533	!! ** Purpose : Initialization to zero of the dynamics and tracers.
534	!!----------------------------------------------------------------------
535	INTEGER, INTENT(in) :: Kmm, Kaa ! ocean time level indices
536	!
537	! now fields ! after fields !
538	uu (:,:,:,Kmm) = 0._wp ; uu(:,:,:,Kaa) = 0._wp !
539	vv (:,:,:,Kmm) = 0._wp ; vv(:,:,:,Kaa) = 0._wp !
540	ww (:,:,:) = 0._wp ! !
541	hdiv (:,:,:) = 0._wp ! !
542	ts (:,:,:,:,Kmm) = 0._wp ! !
543	!
544	rhd (:,:,:) = 0.e0
545	rhop (:,:,:) = 0.e0
546	rn2 (:,:,:) = 0.e0
547	!
548	END SUBROUTINE istate_init
549
550
551	SUBROUTINE stp_ctl( kt, kindic )
552	!!----------------------------------------------------------------------
553	!! * ROUTINE stp_ctl *
554	!!
555	!! ** Purpose : Control the run
556	!!
557	!! ** Method : - Save the time step in numstp
558	!!
559	!! ** Actions : 'time.step' file containing the last ocean time-step
560	!!----------------------------------------------------------------------
561	INTEGER, INTENT(in ) :: kt ! ocean time-step index
562	INTEGER, INTENT(inout) :: kindic ! indicator of solver convergence
563	!!----------------------------------------------------------------------
564	!
565	IF( kt == nit000 .AND. lwm ) THEN
566	WRITE(numout,*)
567	WRITE(numout,*) 'stp_ctl : time-stepping control'
568	WRITE(numout,*) '~~~~~~~'
569	! open time.step file
570	CALL ctl_opn( numstp, 'time.step', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
571	ENDIF
572	!
573	IF(lwm) WRITE ( numstp, '(1x, i8)' ) kt !* save the current time step in numstp
574	IF(lwm) REWIND( numstp ) ! --------------------------
575	!
576	END SUBROUTINE stp_ctl
577	!!======================================================================
578	END MODULE nemogcm

Note: See TracBrowser for help on using the repository browser.

Download in other formats: